qcsrc/server/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SEEKER, w_seeker, IT_ROCKETS, 8, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "seeker", "seeker", _("T.A.G. Seeker"))
   3 #else
   4 #ifdef SVQC
   5 //.float proxytime; = autoswitch
   6 //.float tl; = wait
   7 .entity tag_target, wps_tag_tracker;
   8 .float tag_time;
   9
  10 // ============================
  11 // Begin: Missile functions, these are general functions to be manipulated by other code
  12 // ============================
  13 void Seeker_Missile_Explode ()
  14 {
  15         self.event_damage = SUB_Null;
  16         RadiusDamage (self, self.realowner, autocvar_g_balance_seeker_missile_damage, autocvar_g_balance_seeker_missile_edgedamage, autocvar_g_balance_seeker_missile_radius, world, autocvar_g_balance_seeker_missile_force, self.projectiledeathtype, other);
  17
  18         remove (self);
  19 }
  20
  21 void Seeker_Missile_Touch()
  22 {
  23         PROJECTILE_TOUCH;
  24
  25         Seeker_Missile_Explode();
  26 }
  27
  28 void Seeker_Missile_Think()
  29 {
  30         entity e;
  31         vector desireddir, olddir, newdir, eorg;
  32         float turnrate;
  33         float dist;
  34         float spd;
  35
  36         if (time > self.cnt)
  37         {
  38                 self.projectiledeathtype |= HITTYPE_SPLASH;
  39                 Seeker_Missile_Explode();
  40         }
  41
  42         spd = vlen(self.velocity);
  43         spd = bound(
  44                 spd - autocvar_g_balance_seeker_missile_decel * frametime,
  45                 autocvar_g_balance_seeker_missile_speed_max,
  46                 spd + autocvar_g_balance_seeker_missile_accel * frametime
  47         );
  48
  49         if (self.enemy != world)
  50                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
  51                         self.enemy = world;
  52
  53         if (self.enemy != world)
  54         {
  55                 e               = self.enemy;
  56                 eorg            = 0.5 * (e.absmin + e.absmax);
  57                 turnrate        = autocvar_g_balance_seeker_missile_turnrate; // how fast to turn
  58                 desireddir      = normalize(eorg - self.origin);
  59                 olddir          = normalize(self.velocity); // get my current direction
  60                 dist            = vlen(eorg - self.origin);
  61
  62                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
  63                 if (autocvar_g_balance_seeker_missile_smart && (dist > autocvar_g_balance_seeker_missile_smart_mindist))
  64                 {
  65                         // Is it a better idea (shorter distance) to trace to the target itself?
  66                         if ( vlen(self.origin + olddir * self.wait) < dist)
  67                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
  68                         else
  69                                 traceline(self.origin, eorg, FALSE, self);
  70
  71                         // Setup adaptive tracelength
  72                         self.wait = bound(autocvar_g_balance_seeker_missile_smart_trace_min, vlen(self.origin - trace_endpos), self.wait = autocvar_g_balance_seeker_missile_smart_trace_max);
  73
  74                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
  75                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
  76                 }
  77
  78                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
  79                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
  80         }
  81
  82         // Proxy
  83         if (autocvar_g_balance_seeker_missile_proxy)
  84         {
  85                 if ( dist <= autocvar_g_balance_seeker_missile_proxy_maxrange)
  86                 {
  87                         if (self.autoswitch == 0)
  88                         {
  89                                 self.autoswitch = time + autocvar_g_balance_seeker_missile_proxy_delay;
  90                         }
  91                         else
  92                         {
  93                                 if (self.autoswitch <= time)
  94                                 {
  95                                         Seeker_Missile_Explode();
  96                                         self.autoswitch = 0;
  97                                 }
  98                         }
  99                 }
 100                 else
 101                 {
 102                         if (self.autoswitch != 0)
 103                                 self.autoswitch = 0;
 104                 }
 105         }
 106         ///////////////
 107
 108         if (self.enemy.deadflag != DEAD_NO)
 109         {
 110                 self.enemy = world;
 111                 self.cnt = time + 1 + (random() * 4);
 112                 self.nextthink = self.cnt;
 113                 return;
 114         }
 115
 116         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 117         self.nextthink = time;// + 0.05; // csqc projectiles
 118         UpdateCSQCProjectile(self);
 119 }
 120
 121
 122
 123 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 124 {
 125         if (self.health <= 0)
 126                 return;
 127
 128         if (self.realowner == attacker)
 129                 self.health = self.health - (damage * 0.25);
 130         else
 131                 self.health = self.health - damage;
 132
 133         if (self.health <= 0)
 134                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 135 }
 136
 137 /*
 138 void Seeker_Missile_Animate()
 139 {
 140         self.frame = self.frame +1;
 141         self.nextthink = time + 0.05;
 142
 143         if (self.enemy != world)
 144                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 145                         self.enemy = world;
 146
 147         if(self.frame == 5)
 148         {
 149                 self.think           = Seeker_Missile_Think;
 150                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 151
 152                 if (autocvar_g_balance_seeker_missile_proxy)
 153                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 154                 else
 155                         self.movetype    = MOVETYPE_FLYMISSILE;
 156         }
 157
 158         UpdateCSQCProjectile(self);
 159 }
 160 */
 161
 162 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 163 {
 164         local entity missile;
 165
 166         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_reload_ammo);
 167
 168         makevectors(self.v_angle);
 169         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 170         w_shotorg += f_diff;
 171         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 172
 173         //self.detornator         = FALSE;
 174
 175         missile                 = spawn();
 176         missile.owner           = missile.realowner = self;
 177         missile.classname       = "seeker_missile";
 178         missile.bot_dodge       = TRUE;
 179         missile.bot_dodgerating = autocvar_g_balance_seeker_missile_damage;
 180
 181         missile.think           = Seeker_Missile_Think;
 182         missile.touch           = Seeker_Missile_Touch;
 183         missile.event_damage    = Seeker_Missile_Damage;
 184         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 185         missile.cnt             = time + autocvar_g_balance_seeker_missile_lifetime;
 186         missile.enemy           = m_target;
 187         missile.solid           = SOLID_BBOX;
 188         missile.scale           = 2;
 189         missile.takedamage      = DAMAGE_YES;
 190         missile.health          = autocvar_g_balance_seeker_missile_health;
 191         missile.damageforcescale = autocvar_g_balance_seeker_missile_damageforcescale;
 192         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 193
 194         if (missile.enemy != world)
 195                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 196         else
 197                 missile.projectiledeathtype = WEP_SEEKER;
 198
 199
 200         setorigin (missile, w_shotorg);
 201         setsize (missile, '-4 -4 -4', '4 4 4');
 202         missile.movetype    = MOVETYPE_FLYMISSILE;
 203         missile.flags       = FL_PROJECTILE;
 204         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_missile);
 205
 206         missile.angles = vectoangles (missile.velocity);
 207
 208         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 209
 210         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 211 }
 212
 213 // ============================
 214 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 215 // ============================
 216 void Seeker_Flac_Explode ()
 217 {
 218         self.event_damage = SUB_Null;
 219
 220         RadiusDamage (self, self.realowner, autocvar_g_balance_seeker_flac_damage, autocvar_g_balance_seeker_flac_edgedamage, autocvar_g_balance_seeker_flac_radius, world, autocvar_g_balance_seeker_flac_force, self.projectiledeathtype, other);
 221
 222         remove (self);
 223 }
 224
 225 void Seeker_Flac_Touch()
 226 {
 227         PROJECTILE_TOUCH;
 228
 229         Seeker_Flac_Explode();
 230 }
 231
 232 void Seeker_Fire_Flac()
 233 {
 234         local entity missile;
 235         vector f_diff;
 236         float c;
 237
 238         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_flac_ammo, autocvar_g_balance_seeker_reload_ammo);
 239
 240         c = mod(self.bulletcounter, 4);
 241         switch(c)
 242         {
 243                 case 0:
 244                         f_diff = '-1.25 -3.75 0';
 245                         break;
 246                 case 1:
 247                         f_diff = '+1.25 -3.75 0';
 248                         break;
 249                 case 2:
 250                         f_diff = '-1.25 +3.75 0';
 251                         break;
 252                 case 3:
 253                 default:
 254                         f_diff = '+1.25 +3.75 0';
 255                         break;
 256         }
 257         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, autocvar_g_balance_seeker_flac_damage);
 258         w_shotorg += f_diff;
 259
 260         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 261
 262         missile                                 = spawn ();
 263         missile.owner                   = missile.realowner = self;
 264         missile.classname               = "missile";
 265         missile.bot_dodge               = TRUE;
 266         missile.bot_dodgerating = autocvar_g_balance_seeker_flac_damage;
 267         missile.touch                   = Seeker_Flac_Explode;
 268         missile.use                     = Seeker_Flac_Explode;
 269         missile.think                   = adaptor_think2use_hittype_splash;
 270         missile.nextthink               = time + autocvar_g_balance_seeker_flac_lifetime + autocvar_g_balance_seeker_flac_lifetime_rand;
 271         missile.solid                   = SOLID_BBOX;
 272         missile.movetype                = MOVETYPE_FLY;
 273         missile.projectiledeathtype = WEP_SEEKER;
 274         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 275         missile.flags                           = FL_PROJECTILE;
 276
 277         // csqc projectiles
 278         //missile.angles                                = vectoangles (missile.velocity);
 279         //missile.scale = 0.4; // BUG: the model is too big
 280
 281         setorigin (missile, w_shotorg);
 282         setsize (missile, '-2 -2 -2', '2 2 2');
 283
 284         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_flac);
 285         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 286
 287         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 288 }
 289
 290 // ============================
 291 // Begin: Tag and rocket controllers
 292 // ============================
 293 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 294 {
 295         entity tag;
 296         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 297                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 298                         return tag;
 299
 300         return world;
 301 }
 302
 303 void Seeker_Attack()
 304 {
 305         entity tracker, closest_target;
 306
 307         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 308         {
 309                 if (closest_target)
 310                 {
 311                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 312                                 closest_target = tracker.tag_target;
 313                 }
 314                 else
 315                         closest_target = tracker.tag_target;
 316         }
 317
 318         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 319         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 320                 closest_target = world;
 321
 322         Seeker_Fire_Missile('0 0 0', closest_target);
 323 }
 324
 325 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 326 {
 327         float c;
 328         entity oldself,oldenemy;
 329         self.cnt = self.cnt - 1;
 330
 331         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < autocvar_g_balance_seeker_missile_ammo) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 332         {
 333                 remove(self);
 334                 return;
 335         }
 336
 337         self.nextthink = time + autocvar_g_balance_seeker_missile_delay * W_WeaponRateFactor();
 338
 339         oldself = self;
 340         self = self.realowner;
 341
 342         oldenemy = self.enemy;
 343         self.enemy = oldself.enemy;
 344
 345         c = mod(self.cnt, 4);
 346         switch(c)
 347         {
 348                 case 0:
 349                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 350                         break;
 351                 case 1:
 352                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 353                         break;
 354                 case 2:
 355                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 356                         break;
 357                 case 3:
 358                 default:
 359                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 360                         break;
 361         }
 362
 363         self.enemy = oldenemy;
 364         self = oldself;
 365 }
 366
 367 void Seeker_Tracker_Think()
 368 {
 369         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 370         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 371         || (time > self.tag_time + autocvar_g_balance_seeker_tag_tracker_lifetime))
 372         {
 373                 if (self)
 374                 {
 375                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 376                         remove(self);
 377                 }
 378                 return;
 379         }
 380
 381         // Update the think method information
 382         self.nextthink = time;
 383 }
 384
 385 // ============================
 386 // Begin: Tag projectile
 387 // ============================
 388 void Seeker_Tag_Explode ()
 389 {
 390         //if(other==self.realowner)
 391         //    return;
 392         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, self);
 393
 394         remove (self);
 395 }
 396
 397 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 398 {
 399         if (self.health <= 0)
 400                 return;
 401         self.health = self.health - damage;
 402         if (self.health <= 0)
 403                 Seeker_Tag_Explode();
 404 }
 405
 406 void Seeker_Tag_Touch()
 407 {
 408         vector dir;
 409         vector org2;
 410         entity e;
 411
 412         dir     = normalize (self.realowner.origin - self.origin);
 413         org2    = findbetterlocation (self.origin, 8);
 414
 415         te_knightspike(org2);
 416
 417         self.event_damage = SUB_Null;
 418         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_HEADSHOT, self);
 419
 420         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 421         {
 422                 // check to see if this person is already tagged by me
 423                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 424
 425                 if (tag != world)
 426                 {
 427                         if (other.wps_tag_tracker && (autocvar_g_balance_seeker_type == 1)) // don't attach another waypointsprite without killing the old one first
 428                                 WaypointSprite_Kill(other.wps_tag_tracker);
 429
 430                         tag.tag_time = time;
 431                 }
 432                 else
 433                 {
 434                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 435                         e             = spawn();
 436                         e.cnt         = autocvar_g_balance_seeker_missile_count;
 437                         e.classname   = "tag_tracker";
 438                         e.owner       = self.owner;
 439                         e.realowner   = self.realowner;
 440
 441                         if      (autocvar_g_balance_seeker_type == 1)
 442                         {
 443                                 e.tag_target  = other;
 444                                 e.tag_time    = time;
 445                                 e.think       = Seeker_Tracker_Think;
 446                         }
 447                         else
 448                         {
 449                                 e.enemy     = other;
 450                                 e.think     = Seeker_Vollycontroller_Think;
 451                         }
 452
 453                         e.nextthink   = time;
 454                 }
 455
 456                 if      (autocvar_g_balance_seeker_type == 1)
 457                 {
 458                         WaypointSprite_Spawn("tagged-target", autocvar_g_balance_seeker_tag_tracker_lifetime, 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 459                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 460                 }
 461         }
 462
 463         remove(self);
 464         return;
 465 }
 466
 467 void Seeker_Fire_Tag()
 468 {
 469         local entity missile;
 470         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_tag_ammo, autocvar_g_balance_seeker_reload_ammo);
 471
 472         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, autocvar_g_balance_seeker_missile_damage * autocvar_g_balance_seeker_missile_count);
 473
 474         missile                 = spawn();
 475         missile.owner           = missile.realowner = self;
 476         missile.classname       = "seeker_tag";
 477         missile.bot_dodge       = TRUE;
 478         missile.bot_dodgerating = 50;
 479         missile.touch           = Seeker_Tag_Touch;
 480         missile.think           = SUB_Remove;
 481         missile.nextthink       = time + autocvar_g_balance_seeker_tag_lifetime;
 482         missile.movetype        = MOVETYPE_FLY;
 483         missile.solid           = SOLID_BBOX;
 484
 485         missile.takedamage       = DAMAGE_YES;
 486         missile.event_damage    = Seeker_Tag_Explode;
 487         missile.health          = autocvar_g_balance_seeker_tag_health;
 488         missile.damageforcescale = autocvar_g_balance_seeker_tag_damageforcescale;
 489
 490         setorigin (missile, w_shotorg);
 491         setsize (missile, '-2 -2 -2', '2 2 2');
 492
 493         missile.flags       = FL_PROJECTILE;
 494
 495         missile.movetype    = MOVETYPE_FLY;
 496         W_SETUPPROJECTILEVELOCITY(missile, g_balance_seeker_tag);
 497         missile.angles = vectoangles (missile.velocity);
 498
 499         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 500
 501         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 502 }
 503
 504 // ============================
 505 // Begin: Genereal weapon functions
 506 // ============================
 507 void spawnfunc_weapon_seeker (void)
 508 {
 509         weapon_defaultspawnfunc(WEP_SEEKER);
 510 }
 511
 512 float w_seeker(float req)
 513 {
 514         float ammo_amount;
 515
 516         if (req == WR_AIM)
 517         {
 518                 if (autocvar_g_balance_seeker_type == 1)
 519                         if (Seeker_Tagged_Info(self, self.enemy) != world)
 520                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_seeker_missile_speed_max, 0, autocvar_g_balance_seeker_missile_lifetime, FALSE);
 521                         else
 522                                 self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_seeker_tag_speed, 0, autocvar_g_balance_seeker_tag_lifetime, FALSE);
 523                 else
 524                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_seeker_tag_speed, 0, autocvar_g_balance_seeker_tag_lifetime, FALSE);
 525         }
 526         else if (req == WR_THINK)
 527         {
 528                 if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_tag_ammo)) // forced reload
 529                         weapon_action(self.weapon, WR_RELOAD);
 530
 531                 else if (self.BUTTON_ATCK)
 532                 {
 533                         if (autocvar_g_balance_seeker_type == 1)
 534                         {
 535                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_missile_refire))
 536                                 {
 537                                         Seeker_Attack();
 538                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_missile_animtime, w_ready);
 539                                 }
 540                         }
 541                         else
 542                         {
 543                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_tag_refire))
 544                                 {
 545                                         Seeker_Fire_Tag();
 546                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_tag_animtime, w_ready);
 547                                 }
 548                         }
 549                 }
 550
 551                 else if (self.BUTTON_ATCK2)
 552                 {
 553                         if (autocvar_g_balance_seeker_type == 1)
 554                         {
 555                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_tag_refire))
 556                                 {
 557                                         Seeker_Fire_Tag();
 558                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_tag_animtime, w_ready);
 559                                 }
 560                         }
 561                         else
 562                         {
 563                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_flac_refire))
 564                                 {
 565                                         Seeker_Fire_Flac();
 566                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_flac_animtime, w_ready);
 567                                 }
 568                         }
 569                 }
 570         }
 571         else if (req == WR_PRECACHE)
 572         {
 573                 precache_model ("models/weapons/g_seeker.md3");
 574                 precache_model ("models/weapons/v_seeker.md3");
 575                 precache_model ("models/weapons/h_seeker.iqm");
 576                 precache_sound ("weapons/tag_fire.wav");
 577                 precache_sound ("weapons/flac_fire.wav");
 578                 precache_sound ("weapons/seeker_fire.wav");
 579                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 580         }
 581         else if (req == WR_SETUP)
 582         {
 583                 weapon_setup(WEP_SEEKER);
 584                 self.current_ammo = ammo_rockets;
 585         }
 586         else if (req == WR_CHECKAMMO1)
 587         {
 588                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_seeker_missile_ammo;
 589                 ammo_amount += self.weapon_load[WEP_SEEKER] >= autocvar_g_balance_seeker_missile_ammo;
 590                 return ammo_amount;
 591         }
 592         else if (req == WR_CHECKAMMO2)
 593         {
 594                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_seeker_tag_ammo;
 595                 ammo_amount += self.weapon_load[WEP_SEEKER] >= autocvar_g_balance_seeker_tag_ammo;
 596                 return ammo_amount;
 597         }
 598         else if (req == WR_RELOAD)
 599         {
 600                 W_Reload(min(autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_tag_ammo), autocvar_g_balance_seeker_reload_ammo, autocvar_g_balance_seeker_reload_time, "weapons/reload.wav");
 601         }
 602         return TRUE;
 603 };
 604 #endif
 605 #ifdef CSQC
 606 float w_seeker(float req)
 607 {
 608         if(req == WR_IMPACTEFFECT)
 609         {
 610                 vector org2;
 611                 org2 = w_org + w_backoff * 6;
 612                 if(w_deathtype & HITTYPE_BOUNCE)
 613                 {
 614                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 615                         if(!w_issilent)
 616                         {
 617                                 if (w_random<0.15)
 618                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTN_NORM);
 619                                 else if (w_random<0.7)
 620                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTN_NORM);
 621                                 else
 622                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTN_NORM);
 623                         }
 624                 }
 625                 else if(w_deathtype & HITTYPE_HEADSHOT)
 626                 {
 627                         if(!w_issilent)
 628                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTN_NORM);
 629                 }
 630                 else
 631                 {
 632                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 633                         if(!w_issilent)
 634                         {
 635                                 if (w_random<0.15)
 636                                         sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTN_NORM);
 637                                 else if (w_random<0.7)
 638                                         sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTN_NORM);
 639                                 else
 640                                         sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTN_NORM);
 641                         }
 642                 }
 643         }
 644         else if(req == WR_PRECACHE)
 645         {
 646                 precache_sound("weapons/seekerexp1.wav");
 647                 precache_sound("weapons/seekerexp2.wav");
 648                 precache_sound("weapons/seekerexp3.wav");
 649                 precache_sound("weapons/tagexp1.wav");
 650                 precache_sound("weapons/tagexp2.wav");
 651                 precache_sound("weapons/tagexp3.wav");
 652                 precache_sound("weapons/tag_impact.wav");
 653         }
 654         else if (req == WR_SUICIDEMESSAGE)
 655                 w_deathtypestring = _("%s played with tiny rockets");
 656         else if (req == WR_KILLMESSAGE)
 657         {
 658                 if(w_deathtype & HITTYPE_SECONDARY)
 659                         w_deathtypestring = _("%s was tagged by %s");
 660                 else
 661                         w_deathtypestring = _("%s was pummeled by %s");
 662         }
 663         return TRUE;
 664 }
 665 #endif
 666 #endif