qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set ammo counter to the weapon we have switched to
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.ammo_counter = 0; // also keeps the crosshair ammo from displaying
  13         else
  14                 self.ammo_counter = self.shotgun_load;
  15 }
  16
  17 void W_Shotgun_ReloadedAndReady()
  18 {
  19         float t;
  20
  21         // now do the ammo maths
  22         self.ammo_counter = 0; // when we get here it's -1
  23         while(self.ammo_counter < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more than the amount of ammo we have
  24         {
  25                 self.ammo_counter += 1;
  26                 self.ammo_shells -= 1;
  27         }
  28         self.shotgun_load = self.ammo_counter;
  29
  30         t = ATTACK_FINISHED(self) - autocvar_g_balance_sniperrifle_reloadtime - 1;
  31         ATTACK_FINISHED(self) = t;
  32         w_ready();
  33 }
  34
  35 void W_Shotgun_Reload()
  36 {
  37         // reloading is disabled for this weapon
  38         if(!autocvar_g_balance_shotgun_reload_ammo)
  39                 return;
  40
  41         float t;
  42
  43         if(!W_ReloadCheck(self.ammo_shells))
  44                 return;
  45
  46         sound (self, CHAN_WEAPON2, "weapons/campingrifle_reload.wav", VOL_BASE, ATTN_NORM);
  47
  48         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_sniperrifle_reloadtime + 1;
  49         ATTACK_FINISHED(self) = t;
  50
  51         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_sniperrifle_reloadtime, W_Shotgun_ReloadedAndReady);
  52
  53         self.ammo_counter = -1;
  54 }
  55
  56 void W_Shotgun_Attack (void)
  57 {
  58         float   sc;
  59         float   ammoamount;
  60         float   bullets;
  61         float   d;
  62         float   f;
  63         float   spread;
  64         float   bulletspeed;
  65         float   bulletconstant;
  66         local entity flash;
  67
  68         if(self.ammo_counter <= 0)
  69                 W_Shotgun_Reload();
  70         if(self.ammo_counter < 0)
  71                 return; // reloading, so we are done
  72
  73         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  74         bullets = autocvar_g_balance_shotgun_primary_bullets;
  75         d = autocvar_g_balance_shotgun_primary_damage;
  76         f = autocvar_g_balance_shotgun_primary_force;
  77         spread = autocvar_g_balance_shotgun_primary_spread;
  78         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  79         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  80
  81         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  82         for (sc = 0;sc < bullets;sc = sc + 1)
  83                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  84         endFireBallisticBullet();
  85         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  86         {
  87                 if(!autocvar_g_balance_shotgun_reload_ammo)
  88                         self.ammo_shells = self.ammo_shells - ammoamount;
  89                 else
  90                         self.shotgun_load -= ammoamount;
  91         }
  92
  93         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  94
  95         // casing code
  96         if (autocvar_g_casings >= 1)
  97                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  98                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  99
 100         // muzzle flash for 1st person view
 101         flash = spawn();
 102         setmodel(flash, "models/uziflash.md3"); // precision set below
 103         flash.think = SUB_Remove;
 104         flash.nextthink = time + 0.06;
 105         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 106         W_AttachToShotorg(flash, '5 0 0');
 107
 108         self.ammo_counter = self.ammo_counter - 1;
 109 }
 110
 111 void shotgun_meleethink (void)
 112 {
 113         // store time when we started swinging down inside self.cnt
 114         if(!self.cnt)
 115                 self.cnt = time;
 116
 117         makevectors(self.owner.v_angle);
 118         vector angle;
 119         angle = v_forward;
 120
 121         float meleetime;
 122         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 123
 124         // perform trace
 125         float f;
 126         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 127         vector targpos;
 128         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 129
 130         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 131
 132         // apply the damage, also remove self
 133         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 134         {
 135                 vector force;
 136                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 137                 if(accuracy_isgooddamage(self.owner, trace_ent))
 138                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 139                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 140                 remove(self);
 141         }
 142         else if(time >= self.cnt + meleetime) // missed, remove ent
 143                 remove(self);
 144         else // continue swinging the weapon in hope of hitting someone :)
 145                 self.nextthink = time;
 146 }
 147
 148 void W_Shotgun_Attack2 (void)
 149 {
 150         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 151         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 152
 153         entity meleetemp;
 154         meleetemp = spawn();
 155         meleetemp.owner = self;
 156         meleetemp.think = shotgun_meleethink;
 157         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 158         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 159 }
 160
 161 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 162
 163 .float shotgun_primarytime;
 164
 165 float w_shotgun(float req)
 166 {
 167         if (req == WR_AIM)
 168                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 169                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 170                 else
 171                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 172         else if (req == WR_THINK)
 173         {
 174                 if(self.ammo_counter < 0) // forced reload (e.g. because interrupted)
 175             self.wish_reload = 1;
 176                 else
 177                 {
 178                         if (self.BUTTON_ATCK)
 179                         {
 180                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 181                                 {
 182                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 183                                         {
 184                                                 W_Shotgun_Attack();
 185                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 186                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 187                                         }
 188                                 }
 189                         }
 190                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 191                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 192                         {
 193                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 194                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 195                         }
 196                 }
 197         if(self.wish_reload)
 198         {
 199             if(self.switchweapon == self.weapon)
 200             {
 201                 if(self.weaponentity.state == WS_READY)
 202                 {
 203                     self.wish_reload = 0;
 204                     W_Shotgun_Reload();
 205                 }
 206             }
 207         }
 208         }
 209         else if (req == WR_PRECACHE)
 210         {
 211                 precache_model ("models/uziflash.md3");
 212                 precache_model ("models/weapons/g_shotgun.md3");
 213                 precache_model ("models/weapons/v_shotgun.md3");
 214                 precache_model ("models/weapons/h_shotgun.iqm");
 215                 precache_sound ("misc/itempickup.wav");
 216                 precache_sound ("weapons/shotgun_fire.wav");
 217                 precache_sound ("weapons/shotgun_melee.wav");
 218         }
 219         else if (req == WR_SETUP)
 220         {
 221                 weapon_setup(WEP_SHOTGUN);
 222                 W_Shotgun_SetAmmoCounter();
 223         }
 224         else if (req == WR_CHECKAMMO1)
 225                 return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 226         else if (req == WR_CHECKAMMO2)
 227         {
 228                 return TRUE;
 229         }
 230         return TRUE;
 231 };
 232 #endif
 233 #ifdef CSQC
 234 .float prevric;
 235 float w_shotgun(float req)
 236 {
 237         if(req == WR_IMPACTEFFECT)
 238         {
 239                 vector org2;
 240                 org2 = w_org + w_backoff * 2;
 241                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 242                 if(!w_issilent && time - self.prevric > 0.25)
 243                 {
 244                         if(w_random < 0.0165)
 245                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 246                         else if(w_random < 0.033)
 247                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 248                         else if(w_random < 0.05)
 249                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 250                         self.prevric = time;
 251                 }
 252         }
 253         else if(req == WR_PRECACHE)
 254         {
 255                 precache_sound("weapons/ric1.wav");
 256                 precache_sound("weapons/ric2.wav");
 257                 precache_sound("weapons/ric3.wav");
 258         }
 259         else if (req == WR_SUICIDEMESSAGE)
 260                 w_deathtypestring = "%s did the impossible";
 261         else if (req == WR_KILLMESSAGE)
 262         {
 263                 if(w_deathtype & HITTYPE_SECONDARY)
 264                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 265                 else
 266                         w_deathtypestring = "%s was gunned by %s";
 267         }
 268         return TRUE;
 269 }
 270 #endif
 271 #endif