qcsrc/server/w_tuba.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(TUBA, w_tuba, 0, 1, WEP_FLAG_HIDDEN | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "tuba", "tuba", _("@!#%'n Tuba"))
   3 #else
   4 #ifdef SVQC
   5 //#define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   6 .entity tuba_note;
   7 .float tuba_smoketime;
   8 .float tuba_instrument;
   9
  10 #define MAX_TUBANOTES 32
  11 .float tuba_lastnotes_last;
  12 .float tuba_lastnotes_cnt; // over
  13 .vector tuba_lastnotes[MAX_TUBANOTES];
  14
  15 float W_Tuba_HasPlayed(entity pl, string melody, float instrument, float ignorepitch, float mintempo, float maxtempo)
  16 {
  17         float i, j, mmin, mmax, nolength;
  18         float n = tokenize_console(melody);
  19         if(n > pl.tuba_lastnotes_cnt)
  20                 return FALSE;
  21         float pitchshift = 0;
  22
  23         if(instrument >= 0)
  24                 if(pl.tuba_instrument != instrument)
  25                         return FALSE;
  26
  27         // verify notes...
  28         nolength = FALSE;
  29         for(i = 0; i < n; ++i)
  30         {
  31                 vector v = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  32                 float ai = stof(argv(n - i - 1));
  33                 float np = floor(ai);
  34                 if(ai == np)
  35                         nolength = TRUE;
  36                 // n counts the last played notes BACKWARDS
  37                 // _x is start
  38                 // _y is end
  39                 // _z is note pitch
  40                 if(ignorepitch && i == 0)
  41                 {
  42                         pitchshift = np - v_z;
  43                 }
  44                 else
  45                 {
  46                         if(v_z + pitchshift != np)
  47                                 return FALSE;
  48                 }
  49         }
  50
  51         // now we know the right NOTES were played
  52         if(!nolength)
  53         {
  54                 // verify rhythm...
  55                 float ti = 0;
  56                 if(maxtempo > 0)
  57                         mmin = 240 / maxtempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  58                 else
  59                         mmin = 0;
  60                 if(mintempo > 0)
  61                         mmax = 240 / mintempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  62                 else
  63                         mmax = 240; // you won't try THAT hard... (tempo 1)
  64                 //print(sprintf("initial tempo rules: %f %f\n", mmin, mmax));
  65
  66                 for(i = 0; i < n; ++i)
  67                 {
  68                         vector vi = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  69                         float ai = stof(argv(n - i - 1));
  70                         ti -= 1 / (ai - floor(ai));
  71                         float tj = ti;
  72                         for(j = i+1; j < n; ++j)
  73                         {
  74                                 vector vj = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - j + MAX_TUBANOTES, MAX_TUBANOTES)]);
  75                                 float aj = stof(argv(n - j - 1));
  76                                 tj -= (aj - floor(aj));
  77
  78                                 // note i should be at m*ti+b
  79                                 // note j should be at m*tj+b
  80                                 // so:
  81                                 // we have a LINE l, so that
  82                                 // vi_x <= l(ti) <= vi_y
  83                                 // vj_x <= l(tj) <= vj_y
  84                                 // what is m?
  85
  86                                 // vi_x <= vi_y <= vj_x <= vj_y
  87                                 // ti <= tj
  88                                 //print(sprintf("first note: %f to %f, should be %f\n", vi_x, vi_y, ti));
  89                                 //print(sprintf("second note: %f to %f, should be %f\n", vj_x, vj_y, tj));
  90                                 //print(sprintf("m1 = %f\n", (vi_x - vj_y) / (ti - tj)));
  91                                 //print(sprintf("m2 = %f\n", (vi_y - vj_x) / (ti - tj)));
  92                                 mmin = max(mmin, (vi_x - vj_y) / (ti - tj)); // lower bound
  93                                 mmax = min(mmax, (vi_y - vj_x) / (ti - tj)); // upper bound
  94                         }
  95                 }
  96
  97                 if(mmin > mmax) // rhythm fail
  98                         return FALSE;
  99         }
 100
 101         pl.tuba_lastnotes_cnt = 0;
 102
 103         return TRUE;
 104 }
 105
 106 void W_Tuba_NoteOff()
 107 {
 108         // we have a note:
 109         //   on: self.spawnshieldtime
 110         //   off: time
 111         //   note: self.cnt
 112         if(self.owner.tuba_note == self)
 113         {
 114                 self.owner.tuba_lastnotes_last = mod(self.owner.tuba_lastnotes_last + 1, MAX_TUBANOTES);
 115                 self.owner.(tuba_lastnotes[self.owner.tuba_lastnotes_last]) = eX * self.spawnshieldtime + eY * time + eZ * self.cnt;
 116                 self.owner.tuba_note = world;
 117                 self.owner.tuba_lastnotes_cnt = bound(0, self.owner.tuba_lastnotes_cnt + 1, MAX_TUBANOTES);
 118
 119                 string s;
 120                 s = trigger_magicear_processmessage_forallears(self.owner, 0, world, string_null);
 121                 if(s != "")
 122                 {
 123                         // simulate a server message
 124                         switch(self.tuba_instrument)
 125                         {
 126                                 default:
 127                                 case 0: // Tuba
 128                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Tuba: ^7", s, "\n"));
 129                                         break;
 130                                 case 1:
 131                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Accordeon: ^7", s, "\n"));
 132                                         break;
 133                                 case 2:
 134                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Klein Bottle: ^7", s, "\n"));
 135                                         break;
 136                         }
 137                 }
 138         }
 139         remove(self);
 140 }
 141
 142 float Tuba_GetNote(entity pl, float hittype)
 143 {
 144         float note;
 145         float movestate;
 146         movestate = 5;
 147         if(pl.movement_x < 0) movestate -= 3;
 148         if(pl.movement_x > 0) movestate += 3;
 149         if(pl.movement_y < 0) movestate -= 1;
 150         if(pl.movement_y > 0) movestate += 1;
 151         switch(movestate)
 152         {
 153         // layout: originally I wanted
 154         //   eb e  e#=f
 155         //   B  c  d
 156         //   Gb G  G#
 157         // but then you only use forward and right key. So to make things more
 158         // interesting, I swapped B with e#. Har har har...
 159         //   eb e  B
 160         // f=e# c  d
 161         //   Gb G  G#
 162                 case 1: note = -6; break; // Gb
 163                 case 2: note = -5; break; // G
 164                 case 3: note = -4; break; // G#
 165                 case 4: note = +5; break; // e#
 166                 default:
 167                 case 5: note =  0; break; // c
 168                 case 6: note = +2; break; // d
 169                 case 7: note = +3; break; // eb
 170                 case 8: note = +4; break; // e
 171                 case 9: note = -1; break; // B
 172         }
 173         if(pl.BUTTON_CROUCH)
 174                 note -= 12;
 175         if(pl.BUTTON_JUMP)
 176                 note += 12;
 177         if(hittype & HITTYPE_SECONDARY)
 178                 note += 7;
 179
 180         // we support two kinds of tubas, those tuned in Eb and those tuned in C
 181         // kind of tuba currently is player slot number, or team number if in
 182         // teamplay
 183         // that way, holes in the range of notes are "plugged"
 184         if(teamplay)
 185         {
 186                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
 187                         note += 3;
 188         }
 189         else
 190         {
 191                 if(pl.clientcolors & 1)
 192                         note += 3;
 193         }
 194
 195         // total range of notes:
 196         //                       0
 197         //                 ***  ** ****
 198         //                        ***  ** ****
 199         //     ***  ** ****
 200         //            ***  ** ****
 201         //     ***  ********************* ****
 202         //     -18.........................+12
 203         //        ***  ********************* ****
 204         //     -18............................+15
 205         //     with jump: ... +24
 206         //     ... +27
 207         return note;
 208 }
 209
 210 float W_Tuba_NoteSendEntity(entity to, float sf)
 211 {
 212         float f;
 213
 214         msg_entity = to;
 215         if(!sound_allowed(MSG_ONE, self.realowner))
 216                 return FALSE;
 217
 218         WriteByte(MSG_ENTITY, ENT_CLIENT_TUBANOTE);
 219         WriteByte(MSG_ENTITY, sf);
 220         if(sf & 1)
 221         {
 222                 WriteChar(MSG_ENTITY, self.cnt);
 223                 f = 0;
 224                 if(self.realowner != to)
 225                         f |= 1;
 226                 f |= 2 * self.tuba_instrument;
 227                 WriteByte(MSG_ENTITY, f);
 228         }
 229         if(sf & 2)
 230         {
 231                 WriteCoord(MSG_ENTITY, self.origin_x);
 232                 WriteCoord(MSG_ENTITY, self.origin_y);
 233                 WriteCoord(MSG_ENTITY, self.origin_z);
 234         }
 235         return TRUE;
 236 }
 237
 238 void W_Tuba_NoteThink()
 239 {
 240         float dist_mult;
 241         float vol0, vol1;
 242         vector dir0, dir1;
 243         vector v;
 244         entity e;
 245         if(time > self.teleport_time)
 246         {
 247                 W_Tuba_NoteOff();
 248                 return;
 249         }
 250         self.nextthink = time;
 251         dist_mult = autocvar_g_balance_tuba_attenuation / autocvar_snd_soundradius;
 252         FOR_EACH_REALCLIENT(e)
 253         if(e != self.realowner)
 254         {
 255                 v = self.origin - (e.origin + e.view_ofs);
 256                 vol0 = max(0, 1 - vlen(v) * dist_mult);
 257                 dir0 = normalize(v);
 258                 v = self.realowner.origin - (e.origin + e.view_ofs);
 259                 vol1 = max(0, 1 - vlen(v) * dist_mult);
 260                 dir1 = normalize(v);
 261                 if(fabs(vol0 - vol1) > 0.005) // 0.5 percent change in volume
 262                 {
 263                         setorigin(self, self.realowner.origin);
 264                         self.SendFlags |= 2;
 265                         break;
 266                 }
 267                 if(dir0 * dir1 < 0.9994) // 2 degrees change in angle
 268                 {
 269                         setorigin(self, self.realowner.origin);
 270                         self.SendFlags |= 2;
 271                         break;
 272                 }
 273         }
 274 }
 275
 276 void W_Tuba_NoteOn(float hittype)
 277 {
 278         vector o;
 279         float n;
 280
 281         W_SetupShot(self, FALSE, 2, "", 0, autocvar_g_balance_tuba_damage);
 282
 283         n = Tuba_GetNote(self, hittype);
 284
 285         hittype = 0;
 286         if(self.tuba_instrument & 1)
 287                 hittype |= HITTYPE_SECONDARY;
 288         if(self.tuba_instrument & 2)
 289                 hittype |= HITTYPE_BOUNCE;
 290         if(self.tuba_instrument & 4)
 291                 hittype |= HITTYPE_HEADSHOT;
 292
 293         if(self.tuba_note)
 294         {
 295                 if(self.tuba_note.cnt != n || self.tuba_note.tuba_instrument != self.tuba_instrument)
 296                 {
 297                         entity oldself = self;
 298                         self = self.tuba_note;
 299                         W_Tuba_NoteOff();
 300                         self = oldself;
 301                 }
 302         }
 303
 304         if not(self.tuba_note)
 305         {
 306                 self.tuba_note = spawn();
 307                 self.tuba_note.owner = self.tuba_note.realowner = self;
 308                 self.tuba_note.cnt = n;
 309                 self.tuba_note.tuba_instrument = self.tuba_instrument;
 310                 self.tuba_note.think = W_Tuba_NoteThink;
 311                 self.tuba_note.nextthink = time;
 312                 self.tuba_note.spawnshieldtime = time;
 313                 Net_LinkEntity(self.tuba_note, FALSE, 0, W_Tuba_NoteSendEntity);
 314         }
 315
 316         self.tuba_note.teleport_time = time + autocvar_g_balance_tuba_refire * 2 * W_WeaponRateFactor(); // so it can get prolonged safely
 317
 318         //sound(self, c, TUBA_NOTE(n), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), autocvar_g_balance_tuba_attenuation);
 319         RadiusDamage(self, self, autocvar_g_balance_tuba_damage, autocvar_g_balance_tuba_edgedamage, autocvar_g_balance_tuba_radius, world, autocvar_g_balance_tuba_force, hittype | WEP_TUBA, world);
 320
 321         o = gettaginfo(self.exteriorweaponentity, 0);
 322         if(time > self.tuba_smoketime)
 323         {
 324                 pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
 325                 self.tuba_smoketime = time + 0.25;
 326         }
 327 }
 328
 329 void spawnfunc_weapon_tuba (void)
 330 {
 331         weapon_defaultspawnfunc(WEP_TUBA);
 332 }
 333
 334 float w_tuba(float req)
 335 {
 336         if (req == WR_AIM)
 337         {
 338                 // bots cannot play the Tuba well yet
 339                 // I think they should start with the recorder first
 340                 if(vlen(self.origin - self.enemy.origin) < autocvar_g_balance_tuba_radius)
 341                 {
 342                         if(random() > 0.5)
 343                                 self.BUTTON_ATCK = 1;
 344                         else
 345                                 self.BUTTON_ATCK2 = 1;
 346                 }
 347         }
 348         else if (req == WR_THINK)
 349         {
 350                 if (self.BUTTON_ATCK)
 351                 if (weapon_prepareattack(0, autocvar_g_balance_tuba_refire))
 352                 {
 353                         W_Tuba_NoteOn(0);
 354                         //weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_tuba_animtime, w_ready);
 355                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 356                 }
 357                 if (self.BUTTON_ATCK2)
 358                 if (weapon_prepareattack(1, autocvar_g_balance_tuba_refire))
 359                 {
 360                         W_Tuba_NoteOn(HITTYPE_SECONDARY);
 361                         //weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_tuba_animtime, w_ready);
 362                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 363                 }
 364                 if(self.tuba_note)
 365                 {
 366                         if(!self.BUTTON_ATCK && !self.BUTTON_ATCK2)
 367                         {
 368                                 entity oldself = self;
 369                                 self = self.tuba_note;
 370                                 W_Tuba_NoteOff();
 371                                 self = oldself;
 372                         }
 373                 }
 374         }
 375         else if (req == WR_PRECACHE)
 376         {
 377                 precache_model ("models/weapons/g_tuba.md3");
 378                 precache_model ("models/weapons/v_tuba.md3");
 379                 precache_model ("models/weapons/h_tuba.iqm");
 380                 precache_model ("models/weapons/v_akordeon.md3");
 381                 precache_model ("models/weapons/h_akordeon.iqm");
 382                 precache_model ("models/weapons/v_kleinbottle.md3");
 383                 precache_model ("models/weapons/h_kleinbottle.iqm");
 384
 385                 //float i;
 386                 //for(i = -18; i <= +27; ++i)
 387                 //      precache_sound(TUBA_NOTE(i));
 388         }
 389         else if (req == WR_SETUP)
 390         {
 391                 weapon_setup(WEP_TUBA);
 392                 self.current_ammo = ammo_none;
 393                 self.tuba_instrument = 0;
 394         }
 395         else if (req == WR_RELOAD)
 396         {
 397                 // switch to alternate instruments :)
 398                 if(self.weaponentity.state == WS_READY)
 399                 {
 400                         switch(self.tuba_instrument)
 401                         {
 402                                 case 0:
 403                                         self.tuba_instrument = 1;
 404                                         self.weaponname = "akordeon";
 405                                         break;
 406                                 case 1:
 407                                         self.tuba_instrument = 2;
 408                                         self.weaponname = "kleinbottle";
 409                                         break;
 410                                 case 2:
 411                                         self.tuba_instrument = 0;
 412                                         self.weaponname = "tuba";
 413                                         break;
 414                         }
 415                         W_SetupShot(self, FALSE, 0, "", 0, 0);
 416                         pointparticles(particleeffectnum("teleport"), w_shotorg, '0 0 0', 1);
 417                         self.weaponentity.state = WS_INUSE;
 418                         weapon_thinkf(WFRAME_RELOAD, 0.5, w_ready);
 419                 }
 420         }
 421         else if (req == WR_CHECKAMMO1)
 422                 return TRUE; // TODO use fuel?
 423         else if (req == WR_CHECKAMMO2)
 424                 return TRUE; // TODO use fuel?
 425         return TRUE;
 426 }
 427 #endif
 428 #ifdef CSQC
 429 float w_tuba(float req)
 430 {
 431         if(req == WR_IMPACTEFFECT)
 432         {
 433                 // nothing to do here; particles of tuba are handled differently
 434         }
 435         else if(req == WR_PRECACHE)
 436         {
 437                 // nothing to do
 438         }
 439         else if (req == WR_SUICIDEMESSAGE)
 440         {
 441                 float instr;
 442                 instr = 0;
 443                 if(w_deathtype & HITTYPE_SECONDARY)
 444                         instr |= 1;
 445                 if(w_deathtype & HITTYPE_BOUNCE)
 446                         instr |= 2;
 447                 if(w_deathtype & HITTYPE_HEADSHOT)
 448                         instr |= 4;
 449                 switch(instr)
 450                 {
 451                         default:
 452                         case 0: // Tuba
 453                                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Tuba");
 454                                 break;
 455                         case 1: // Accordeon
 456                                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Accordeon");
 457                                 break;
 458                         case 2: // Klein Bottle
 459                                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Klein Bottle");
 460                                 break;
 461                 }
 462         }
 463         else if (req == WR_KILLMESSAGE)
 464         {
 465                 float instr;
 466                 instr = 0;
 467                 if(w_deathtype & HITTYPE_SECONDARY)
 468                         instr |= 1;
 469                 if(w_deathtype & HITTYPE_BOUNCE)
 470                         instr |= 2;
 471                 if(w_deathtype & HITTYPE_HEADSHOT)
 472                         instr |= 4;
 473                 switch(instr)
 474                 {
 475                         default:
 476                         case 0: // Tuba
 477                                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Tuba");
 478                                 break;
 479                         case 1: // Accordeon
 480                                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Accordeon");
 481                                 break;
 482                         case 2: // Klein Bottle
 483                                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Klein Bottle");
 484                                 break;
 485                 }
 486         }
 487         return TRUE;
 488 }
 489 #endif
 490 #endif