qcsrc/server/waypointsprites.qc

   1 #include "waypointsprites.qh"
   2
   3 #if defined(CSQC)
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6     #include "../common/constants.qh"
   7     #include "../common/util.qh"
   8     #include "../common/buffs.qh"
   9     #include "autocvars.qh"
  10     #include "constants.qh"
  11     #include "defs.qh"
  12     #include "../common/deathtypes.qh"
  13     #include "mutators/mutators_include.qh"
  14     #include "../common/mapinfo.qh"
  15     #include "miscfunctions.qh"
  16 #endif
  17
  18 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  19 {
  20         if(m1 != e.model1)
  21         {
  22                 e.model1 = m1;
  23                 e.SendFlags |= 2;
  24         }
  25         if(m2 != e.model2)
  26         {
  27                 e.model2 = m2;
  28                 e.SendFlags |= 4;
  29         }
  30         if(m3 != e.model3)
  31         {
  32                 e.model3 = m3;
  33                 e.SendFlags |= 8;
  34         }
  35 }
  36
  37 void WaypointSprite_UpdateHealth(entity e, float f)
  38 {
  39         f = bound(0, f, e.max_health);
  40         if(f != e.health || e.pain_finished)
  41         {
  42                 e.health = f;
  43                 e.pain_finished = 0;
  44                 e.SendFlags |= 0x80;
  45         }
  46 }
  47
  48 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  49 {
  50         if(f != e.max_health || e.pain_finished)
  51         {
  52                 e.max_health = f;
  53                 e.pain_finished = 0;
  54                 e.SendFlags |= 0x80;
  55         }
  56 }
  57
  58 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  59 {
  60         if(f != e.pain_finished || e.max_health)
  61         {
  62                 e.max_health = 0;
  63                 e.pain_finished = f;
  64                 e.SendFlags |= 0x80;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateOrigin(entity e, vector o)
  69 {
  70         if(o != e.origin)
  71         {
  72                 setorigin(e, o);
  73                 e.SendFlags |= 64;
  74         }
  75 }
  76
  77 void WaypointSprite_UpdateRule(entity e, float t, float r)
  78 {
  79         // no check, as this is never called without doing an actual change (usually only once)
  80         e.rule = r;
  81         e.team = t;
  82         e.SendFlags |= 1;
  83 }
  84
  85 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  86 {
  87         // no check, as this is never called without doing an actual change (usually only once)
  88         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  89         e.colormod = col;
  90         e.SendFlags |= 32;
  91 }
  92
  93 void WaypointSprite_Ping(entity e)
  94 {
  95         // anti spam
  96         if(time < e.waypointsprite_pingtime)
  97                 return;
  98         e.waypointsprite_pingtime = time + 0.3;
  99         // ALWAYS sends (this causes a radar circle), thus no check
 100         e.cnt |= 0x80;
 101         e.SendFlags |= 32;
 102 }
 103
 104 void WaypointSprite_HelpMePing(entity e)
 105 {
 106         WaypointSprite_Ping(e);
 107         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 108         e.SendFlags |= 32;
 109 }
 110
 111 void WaypointSprite_FadeOutIn(entity e, float t)
 112 {
 113         if(!e.fade_time)
 114         {
 115                 e.fade_time = t;
 116                 e.teleport_time = time + t;
 117         }
 118         else if(t < (e.teleport_time - time))
 119         {
 120                 // accelerate the waypoint's dying
 121                 // ensure:
 122                 //   (e.teleport_time - time) / wp.fade_time stays
 123                 //   e.teleport_time = time + fadetime
 124                 float current_fadetime;
 125                 current_fadetime = e.teleport_time - time;
 126                 e.teleport_time = time + t;
 127                 e.fade_time = e.fade_time * t / current_fadetime;
 128         }
 129
 130         e.SendFlags |= 16;
 131 }
 132
 133 void WaypointSprite_Init()
 134 {
 135         waypointsprite_limitedrange = autocvar_sv_waypointsprite_limitedrange;
 136         waypointsprite_deployed_lifetime = autocvar_sv_waypointsprite_deployed_lifetime;
 137         waypointsprite_deadlifetime = autocvar_sv_waypointsprite_deadlifetime;
 138 }
 139
 140 void WaypointSprite_InitClient(entity e)
 141 {
 142 }
 143
 144 void WaypointSprite_Kill(entity wp)
 145 {
 146         if(!wp)
 147                 return;
 148         if(wp.owner)
 149                 wp.owner.(wp.owned_by_field) = world;
 150         remove(wp);
 151 }
 152
 153 void WaypointSprite_Disown(entity wp, float fadetime)
 154 {
 155         if(!wp)
 156                 return;
 157         if(wp.classname != "sprite_waypoint")
 158         {
 159                 backtrace("Trying to disown a non-waypointsprite");
 160                 return;
 161         }
 162         if(wp.owner)
 163         {
 164                 if(wp.exteriormodeltoclient == wp.owner)
 165                         wp.exteriormodeltoclient = world;
 166                 wp.owner.(wp.owned_by_field) = world;
 167                 wp.owner = world;
 168
 169                 WaypointSprite_FadeOutIn(wp, fadetime);
 170         }
 171 }
 172
 173 void WaypointSprite_Think()
 174 {
 175         float doremove;
 176
 177         doremove = false;
 178
 179         if(self.fade_time)
 180         {
 181                 if(time >= self.teleport_time)
 182                         doremove = true;
 183         }
 184
 185         if(self.exteriormodeltoclient)
 186                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 187
 188         if(doremove)
 189                 WaypointSprite_Kill(self);
 190         else
 191                 self.nextthink = time; // WHY?!?
 192 }
 193
 194 float WaypointSprite_visible_for_player(entity e)
 195 {
 196         // personal waypoints
 197         if(self.enemy)
 198                 if(self.enemy != e)
 199                         return false;
 200
 201         // team waypoints
 202         if(self.rule == SPRITERULE_SPECTATOR)
 203         {
 204                 if(!autocvar_sv_itemstime)
 205                         return FALSE;
 206                 if(!warmup_stage && e.classname == "player")
 207                         return FALSE;
 208         }
 209         else if(self.team && self.rule == SPRITERULE_DEFAULT)
 210         {
 211                 if(self.team != e.team)
 212                         return false;
 213                 if (!IS_PLAYER(e))
 214                         return false;
 215         }
 216
 217         return true;
 218 }
 219
 220 entity WaypointSprite_getviewentity(entity e)
 221 {
 222         if(IS_SPEC(e))
 223                 e = e.enemy;
 224         /* TODO idea (check this breaks nothing)
 225         else if(e.classname == "observer")
 226                 e = world;
 227         */
 228         return e;
 229 }
 230
 231 float WaypointSprite_isteammate(entity e, entity e2)
 232 {
 233         if(teamplay)
 234         {
 235                 if(e2.team != e.team)
 236                         return false;
 237         }
 238         else
 239         {
 240                 if(e2 != e)
 241                         return false;
 242         }
 243         return true;
 244 }
 245
 246 float WaypointSprite_Customize()
 247 {
 248         // this is not in SendEntity because it shall run every frame, not just every update
 249
 250         // make spectators see what the player would see
 251         entity e;
 252         e = WaypointSprite_getviewentity(other);
 253
 254         if(MUTATOR_CALLHOOK(CustomizeWaypoint))
 255                 return false;
 256
 257         return self.waypointsprite_visible_for_player(e);
 258 }
 259
 260 float WaypointSprite_SendEntity(entity to, float sendflags)
 261 {
 262         float dt;
 263
 264         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 265
 266         sendflags = sendflags & 0x7F;
 267
 268         if(g_nexball)
 269                 sendflags &= ~0x80;
 270         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 271                 sendflags |= 0x80;
 272
 273         WriteByte(MSG_ENTITY, sendflags);
 274
 275         if(sendflags & 0x80)
 276         {
 277                 if(self.max_health)
 278                 {
 279                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 280                 }
 281                 else
 282                 {
 283                         dt = self.pain_finished - time;
 284                         dt = bound(0, dt * 32, 16383);
 285                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 286                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 287                 }
 288         }
 289
 290         if(sendflags & 64)
 291         {
 292                 WriteCoord(MSG_ENTITY, self.origin.x);
 293                 WriteCoord(MSG_ENTITY, self.origin.y);
 294                 WriteCoord(MSG_ENTITY, self.origin.z);
 295         }
 296
 297         if(sendflags & 1)
 298         {
 299                 WriteByte(MSG_ENTITY, self.team);
 300                 WriteByte(MSG_ENTITY, self.rule);
 301         }
 302
 303         if(sendflags & 2)
 304                 WriteString(MSG_ENTITY, self.model1);
 305
 306         if(sendflags & 4)
 307                 WriteString(MSG_ENTITY, self.model2);
 308
 309         if(sendflags & 8)
 310                 WriteString(MSG_ENTITY, self.model3);
 311
 312         if(sendflags & 16)
 313         {
 314                 WriteCoord(MSG_ENTITY, self.fade_time);
 315                 WriteCoord(MSG_ENTITY, self.teleport_time);
 316                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 317                 float f;
 318                 f = 0;
 319                 if(self.currentammo)
 320                         f |= 1; // hideable
 321                 if(self.exteriormodeltoclient == to)
 322                         f |= 2; // my own
 323                 WriteByte(MSG_ENTITY, f);
 324         }
 325
 326         if(sendflags & 32)
 327         {
 328                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 329                 WriteByte(MSG_ENTITY, self.colormod.x * 255.0);
 330                 WriteByte(MSG_ENTITY, self.colormod.y * 255.0);
 331                 WriteByte(MSG_ENTITY, self.colormod.z * 255.0);
 332
 333                 if(WaypointSprite_isteammate(self.owner, WaypointSprite_getviewentity(to)))
 334                 {
 335                         dt = (self.waypointsprite_helpmetime - time) / 0.1;
 336                         if(dt < 0)
 337                                 dt = 0;
 338                         if(dt > 255)
 339                                 dt = 255;
 340                         WriteByte(MSG_ENTITY, dt);
 341                 }
 342                 else
 343                         WriteByte(MSG_ENTITY, 0);
 344         }
 345
 346         return true;
 347 }
 348
 349 void WaypointSprite_Reset()
 350 {
 351         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 352
 353         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 354                 WaypointSprite_Kill(self);
 355 }
 356
 357 entity WaypointSprite_Spawn(
 358         string spr, // sprite
 359         float _lifetime, float maxdistance, // lifetime, max distance
 360         entity ref, vector ofs, // position
 361         entity showto, float t, // show to whom? Use a flag to indicate a team
 362         entity own, .entity ownfield, // remove when own gets killed
 363         float hideable, // true when it should be controlled by cl_hidewaypoints
 364         float icon, vector rgb // initial icon and color
 365 )
 366 {
 367         entity wp;
 368         wp = spawn();
 369         wp.classname = "sprite_waypoint";
 370         wp.teleport_time = time + _lifetime;
 371         wp.fade_time = _lifetime;
 372         wp.exteriormodeltoclient = ref;
 373         if(ref)
 374         {
 375                 wp.view_ofs = ofs;
 376                 setorigin(wp, ref.origin + ofs);
 377         }
 378         else
 379                 setorigin(wp, ofs);
 380         wp.enemy = showto;
 381         wp.team = t;
 382         wp.owner = own;
 383         wp.currentammo = hideable;
 384         if (own)
 385         {
 386                 if (own.(ownfield))
 387                         remove(own.(ownfield));
 388                 own.(ownfield) = wp;
 389                 wp.owned_by_field = ownfield;
 390         }
 391         wp.fade_rate = maxdistance;
 392         wp.think = WaypointSprite_Think;
 393         wp.nextthink = time;
 394         wp.model1 = spr;
 395         wp.customizeentityforclient = WaypointSprite_Customize;
 396         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 397         wp.reset2 = WaypointSprite_Reset;
 398         wp.cnt = icon;
 399         wp.colormod = rgb;
 400         Net_LinkEntity(wp, false, 0, WaypointSprite_SendEntity);
 401         return wp;
 402 }
 403
 404 entity WaypointSprite_SpawnFixed(
 405         string spr,
 406         vector ofs,
 407         entity own,
 408         .entity ownfield,
 409         float icon, vector rgb // initial icon and color
 410 )
 411 {
 412         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, true, icon, rgb);
 413 }
 414
 415 entity WaypointSprite_DeployFixed(
 416         string spr,
 417         float limited_range,
 418         vector ofs,
 419         float icon, vector rgb // initial icon and color
 420 )
 421 {
 422         float t, maxdistance;
 423         if(teamplay)
 424                 t = self.team;
 425         else
 426                 t = 0;
 427         if(limited_range)
 428                 maxdistance = waypointsprite_limitedrange;
 429         else
 430                 maxdistance = 0;
 431         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, false, icon, rgb);
 432 }
 433
 434 entity WaypointSprite_DeployPersonal(
 435         string spr,
 436         vector ofs,
 437         float icon, vector rgb // initial icon and color
 438 )
 439 {
 440         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, false, icon, rgb);
 441 }
 442
 443 entity WaypointSprite_Attach(
 444         string spr,
 445         float limited_range,
 446         float icon, vector rgb // initial icon and color
 447 )
 448 {
 449         float t, maxdistance;
 450         if(self.waypointsprite_attachedforcarrier)
 451                 return world; // can't attach to FC
 452         if(teamplay)
 453                 t = self.team;
 454         else
 455                 t = 0;
 456         if(limited_range)
 457                 maxdistance = waypointsprite_limitedrange;
 458         else
 459                 maxdistance = 0;
 460         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, false, icon, rgb);
 461 }
 462
 463 entity WaypointSprite_AttachCarrier(
 464         string spr,
 465         entity carrier,
 466         float icon, vector rgb // initial icon and color
 467 )
 468 {
 469         entity e;
 470         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 471         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, false, icon, rgb);
 472         if(e)
 473         {
 474                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON) * 2);
 475                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
 476         }
 477         return e;
 478 }
 479
 480 void WaypointSprite_DetachCarrier(entity carrier)
 481 {
 482         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 483 }
 484
 485 void WaypointSprite_ClearPersonal()
 486 {
 487         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 488 }
 489
 490 void WaypointSprite_ClearOwned()
 491 {
 492         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 493         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 494         WaypointSprite_Kill(self.waypointsprite_attached);
 495 }
 496
 497 void WaypointSprite_PlayerDead()
 498 {
 499         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 500         WaypointSprite_DetachCarrier(self);
 501 }
 502
 503 void WaypointSprite_PlayerGone()
 504 {
 505         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 506         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 507         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 508         WaypointSprite_DetachCarrier(self);
 509 }