qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/checkextension.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/gamemodes/_mod.qh>
   7 #include <common/gamemodes/sv_rules.qh>
   8 #include <common/items/_mod.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/mapobjects/target/music.qh>
  11 #include <common/mapobjects/trigger/hurt.qh>
  12 #include <common/mapobjects/trigger/secret.qh>
  13 #include <common/mapobjects/triggers.qh>
  14 #include <common/monsters/_mod.qh>
  15 #include <common/monsters/sv_monsters.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/notifications/all.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/playerstats.qh>
  20 #include <common/state.qh>
  21 #include <common/stats.qh>
  22 #include <common/teams.qh>
  23 #include <common/util.qh>
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <lib/warpzone/common.qh>
  27 #include <server/anticheat.qh>
  28 #include <server/antilag.qh>
  29 #include <server/bot/api.qh>
  30 #include <server/campaign.qh>
  31 #include <server/cheats.qh>
  32 #include <server/client.qh>
  33 #include <server/command/common.qh>
  34 #include <server/command/getreplies.qh>
  35 #include <server/command/sv_cmd.qh>
  36 #include <server/command/vote.qh>
  37 #include <server/damage.qh>
  38 #include <server/gamelog.qh>
  39 #include <server/hook.qh>
  40 #include <server/ipban.qh>
  41 #include <server/items/items.qh>
  42 #include <server/main.qh>
  43 #include <server/mapvoting.qh>
  44 #include <server/mutators/_mod.qh>
  45 #include <server/race.qh>
  46 #include <server/scores.qh>
  47 #include <server/scores_rules.qh>
  48 #include <server/spawnpoints.qh>
  49 #include <server/teamplay.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent harm
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 this.nextthink = time;
 136         }
 137         else
 138         {
 139                 this.nextthink = time + 1;
 140                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         strfree(cvar_changes);
 151         strfree(cvar_purechanges);
 152         cvar_purechanges_count = 0;
 153
 154         h = buf_create();
 155         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 156         n = buf_getsize(h);
 157
 158         adding = true;
 159         pureadding = true;
 160
 161         for(i = 0; i < n; ++i)
 162         {
 163                 k = bufstr_get(h, i);
 164
 165 #define BADPREFIX_COND(p) (substring(k, 0, strlen(p)) == p)
 166 #define BADSUFFIX_COND(s) (substring(k, -strlen(s), -1) == s)
 167
 168 #define BADPREFIX(p) if(BADPREFIX_COND(p)) continue
 169 #define BADPRESUFFIX(p, s) if(BADPREFIX_COND(p) && BADSUFFIX_COND(s)) continue
 170 #define BADCVAR(p) if(k == p) continue
 171 #define BADVALUE(p, val) if (k == p && v == val) continue
 172 #define BADPRESUFFIXVALUE(p, s, val) if(BADPREFIX_COND(p) && BADSUFFIX_COND(s) && v == val) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("halflifebsp");
 183                 BADCVAR("sv_mapformat_is_quake2");
 184                 BADCVAR("sv_mapformat_is_quake3");
 185                 BADPREFIX("sv_world");
 186
 187                 // client
 188                 BADPREFIX("chase_");
 189                 BADPREFIX("cl_");
 190                 BADPREFIX("con_");
 191                 BADPREFIX("scoreboard_");
 192                 BADPREFIX("g_campaign");
 193                 BADPREFIX("g_waypointsprite_");
 194                 BADPREFIX("gl_");
 195                 BADPREFIX("joy");
 196                 BADPREFIX("hud_");
 197                 BADPREFIX("m_");
 198                 BADPREFIX("menu_");
 199                 BADPREFIX("net_slist_");
 200                 BADPREFIX("r_");
 201                 BADPREFIX("sbar_");
 202                 BADPREFIX("scr_");
 203                 BADPREFIX("snd_");
 204                 BADPREFIX("show");
 205                 BADPREFIX("sensitivity");
 206                 BADPREFIX("userbind");
 207                 BADPREFIX("v_");
 208                 BADPREFIX("vid_");
 209                 BADPREFIX("crosshair");
 210                 BADCVAR("mod_q3bsp_lightmapmergepower");
 211                 BADCVAR("mod_q3bsp_nolightmaps");
 212                 BADCVAR("fov");
 213                 BADCVAR("mastervolume");
 214                 BADCVAR("volume");
 215                 BADCVAR("bgmvolume");
 216                 BADCVAR("in_pitch_min");
 217                 BADCVAR("in_pitch_max");
 218
 219                 // private
 220                 BADCVAR("developer");
 221                 BADCVAR("log_dest_udp");
 222                 BADCVAR("net_address");
 223                 BADCVAR("net_address_ipv6");
 224                 BADCVAR("port");
 225                 BADCVAR("savedgamecfg");
 226                 BADCVAR("serverconfig");
 227                 BADCVAR("sv_autoscreenshot");
 228                 BADCVAR("sv_heartbeatperiod");
 229                 BADCVAR("sv_vote_master_password");
 230                 BADCVAR("sys_colortranslation");
 231                 BADCVAR("sys_specialcharactertranslation");
 232                 BADCVAR("timeformat");
 233                 BADCVAR("timestamps");
 234                 BADCVAR("g_require_stats");
 235                 BADCVAR("g_chatban_list");
 236                 BADCVAR("g_playban_list");
 237                 BADCVAR("g_playban_minigames");
 238                 BADCVAR("g_voteban_list");
 239                 BADPREFIX("developer_");
 240                 BADPREFIX("g_ban_");
 241                 BADPREFIX("g_banned_list");
 242                 BADPREFIX("g_require_stats_");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_voice_flood_");
 247                 BADPREFIX("log_file");
 248                 BADPREFIX("quit_");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262                 BADCVAR("sv_allow_customplayermodels_idlist");
 263                 BADCVAR("sv_allow_customplayermodels_speciallist");
 264
 265                 // mapinfo
 266                 BADCVAR("fraglimit");
 267                 BADCVAR("g_arena");
 268                 BADCVAR("g_assault");
 269                 BADCVAR("g_ca");
 270                 BADCVAR("g_ca_teams");
 271                 BADCVAR("g_conquest");
 272                 BADCVAR("g_conquest_teams");
 273                 BADCVAR("g_ctf");
 274                 BADCVAR("g_cts");
 275                 BADCVAR("g_dotc");
 276                 BADCVAR("g_dm");
 277                 BADCVAR("g_domination");
 278                 BADCVAR("g_domination_default_teams");
 279                 BADCVAR("g_duel");
 280                 BADCVAR("g_duel_not_dm_maps");
 281                 BADCVAR("g_freezetag");
 282                 BADCVAR("g_freezetag_teams");
 283                 BADCVAR("g_invasion_type");
 284                 BADCVAR("g_jailbreak");
 285                 BADCVAR("g_jailbreak_teams");
 286                 BADCVAR("g_keepaway");
 287                 BADCVAR("g_keyhunt");
 288                 BADCVAR("g_keyhunt_teams");
 289                 BADCVAR("g_lms");
 290                 BADCVAR("g_mayhem");
 291                 BADCVAR("g_nexball");
 292                 BADCVAR("g_onslaught");
 293                 BADCVAR("g_race");
 294                 BADCVAR("g_race_laps_limit");
 295                 BADCVAR("g_race_qualifying_timelimit");
 296                 BADCVAR("g_race_qualifying_timelimit_override");
 297                 BADCVAR("g_runematch");
 298                 BADCVAR("g_shootfromeye");
 299                 BADCVAR("g_snafu");
 300                 BADCVAR("g_survival");
 301                 BADCVAR("g_survival_not_dm_maps");
 302                 BADCVAR("g_tdm");
 303                 BADCVAR("g_tdm_on_dm_maps");
 304                 BADCVAR("g_tdm_teams");
 305                 BADCVAR("g_tka");
 306                 BADCVAR("g_tka_on_ka_maps");
 307                 BADCVAR("g_tka_on_tdm_maps");
 308                 BADCVAR("g_tka_teams");
 309                 BADCVAR("g_tmayhem");
 310                 BADCVAR("g_tmayhem_teams");
 311                 BADCVAR("g_vip");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("nextmap");
 314                 BADCVAR("teamplay");
 315                 BADCVAR("timelimit");
 316                 BADCVAR("g_mapinfo_q3compat");
 317                 BADCVAR("g_mapinfo_settemp_acl");
 318                 BADCVAR("g_mapinfo_ignore_warnings");
 319                 BADCVAR("g_maplist_ignore_sizes");
 320                 BADCVAR("g_maplist_sizes_count_bots");
 321
 322                 // long
 323                 BADCVAR("hostname");
 324                 BADCVAR("g_maplist");
 325                 BADCVAR("g_maplist_mostrecent");
 326                 BADCVAR("sv_motd");
 327                 BADCVAR("sv_termsofservice_url");
 328
 329                 v = cvar_string(k);
 330                 d = cvar_defstring(k);
 331                 if(v == d)
 332                         continue;
 333
 334                 if(adding)
 335                 {
 336                         if (cvar_changes == "")
 337                                 cvar_changes = "// this server runs at modified server settings:\n";
 338
 339                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 340                         if(strlen(cvar_changes) >= VM_TEMPSTRING_MAXSIZE)
 341                         {
 342                                 cvar_changes = "// too many settings have been changed to show them here\n";
 343                                 adding = 0;
 344                         }
 345                 }
 346
 347                 // now check if the changes are actually gameplay relevant
 348
 349                 // does nothing gameplay relevant
 350                 BADCVAR("captureleadlimit_override");
 351                 BADCVAR("condump_stripcolors");
 352                 BADCVAR("fs_gamedir");
 353                 BADCVAR("g_allow_oldvortexbeam");
 354                 BADCVAR("g_balance_kill_delay");
 355                 BADCVAR("g_buffs_pickup_anyway");
 356                 BADCVAR("g_buffs_randomize");
 357                 BADCVAR("g_buffs_randomize_teamplay");
 358                 BADCVAR("g_campcheck_distance");
 359                 BADCVAR("g_chatsounds");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ca_point_limit");
 362                 BADCVAR("g_ca_spectate_enemies");
 363                 BADCVAR("g_ctf_captimerecord_always");
 364                 BADCVAR("g_ctf_flag_glowtrails");
 365                 BADCVAR("g_ctf_dynamiclights");
 366                 BADCVAR("g_ctf_flag_pickup_verbosename");
 367                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 368                 BADPRESUFFIX("g_ctf_flag_", "_model");
 369                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 370                 BADCVAR("g_domination_point_leadlimit");
 371                 BADCVAR("g_forced_respawn");
 372                 BADCVAR("g_freezetag_point_leadlimit");
 373                 BADCVAR("g_freezetag_point_limit");
 374                 BADCVAR("g_glowtrails");
 375                 BADCVAR("g_hats");
 376                 BADCVAR("g_casings");
 377                 BADCVAR("g_invasion_point_limit");
 378                 BADCVAR("g_jump_grunt");
 379                 BADCVAR("g_keepaway_ballcarrier_effects");
 380                 BADCVAR("g_keepawayball_effects");
 381                 BADCVAR("g_keyhunt_point_leadlimit");
 382                 BADCVAR("g_nexball_goalleadlimit");
 383                 BADCVAR("g_new_toys_autoreplace");
 384                 BADCVAR("g_new_toys_use_pickupsound");
 385                 BADCVAR("g_physics_predictall");
 386                 BADCVAR("g_piggyback");
 387                 BADCVAR("g_playerclip_collisions");
 388                 BADCVAR("g_spawn_alloweffects");
 389                 BADCVAR("g_tdm_point_leadlimit");
 390                 BADCVAR("g_tdm_point_limit");
 391                 BADCVAR("g_mayhem_point_limit");
 392                 BADCVAR("g_mayhem_point_leadlimit");
 393                 BADCVAR("g_tmayhem_point_limit");
 394                 BADCVAR("g_tmayhem_point_leadlimit");
 395                 BADCVAR("leadlimit_and_fraglimit");
 396                 BADCVAR("leadlimit_override");
 397                 BADCVAR("pausable");
 398                 BADCVAR("sv_announcer");
 399                 BADCVAR("sv_autopause");
 400                 BADCVAR("sv_checkforpacketsduringsleep");
 401                 BADCVAR("sv_damagetext");
 402                 BADCVAR("sv_db_saveasdump");
 403                 BADCVAR("sv_intermission_cdtrack");
 404                 BADCVAR("sv_mapchange_delay");
 405                 BADCVAR("sv_minigames");
 406                 BADCVAR("sv_namechangetimer");
 407                 BADCVAR("sv_precacheplayermodels");
 408                 BADCVAR("sv_qcphysics");
 409                 BADCVAR("sv_radio");
 410                 BADCVAR("sv_stepheight");
 411                 BADCVAR("sv_timeout");
 412                 BADCVAR("sv_weapons_modeloverride");
 413                 BADCVAR("w_prop_interval");
 414                 BADPREFIX("chat_");
 415                 BADPREFIX("crypto_");
 416                 BADPREFIX("g_chat_");
 417                 BADPREFIX("g_ctf_captimerecord_");
 418                 BADPREFIX("g_hats_");
 419                 BADPREFIX("g_maplist_");
 420                 BADPREFIX("g_mod_");
 421                 BADPREFIX("g_respawn_");
 422                 BADPREFIX("net_");
 423                 BADPREFIX("notification_");
 424                 BADPREFIX("prvm_");
 425                 BADPREFIX("skill_");
 426                 BADPREFIX("sv_allow_");
 427                 BADPREFIX("sv_cullentities_");
 428                 BADPREFIX("sv_maxidle");
 429                 BADPREFIX("sv_minigames_");
 430                 BADPREFIX("sv_radio_");
 431                 BADPREFIX("sv_timeout_");
 432                 BADPREFIX("sv_vote_");
 433                 BADPREFIX("timelimit_");
 434                 BADPRESUFFIX("g_", "_round_timelimit");
 435
 436                 // allowed changes to server admins (please sync this to server.cfg)
 437                 // vi commands:
 438                 //   :/"impure"/,$d
 439                 //   :g!,^\/\/[^ /],d
 440                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 441                 //   :%!sort
 442                 // yes, this does contain some redundant stuff, don't really care
 443                 BADPREFIX("bot_ai_");
 444                 BADCVAR("bot_config_file");
 445                 BADCVAR("bot_number");
 446                 BADCVAR("bot_prefix");
 447                 BADCVAR("bot_suffix");
 448                 BADCVAR("capturelimit_override");
 449                 BADCVAR("fraglimit_override");
 450                 BADCVAR("gametype");
 451                 BADCVAR("g_antilag");
 452                 BADCVAR("g_balance_teams");
 453                 BADCVAR("g_balance_teams_prevent_imbalance");
 454                 BADCVAR("g_balance_teams_scorefactor");
 455                 BADCVAR("g_ban_sync_trusted_servers");
 456                 BADCVAR("g_ban_sync_uri");
 457                 BADCVAR("g_buffs");
 458                 BADCVAR("g_ca_teams_override");
 459                 BADCVAR("g_ca_prevent_stalemate");
 460                 BADCVAR("g_ctf_fullbrightflags");
 461                 BADCVAR("g_ctf_ignore_frags");
 462                 BADCVAR("g_ctf_leaderboard");
 463                 BADCVAR("g_domination_point_limit");
 464                 BADCVAR("g_domination_teams_override");
 465                 BADCVAR("g_freezetag_revive_spawnshield");
 466                 BADCVAR("g_freezetag_teams_override");
 467                 BADCVAR("g_friendlyfire");
 468                 BADCVAR("g_fullbrightitems");
 469                 BADCVAR("g_fullbrightplayers");
 470                 BADCVAR("g_keyhunt_point_limit");
 471                 BADCVAR("g_keyhunt_teams_override");
 472                 BADCVAR("g_lms_lives_override");
 473                 BADCVAR("g_mayhem_powerups");
 474                 BADCVAR("g_maplist");
 475                 BADCVAR("g_maxplayers");
 476                 BADCVAR("g_mirrordamage");
 477                 BADCVAR("g_nexball_goallimit");
 478                 BADCVAR("g_norecoil");
 479                 BADCVAR("g_physics_clientselect");
 480                 BADCVAR("g_pinata");
 481                 BADCVAR("g_powerups");
 482                 BADCVAR("g_powerups_drop_ondeath");
 483                 BADCVAR("g_player_brightness");
 484                 BADCVAR("g_rocket_flying");
 485                 BADCVAR("g_rocket_flying_disabledelays");
 486                 BADPREFIX("g_spawnshield");
 487                 BADCVAR("g_start_delay");
 488                 BADCVAR("g_superspectate");
 489                 BADCVAR("g_tdm_teams_override");
 490                 BADCVAR("g_tmayhem_teams_override");
 491                 BADCVAR("g_tmayhem_powerups");
 492                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 493                 BADCVAR("hostname");
 494                 BADCVAR("log_file");
 495                 BADCVAR("maxplayers");
 496                 BADCVAR("minplayers");
 497                 BADCVAR("minplayers_per_team");
 498                 BADCVAR("net_address");
 499                 BADCVAR("port");
 500                 BADCVAR("rcon_password");
 501                 BADCVAR("rcon_restricted_commands");
 502                 BADCVAR("rcon_restricted_password");
 503                 BADCVAR("skill");
 504                 BADCVAR("sv_adminnick");
 505                 BADCVAR("sv_autoscreenshot");
 506                 BADCVAR("sv_autotaunt");
 507                 BADCVAR("sv_curl_defaulturl");
 508                 BADCVAR("sv_defaultcharacter");
 509                 BADCVAR("sv_defaultcharacterskin");
 510                 BADCVAR("sv_defaultplayercolors");
 511                 BADCVAR("sv_defaultplayermodel");
 512                 BADCVAR("sv_defaultplayerskin");
 513                 BADCVAR("sv_maxrate");
 514                 BADCVAR("sv_motd");
 515                 BADCVAR("sv_public");
 516                 BADCVAR("sv_showfps");
 517                 BADCVAR("sv_showspectators");
 518                 BADCVAR("sv_status_privacy");
 519                 BADCVAR("sv_taunt");
 520                 BADCVAR("sv_vote_call");
 521                 BADCVAR("sv_vote_commands");
 522                 BADCVAR("sv_vote_majority_factor");
 523                 BADCVAR("sv_vote_master");
 524                 BADCVAR("sv_vote_master_commands");
 525                 BADCVAR("sv_vote_master_password");
 526                 BADCVAR("sv_vote_simple_majority_factor");
 527                 BADVALUE("sys_ticrate", "0.0166667");
 528                 BADVALUE("sys_ticrate", "0.0333333");
 529                 BADCVAR("teamplay_mode");
 530                 BADCVAR("timelimit_override");
 531                 BADPREFIX("g_warmup");
 532                 BADPREFIX("sv_info_");
 533                 BADPREFIX("sv_ready_restart_");
 534
 535                 BADPRESUFFIXVALUE("g_", "_weaponarena", "most");
 536                 BADPRESUFFIXVALUE("g_", "_weaponarena", "most_available");
 537
 538                 // mutators that announce themselves properly to the server browser
 539                 BADCVAR("g_instagib");
 540                 BADCVAR("g_new_toys");
 541                 BADCVAR("g_nix");
 542                 BADCVAR("g_grappling_hook");
 543                 BADCVAR("g_jetpack");
 544
 545 #undef BADPRESUFFIX
 546 #undef BADPREFIX
 547 #undef BADCVAR
 548 #undef BADVALUE
 549 #undef BADPRESUFFIXVALUE
 550
 551                 if(pureadding)
 552                 {
 553                         if (cvar_purechanges == "")
 554                                 cvar_purechanges = "// this server runs at modified gameplay settings:\n";
 555
 556                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 557                         if(strlen(cvar_purechanges) >= VM_TEMPSTRING_MAXSIZE)
 558                         {
 559                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 560                                 pureadding = 0;
 561                         }
 562                 }
 563                 ++cvar_purechanges_count;
 564                 // WARNING: this variable is used for the server list
 565                 // NEVER dare to skip this code!
 566                 // Hacks to intentionally appearing as "pure server" even though you DO have
 567                 // modified settings may be punished by removal from the server list.
 568                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 569                 // though.
 570         }
 571         buf_del(h);
 572
 573         if(cvar_changes == "")
 574                 cvar_changes = "// this server runs at default server settings\n";
 575         cvar_changes = strzone(cvar_changes);
 576
 577         if(cvar_purechanges == "")
 578                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 579         cvar_purechanges = strzone(cvar_purechanges);
 580 }
 581
 582 entity randomseed;
 583 bool RandomSeed_Send(entity this, entity to, int sf)
 584 {
 585         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 586         WriteShort(MSG_ENTITY, this.cnt);
 587         return true;
 588 }
 589 void RandomSeed_Think(entity this)
 590 {
 591         this.cnt = bound(0, floor(random() * 65536), 65535);
 592         this.nextthink = time + 5;
 593
 594         this.SendFlags |= 1;
 595 }
 596 void RandomSeed_Spawn()
 597 {
 598         randomseed = new_pure(randomseed);
 599         setthink(randomseed, RandomSeed_Think);
 600         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 601
 602         getthink(randomseed)(randomseed); // sets random seed and nextthink
 603 }
 604
 605 spawnfunc(__init_dedicated_server)
 606 {
 607         // handler for _init/_init map (only for dedicated server initialization)
 608
 609         world_initialized = -1; // don't complain
 610
 611         delete_fn = remove_unsafely;
 612
 613         entity e = new(GotoFirstMap);
 614         setthink(e, GotoFirstMap);
 615         e.nextthink = time; // this is usually 1 at this point
 616
 617         e = new(info_player_deathmatch);  // safeguard against player joining
 618
 619         // assign reflectively to avoid "assignment to world" warning
 620         for (int i = 0, n = numentityfields(); i < n; ++i)
 621         {
 622                 string k = entityfieldname(i);
 623                 if (k == "classname")
 624                 {
 625                         // safeguard against various stuff ;)
 626                         putentityfieldstring(i, this, "worldspawn");
 627                         break;
 628                 }
 629         }
 630
 631         // needs to be done so early because of the constants they create
 632         static_init();
 633         static_init_late();
 634         static_init_precache();
 635
 636         IL_PUSH(g_spawnpoints, e); // just incase
 637
 638         MapInfo_Enumerate();
 639         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 640 }
 641
 642 void __init_dedicated_server_shutdown() {
 643         MapInfo_Shutdown();
 644 }
 645
 646 STATIC_INIT_EARLY(maxclients)
 647 {
 648         maxclients = 0;
 649         for (entity head = nextent(NULL); head; head = nextent(head)) {
 650                 ++maxclients;
 651         }
 652 }
 653
 654 void GameplayMode_DelayedInit(entity this)
 655 {
 656         // at this stage team entities are spawned, teamplay contains the number of them
 657
 658         if(!scores_initialized)
 659                 ScoreRules_generic();
 660
 661         if (warmup_stage >= 0 && autocvar_g_maxplayers >= 0)
 662                 return;
 663         if (!g_duel)
 664                 MapReadSizes(mapname);
 665
 666         if (autocvar_g_maxplayers < 0)
 667         {
 668                 if (map_maxplayers <= 0)
 669                         map_maxplayers = maxclients; // unlimited, but may need rounding
 670                 map_maxplayers = bound(max(2, AVAILABLE_TEAMS * 2), map_maxplayers, maxclients);
 671                 if (teamplay)
 672                 {
 673                         // automatic maxplayers should be a multiple of team count
 674                         int down = map_maxplayers % AVAILABLE_TEAMS;
 675                         int up = AVAILABLE_TEAMS - down;
 676                         map_maxplayers += (up < down && up + map_maxplayers <= maxclients) ? up : -down;
 677                 }
 678         }
 679
 680         if (warmup_stage < 0)
 681         {
 682                 int m = GetPlayerLimit();
 683                 if (m <= 0) m = maxclients;
 684                 map_minplayers = bound(max(2, AVAILABLE_TEAMS * 2), map_minplayers, m);
 685                 if (teamplay)
 686                 {
 687                         // automatic minplayers should be a multiple of team count
 688                         int down = map_minplayers % AVAILABLE_TEAMS;
 689                         int up = AVAILABLE_TEAMS - down;
 690                         map_minplayers += (up < down && up + map_minplayers <= m) ? up : -down;
 691                 }
 692         }
 693         else
 694                 map_minplayers = 0; // don't display a minimum if it's not used (g_maxplayers < 0 && g_warmup >= 0)
 695 }
 696
 697 void InitGameplayMode()
 698 {
 699         VoteReset(false);
 700
 701         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 702         get_mi_min_max(1);
 703         // assign reflectively to avoid "assignment to world" warning
 704         for (int i = 0, done = 0, n = numentityfields(); i < n; ++i)
 705         {
 706                 string k = entityfieldname(i);
 707                 vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 708                 if (v)
 709                 {
 710                         putentityfieldstring(i, world, sprintf("%v", v));
 711                         if (++done == 2) break;
 712                 }
 713         }
 714         // currently, NetRadiant's limit is 131072 qu for each side
 715         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 716         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 717         // in case somebody makes extremely large maps
 718         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 719
 720         MapInfo_LoadMapSettings(mapname);
 721         GameRules_teams(false);
 722
 723         if (!cvar_value_issafe(world.fog))
 724         {
 725                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 726                 world.fog = string_null;
 727         }
 728         if(MapInfo_Map_fog != "")
 729         {
 730                 if(MapInfo_Map_fog == "none")
 731                         world.fog = string_null;
 732                 else
 733                         world.fog = strzone(MapInfo_Map_fog);
 734         }
 735         clientstuff = strzone(MapInfo_Map_clientstuff);
 736
 737         MapInfo_ClearTemps();
 738
 739         strcpy(loaded_gametype_custom_string, autocvar__sv_vote_gametype_custom);
 740         gametype_custom_enabled = (loaded_gametype_custom_string != "");
 741         cvar_set("_sv_vote_gametype_custom", ""); // clear it immediately so it can't get stuck
 742
 743         cache_mutatormsg = strzone("");
 744         cache_lastmutatormsg = strzone("");
 745
 746         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 747 }
 748
 749 bool world_already_spawned;
 750 spawnfunc(worldspawn)
 751 {
 752         CheckEngineExtensions();
 753
 754         cvar_set("_endmatch", "0");
 755         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 756
 757         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 758         {
 759                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 760         }
 761         else
 762         {
 763                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 764         }
 765
 766         bool wantrestart = false;
 767         {
 768                 if (!server_is_dedicated)
 769                 {
 770                         // DP unloads dlcache pk3s before starting a listen server since https://gitlab.com/xonotic/darkplaces/-/merge_requests/134
 771                         // restore csqc_progname too
 772                         string expect = "csprogs.dat";
 773                         wantrestart = cvar_string("csqc_progname") != expect;
 774                         cvar_set("csqc_progname", expect);
 775                 }
 776                 else
 777                 {
 778                         // Try to use versioned csprogs from pk3
 779                         // Only ever use versioned csprogs.dat files on dedicated servers;
 780                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 781                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 782                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 783                         string select = "csprogs.dat";
 784                         if (fexists(pk3csprogs)) select = pk3csprogs;
 785                         if (cvar_string("csqc_progname") != select)
 786                         {
 787                                 cvar_set("csqc_progname", select);
 788                                 wantrestart = true;
 789                         }
 790                         // Check for updates on startup
 791                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 792                         int sentinel = fopen("progs.txt", FILE_READ);
 793                         if (sentinel >= 0)
 794                         {
 795                                 string switchversion = fgets(sentinel);
 796                                 fclose(sentinel);
 797                                 if (switchversion != "" && switchversion != WATERMARK)
 798                                 {
 799                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 800                                         // if it doesn't exist, assume either:
 801                                         //   a) the current program was overwritten
 802                                         //   b) this is a client only update
 803                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 804                                         if (fexists(newprogs))
 805                                         {
 806                                                 cvar_set("sv_progs", newprogs);
 807                                                 wantrestart = true;
 808                                         }
 809                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 810                                         if (fexists(newcsprogs))
 811                                         {
 812                                                 cvar_set("csqc_progname", newcsprogs);
 813                                                 wantrestart = true;
 814                                         }
 815                                 }
 816                         }
 817                 }
 818                 if (wantrestart)
 819                 {
 820                         LOG_INFO("Restart requested");
 821                         changelevel(mapname);
 822                         // let initialization continue, shutdown depends on it
 823                 }
 824         }
 825
 826         if(world_already_spawned)
 827                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 828         world_already_spawned = true;
 829
 830         delete_fn = remove_safely; // during spawning, watch what you remove!
 831
 832         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 833
 834         // default to RACE_RECORD, can be overwritten by gamemodes
 835         record_type = RACE_RECORD;
 836
 837         // needs to be done so early because of the constants they create
 838         static_init();
 839
 840         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 841
 842         TemporaryDB = db_create();
 843
 844         // 0 normal
 845         lightstyle(0, "m");
 846
 847         // 1 FLICKER (first variety)
 848         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 849
 850         // 2 SLOW STRONG PULSE
 851         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 852
 853         // 3 CANDLE (first variety)
 854         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 855
 856         // 4 FAST STROBE
 857         lightstyle(4, "mamamamamama");
 858
 859         // 5 GENTLE PULSE 1
 860         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 861
 862         // 6 FLICKER (second variety)
 863         lightstyle(6, "nmonqnmomnmomomno");
 864
 865         // 7 CANDLE (second variety)
 866         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 867
 868         // 8 CANDLE (third variety)
 869         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 870
 871         // 9 SLOW STROBE (fourth variety)
 872         lightstyle(9, "aaaaaaaazzzzzzzz");
 873
 874         // 10 FLUORESCENT FLICKER
 875         lightstyle(10, "mmamammmmammamamaaamammma");
 876
 877         // 11 SLOW PULSE NOT FADE TO BLACK
 878         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 879
 880         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 881
 882         // 63 testing
 883         lightstyle(63, "a");
 884
 885         if(autocvar_g_campaign)
 886                 CampaignPreInit();
 887         else
 888                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 889
 890         Map_MarkAsRecent(mapname);
 891
 892         InitGameplayMode();
 893         static_init_late();
 894         static_init_precache();
 895         readlevelcvars();
 896
 897         GameRules_limit_fallbacks();
 898
 899         player_count = 0;
 900         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 901         if(bot_waypoints_for_items == 1)
 902                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 903                         bot_waypoints_for_items = 0;
 904
 905         WaypointSprite_Init();
 906
 907         // NOTE for matchid:
 908         // changing the logic generating it is okay. But:
 909         // it HAS to stay <= 64 chars
 910         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 911         // strftime(false, "%s") isn't reliable, see strftime_s description
 912         matchid = strzone(sprintf("%d.%s.%06d", autocvar_sv_eventlog_files_counter, strftime_s(), random() * 1000000));
 913
 914         if(autocvar_sv_eventlog)
 915                 GameLogInit(); // requires matchid to be set
 916
 917         cvar_set("nextmap", "");
 918
 919         SetDefaultAlpha();
 920
 921         if(autocvar_g_campaign)
 922                 CampaignPostInit();
 923
 924         Ban_LoadBans();
 925
 926         MapInfo_Enumerate();
 927         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 928
 929         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, _MapInfo_FindArenaFile(mapname, ".arena") != "");
 930         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, _MapInfo_FindArenaFile(mapname, ".defi") != "");
 931
 932         // quake 3 music support
 933         if(world.music || world.noise)
 934         {
 935                 // prefer .music over .noise
 936                 string chosen_music;
 937                 if(world.music)
 938                         chosen_music = world.music;
 939                 else
 940                         chosen_music = world.noise;
 941
 942                 string newstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 943                 strcpy(clientstuff, newstuff);
 944         }
 945
 946         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 947         {
 948                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 949                 if(fd != -1)
 950                 {
 951                         string s;
 952                         while((s = fgets(fd)))
 953                         {
 954                                 int l = tokenize_console(s);
 955                                 if(l < 2)
 956                                         continue;
 957                                 if(argv(0) == "cd")
 958                                 {
 959                                         string trackname = argv(2);
 960                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 961                                         LOG_INFO("  cdtrack ", trackname);
 962                                         if (cvar_value_issafe(trackname))
 963                                         {
 964                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 965                                                 strcpy(clientstuff, newstuff);
 966                                         }
 967                                 }
 968                                 else if(argv(0) == "fog")
 969                                 {
 970                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 971                                         LOG_INFO("  \"fog\" \"", s, "\"");
 972                                 }
 973                                 else if(argv(0) == "set")
 974                                 {
 975                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 976                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 977                                 }
 978                                 else if(argv(0) != "//")
 979                                 {
 980                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 981                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 982                                 }
 983                         }
 984                         fclose(fd);
 985                 }
 986         }
 987
 988         WeaponStats_Init();
 989
 990         Nagger_Init();
 991
 992         // set up information replies for clients and server to use
 993         maplist_reply = strzone(getmaplist());
 994         lsmaps_reply = strzone(getlsmaps());
 995         monsterlist_reply = strzone(getmonsterlist());
 996         bool records_available = false;
 997         for(int i = 0; i < 10; ++i)
 998         {
 999                 string s = getrecords(i);
1000                 if (s != "")
1001                 {
1002                         records_reply[i] = strzone(s);
1003                         records_available = true;
1004                 }
1005         }
1006         if (!records_available)
1007                 records_reply[0] = "No records available for the current game mode.\n";
1008         ladder_reply = strzone(getladder());
1009         rankings_reply = strzone(getrankings());
1010
1011         // begin other init
1012         ClientInit_Spawn();
1013         RandomSeed_Spawn();
1014         PingPLReport_Spawn();
1015
1016         CheatInit();
1017
1018         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
1019
1020         // fill sv_curl_serverpackages from .serverpackage files
1021         if (autocvar_sv_curl_serverpackages_auto)
1022         {
1023                 string s = "csprogs-" WATERMARK ".dat";
1024                 // remove automatically managed files from the list to prevent duplicates
1025                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
1026                 {
1027                         string pkg = argv(i);
1028                         if (startsWith(pkg, "csprogs-")) continue;
1029                         if (endsWith(pkg, "-serverpackage.txt")) continue;
1030                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
1031                         s = cons(s, pkg);
1032                 }
1033                 // add automatically managed files to the list
1034                 #define X(match) MACRO_BEGIN \
1035                         int fd = search_begin(match, true, false); \
1036                         if (fd >= 0) \
1037                         { \
1038                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
1039                                 { \
1040                                         s = cons(s, search_getfilename(fd, i)); \
1041                                 } \
1042                                 search_end(fd); \
1043                         } \
1044                 MACRO_END
1045                 X("*-serverpackage.txt");
1046                 X("*.serverpackage");
1047                 #undef X
1048                 cvar_set("sv_curl_serverpackages", s);
1049         }
1050
1051         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1052         modname = "Xonotic";
1053         // physics/balance/config changes that count as mod
1054         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1055                 modname = cvar_string("g_mod_physics");
1056         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1057                 modname = cvar_string("g_mod_balance");
1058         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1059                 modname = cvar_string("g_mod_config");
1060         // extra mutators that deserve to count as mod
1061         MUTATOR_CALLHOOK(SetModname, modname);
1062         modname = M_ARGV(0, string);
1063
1064         // save it for later
1065         modname = strzone(modname);
1066
1067         WinningConditionHelper(this); // set worldstatus
1068
1069         if (autocvar_sv_autopause && server_is_dedicated && !wantrestart)
1070                 // INITPRIO_LAST is too soon: bots either didn't join yet or didn't leave yet, see: bot_fixcount()
1071                 defer(this, 5, Pause_TryPause_Dedicated);
1072
1073         world_initialized = 1;
1074         __spawnfunc_spawn_all();
1075 }
1076
1077 spawnfunc(light)
1078 {
1079         //makestatic (this); // Who the f___ did that?
1080         delete(this);
1081 }
1082
1083 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1084 {
1085         float m = e.dphitcontentsmask;
1086         e.dphitcontentsmask = goodcontents | badcontents;
1087
1088         vector org = boundmin;
1089         vector delta = boundmax - boundmin;
1090
1091         vector start, end;
1092         start = end = org;
1093         int j; // used after the loop
1094         for(j = 0; j < attempts; ++j)
1095         {
1096                 start.x = org.x + random() * delta.x;
1097                 start.y = org.y + random() * delta.y;
1098                 start.z = org.z + random() * delta.z;
1099
1100                 // rule 1: start inside world bounds, and outside
1101                 // solid, and don't start from somewhere where you can
1102                 // fall down to evil
1103                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1104                 if (trace_fraction >= 1)
1105                         continue;
1106                 if (trace_startsolid)
1107                         continue;
1108                 if (trace_dphitcontents & badcontents)
1109                         continue;
1110                 if (trace_dphitq3surfaceflags & badsurfaceflags)
1111                         continue;
1112
1113                 // rule 2: if we are too high, lower the point
1114                 if (trace_fraction * delta.z > maxaboveground)
1115                         start = trace_endpos + '0 0 1' * maxaboveground;
1116                 vector enddown = trace_endpos;
1117
1118                 // rule 3: make sure we aren't outside the map. This only works
1119                 // for somewhat well formed maps. A good rule of thumb is that
1120                 // the map should have a convex outside hull.
1121                 // these can be traceLINES as we already verified the starting box
1122                 vector mstart = start + 0.5 * (e.mins + e.maxs);
1123                 traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1124                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1125                         continue;
1126                 traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1127                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1128                         continue;
1129                 traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1130                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1131                         continue;
1132                 traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1133                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1134                         continue;
1135                 traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1136                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1137                         continue;
1138
1139                 // rule 4: we must "see" some spawnpoint or item
1140                 entity sp = NULL;
1141                 if(frompos)
1142                 {
1143                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1144                                 sp = e;
1145                 }
1146                 if(!sp)
1147                 {
1148                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1149                         {
1150                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1151                                 {
1152                                         sp = it;
1153                                         break;
1154                                 }
1155                         });
1156                 }
1157                 if(!sp)
1158                 {
1159                         int items_checked = 0;
1160                         IL_EACH(g_items, checkpvs(mstart, it),
1161                         {
1162                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1163                                 {
1164                                         sp = it;
1165                                         break;
1166                                 }
1167
1168                                 ++items_checked;
1169                                 if(items_checked >= attempts)
1170                                         break; // sanity
1171                         });
1172
1173                         if(!sp)
1174                                 continue;
1175                 }
1176
1177                 // find a random vector to "look at"
1178                 end.x = org.x + random() * delta.x;
1179                 end.y = org.y + random() * delta.y;
1180                 end.z = org.z + random() * delta.z;
1181                 end = start + normalize(end - start) * vlen(delta);
1182
1183                 // rule 4: start TO end must not be too short
1184                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1185                 if(trace_startsolid)
1186                         continue;
1187                 if(trace_fraction < minviewdistance / vlen(delta))
1188                         continue;
1189
1190                 // rule 5: don't want to look at sky
1191                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1192                         continue;
1193
1194                 // rule 6: we must not end up in trigger_hurt
1195                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1196                         continue;
1197
1198                 break;
1199         }
1200
1201         e.dphitcontentsmask = m;
1202
1203         if(j < attempts)
1204         {
1205                 setorigin(e, start);
1206                 e.angles = vectoangles(end - start);
1207                 LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1208                 return true;
1209         }
1210         return false;
1211 }
1212
1213 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1214 {
1215         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1216 }
1217
1218 /*
1219 ===============================================================================
1220
1221 RULES
1222
1223 ===============================================================================
1224 */
1225
1226 void DumpStats(float final)
1227 {
1228         float file;
1229         string s;
1230         float to_console;
1231         float to_eventlog;
1232         float to_file;
1233         float i;
1234
1235         to_console = autocvar_sv_logscores_console;
1236         to_eventlog = autocvar_sv_eventlog;
1237         to_file = autocvar_sv_logscores_file;
1238
1239         if(!final)
1240         {
1241                 to_console = true; // always print printstats replies
1242                 to_eventlog = false; // but never print them to the event log
1243         }
1244
1245         if(to_eventlog)
1246                 if(autocvar_sv_eventlog_console)
1247                         to_console = false; // otherwise we get the output twice
1248
1249         if(final)
1250                 s = ":scores:";
1251         else
1252                 s = ":status:";
1253         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1254
1255         if(to_console)
1256                 LOG_HELP(s);
1257         if(to_eventlog)
1258                 GameLogEcho(s);
1259
1260         file = -1;
1261         if(to_file)
1262         {
1263                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1264                 if(file == -1)
1265                         to_file = false;
1266                 else
1267                         fputs(file, strcat(s, "\n"));
1268         }
1269
1270         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1271         if(to_console)
1272                 LOG_HELP(s);
1273         if(to_eventlog)
1274                 GameLogEcho(s);
1275         if(to_file)
1276                 fputs(file, strcat(s, "\n"));
1277
1278         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1279                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1280                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1281                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1282                         s = strcat(s, ftos(it.team), ":");
1283                 else
1284                         s = strcat(s, "spectator:");
1285
1286                 if(to_console)
1287                         LOG_HELP(s, playername(it.netname, it.team, false));
1288                 if(to_eventlog)
1289                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1290                 if(to_file)
1291                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1292         });
1293
1294         if(teamplay)
1295         {
1296                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1297                 if(to_console)
1298                         LOG_HELP(s);
1299                 if(to_eventlog)
1300                         GameLogEcho(s);
1301                 if(to_file)
1302                         fputs(file, strcat(s, "\n"));
1303
1304                 for(i = 1; i < 16; ++i)
1305                 {
1306                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1307                         s = strcat(s, ":", ftos(i));
1308                         if(to_console)
1309                                 LOG_HELP(s);
1310                         if(to_eventlog)
1311                                 GameLogEcho(s);
1312                         if(to_file)
1313                                 fputs(file, strcat(s, "\n"));
1314                 }
1315         }
1316
1317         if(to_console)
1318                 LOG_HELP(":end");
1319         if(to_eventlog)
1320                 GameLogEcho(":end");
1321         if(to_file)
1322         {
1323                 fputs(file, ":end\n");
1324                 fclose(file);
1325         }
1326 }
1327
1328 /*
1329 go to the next level for deathmatch
1330 only called if a time or frag limit has expired
1331 */
1332 void NextLevel()
1333 {
1334         cvar_set("_endmatch", "0");
1335         game_stopped = true;
1336         intermission_running = true; // game over
1337
1338         // enforce a wait time before allowing changelevel
1339         if(player_count > 0)
1340                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1341         else
1342                 intermission_exittime = -1;
1343
1344         /*
1345         WriteByte (MSG_ALL, SVC_CDTRACK);
1346         WriteByte (MSG_ALL, 3);
1347         WriteByte (MSG_ALL, 3);
1348         // done in FixIntermission
1349         */
1350
1351         //pos = FindIntermission ();
1352
1353         VoteReset(true);
1354
1355         DumpStats(true);
1356
1357         // send statistics
1358         PlayerStats_GameReport(true);
1359         WeaponStats_Shutdown();
1360
1361         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1362
1363         if(autocvar_sv_eventlog)
1364                 GameLogEcho(":gameover");
1365
1366         GameLogClose();
1367
1368         int winner_team = 0;
1369         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1370                 FixIntermissionClient(it);
1371                 if(it.winning)
1372                 {
1373                         if (teamplay && !winner_team)
1374                         {
1375                                 winner_team = it.team;
1376                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1377                         }
1378                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1379                 }
1380         });
1381
1382         target_music_kill();
1383
1384         if(autocvar_g_campaign)
1385                 CampaignPreIntermission();
1386
1387         MUTATOR_CALLHOOK(MatchEnd);
1388
1389         localcmd("\nsv_hook_gameend\n");
1390 }
1391
1392
1393 int InitiateSuddenDeath()
1394 {
1395         // Check first whether normal overtimes could be added before initiating suddendeath mode
1396         // - for this timelimit_overtime needs to be >0 of course
1397         // - also check the winning condition calculated in the previous frame and only add normal overtime
1398         //   again, if at the point at which timelimit would be extended again, still no winner was found
1399         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1400                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1401                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1402         {
1403                 return 1; // need to call InitiateOvertime later
1404         }
1405         else
1406         {
1407                 if(!checkrules_suddendeathend)
1408                 {
1409                         if(autocvar_g_campaign)
1410                         {
1411                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1412                         }
1413                         else
1414                         {
1415                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1416                                 overtimes = -1;
1417                         }
1418                         if(g_race && !g_race_qualifying)
1419                                 race_StartCompleting();
1420                 }
1421                 return 0;
1422         }
1423 }
1424
1425 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1426 {
1427         ++checkrules_overtimesadded;
1428         overtimes = checkrules_overtimesadded;
1429         //add one more overtime by simply extending the timelimit
1430         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1431         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1432 }
1433
1434 float GetWinningCode(float fraglimitreached, float equality)
1435 {
1436         if(autocvar_g_campaign == 1)
1437         {
1438                 if(fraglimitreached)
1439                         return WINNING_YES;
1440                 else
1441                         return WINNING_NO;
1442         }
1443         else
1444         {
1445                 if(equality)
1446                 {
1447                         if(fraglimitreached)
1448                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1449                         else
1450                                 return WINNING_NEVER;
1451                 }
1452                 else
1453                 {
1454                         if(fraglimitreached)
1455                                 return WINNING_YES;
1456                         else
1457                                 return WINNING_NO;
1458                 }
1459         }
1460 }
1461
1462 // set the .winning flag for exactly those players with a given field value
1463 void SetWinners(.float field, float value)
1464 {
1465         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1466 }
1467
1468 // set the .winning flag for those players with a given field value
1469 void AddWinners(.float field, float value)
1470 {
1471         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1472                 if(it.(field) == value)
1473                         it.winning = 1;
1474         });
1475 }
1476
1477 // clear the .winning flags
1478 void ClearWinners()
1479 {
1480         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1481 }
1482
1483 int fragsleft_last;
1484 float WinningCondition_Scores(float limit, float leadlimit)
1485 {
1486         // TODO make everything use THIS winning condition (except LMS)
1487         WinningConditionHelper(NULL);
1488
1489         if(teamplay)
1490         {
1491                 for (int i = 1; i < 5; ++i)
1492                 {
1493                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1494                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1495                 }
1496         }
1497
1498         ClearWinners();
1499         if(WinningConditionHelper_winner)
1500                 WinningConditionHelper_winner.winning = 1;
1501         if(WinningConditionHelper_winnerteam >= 0)
1502                 SetWinners(team, WinningConditionHelper_winnerteam);
1503
1504         if(WinningConditionHelper_lowerisbetter)
1505         {
1506                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1507                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1508                 limit = -limit;
1509         }
1510
1511         if(WinningConditionHelper_zeroisworst)
1512                 leadlimit = 0; // not supported in this mode
1513
1514         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1515         {
1516                 float fragsleft;
1517                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1518                 {
1519                         fragsleft = 1;
1520                 }
1521                 else
1522                 {
1523                         fragsleft = FLOAT_MAX;
1524                         float leadingfragsleft = FLOAT_MAX;
1525                         if (limit)
1526                                 fragsleft = limit - WinningConditionHelper_topscore;
1527                         if (leadlimit)
1528                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1529
1530                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1531                                 fragsleft = max(fragsleft, leadingfragsleft);
1532                         else
1533                                 fragsleft = min(fragsleft, leadingfragsleft);
1534                 }
1535
1536                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1537                 {
1538                         if (fragsleft == 1)
1539                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1540                         else if (fragsleft == 2)
1541                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1542                         else if (fragsleft == 3)
1543                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1544
1545                         fragsleft_last = fragsleft;
1546                 }
1547         }
1548
1549         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1550         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1551
1552         bool limit_reached;
1553         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1554         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1555                 limit_reached = (fraglimit_reached && leadlimit_reached);
1556         else
1557                 limit_reached = (fraglimit_reached || leadlimit_reached);
1558
1559         return GetWinningCode(
1560                 WinningConditionHelper_topscore && limit_reached,
1561                 WinningConditionHelper_equality
1562         );
1563 }
1564
1565 float WinningCondition_RanOutOfSpawns()
1566 {
1567         if(have_team_spawns <= 0)
1568                 return WINNING_NO;
1569
1570         if(!autocvar_g_spawn_useallspawns)
1571                 return WINNING_NO;
1572
1573         if(!some_spawn_has_been_used)
1574                 return WINNING_NO;
1575
1576         for (int i = 1; i < 5; ++i)
1577         {
1578                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1579         }
1580
1581         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1582         {
1583                 if (Team_IsValidTeam(it.team))
1584                 {
1585                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1586                 }
1587         });
1588
1589         IL_EACH(g_spawnpoints, true,
1590         {
1591                 if (Team_IsValidTeam(it.team))
1592                 {
1593                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1594                 }
1595         });
1596
1597         ClearWinners();
1598         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1599         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1600         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1601         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1602         if(team1_score + team2_score + team3_score + team4_score == 0)
1603         {
1604                 checkrules_equality = true;
1605                 return WINNING_YES;
1606         }
1607         else if(team1_score + team2_score + team3_score + team4_score == 1)
1608         {
1609                 float t, i;
1610                 if(team1_score)
1611                         t = 1;
1612                 else if(team2_score)
1613                         t = 2;
1614                 else if(team3_score)
1615                         t = 3;
1616                 else // if(team4_score)
1617                         t = 4;
1618                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1619                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1620                 {
1621                         for (int j = 1; j <= NUM_TEAMS; ++j)
1622                         {
1623                                 if (t == j)
1624                                 {
1625                                         continue;
1626                                 }
1627                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1628                                 {
1629                                         continue;
1630                                 }
1631                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1632                         }
1633                 }
1634
1635                 AddWinners(team, t);
1636                 return WINNING_YES;
1637         }
1638         else
1639                 return WINNING_NO;
1640 }
1641
1642 /*
1643 ============
1644 CheckRules_World
1645
1646 Exit deathmatch games upon conditions
1647 ============
1648 */
1649 void CheckRules_World()
1650 {
1651         VoteThink();
1652         MapVote_Think();
1653
1654         SetDefaultAlpha();
1655
1656         if (intermission_running) // someone else quit the game already
1657         {
1658                 if(player_count == 0) // Nobody there? Then let's go to the next map
1659                         MapVote_Start();
1660                         // this will actually check the player count in the next frame
1661                         // again, but this shouldn't hurt
1662                 return;
1663         }
1664
1665         float timelimit = autocvar_timelimit * 60;
1666         float fraglimit = autocvar_fraglimit;
1667         float leadlimit = autocvar_leadlimit;
1668         if (leadlimit < 0) leadlimit = 0;
1669
1670         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1671         {
1672                 if(timelimit > 0)
1673                         timelimit = 0; // timelimit is not made for warmup
1674                 if(fraglimit > 0)
1675                         fraglimit = 0; // no fraglimit for now
1676                 leadlimit = 0; // no leadlimit for now
1677         }
1678
1679         if (autocvar__endmatch || timelimit < 0)
1680         {
1681                 // endmatch
1682                 NextLevel();
1683                 return;
1684         }
1685
1686         if(timelimit > 0)
1687                 timelimit += game_starttime;
1688
1689         int overtimes_prev = overtimes;
1690         int wantovertime = 0;
1691
1692         if(checkrules_suddendeathend)
1693         {
1694                 if(!checkrules_suddendeathwarning)
1695                 {
1696                         checkrules_suddendeathwarning = true;
1697                         if(g_race && !g_race_qualifying)
1698                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1699                         else
1700                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1701                 }
1702         }
1703         else
1704         {
1705                 if (timelimit && time >= timelimit)
1706                 {
1707                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1708                         {
1709                                 float totalplayers;
1710                                 float playerswithlaps;
1711                                 float readyplayers;
1712                                 totalplayers = playerswithlaps = readyplayers = 0;
1713                                 FOREACH_CLIENT(IS_PLAYER(it), {
1714                                         ++totalplayers;
1715                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1716                                                 ++playerswithlaps;
1717                                         if(it.ready)
1718                                                 ++readyplayers;
1719                                 });
1720
1721                                 // at least 2 of the players have completed a lap: start the RACE
1722                                 // otherwise, the players should end the qualifying on their own
1723                                 if(readyplayers || playerswithlaps >= 2)
1724                                 {
1725                                         checkrules_suddendeathend = 0;
1726                                         ReadyRestart(true); // go to race
1727                                         return;
1728                                 }
1729                                 else
1730                                         wantovertime |= InitiateSuddenDeath();
1731                         }
1732                         else
1733                                 wantovertime |= InitiateSuddenDeath();
1734                 }
1735         }
1736
1737         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1738         {
1739                 NextLevel();
1740                 return;
1741         }
1742
1743         int checkrules_status = WinningCondition_RanOutOfSpawns();
1744         if(checkrules_status == WINNING_YES)
1745                 bprint("Hey! Someone ran out of spawns!\n");
1746         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1747                 checkrules_status = M_ARGV(0, float);
1748         else
1749                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1750
1751         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1752         {
1753                 checkrules_status = WINNING_NEVER;
1754                 checkrules_overtimesadded = -1;
1755                 wantovertime |= InitiateSuddenDeath();
1756         }
1757
1758         if(checkrules_status == WINNING_NEVER)
1759                 // equality cases! Nobody wins if the overtime ends in a draw.
1760                 ClearWinners();
1761
1762         if(wantovertime)
1763         {
1764                 if(checkrules_status == WINNING_NEVER)
1765                         InitiateOvertime();
1766                 else
1767                         checkrules_status = WINNING_YES;
1768         }
1769
1770         if(checkrules_suddendeathend)
1771                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1772                         checkrules_status = WINNING_YES;
1773
1774         if(checkrules_status == WINNING_YES)
1775         {
1776                 if (overtimes == -1 && overtimes != overtimes_prev)
1777                 {
1778                         // if suddendeathend overtime has just begun, revert it
1779                         checkrules_suddendeathend = 0;
1780                         overtimes = overtimes_prev;
1781                 }
1782                 //print("WINNING\n");
1783                 NextLevel();
1784         }
1785 }
1786
1787 float want_weapon(entity weaponinfo, float allguns)
1788 {
1789         int d = 0;
1790         bool allow_mutatorblocked = false;
1791
1792         if(!weaponinfo.m_id)
1793                 return 0;
1794
1795         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1796         d = M_ARGV(1, float);
1797         allguns = M_ARGV(2, bool);
1798         allow_mutatorblocked = M_ARGV(3, bool);
1799
1800         if(allguns)
1801                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1802         else if(!mutator_returnvalue)
1803                 d = !(!weaponinfo.weaponstart);
1804
1805         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1806                 d = 0;
1807
1808         float t = weaponinfo.weaponstartoverride;
1809
1810         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1811
1812         // bit order in t:
1813         // 1: want or not
1814         // 2: is default?
1815         // 4: is set by default?
1816         if(t < 0)
1817                 t = 4 | (3 * d);
1818         else
1819                 t |= (2 * d);
1820
1821         return t;
1822 }
1823
1824 /// Weapons the player normally starts with outside weapon arena.
1825 WepSet weapons_start()
1826 {
1827         WepSet ret = '0 0 0';
1828         FOREACH(Weapons, it != WEP_Null, {
1829                 int w = want_weapon(it, false);
1830                 if (w & 1)
1831                         ret |= it.m_wepset;
1832         });
1833         return ret;
1834 }
1835
1836 WepSet weapons_all()
1837 {
1838         WepSet ret = '0 0 0';
1839         FOREACH(Weapons, it != WEP_Null, {
1840                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1841                         ret |= it.m_wepset;
1842         });
1843         return ret;
1844 }
1845
1846 WepSet weapons_devall()
1847 {
1848         WepSet ret = '0 0 0';
1849         FOREACH(Weapons, it != WEP_Null,
1850         {
1851                 ret |= it.m_wepset;
1852         });
1853         return ret;
1854 }
1855
1856 WepSet weapons_most()
1857 {
1858         WepSet ret = '0 0 0';
1859         FOREACH(Weapons, it != WEP_Null, {
1860                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1861                         ret |= it.m_wepset;
1862         });
1863         return ret;
1864 }
1865
1866 void weaponarena_available_all_update(entity this)
1867 {
1868         if (weaponsInMapAll)
1869         {
1870                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1871         }
1872         else
1873         {
1874                 // if no weapons are available on the map, just fall back to all weapons arena
1875                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1876         }
1877 }
1878
1879 void weaponarena_available_devall_update(entity this)
1880 {
1881         if (weaponsInMapAll)
1882         {
1883                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1884         }
1885         else
1886         {
1887                 // if no weapons are available on the map, just fall back to devall weapons arena
1888                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1889         }
1890 }
1891
1892 void weaponarena_available_most_update(entity this)
1893 {
1894         if (weaponsInMapAll)
1895         {
1896                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1897         }
1898         else
1899         {
1900                 // if no weapons are available on the map, just fall back to most weapons arena
1901                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1902         }
1903 }
1904
1905 void readplayerstartcvars()
1906 {
1907         // initialize starting values for players
1908         start_weapons = '0 0 0';
1909         start_weapons_default = '0 0 0';
1910         start_weapons_defaultmask = '0 0 0';
1911         start_items = 0;
1912         start_ammo_shells = 0;
1913         start_ammo_nails = 0;
1914         start_ammo_rockets = 0;
1915         start_ammo_cells = 0;
1916         start_ammo_plasma = 0;
1917         if (random_start_ammo == NULL)
1918         {
1919                 random_start_ammo = new_pure(random_start_ammo);
1920         }
1921         start_health = cvar("g_balance_health_start");
1922         start_armorvalue = cvar("g_balance_armor_start");
1923
1924         g_weaponarena = 0;
1925         g_weaponarena_weapons = '0 0 0';
1926
1927         string s = cvar_string("g_weaponarena");
1928
1929         MUTATOR_CALLHOOK(SetWeaponArena, s);
1930         s = M_ARGV(0, string);
1931
1932         if (s == "0" || s == "")
1933         {
1934                 // no arena
1935         }
1936         else if (s == "off")
1937         {
1938                 // forcibly turn off weaponarena
1939         }
1940         else if (s == "all" || s == "1")
1941         {
1942                 g_weaponarena = 1;
1943                 g_weaponarena_list = "All Weapons Arena";
1944                 g_weaponarena_weapons = weapons_all();
1945         }
1946         else if (s == "devall")
1947         {
1948                 g_weaponarena = 1;
1949                 g_weaponarena_list = "Dev All Weapons Arena";
1950                 g_weaponarena_weapons = weapons_devall();
1951         }
1952         else if (s == "most")
1953         {
1954                 g_weaponarena = 1;
1955                 g_weaponarena_list = "Most Weapons Arena";
1956                 g_weaponarena_weapons = weapons_most();
1957         }
1958         else if (s == "all_available")
1959         {
1960                 g_weaponarena = 1;
1961                 g_weaponarena_list = "All Available Weapons Arena";
1962
1963                 // this needs to run after weaponsInMapAll is initialized
1964                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1965         }
1966         else if (s == "devall_available")
1967         {
1968                 g_weaponarena = 1;
1969                 g_weaponarena_list = "Dev All Available Weapons Arena";
1970
1971                 // this needs to run after weaponsInMapAll is initialized
1972                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1973         }
1974         else if (s == "most_available")
1975         {
1976                 g_weaponarena = 1;
1977                 g_weaponarena_list = "Most Available Weapons Arena";
1978
1979                 // this needs to run after weaponsInMapAll is initialized
1980                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1981         }
1982         else if (s == "none")
1983         {
1984                 g_weaponarena = 1;
1985                 g_weaponarena_list = "No Weapons Arena";
1986         }
1987         else
1988         {
1989                 g_weaponarena = 1;
1990                 float t = tokenize_console(s);
1991                 g_weaponarena_list = "";
1992                 for (int j = 0; j < t; ++j)
1993                 {
1994                         s = argv(j);
1995                         Weapon wep = Weapon_from_name(s);
1996                         if(wep != WEP_Null)
1997                         {
1998                                 g_weaponarena_weapons |= (wep.m_wepset);
1999                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
2000                         }
2001                 }
2002                 if (g_weaponarena_list != "") // remove trailing " & "
2003                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
2004                 else // no valid weapon found
2005                         g_weaponarena_list = "No Weapons Arena";
2006         }
2007
2008         if (g_weaponarena)
2009         {
2010                 g_weapon_stay = 0; // incompatible
2011                 start_weapons = g_weaponarena_weapons;
2012                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
2013                 g_weaponarena_list = strzone(g_weaponarena_list);
2014         }
2015         else
2016         {
2017                 FOREACH(Weapons, it != WEP_Null, {
2018                         int w = want_weapon(it, false);
2019                         WepSet s = it.m_wepset;
2020                         if(w & 1)
2021                                 start_weapons |= s;
2022                         if(w & 2)
2023                                 start_weapons_default |= s;
2024                         if(w & 4)
2025                                 start_weapons_defaultmask |= s;
2026                 });
2027         }
2028
2029         if(cvar("g_balance_superweapons_time") < 0)
2030                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
2031
2032         if(!cvar("g_use_ammunition"))
2033                 start_items |= IT_UNLIMITED_AMMO;
2034
2035         if(start_items & IT_UNLIMITED_AMMO)
2036         {
2037                 start_ammo_shells = 999;
2038                 start_ammo_nails = 999;
2039                 start_ammo_rockets = 999;
2040                 start_ammo_cells = 999;
2041                 start_ammo_plasma = 999;
2042                 start_ammo_fuel = 999;
2043         }
2044         else
2045         {
2046                 start_ammo_shells = cvar("g_start_ammo_shells");
2047                 start_ammo_nails = cvar("g_start_ammo_nails");
2048                 start_ammo_rockets = cvar("g_start_ammo_rockets");
2049                 start_ammo_cells = cvar("g_start_ammo_cells");
2050                 start_ammo_plasma = cvar("g_start_ammo_plasma");
2051                 start_ammo_fuel = cvar("g_start_ammo_fuel");
2052                 random_start_weapons_count = cvar("g_random_start_weapons_count");
2053                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
2054                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
2055                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
2056                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
2057                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
2058         }
2059
2060         warmup_start_ammo_shells = start_ammo_shells;
2061         warmup_start_ammo_nails = start_ammo_nails;
2062         warmup_start_ammo_rockets = start_ammo_rockets;
2063         warmup_start_ammo_cells = start_ammo_cells;
2064         warmup_start_ammo_plasma = start_ammo_plasma;
2065         warmup_start_ammo_fuel = start_ammo_fuel;
2066         warmup_start_health = start_health;
2067         warmup_start_armorvalue = start_armorvalue;
2068         warmup_start_weapons = start_weapons;
2069         warmup_start_weapons_default = start_weapons_default;
2070         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2071
2072         if (!g_weaponarena)
2073         {
2074                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2075                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2076                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2077                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2078                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2079                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2080                 warmup_start_health = cvar("g_warmup_start_health");
2081                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2082                 warmup_start_weapons = '0 0 0';
2083                 warmup_start_weapons_default = '0 0 0';
2084                 warmup_start_weapons_defaultmask = '0 0 0';
2085                 FOREACH(Weapons, it != WEP_Null, {
2086                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2087                         WepSet s = it.m_wepset;
2088                         if(w & 1)
2089                                 warmup_start_weapons |= s;
2090                         if(w & 2)
2091                                 warmup_start_weapons_default |= s;
2092                         if(w & 4)
2093                                 warmup_start_weapons_defaultmask |= s;
2094                 });
2095         }
2096
2097         if (autocvar_g_jetpack)
2098                 start_items |= ITEM_Jetpack.m_itemid;
2099
2100         MUTATOR_CALLHOOK(SetStartItems);
2101
2102         if (start_items & ITEM_Jetpack.m_itemid)
2103         {
2104                 start_items |= ITEM_JetpackRegen.m_itemid;
2105                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2106                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2107         }
2108
2109         start_ammo_shells = max(0, start_ammo_shells);
2110         start_ammo_nails = max(0, start_ammo_nails);
2111         start_ammo_rockets = max(0, start_ammo_rockets);
2112         start_ammo_cells = max(0, start_ammo_cells);
2113         start_ammo_plasma = max(0, start_ammo_plasma);
2114         start_ammo_fuel = max(0, start_ammo_fuel);
2115         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2116         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2117         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2118         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2119         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2120
2121         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2122         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2123         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2124         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2125         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2126         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2127 }
2128
2129 void readlevelcvars()
2130 {
2131         serverflags &= ~SERVERFLAG_ALLOW_FULLBRIGHT;
2132         if(cvar("sv_allow_fullbright"))
2133                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2134
2135         serverflags &= ~SERVERFLAG_FORBID_PICKUPTIMER;
2136         if(cvar("sv_forbid_pickuptimer"))
2137                 serverflags |= SERVERFLAG_FORBID_PICKUPTIMER;
2138
2139         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2140
2141         if(cvar("g_campaign"))
2142                 warmup_stage = 0; // no warmup during campaign
2143         else
2144         {
2145                 warmup_stage = autocvar_g_warmup;
2146                 if (warmup_stage < 0 || warmup_stage > 1)
2147                         warmup_limit = -1; // don't start until there's enough players
2148                 else if (warmup_stage == 1)
2149                 {
2150                         // this code is duplicated in ReadyCount()
2151                         warmup_limit = cvar("g_warmup_limit");
2152                         if(warmup_limit == 0)
2153                                 warmup_limit = autocvar_timelimit * 60;
2154                 }
2155         }
2156
2157         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2158         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2159         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2160         g_pickup_respawntime_armor_small = cvar("g_pickup_respawntime_armor_small");
2161         g_pickup_respawntime_armor_medium = cvar("g_pickup_respawntime_armor_medium");
2162         g_pickup_respawntime_armor_big = cvar("g_pickup_respawntime_armor_big");
2163         g_pickup_respawntime_armor_mega = cvar("g_pickup_respawntime_armor_mega");
2164         g_pickup_respawntime_health_small = cvar("g_pickup_respawntime_health_small");
2165         g_pickup_respawntime_health_medium = cvar("g_pickup_respawntime_health_medium");
2166         g_pickup_respawntime_health_big = cvar("g_pickup_respawntime_health_big");
2167         g_pickup_respawntime_health_mega = cvar("g_pickup_respawntime_health_mega");
2168         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2169         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2170         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2171         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2172         g_pickup_respawntimejitter_armor_small = cvar("g_pickup_respawntimejitter_armor_small");
2173         g_pickup_respawntimejitter_armor_medium = cvar("g_pickup_respawntimejitter_armor_medium");
2174         g_pickup_respawntimejitter_armor_big = cvar("g_pickup_respawntimejitter_armor_big");
2175         g_pickup_respawntimejitter_armor_mega = cvar("g_pickup_respawntimejitter_armor_mega");
2176         g_pickup_respawntimejitter_health_small = cvar("g_pickup_respawntimejitter_health_small");
2177         g_pickup_respawntimejitter_health_medium = cvar("g_pickup_respawntimejitter_health_medium");
2178         g_pickup_respawntimejitter_health_big = cvar("g_pickup_respawntimejitter_health_big");
2179         g_pickup_respawntimejitter_health_mega = cvar("g_pickup_respawntimejitter_health_mega");
2180         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2181
2182         g_pickup_shells = cvar("g_pickup_shells");
2183         g_pickup_shells_max = cvar("g_pickup_shells_max");
2184         g_pickup_nails = cvar("g_pickup_nails");
2185         g_pickup_nails_max = cvar("g_pickup_nails_max");
2186         g_pickup_rockets = cvar("g_pickup_rockets");
2187         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2188         g_pickup_cells = cvar("g_pickup_cells");
2189         g_pickup_cells_max = cvar("g_pickup_cells_max");
2190         g_pickup_plasma = cvar("g_pickup_plasma");
2191         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2192         g_pickup_fuel = cvar("g_pickup_fuel");
2193         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2194         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2195         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2196         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2197         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2198         g_pickup_armormedium = cvar("g_pickup_armormedium");
2199         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2200         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2201         g_pickup_armorbig = cvar("g_pickup_armorbig");
2202         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2203         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2204         g_pickup_armormega = cvar("g_pickup_armormega");
2205         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2206         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2207         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2208         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2209         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2210         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2211         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2212         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2213         g_pickup_healthbig = cvar("g_pickup_healthbig");
2214         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2215         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2216         g_pickup_healthmega = cvar("g_pickup_healthmega");
2217         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2218         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2219
2220         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2221         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2222
2223         g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2224         if(!g_weapon_stay)
2225                 g_weapon_stay = cvar("g_weapon_stay");
2226
2227         MUTATOR_CALLHOOK(ReadLevelCvars);
2228
2229         if (!warmup_stage && !autocvar_g_campaign)
2230                 game_starttime = time + cvar("g_start_delay");
2231
2232         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2233
2234         readplayerstartcvars();
2235 }
2236
2237 void InitializeEntity(entity e, void(entity this) func, int order)
2238 {
2239         entity prev, cur;
2240
2241         if (!e || e.initialize_entity)
2242         {
2243                 // make a proxy initializer entity
2244                 entity e_old = e;
2245                 e = new(initialize_entity);
2246                 e.enemy = e_old;
2247         }
2248
2249         e.initialize_entity = func;
2250         e.initialize_entity_order = order;
2251
2252         cur = initialize_entity_first;
2253         prev = NULL;
2254         for (;;)
2255         {
2256                 if (!cur || cur.initialize_entity_order > order)
2257                 {
2258                         // insert between prev and cur
2259                         if (prev)
2260                                 prev.initialize_entity_next = e;
2261                         else
2262                                 initialize_entity_first = e;
2263                         e.initialize_entity_next = cur;
2264                         return;
2265                 }
2266                 prev = cur;
2267                 cur = cur.initialize_entity_next;
2268         }
2269 }
2270 void InitializeEntitiesRun()
2271 {
2272         entity startoflist = initialize_entity_first;
2273         initialize_entity_first = NULL;
2274         delete_fn = remove_except_protected;
2275         for (entity e = startoflist; e; e = e.initialize_entity_next)
2276         {
2277                 e.remove_except_protected_forbidden = 1;
2278         }
2279         for (entity e = startoflist; e; )
2280         {
2281                 e.remove_except_protected_forbidden = 0;
2282                 e.initialize_entity_order = 0;
2283                 entity next = e.initialize_entity_next;
2284                 e.initialize_entity_next = NULL;
2285                 var void(entity this) func = e.initialize_entity;
2286                 e.initialize_entity = func_null;
2287                 if (e.classname == "initialize_entity")
2288                 {
2289                         entity wrappee = e.enemy;
2290                         builtin_remove(e);
2291                         e = wrappee;
2292                 }
2293                 //dprint("Delayed initialization: ", e.classname, "\n");
2294                 if (func)
2295                 {
2296                         func(e);
2297                 }
2298                 else
2299                 {
2300                         eprint(e);
2301                         backtrace(strcat("Null function in: ", e.classname, "\n"));
2302                 }
2303                 e = next;
2304         }
2305         delete_fn = remove_unsafely;
2306 }
2307
2308 // originally ported from DP's droptofloor() builtin
2309 // TODO: make a common function for the client-side?
2310 // bones_was_here: when we have a use case for it, yes
2311 void DropToFloor_QC(entity this)
2312 {
2313         int nudgeresult;
2314
2315         if(!this || wasfreed(this))
2316         {
2317                 LOG_WARN("DropToFloor_QC: can not modify free entity");
2318                 return;
2319         }
2320
2321         /* Prior to sv_legacy_bbox_expand 0, both droptofloor and nudgeoutofsolid were done for items
2322          * using box '-16 -16 0' '16 16 48' (without the FL_ITEM expansion applied),
2323          * which often resulted in bboxes partially in solids once expansion was applied.
2324          * We don't want bboxes in solids (bad for gameplay and culling),
2325          * but we also don't want items to land on a "skirting board" or the base of a sloping wall.
2326          * For initial nudgeoutofsolid and droptofloor stages we use a small box
2327          * so they fall as far and in the same place as they traditionally would,
2328          * then we nudge the full size box out of solid, in a direction appropriate for the plane(s).
2329          */
2330         vector saved_mins = this.mins; // gmqcc's used-uninitialized check doesn't handle
2331         vector saved_maxs = this.maxs; // making these assignments FL_ITEM conditional.
2332         if (this.flags & FL_ITEM)
2333         {
2334                 // Using the Q3 bbox for best compatibility with all maps, except...
2335                 this.mins.x = -15;
2336                 this.mins.y = -15;
2337                 this.maxs.x = 15;
2338                 this.maxs.y = 15;
2339                 this.maxs.z = this.mins.z + 30; // ...Nex, Xon and Quake use a different vertical offset, see also: StartItem()
2340         }
2341
2342         /* NOTE: sv_gameplayfix_droptofloorstartsolid_nudgetocorrect isn't checked, so it won't need to be networked to CSQC.
2343          * It was enabled by default in all Xonotic releases and in Nexuiz, so now certain maps depend on it.
2344          * Example: on erbium 0.8.6 the shards @ crylink are too low (in collision with the floor),
2345          * so without this those fall through the floor.
2346          * Q3, Q2 and Quake don't try to move items out of solid.
2347          */
2348         if(!Q3COMPAT_COMMON && autocvar_sv_mapformat_is_quake3) // Xonotic, Nexuiz
2349         {
2350                 nudgeresult = nudgeoutofsolid(this);
2351                 if (!nudgeresult)
2352                         LOG_WARNF("DropToFloor_QC at \"%v\": COULD NOT FIX badly placed entity \"%s\" before drop", this.origin, this.classname);
2353                 else if (nudgeresult > 0)
2354                         LOG_WARNF("DropToFloor_QC at \"%v\": FIXED badly placed entity \"%s\" before drop", this.origin, this.classname);
2355         }
2356
2357         vector end = this.origin;
2358         if (autocvar_sv_mapformat_is_quake3)
2359                 end.z -= 4096;
2360         else if (autocvar_sv_mapformat_is_quake2)
2361                 end.z -= 128;
2362         else
2363                 end.z -= 256; // Quake, QuakeWorld
2364         tracebox(this.origin, this.mins, this.maxs, end, MOVE_NOMONSTERS, this);
2365
2366         if (!autocvar_sv_mapformat_is_quake3 && !autocvar_sv_mapformat_is_quake2 && (trace_allsolid || trace_fraction == 1)) // Quake
2367         {
2368                 // Quake games just delete badly placed entities...
2369                 LOG_WARNF("DropToFloor_QC at \"%v\" (Quake compat): DELETING badly placed entity \"%s\"", this.origin, this.classname);
2370                 delete(this);
2371                 return;
2372         }
2373         else if ((Q3COMPAT_COMMON || autocvar_sv_mapformat_is_quake2) && trace_startsolid) // Q3, Q2
2374         {
2375                 // ...but we can't do that on Q3 maps like jamdm1
2376                 // because our tracebox hits things Q3's trace doesn't (patches?).
2377                 LOG_WARNF("DropToFloor_QC at \"%v\" (Quake 3 compat): badly placed entity \"%s\"", this.origin, this.classname);
2378         }
2379
2380         /* NOTE: sv_gameplayfix_droptofloorstartsolid (fallback from tracebox to traceline) isn't implemented.
2381          * It was disabled by default in all Xonotic releases and in Nexuiz.
2382          * Q3 doesn't support it (always uses its '-15 -15 -15' '15 15 15' box when dropping items), neither does Quake or Q2.
2383          */
2384
2385         if (!autocvar_sv_mapformat_is_quake2) // Quake, Q3, Nexuiz, Xonotic
2386                 // allow to ride movers (or unset if in freefall)
2387                 this.groundentity = trace_ent;
2388
2389         if (!autocvar_sv_mapformat_is_quake3)
2390                 // if support is destroyed, keep suspended (gross hack for floating items in various maps)
2391                 // bones_was_here: is this for Q1BSP only? Which maps use it? Do we need it at all? Intentions unclear in DP...
2392                 this.move_suspendedinair = true;
2393
2394         if (trace_fraction)
2395                 this.origin = trace_endpos;
2396
2397         if (this.flags & FL_ITEM)
2398         {
2399                 this.mins = saved_mins;
2400                 this.maxs = saved_maxs;
2401
2402                 // A side effect of using a small box to drop items (and do the initial nudge) is
2403                 // the full size box can end up in collision with a sloping floor or terrain model.
2404                 nudgeresult = nudgeoutofsolid(this);
2405                 // No warns for successful nudge because it would spam about items on slopes/terrain.
2406         }
2407         else if (trace_allsolid && trace_fraction) // dropped using "proper" bbox but never left solid
2408         {
2409                 nudgeresult = nudgeoutofsolid(this);
2410                 if (nudgeresult > 0)
2411                         LOG_WARNF("DropToFloor_QC at \"%v\": FIXED badly placed entity \"%s\" after drop", this.origin, this.classname);
2412         }
2413         else
2414                 nudgeresult = -1;
2415
2416         if (!nudgeresult)
2417         if (!Q3COMPAT_COMMON) // to be expected on Q3 maps like gu3-pewter because we use bigger final bboxes
2418                 LOG_WARNF("DropToFloor_QC at \"%v\": COULD NOT FIX stuck entity \"%s\" after drop", this.origin, this.classname);
2419
2420         setorigin(this, this.dropped_origin = this.origin);
2421 }
2422
2423 void droptofloor(entity this)
2424 {
2425         InitializeEntity(this, DropToFloor_QC, INITPRIO_DROPTOFLOOR);
2426 }
2427
2428 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2429 void RunThink(entity this, float dt)
2430 {
2431         // don't let things stay in the past.
2432         // it is possible to start that way by a trigger with a local time.
2433         if(this.nextthink <= 0 || this.nextthink > time + dt)
2434                 return;
2435
2436         float oldtime = time; // do we need to save this?
2437
2438         for (int iterations = 0; iterations < 128 && !wasfreed(this); ++iterations)
2439         {
2440                 time = max(oldtime, this.nextthink);
2441                 this.nextthink = 0;
2442
2443                 if(getthink(this))
2444                         getthink(this)(this);
2445                 // mods often set nextthink to time to cause a think every frame,
2446                 // we don't want to loop in that case, so exit if the new nextthink is
2447                 // <= the time the qc was told, also exit if it is past the end of the
2448                 // frame
2449                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2450                         break;
2451         }
2452
2453         time = oldtime;
2454 }
2455
2456 bool autocvar_sv_freezenonclients;
2457 void Physics_Frame()
2458 {
2459         if(autocvar_sv_freezenonclients)
2460                 return;
2461
2462         IL_EACH(g_moveables, true,
2463         {
2464                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2465                         continue;
2466
2467                 //set_movetype(it, it.move_movetype);
2468                 // inline the set_movetype function, since this is called a lot
2469                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2470
2471                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2472                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2473
2474                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2475                 {
2476                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2477                                 continue; // these movetypes have no regular think function
2478                         // handle thinking here
2479                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2480                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2481                 }
2482         });
2483
2484         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2485                 return;
2486
2487         // make a second pass to see if any ents spawned this frame and make
2488         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2489         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2490         IL_EACH(g_moveables, it.move_qcphysics,
2491         {
2492                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2493                         continue;
2494                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2495         });
2496 }
2497
2498 void systems_update();
2499 void EndFrame()
2500 {
2501         anticheat_endframe();
2502
2503         Physics_Frame();
2504
2505         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2506                 entity e = IS_SPEC(it) ? it.enemy : it;
2507                 if (e.typehitsound) {
2508                         STAT(TYPEHIT_TIME, it) = time;
2509                 } else if (e.killsound) {
2510                         STAT(KILL_TIME, it) = time;
2511                 } else if (e.hitsound_damage_dealt) {
2512                         STAT(HIT_TIME, it) = time;
2513                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2514                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2515                 }
2516         });
2517         // add 1 frametime because after this, engine SV_Physics
2518         // increases time by a frametime and then networks the frame
2519         // add another frametime because client shows everything with
2520         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2521         // needed!
2522         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2523         FOREACH_CLIENT(true, {
2524                 it.typehitsound = false;
2525                 it.hitsound_damage_dealt = 0;
2526                 it.killsound = false;
2527                 antilag_record(it, CS(it), altime);
2528         });
2529         IL_EACH(g_monsters, true,
2530         {
2531                 antilag_record(it, it, altime);
2532         });
2533         IL_EACH(g_projectiles, it.classname == "nade",
2534         {
2535                 antilag_record(it, it, altime);
2536         });
2537         systems_update();
2538         IL_ENDFRAME();
2539 }
2540
2541
2542 /*
2543  * RedirectionThink:
2544  * returns true if redirecting
2545  */
2546 float redirection_timeout;
2547 float redirection_nextthink;
2548 float RedirectionThink()
2549 {
2550         float clients_found;
2551
2552         if(redirection_target == "")
2553                 return false;
2554
2555         if(!redirection_timeout)
2556         {
2557                 cvar_set("sv_public", "-2");
2558                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2559                 if(redirection_target == "self")
2560                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2561                 else
2562                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2563         }
2564
2565         if(time < redirection_nextthink)
2566                 return true;
2567
2568         redirection_nextthink = time + 1;
2569
2570         clients_found = 0;
2571         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2572                 // TODO add timer
2573                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2574                 if(redirection_target == "self")
2575                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2576                 else
2577                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2578                 ++clients_found;
2579         });
2580
2581         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2582
2583         if(time > redirection_timeout || clients_found == 0)
2584                 localcmd("\nwait; wait; wait; quit\n");
2585
2586         return true;
2587 }
2588
2589 void RestoreGame()
2590 {
2591         // Loaded from a save game
2592         // some things then break, so let's work around them...
2593
2594         // Progs DB (capture records)
2595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2596
2597         // Mapinfo
2598         MapInfo_Shutdown();
2599         MapInfo_Enumerate();
2600         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2601         WeaponStats_Init();
2602
2603         TargetMusic_RestoreGame();
2604 }
2605
2606 void Shutdown()
2607 {
2608         game_stopped = 2;
2609
2610         if(world_initialized > 0)
2611         {
2612                 world_initialized = 0;
2613
2614                 // if a timeout is active, reset the slowmo value to normal
2615                 if(timeout_status == TIMEOUT_ACTIVE)
2616                         cvar_set("slowmo", ftos(orig_slowmo));
2617
2618                 LOG_TRACE("Saving persistent data...");
2619                 Ban_SaveBans();
2620
2621                 // playerstats with unfinished match
2622                 PlayerStats_GameReport(false);
2623
2624                 if(!cheatcount_total)
2625                 {
2626                         if(autocvar_sv_db_saveasdump)
2627                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2628                         else
2629                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2630                 }
2631                 if(autocvar_developer > 0)
2632                 {
2633                         if(autocvar_sv_db_saveasdump)
2634                                 db_dump(TemporaryDB, "server-temp.db");
2635                         else
2636                                 db_save(TemporaryDB, "server-temp.db");
2637                 }
2638                 CheatShutdown(); // must be after cheatcount check
2639                 db_close(ServerProgsDB);
2640                 db_close(TemporaryDB);
2641                 LOG_TRACE("Saving persistent data... done!");
2642                 // tell the bot system the game is ending now
2643                 bot_endgame();
2644
2645                 WeaponStats_Shutdown();
2646                 MapInfo_Shutdown();
2647
2648                 strfree(sv_termsofservice_url_escaped);
2649                 strfree(loaded_gametype_custom_string);
2650         }
2651         else if(world_initialized == 0)
2652         {
2653                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2654         }
2655         else
2656         {
2657                 __init_dedicated_server_shutdown();
2658         }
2659 }