qcsrc/warpzonelib/server.qc

   1 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
   2 .float warpzone_teleport_time;
   3
   4 void WarpZone_StoreProjectileData(entity e)
   5 {
   6         e.warpzone_oldorigin = e.origin;
   7         e.warpzone_oldvelocity = e.velocity;
   8         e.warpzone_oldangles = e.angles;
   9 }
  10
  11 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  12 {
  13         vector from;
  14
  15         makevectors (to_angles);
  16
  17         from = player.origin;
  18         setorigin (player, to);
  19         player.oldorigin = to; // for DP's unsticking
  20         player.angles = to_angles;
  21         player.fixangle = TRUE;
  22         player.velocity = to_velocity;
  23
  24         if(player.effects & EF_TELEPORT_BIT)
  25                 player.effects &~= EF_TELEPORT_BIT;
  26         else
  27                 player.effects |= EF_TELEPORT_BIT;
  28
  29         if(player.classname == "player")
  30                 player.flags &~= FL_ONGROUND;
  31
  32         WarpZone_PostTeleportPlayer_Callback(player);
  33 }
  34
  35 float WarpZone_Teleport(entity player)
  36 {
  37         vector o0, a0, v0, o1, a1, v1;
  38
  39         o0 = player.origin + player.view_ofs;
  40         v0 = player.velocity;
  41         a0 = player.angles;
  42
  43         if(WarpZone_PlaneDist(self, o0) >= 0) // wrong side of the trigger_warpzone
  44                 return 2;
  45         // no failure, we simply don't want to teleport yet; TODO in
  46         // this situation we may want to create a temporary clone
  47         // entity of the player to fix graphics glitch
  48
  49         o1 = WarpZone_TransformOrigin(self, o0);
  50         v1 = WarpZone_TransformVelocity(self, v0);
  51         if(player.classname == "player")
  52                 a1 = WarpZone_TransformVAngles(self, player.v_angle);
  53         else
  54                 a1 = WarpZone_TransformAngles(self, a0);
  55
  56         // put him inside solid
  57         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
  58         if(trace_startsolid)
  59         {
  60                 vector mi, ma;
  61                 mi = player.mins;
  62                 ma = player.maxs;
  63                 setsize(player, mi - player.view_ofs, ma - player.view_ofs);
  64                 setorigin(player, o1);
  65                 if(WarpZoneLib_MoveOutOfSolid(player))
  66                 {
  67                         o1 = player.origin;
  68                         setsize(player, mi, ma);
  69                         setorigin(player, o0);
  70                 }
  71                 else
  72                 {
  73                         print("would have to put player in solid, won't do that\n");
  74                         setsize(player, mi, ma);
  75                         setorigin(player, o0 - player.view_ofs);
  76                         return 0; // cannot fix
  77                 }
  78         }
  79
  80         if(WarpZone_TargetPlaneDist(self, o1) <= 0)
  81         {
  82                 print("inconsistent warp zones or evil roundoff error\n");
  83                 return 0;
  84         }
  85
  86         //print(sprintf("warpzone: %f %f %f -> %f %f %f\n", o0_x, o0_y, o0_z, o1_x, o1_y, o1_z));
  87
  88         //o1 = trace_endpos;
  89         WarpZone_RefSys_Add(player, self);
  90         WarpZone_TeleportPlayer(self, player, o1 - player.view_ofs, a1, v1);
  91         WarpZone_StoreProjectileData(player);
  92         player.warpzone_teleport_time = time;
  93
  94         return 1;
  95 }
  96
  97 void WarpZone_Touch (void)
  98 {
  99         entity oldself, e;
 100
 101         if(other.classname == "trigger_warpzone")
 102                 return;
 103
 104         // FIXME needs a better check to know what is safe to teleport and what not
 105         if(other.movetype == MOVETYPE_NONE)
 106                 return;
 107
 108         if(WarpZoneLib_ExactTrigger_Touch())
 109                 return;
 110
 111         e = self.enemy;
 112         if(WarpZone_Teleport(other))
 113         {
 114                 string save1, save2;
 115                 activator = other;
 116
 117                 save1 = self.target; self.target = string_null;
 118                 save2 = self.target3; self.target3 = string_null;
 119                 SUB_UseTargets();
 120                 if not(self.target) self.target = save1;
 121                 if not(self.target3) self.target3 = save2;
 122
 123                 oldself = self;
 124                 self = self.aiment;
 125                 save1 = self.target; self.target = string_null;
 126                 save2 = self.target2; self.target2 = string_null;
 127                 SUB_UseTargets();
 128                 if not(self.target) self.target = save1;
 129                 if not(self.target2) self.target2 = save2;
 130                 self = oldself;
 131         }
 132         else
 133         {
 134                 dprint("WARPZONE FAIL AHAHAHAHAH))\n");
 135         }
 136 }
 137
 138 float WarpZone_Send(entity to, float sendflags)
 139 {
 140         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 141
 142         // we must send this flag for clientside to match properly too
 143         WriteByte(MSG_ENTITY, self.warpzone_isboxy);
 144
 145         // we need THESE to render the warpzone (and cull properly)...
 146         WriteCoord(MSG_ENTITY, self.origin_x);
 147         WriteCoord(MSG_ENTITY, self.origin_y);
 148         WriteCoord(MSG_ENTITY, self.origin_z);
 149
 150         WriteShort(MSG_ENTITY, self.modelindex);
 151         WriteCoord(MSG_ENTITY, self.mins_x);
 152         WriteCoord(MSG_ENTITY, self.mins_y);
 153         WriteCoord(MSG_ENTITY, self.mins_z);
 154         WriteCoord(MSG_ENTITY, self.maxs_x);
 155         WriteCoord(MSG_ENTITY, self.maxs_y);
 156         WriteCoord(MSG_ENTITY, self.maxs_z);
 157         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 158
 159         // we need THESE to calculate the proper transform
 160         WriteCoord(MSG_ENTITY, self.warpzone_origin_x);
 161         WriteCoord(MSG_ENTITY, self.warpzone_origin_y);
 162         WriteCoord(MSG_ENTITY, self.warpzone_origin_z);
 163         WriteCoord(MSG_ENTITY, self.warpzone_angles_x);
 164         WriteCoord(MSG_ENTITY, self.warpzone_angles_y);
 165         WriteCoord(MSG_ENTITY, self.warpzone_angles_z);
 166         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_x);
 167         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_y);
 168         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_z);
 169         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_x);
 170         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_y);
 171         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_z);
 172
 173         return TRUE;
 174 }
 175
 176 float WarpZone_Camera_Send(entity to, float sendflags)
 177 {
 178         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 179
 180         // we need THESE to render the warpzone (and cull properly)...
 181         WriteCoord(MSG_ENTITY, self.origin_x);
 182         WriteCoord(MSG_ENTITY, self.origin_y);
 183         WriteCoord(MSG_ENTITY, self.origin_z);
 184
 185         WriteShort(MSG_ENTITY, self.modelindex);
 186         WriteCoord(MSG_ENTITY, self.mins_x);
 187         WriteCoord(MSG_ENTITY, self.mins_y);
 188         WriteCoord(MSG_ENTITY, self.mins_z);
 189         WriteCoord(MSG_ENTITY, self.maxs_x);
 190         WriteCoord(MSG_ENTITY, self.maxs_y);
 191         WriteCoord(MSG_ENTITY, self.maxs_z);
 192         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 193
 194         // we need THESE to calculate the proper transform
 195         WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 196         WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 197         WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 198         WriteCoord(MSG_ENTITY, self.enemy.angles_x);
 199         WriteCoord(MSG_ENTITY, self.enemy.angles_y);
 200         WriteCoord(MSG_ENTITY, self.enemy.angles_z);
 201
 202         return TRUE;
 203 }
 204
 205 float WarpZone_CheckProjectileImpact()
 206 {
 207         // if self hit a warpzone, abort
 208         vector o0, v0, a0;
 209         float mpd, pd, dpd;
 210         entity wz;
 211         wz = WarpZone_Find(self.origin + self.mins, self.origin + self.maxs);
 212         if(!wz)
 213                 return FALSE;
 214         o0 = self.origin;
 215         v0 = self.velocity;
 216         a0 = self.angles;
 217
 218         // this approach transports the projectile at its full speed, but does
 219         // not properly retain the projectile trail (but we can't retain it
 220         // easily anyway without delaying the projectile by two frames, so who
 221         // cares)
 222         WarpZone_TraceBox_ThroughZone(self.warpzone_oldorigin, self.mins, self.maxs, self.warpzone_oldorigin + self.warpzone_oldvelocity * frametime, MOVE_NORMAL, self, wz, WarpZone_trace_callback_t_null); // this will get us through the warpzone
 223         setorigin(self, trace_endpos);
 224         self.angles = WarpZone_TransformAngles(WarpZone_trace_transform, self.angles);
 225         self.velocity = WarpZone_TransformVelocity(WarpZone_trace_transform, self.velocity);
 226
 227         // in case we are in our warp zone post-teleport, shift the projectile forward a bit
 228         mpd = max(vlen(self.mins), vlen(self.maxs));
 229         pd = WarpZone_TargetPlaneDist(wz, self.origin);
 230         if(pd < mpd)
 231         {
 232                 dpd = normalize(self.velocity) * self.warpzone_targetforward;
 233                 setorigin(self, self.origin + normalize(self.velocity) * ((mpd - pd) / dpd));
 234                 if(!WarpZoneLib_MoveOutOfSolid(self))
 235                 {
 236                         setorigin(self, o0);
 237                         self.angles = a0;
 238                         self.velocity = v0;
 239                         return FALSE;
 240                 }
 241         }
 242         WarpZone_RefSys_Add(self, wz);
 243         WarpZone_StoreProjectileData(self);
 244         self.warpzone_teleport_time = time;
 245
 246         return TRUE;
 247 }
 248 float WarpZone_Projectile_Touch()
 249 {
 250         if(other.classname == "trigger_warpzone")
 251                 return TRUE;
 252         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 253                 return TRUE;
 254         if(WarpZone_CheckProjectileImpact())
 255                 return TRUE;
 256         if(self.warpzone_teleport_time == time) // already got teleported this frame? no collision then please
 257         {
 258                 setorigin(self, self.warpzone_oldorigin);
 259                 self.velocity = self.warpzone_oldvelocity;
 260                 self.angles = self.warpzone_oldangles;
 261                 return TRUE;
 262         }
 263
 264         return FALSE;
 265 }
 266
 267 void WarpZone_InitStep_FindOriginTarget()
 268 {
 269         if(self.killtarget != "")
 270         {
 271                 self.aiment = find(world, targetname, self.killtarget);
 272                 if(self.aiment == world)
 273                 {
 274                         error("Warp zone with nonexisting killtarget");
 275                         return;
 276                 }
 277         }
 278 }
 279
 280 void WarpZonePosition_InitStep_FindTarget()
 281 {
 282         if(self.target == "")
 283         {
 284                 error("Warp zone position with no target");
 285                 return;
 286         }
 287         self.enemy = find(world, targetname, self.target);
 288         if(self.enemy == world)
 289         {
 290                 error("Warp zone position with nonexisting target");
 291                 return;
 292         }
 293         if(self.enemy.aiment)
 294         {
 295                 // already is positioned
 296                 error("Warp zone position targeting already oriented warpzone");
 297                 return;
 298         }
 299         self.enemy.aiment = self;
 300 }
 301
 302 void WarpZoneCamera_InitStep_FindTarget()
 303 {
 304         if(self.target == "")
 305         {
 306                 error("Camera with no target");
 307                 return;
 308         }
 309         self.enemy = find(world, targetname, self.target);
 310         if(self.enemy == world)
 311         {
 312                 error("Camera with nonexisting target");
 313                 return;
 314         }
 315         ++warpzone_cameras_exist;
 316         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 317 }
 318
 319 void WarpZone_InitStep_UpdateTransform()
 320 {
 321         vector org, ang, norm, point;
 322         float area;
 323         vector tri, a, b, c, p, q, n;
 324         float i_s, i_t, n_t;
 325         string tex;
 326
 327         org = self.origin;
 328         if(org == '0 0 0')
 329                 org = 0.5 * (self.mins + self.maxs);
 330
 331         norm = point = '0 0 0';
 332         area = 0;
 333         for(i_s = 0; ; ++i_s)
 334         {
 335                 tex = getsurfacetexture(self, i_s);
 336                 if not(tex)
 337                         break; // this is beyond the last one
 338                 if(tex == "textures/common/trigger")
 339                         continue;
 340                 n_t = getsurfacenumtriangles(self, i_s);
 341                 for(i_t = 0; i_t < n_t; ++i_t)
 342                 {
 343                         tri = getsurfacetriangle(self, i_s, i_t);
 344                         a = getsurfacepoint(self, i_s, tri_x);
 345                         b = getsurfacepoint(self, i_s, tri_y);
 346                         c = getsurfacepoint(self, i_s, tri_z);
 347                         p = b - a;
 348                         q = c - a;
 349                         n =     '1 0 0' * (q_y * p_z - q_z * p_y)
 350                         +       '0 1 0' * (q_z * p_x - q_x * p_z)
 351                         +       '0 0 1' * (q_x * p_y - q_y * p_x);
 352                         area = area + vlen(n);
 353                         norm = norm + n;
 354                         point = point + vlen(n) * (a + b + c);
 355                 }
 356         }
 357         if(area > 0)
 358         {
 359                 norm = norm * (1 / area);
 360                 point = point * (1 / (3 * area));
 361                 if(vlen(norm) < 0.99)
 362                 {
 363                         print("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 364                         area = 0; // no autofixing in this case
 365                 }
 366                 norm = normalize(norm);
 367         }
 368
 369         if(self.aiment)
 370         {
 371                 org = self.aiment.origin;
 372                 ang = self.aiment.angles;
 373                 if(area > 0)
 374                 {
 375                         org = org - ((org - point) * norm) * norm; // project to plane
 376                         makevectors(ang);
 377                         if(norm * v_forward < 0)
 378                         {
 379                                 print("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 380                                 norm = -1 * norm;
 381                         }
 382                         ang = vectoangles(norm, v_up); // keep rotation, but turn exactly against plane
 383                         ang_x = -ang_x;
 384                         if(norm * v_forward < 0.99)
 385                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 386                         if(vlen(org - self.aiment.origin) > 0.5)
 387                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 388                 }
 389         }
 390         else if(area > 0)
 391         {
 392                 org = point;
 393                 ang = vectoangles(norm);
 394                 ang_x = -ang_x;
 395         }
 396         else
 397                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 398
 399         self.warpzone_origin = org;
 400         self.warpzone_angles = ang;
 401 }
 402
 403 void WarpZone_InitStep_ClearTarget()
 404 {
 405         if(self.enemy)
 406                 self.enemy.enemy = world;
 407         self.enemy = world;
 408 }
 409
 410 entity warpzone_first; .entity warpzone_next;
 411 void WarpZone_InitStep_FindTarget()
 412 {
 413         float i;
 414         entity e, e2;
 415
 416         if(self.enemy)
 417                 return;
 418
 419         // this way only one of the two ents needs to target
 420         if(self.target != "")
 421         {
 422                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 423
 424                 e2 = world;
 425                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 426                         if(!e.enemy)
 427                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 428                                         if(random() * ++i < 1)
 429                                                 e2 = e;
 430                 if(!e2)
 431                 {
 432                         self.enemy = world;
 433                         error("Warpzone with non-existing target");
 434                         return;
 435                 }
 436                 self.enemy = e2;
 437                 e2.enemy = self;
 438         }
 439 }
 440
 441 void WarpZone_InitStep_FinalizeTransform()
 442 {
 443         if(!self.enemy || self.enemy.enemy != self)
 444         {
 445                 error("Invalid warp zone detected. Killed.");
 446                 return;
 447         }
 448
 449         ++warpzone_warpzones_exist;
 450         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 451         self.touch = WarpZone_Touch;
 452         self.SendFlags = 0xFFFFFF;
 453 }
 454
 455 float warpzone_initialized;
 456 entity warpzone_first;
 457 entity warpzone_position_first;
 458 entity warpzone_camera_first;
 459 .entity warpzone_next;
 460 void spawnfunc_misc_warpzone_position(void)
 461 {
 462         // "target", "angles", "origin"
 463         self.warpzone_next = warpzone_position_first;
 464         warpzone_position_first = self;
 465 }
 466 void spawnfunc_trigger_warpzone_position(void)
 467 {
 468         spawnfunc_misc_warpzone_position();
 469 }
 470 void spawnfunc_trigger_warpzone(void)
 471 {
 472         // warp zone entities must have:
 473         // "killtarget" pointing to a target_position with a direction arrow
 474         //              that points AWAY from the warp zone, and that is inside
 475         //              the warp zone trigger
 476         // "target"     pointing to an identical warp zone at another place in
 477         //              the map, with another killtarget to designate its
 478         //              orientation
 479
 480         if(!self.scale)
 481                 self.scale = self.modelscale;
 482         if(!self.scale)
 483                 self.scale = 1;
 484         string m;
 485         m = self.model;
 486         WarpZoneLib_ExactTrigger_Init();
 487         if(m != "")
 488         {
 489                 precache_model(m);
 490                 setmodel(self, m); // no precision needed
 491         }
 492         setorigin(self, self.origin);
 493         if(self.scale)
 494                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 495         else
 496                 setsize(self, self.mins, self.maxs);
 497         self.SendEntity = WarpZone_Send;
 498         self.SendFlags = 0xFFFFFF;
 499         self.effects |= EF_NODEPTHTEST;
 500         self.warpzone_next = warpzone_first;
 501         warpzone_first = self;
 502 }
 503 void spawnfunc_func_camera(void)
 504 {
 505         if(!self.scale)
 506                 self.scale = self.modelscale;
 507         if(!self.scale)
 508                 self.scale = 1;
 509         if(self.model != "")
 510         {
 511                 precache_model(self.model);
 512                 setmodel(self, self.model); // no precision needed
 513         }
 514         setorigin(self, self.origin);
 515         if(self.scale)
 516                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 517         else
 518                 setsize(self, self.mins, self.maxs);
 519         if(!self.solid)
 520                 self.solid = SOLID_BSP;
 521         else if(self.solid < 0)
 522                 self.solid = SOLID_NOT;
 523         self.SendEntity = WarpZone_Camera_Send;
 524         self.SendFlags = 0xFFFFFF;
 525         self.warpzone_next = warpzone_camera_first;
 526         warpzone_camera_first = self;
 527 }
 528 void WarpZones_Reconnect()
 529 {
 530         entity e;
 531         e = self;
 532         for(self = warpzone_first; self; self = self.warpzone_next)
 533                 WarpZone_InitStep_ClearTarget();
 534         for(self = warpzone_first; self; self = self.warpzone_next)
 535                 WarpZone_InitStep_FindTarget();
 536         for(self = warpzone_first; self; self = self.warpzone_next)
 537                 WarpZone_InitStep_FinalizeTransform();
 538         self = e;
 539 }
 540
 541 void WarpZone_StartFrame()
 542 {
 543         entity e;
 544         if(warpzone_initialized == 0)
 545         {
 546                 warpzone_initialized = 1;
 547                 e = self;
 548                 for(self = warpzone_first; self; self = self.warpzone_next)
 549                         WarpZone_InitStep_FindOriginTarget();
 550                 for(self = warpzone_position_first; self; self = self.warpzone_next)
 551                         WarpZonePosition_InitStep_FindTarget();
 552                 for(self = warpzone_camera_first; self; self = self.warpzone_next)
 553                         WarpZoneCamera_InitStep_FindTarget();
 554                 for(self = warpzone_first; self; self = self.warpzone_next)
 555                         WarpZone_InitStep_UpdateTransform();
 556                 self = e;
 557                 WarpZones_Reconnect();
 558         }
 559         for(e = world; (e = nextent(e)); )
 560                 WarpZone_StoreProjectileData(e);
 561 }
 562
 563 void trigger_warpzone_reconnect_use()
 564 {
 565         entity e;
 566         e = self;
 567         // NOTE: this matches for target, not targetname, but of course
 568         // targetname must be set too on the other entities
 569         for(self = warpzone_first; self; self = self.warpzone_next)
 570                 if(e.target == "" || self.target == e.target)
 571                         WarpZone_InitStep_ClearTarget();
 572         for(self = warpzone_first; self; self = self.warpzone_next)
 573                 if(e.target == "" || self.target == e.target)
 574                         WarpZone_InitStep_FindTarget();
 575         for(self = warpzone_first; self; self = self.warpzone_next)
 576                 if(e.target == "" || self.target == e.target || self.enemy.target == e.target)
 577                         WarpZone_InitStep_FinalizeTransform();
 578         self = e;
 579 }
 580
 581 void spawnfunc_trigger_warpzone_reconnect()
 582 {
 583         self.use = trigger_warpzone_reconnect_use;
 584 }
 585
 586 void spawnfunc_target_warpzone_reconnect()
 587 {
 588         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 589 }