qcsrc/warpzonelib/server.qc

   1 #include "server.qh"
   2
   3 #include "common.qh"
   4 #if defined(CSQC)
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include "../common/constants.qh"
   8         #include "../common/util.qh"
   9         #include "../dpdefs/dpextensions.qh"
  10         #include "../dpdefs/progsdefs.qh"
  11         #include "../server/command/common.qh"
  12         #include "../server/constants.qh"
  13         #include "../server/defs.qh"
  14 #endif
  15
  16 #ifdef WARPZONELIB_KEEPDEBUG
  17 #define WARPZONELIB_REMOVEHACK
  18 #endif
  19
  20 // for think function
  21 .vector warpzone_save_origin;
  22 .vector warpzone_save_angles;
  23 .vector warpzone_save_eorigin;
  24 .vector warpzone_save_eangles;
  25
  26 // for all entities
  27 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
  28 .float warpzone_teleport_time;
  29 .float warpzone_teleport_finishtime;
  30 .entity warpzone_teleport_zone;
  31
  32 void WarpZone_StoreProjectileData(entity e)
  33 {
  34         e.warpzone_oldorigin = e.origin;
  35         e.warpzone_oldvelocity = e.velocity;
  36         e.warpzone_oldangles = e.angles;
  37 }
  38
  39 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  40 {
  41         setorigin (player, to); // NOTE: this also aborts the move, when this is called by touch
  42         player.oldorigin = to; // for DP's unsticking
  43         player.angles = to_angles;
  44         player.fixangle = true;
  45         player.velocity = to_velocity;
  46
  47         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  48
  49         if(IS_PLAYER(player))
  50                 BITCLR_ASSIGN(player.flags, FL_ONGROUND);
  51
  52         WarpZone_PostTeleportPlayer_Callback(player);
  53 }
  54
  55 bool WarpZone_Teleported_Send(entity to, int sf)
  56 {
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_TELEPORTED);
  58         WriteCoord(MSG_ENTITY, self.angles.x);
  59         WriteCoord(MSG_ENTITY, self.angles.y);
  60         WriteCoord(MSG_ENTITY, self.angles.z);
  61         return true;
  62 }
  63
  64 float WarpZone_Teleport(entity wz, entity player, float f0, float f1)
  65 {
  66         vector o0, a0, v0, o1, a1, v1, o10;
  67
  68         o0 = player.origin + player.view_ofs;
  69         v0 = player.velocity;
  70         a0 = player.angles;
  71
  72         o10 = o1 = WarpZone_TransformOrigin(wz, o0);
  73         v1 = WarpZone_TransformVelocity(wz, v0);
  74         if (!IS_NOT_A_CLIENT(player))
  75                 a1 = WarpZone_TransformVAngles(wz, player.v_angle);
  76         else
  77                 a1 = WarpZone_TransformAngles(wz, a0);
  78
  79         if(f0 != 0 || f1 != 0)
  80         {
  81                 // retry last move but behind the warpzone!
  82                 // we must first go back as far as we can, then forward again, to not cause double touch events!
  83
  84                 tracebox(o1 - player.view_ofs + v1 * frametime * f1, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f0, MOVE_WORLDONLY, player);
  85                 {
  86                         entity own;
  87                         own = player.owner;
  88                         player.owner = world;
  89                         tracebox(trace_endpos, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f1, MOVE_NORMAL, player); // this should get us through the warpzone
  90                         player.owner = own;
  91                 }
  92                 o1 = trace_endpos + player.view_ofs;
  93
  94                 float d, dv, md;
  95                 md = max(vlen(player.mins), vlen(player.maxs));
  96                 d = WarpZone_TargetPlaneDist(wz, o1);
  97                 dv = WarpZone_TargetPlaneDist(wz, v1);
  98                 if(d < 0)
  99                         o1 = o1 - v1 * (d / dv);
 100         }
 101
 102         // put him out of solid
 103         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
 104         if(trace_startsolid)
 105         {
 106                 setorigin(player, o1 - player.view_ofs);
 107                 if(WarpZoneLib_MoveOutOfSolid(player))
 108                 {
 109                         o1 = player.origin + player.view_ofs;
 110                         setorigin(player, o0 - player.view_ofs);
 111                 }
 112                 else
 113                 {
 114                         print("would have to put player in solid, won't do that\n");
 115                         setorigin(player, o0 - player.view_ofs);
 116                         return 0;
 117                 }
 118         }
 119
 120         // do the teleport
 121         WarpZone_RefSys_Add(player, wz);
 122         WarpZone_TeleportPlayer(wz, player, o1 - player.view_ofs, a1, v1);
 123         WarpZone_StoreProjectileData(player);
 124         player.warpzone_teleport_time = time;
 125         player.warpzone_teleport_finishtime = time;
 126         player.warpzone_teleport_zone = wz;
 127
 128         // prevent further teleports back
 129         float dt = (o1 - o10) * v1 * (1 / (v1 * v1));
 130         if(dt < sys_frametime)
 131                 player.warpzone_teleport_finishtime += sys_frametime - dt;
 132
 133 #ifndef WARPZONE_USE_FIXANGLE
 134         if(IS_PLAYER(player))
 135         {
 136                 // instead of fixangle, send the transform to the client for smoother operation
 137                 player.fixangle = false;
 138
 139                 entity ts = spawn();
 140                 setmodel(ts, "null");
 141                 ts.SendEntity = WarpZone_Teleported_Send;
 142                 ts.SendFlags = 0xFFFFFF;
 143                 ts.drawonlytoclient = player;
 144                 ts.think = SUB_Remove;
 145                 ts.nextthink = time + 1;
 146                 ts.owner = player;
 147                 ts.enemy = wz;
 148                 ts.effects = EF_NODEPTHTEST;
 149                 ts.classname = "warpzone_teleported";
 150                 ts.angles = wz.warpzone_transform;
 151         }
 152 #endif
 153
 154         return 1;
 155 }
 156
 157 void WarpZone_Touch (void)
 158 {
 159         entity oldself;
 160
 161         if(other.classname == "trigger_warpzone")
 162                 return;
 163
 164         if(time <= other.warpzone_teleport_finishtime) // already teleported this frame
 165                 return;
 166
 167         // FIXME needs a better check to know what is safe to teleport and what not
 168         if(other.movetype == MOVETYPE_NONE || other.movetype == MOVETYPE_FOLLOW || other.tag_entity)
 169                 return;
 170
 171         if(WarpZoneLib_ExactTrigger_Touch())
 172                 return;
 173
 174         if(WarpZone_PlaneDist(self, other.origin + other.view_ofs) >= 0) // wrong side of the trigger_warpzone (don't teleport yet)
 175                 return;
 176
 177         float f;
 178         // number of frames we need to go back:
 179         //   dist = 16*sqrt(2) qu
 180         //   dist ~ 24 qu
 181         //   24 qu = v*t
 182         //   24 qu = v*frametime*n
 183         //       n = 24 qu/(v*frametime)
 184         // for clients go only one frame though, may be too irritating otherwise
 185         // but max 0.25 sec = 0.25/frametime frames
 186         //       24/(0.25/frametime)
 187         //       96*frametime
 188         float d;
 189         d = 24 + max(vlen(other.mins), vlen(other.maxs));
 190         if(IS_NOT_A_CLIENT(other))
 191                 f = -d / bound(frametime * d * 1, frametime * vlen(other.velocity), d);
 192         else
 193                 f = -1;
 194         if(WarpZone_Teleport(self, other, f, 0))
 195         {
 196                 string save1, save2;
 197                 activator = other;
 198
 199                 save1 = self.target; self.target = string_null;
 200                 save2 = self.target3; self.target3 = string_null;
 201                 SUB_UseTargets();
 202                 if (!self.target) self.target = save1;
 203                 if (!self.target3) self.target3 = save2;
 204
 205                 oldself = self;
 206                 self = self.enemy;
 207                 save1 = self.target; self.target = string_null;
 208                 save2 = self.target2; self.target2 = string_null;
 209                 SUB_UseTargets();
 210                 if (!self.target) self.target = save1;
 211                 if (!self.target2) self.target2 = save2;
 212                 self = oldself;
 213         }
 214         else
 215         {
 216                 dprint("WARPZONE FAIL AHAHAHAHAH))\n");
 217         }
 218 }
 219
 220 bool WarpZone_Send(entity to, int sendflags)
 221 {
 222         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 223
 224         // we must send this flag for clientside to match properly too
 225         int f = 0;
 226         if(self.warpzone_isboxy)
 227                 BITSET_ASSIGN(f, 1);
 228         if(self.warpzone_fadestart)
 229                 BITSET_ASSIGN(f, 2);
 230         if(self.origin != '0 0 0')
 231                 BITSET_ASSIGN(f, 4);
 232         WriteByte(MSG_ENTITY, f);
 233
 234         // we need THESE to render the warpzone (and cull properly)...
 235         if(f & 4)
 236         {
 237                 WriteCoord(MSG_ENTITY, self.origin.x);
 238                 WriteCoord(MSG_ENTITY, self.origin.y);
 239                 WriteCoord(MSG_ENTITY, self.origin.z);
 240         }
 241
 242         WriteShort(MSG_ENTITY, self.modelindex);
 243         WriteCoord(MSG_ENTITY, self.mins.x);
 244         WriteCoord(MSG_ENTITY, self.mins.y);
 245         WriteCoord(MSG_ENTITY, self.mins.z);
 246         WriteCoord(MSG_ENTITY, self.maxs.x);
 247         WriteCoord(MSG_ENTITY, self.maxs.y);
 248         WriteCoord(MSG_ENTITY, self.maxs.z);
 249         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 250
 251         // we need THESE to calculate the proper transform
 252         WriteCoord(MSG_ENTITY, self.warpzone_origin.x);
 253         WriteCoord(MSG_ENTITY, self.warpzone_origin.y);
 254         WriteCoord(MSG_ENTITY, self.warpzone_origin.z);
 255         WriteCoord(MSG_ENTITY, self.warpzone_angles.x);
 256         WriteCoord(MSG_ENTITY, self.warpzone_angles.y);
 257         WriteCoord(MSG_ENTITY, self.warpzone_angles.z);
 258         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.x);
 259         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.y);
 260         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin.z);
 261         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.x);
 262         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.y);
 263         WriteCoord(MSG_ENTITY, self.warpzone_targetangles.z);
 264
 265         if(f & 2)
 266         {
 267                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 268                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 269         }
 270
 271         return true;
 272 }
 273
 274 bool WarpZone_Camera_Send(entity to, int sendflags)
 275 {
 276         int f = 0;
 277         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 278
 279         if(self.warpzone_fadestart)
 280                 BITSET_ASSIGN(f, 2);
 281         if(self.origin != '0 0 0')
 282                 BITSET_ASSIGN(f, 4);
 283         WriteByte(MSG_ENTITY, f);
 284
 285         // we need THESE to render the warpzone (and cull properly)...
 286         if(f & 4)
 287         {
 288                 WriteCoord(MSG_ENTITY, self.origin.x);
 289                 WriteCoord(MSG_ENTITY, self.origin.y);
 290                 WriteCoord(MSG_ENTITY, self.origin.z);
 291         }
 292
 293         WriteShort(MSG_ENTITY, self.modelindex);
 294         WriteCoord(MSG_ENTITY, self.mins.x);
 295         WriteCoord(MSG_ENTITY, self.mins.y);
 296         WriteCoord(MSG_ENTITY, self.mins.z);
 297         WriteCoord(MSG_ENTITY, self.maxs.x);
 298         WriteCoord(MSG_ENTITY, self.maxs.y);
 299         WriteCoord(MSG_ENTITY, self.maxs.z);
 300         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 301
 302         // we need THESE to calculate the proper transform
 303         WriteCoord(MSG_ENTITY, self.enemy.origin.x);
 304         WriteCoord(MSG_ENTITY, self.enemy.origin.y);
 305         WriteCoord(MSG_ENTITY, self.enemy.origin.z);
 306         WriteCoord(MSG_ENTITY, self.enemy.angles.x);
 307         WriteCoord(MSG_ENTITY, self.enemy.angles.y);
 308         WriteCoord(MSG_ENTITY, self.enemy.angles.z);
 309
 310         if(f & 2)
 311         {
 312                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 313                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 314         }
 315
 316         return true;
 317 }
 318
 319 #ifdef WARPZONELIB_KEEPDEBUG
 320 float WarpZone_CheckProjectileImpact(entity player)
 321 {
 322         vector o0, v0;
 323
 324         o0 = player.origin + player.view_ofs;
 325         v0 = player.velocity;
 326
 327         // if we teleported shortly before, abort
 328         if(time <= player.warpzone_teleport_finishtime + 0.1)
 329                 return 0;
 330
 331         // if player hit a warpzone, abort
 332         entity wz;
 333         wz = WarpZone_Find(o0 + player.mins, o0 + player.maxs);
 334         if(!wz)
 335                 return 0;
 336
 337 #ifdef WARPZONELIB_REMOVEHACK
 338         print("impactfilter found something - and it no longer gets handled correctly - please tell divVerent whether anything behaves broken now\n");
 339 #else
 340         print("impactfilter found something - and it even gets handled correctly - please tell divVerent that this code apparently gets triggered again\n");
 341 #endif
 342         print("Entity type: ", player.classname, "\n");
 343         print("Origin: ", vtos(player.origin), "\n");
 344         print("Velocity: ", vtos(player.velocity), "\n");
 345
 346 #ifdef WARPZONELIB_REMOVEHACK
 347         return 0;
 348 #else
 349         // retry previous move
 350         setorigin(player, player.warpzone_oldorigin);
 351         player.velocity = player.warpzone_oldvelocity;
 352         if(WarpZone_Teleport(wz, player, 0, 1))
 353         {
 354                 entity oldself;
 355                 string save1, save2;
 356
 357                 oldself = self;
 358                 self = wz;
 359                 other = player;
 360                 activator = player;
 361
 362                 save1 = self.target; self.target = string_null;
 363                 save2 = self.target3; self.target3 = string_null;
 364                 SUB_UseTargets();
 365                 if (!self.target) self.target = save1;
 366                 if (!self.target3) self.target3 = save2;
 367
 368                 self = self.enemy;
 369                 save1 = self.target; self.target = string_null;
 370                 save2 = self.target2; self.target2 = string_null;
 371                 SUB_UseTargets();
 372                 if (!self.target) self.target = save1;
 373                 if (!self.target2) self.target2 = save2;
 374                 self = oldself;
 375         }
 376         else
 377         {
 378                 setorigin(player, o0 - player.view_ofs);
 379                 player.velocity = v0;
 380         }
 381
 382         return +1;
 383 #endif
 384 }
 385 #endif
 386
 387 float WarpZone_Projectile_Touch()
 388 {
 389         if(other.classname == "trigger_warpzone")
 390                 return true;
 391
 392         // no further impacts if we teleported this frame!
 393         // this is because even if we did teleport, the engine still may raise
 394         // touch events for the previous location
 395         // engine now aborts moves on teleport, so this SHOULD not happen any more
 396         // but if this is called from TouchAreaGrid of the projectile moving,
 397         // then this won't do
 398         if(time == self.warpzone_teleport_time)
 399                 return true;
 400
 401 #ifdef WARPZONELIB_KEEPDEBUG
 402         // this SEEMS to not happen at the moment, but if it did, it would be more reliable
 403         {
 404                 float save_dpstartcontents;
 405                 float save_dphitcontents;
 406                 float save_dphitq3surfaceflags;
 407                 string save_dphittexturename;
 408                 float save_allsolid;
 409                 float save_startsolid;
 410                 float save_fraction;
 411                 vector save_endpos;
 412                 vector save_plane_normal;
 413                 float save_plane_dist;
 414                 entity save_ent;
 415                 float save_inopen;
 416                 float save_inwater;
 417                 save_dpstartcontents = trace_dpstartcontents;
 418                 save_dphitcontents = trace_dphitcontents;
 419                 save_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 420                 save_dphittexturename = trace_dphittexturename;
 421                 save_allsolid = trace_allsolid;
 422                 save_startsolid = trace_startsolid;
 423                 save_fraction = trace_fraction;
 424                 save_endpos = trace_endpos;
 425                 save_plane_normal = trace_plane_normal;
 426                 save_plane_dist = trace_plane_dist;
 427                 save_ent = trace_ent;
 428                 save_inopen = trace_inopen;
 429                 save_inwater = trace_inwater;
 430                 float f;
 431                 if((f = WarpZone_CheckProjectileImpact(self)) != 0)
 432                         return (f > 0);
 433                 trace_dpstartcontents = save_dpstartcontents;
 434                 trace_dphitcontents = save_dphitcontents;
 435                 trace_dphitq3surfaceflags = save_dphitq3surfaceflags;
 436                 trace_dphittexturename = save_dphittexturename;
 437                 trace_allsolid = save_allsolid;
 438                 trace_startsolid = save_startsolid;
 439                 trace_fraction = save_fraction;
 440                 trace_endpos = save_endpos;
 441                 trace_plane_normal = save_plane_normal;
 442                 trace_plane_dist = save_plane_dist;
 443                 trace_ent = save_ent;
 444                 trace_inopen = save_inopen;
 445                 trace_inwater = save_inwater;
 446         }
 447 #endif
 448
 449         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 450                 return true;
 451
 452         return false;
 453 }
 454
 455 void WarpZone_InitStep_FindOriginTarget()
 456 {
 457         if(self.killtarget != "")
 458         {
 459                 self.aiment = find(world, targetname, self.killtarget);
 460                 if(self.aiment == world)
 461                 {
 462                         error("Warp zone with nonexisting killtarget");
 463                         return;
 464                 }
 465                 self.killtarget = string_null;
 466         }
 467 }
 468
 469 void WarpZonePosition_InitStep_FindTarget()
 470 {
 471         if(self.target == "")
 472         {
 473                 error("Warp zone position with no target");
 474                 return;
 475         }
 476         self.enemy = find(world, targetname, self.target);
 477         if(self.enemy == world)
 478         {
 479                 error("Warp zone position with nonexisting target");
 480                 return;
 481         }
 482         if(self.enemy.aiment)
 483         {
 484                 // already is positioned
 485                 error("Warp zone position targeting already oriented warpzone");
 486                 return;
 487         }
 488         self.enemy.aiment = self;
 489 }
 490
 491 void WarpZoneCamera_Think(void)
 492 {
 493         if(self.warpzone_save_origin != self.origin
 494         || self.warpzone_save_angles != self.angles
 495         || self.warpzone_save_eorigin != self.enemy.origin
 496         || self.warpzone_save_eangles != self.enemy.angles)
 497         {
 498                 WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 499                 self.warpzone_save_origin = self.origin;
 500                 self.warpzone_save_angles = self.angles;
 501                 self.warpzone_save_eorigin = self.enemy.origin;
 502                 self.warpzone_save_eangles = self.enemy.angles;
 503         }
 504         self.nextthink = time;
 505 }
 506
 507 void WarpZoneCamera_InitStep_FindTarget()
 508 {
 509         entity e;
 510         float i;
 511         if(self.target == "")
 512         {
 513                 error("Camera with no target");
 514                 return;
 515         }
 516         self.enemy = world;
 517         for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 518                 if(random() * ++i < 1)
 519                         self.enemy = e;
 520         if(self.enemy == world)
 521         {
 522                 error("Camera with nonexisting target");
 523                 return;
 524         }
 525         warpzone_cameras_exist = 1;
 526         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 527         self.SendFlags = 0xFFFFFF;
 528         if(self.spawnflags & 1)
 529         {
 530                 self.think = WarpZoneCamera_Think;
 531                 self.nextthink = time;
 532         }
 533         else
 534                 self.nextthink = 0;
 535 }
 536
 537 void WarpZone_InitStep_UpdateTransform()
 538 {
 539         vector org, ang, norm, point;
 540         float area;
 541         vector tri, a, b, c, n;
 542         float i_s, i_t, n_t;
 543         string tex;
 544
 545         org = self.origin;
 546         if(org == '0 0 0')
 547                 org = 0.5 * (self.mins + self.maxs);
 548
 549         norm = point = '0 0 0';
 550         area = 0;
 551         for(i_s = 0; ; ++i_s)
 552         {
 553                 tex = getsurfacetexture(self, i_s);
 554                 if (!tex)
 555                         break; // this is beyond the last one
 556                 if(tex == "textures/common/trigger" || tex == "trigger")
 557                         continue;
 558                 n_t = getsurfacenumtriangles(self, i_s);
 559                 for(i_t = 0; i_t < n_t; ++i_t)
 560                 {
 561                         tri = getsurfacetriangle(self, i_s, i_t);
 562                         a = getsurfacepoint(self, i_s, tri.x);
 563                         b = getsurfacepoint(self, i_s, tri.y);
 564                         c = getsurfacepoint(self, i_s, tri.z);
 565                         n = cross(c - a, b - a);
 566                         area = area + vlen(n);
 567                         norm = norm + n;
 568                         point = point + vlen(n) * (a + b + c);
 569                 }
 570         }
 571         if(area > 0)
 572         {
 573                 norm = norm * (1 / area);
 574                 point = point * (1 / (3 * area));
 575                 if(vlen(norm) < 0.99)
 576                 {
 577                         print("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 578                         area = 0; // no autofixing in this case
 579                 }
 580                 norm = normalize(norm);
 581         }
 582
 583         ang = '0 0 0';
 584         if(self.aiment)
 585         {
 586                 org = self.aiment.origin;
 587                 ang = self.aiment.angles;
 588                 if(area > 0)
 589                 {
 590                         org = org - ((org - point) * norm) * norm; // project to plane
 591                         makevectors(ang);
 592                         if(norm * v_forward < 0)
 593                         {
 594                                 print("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 595                                 norm = -1 * norm;
 596                         }
 597                         ang = vectoangles2(norm, v_up); // keep rotation, but turn exactly against plane
 598                         ang.x = -ang.x;
 599                         if(norm * v_forward < 0.99)
 600                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 601                         if(vlen(org - self.aiment.origin) > 0.5)
 602                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 603                 }
 604         }
 605         else if(area > 0)
 606         {
 607                 org = point;
 608                 ang = vectoangles(norm);
 609                 ang.x = -ang.x;
 610         }
 611         else
 612                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 613
 614         self.warpzone_origin = org;
 615         self.warpzone_angles = ang;
 616 }
 617
 618 void WarpZone_InitStep_ClearTarget()
 619 {
 620         if(self.enemy)
 621                 self.enemy.enemy = world;
 622         self.enemy = world;
 623 }
 624
 625 entity warpzone_first; .entity warpzone_next;
 626 void WarpZone_InitStep_FindTarget()
 627 {
 628         float i;
 629         entity e, e2;
 630
 631         if(self.enemy)
 632                 return;
 633
 634         // this way only one of the two ents needs to target
 635         if(self.target != "")
 636         {
 637                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 638
 639                 e2 = world;
 640                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 641                         if(!e.enemy)
 642                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 643                                         if(random() * ++i < 1)
 644                                                 e2 = e;
 645                 if(!e2)
 646                 {
 647                         self.enemy = world;
 648                         error("Warpzone with non-existing target");
 649                         return;
 650                 }
 651                 self.enemy = e2;
 652                 e2.enemy = self;
 653         }
 654 }
 655
 656 void WarpZone_Think();
 657 void WarpZone_InitStep_FinalizeTransform()
 658 {
 659         if(!self.enemy || self.enemy.enemy != self)
 660         {
 661                 error("Invalid warp zone detected. Killed.");
 662                 return;
 663         }
 664
 665         warpzone_warpzones_exist = 1;
 666         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 667         self.touch = WarpZone_Touch;
 668         self.SendFlags = 0xFFFFFF;
 669         if(self.spawnflags & 1)
 670         {
 671                 self.think = WarpZone_Think;
 672                 self.nextthink = time;
 673         }
 674         else
 675                 self.nextthink = 0;
 676 }
 677
 678 float warpzone_initialized;
 679 //entity warpzone_first;
 680 entity warpzone_position_first;
 681 entity warpzone_camera_first;
 682 .entity warpzone_next;
 683 void spawnfunc_misc_warpzone_position(void)
 684 {
 685         // "target", "angles", "origin"
 686         self.warpzone_next = warpzone_position_first;
 687         warpzone_position_first = self;
 688 }
 689 void spawnfunc_trigger_warpzone_position(void)
 690 {
 691         spawnfunc_misc_warpzone_position();
 692 }
 693 void spawnfunc_trigger_warpzone(void)
 694 {
 695         // warp zone entities must have:
 696         // "killtarget" pointing to a target_position with a direction arrow
 697         //              that points AWAY from the warp zone, and that is inside
 698         //              the warp zone trigger
 699         // "target"     pointing to an identical warp zone at another place in
 700         //              the map, with another killtarget to designate its
 701         //              orientation
 702
 703 #ifndef WARPZONE_USE_FIXANGLE
 704         // used when teleporting
 705         precache_model("null");
 706 #endif
 707
 708         if(!self.scale)
 709                 self.scale = self.modelscale;
 710         if(!self.scale)
 711                 self.scale = 1;
 712         string m;
 713         m = self.model;
 714         WarpZoneLib_ExactTrigger_Init();
 715         if(m != "")
 716         {
 717                 precache_model(m);
 718                 setmodel(self, m); // no precision needed
 719         }
 720         setorigin(self, self.origin);
 721         if(self.scale)
 722                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 723         else
 724                 setsize(self, self.mins, self.maxs);
 725         self.SendEntity = WarpZone_Send;
 726         self.SendFlags = 0xFFFFFF;
 727         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 728         self.warpzone_next = warpzone_first;
 729         warpzone_first = self;
 730 }
 731 void spawnfunc_func_camera(void)
 732 {
 733         if(!self.scale)
 734                 self.scale = self.modelscale;
 735         if(!self.scale)
 736                 self.scale = 1;
 737         if(self.model != "")
 738         {
 739                 precache_model(self.model);
 740                 setmodel(self, self.model); // no precision needed
 741         }
 742         setorigin(self, self.origin);
 743         if(self.scale)
 744                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 745         else
 746                 setsize(self, self.mins, self.maxs);
 747         if(!self.solid)
 748                 self.solid = SOLID_BSP;
 749         else if(self.solid < 0)
 750                 self.solid = SOLID_NOT;
 751         self.SendEntity = WarpZone_Camera_Send;
 752         self.SendFlags = 0xFFFFFF;
 753         self.warpzone_next = warpzone_camera_first;
 754         warpzone_camera_first = self;
 755 }
 756 void WarpZones_Reconnect()
 757 {
 758         entity e;
 759         e = self;
 760         for(self = warpzone_first; self; self = self.warpzone_next)
 761                 WarpZone_InitStep_ClearTarget();
 762         for(self = warpzone_first; self; self = self.warpzone_next)
 763                 WarpZone_InitStep_FindTarget();
 764         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 765                 WarpZoneCamera_InitStep_FindTarget();
 766         for(self = warpzone_first; self; self = self.warpzone_next)
 767                 WarpZone_InitStep_FinalizeTransform();
 768         self = e;
 769 }
 770
 771 void WarpZone_Think()
 772 {
 773         if(self.warpzone_save_origin != self.origin
 774         || self.warpzone_save_angles != self.angles
 775         || self.warpzone_save_eorigin != self.enemy.origin
 776         || self.warpzone_save_eangles != self.enemy.angles)
 777         {
 778                 entity oldself;
 779                 oldself = self;
 780                 WarpZone_InitStep_UpdateTransform();
 781                 self = self.enemy;
 782                 WarpZone_InitStep_UpdateTransform();
 783                 self = oldself;
 784                 WarpZone_InitStep_FinalizeTransform();
 785                 self = self.enemy;
 786                 WarpZone_InitStep_FinalizeTransform();
 787                 self = oldself;
 788                 self.warpzone_save_origin = self.origin;
 789                 self.warpzone_save_angles = self.angles;
 790                 self.warpzone_save_eorigin = self.enemy.origin;
 791                 self.warpzone_save_eangles = self.enemy.angles;
 792         }
 793         self.nextthink = time;
 794 }
 795
 796 void WarpZone_StartFrame()
 797 {
 798         entity e;
 799         if(warpzone_initialized == 0)
 800         {
 801                 warpzone_initialized = 1;
 802                 e = self;
 803                 for(self = warpzone_first; self; self = self.warpzone_next)
 804                         WarpZone_InitStep_FindOriginTarget();
 805                 for(self = warpzone_position_first; self; self = self.warpzone_next)
 806                         WarpZonePosition_InitStep_FindTarget();
 807                 for(self = warpzone_first; self; self = self.warpzone_next)
 808                         WarpZone_InitStep_UpdateTransform();
 809                 self = e;
 810                 WarpZones_Reconnect();
 811                 WarpZone_PostInitialize_Callback();
 812         }
 813
 814         entity oldself, oldother;
 815         oldself = self;
 816         oldother = other;
 817         for(e = world; (e = nextent(e)); )
 818         {
 819                 if(warpzone_warpzones_exist) { WarpZone_StoreProjectileData(e); }
 820
 821                 if(IS_REAL_CLIENT(e))
 822                 {
 823                         if(e.solid == SOLID_NOT) // not spectating?
 824                         if(e.movetype == MOVETYPE_NOCLIP || e.movetype == MOVETYPE_FLY || e.movetype == MOVETYPE_FLY_WORLDONLY) // not spectating? (this is to catch observers)
 825                         {
 826                                 other = e; // player
 827
 828                                 // warpzones
 829                                 if(warpzone_warpzones_exist) {
 830                                 self = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 831                                 if(self)
 832                                 if(!WarpZoneLib_ExactTrigger_Touch())
 833                                         if(WarpZone_PlaneDist(self, e.origin + e.view_ofs) <= 0)
 834                                                 WarpZone_Teleport(self, e, -1, 0); } // NOT triggering targets by this!
 835
 836                                 // teleporters
 837                                 self = Teleport_Find(e.origin + e.mins, e.origin + e.maxs);
 838                                 if(self)
 839                                 if(!WarpZoneLib_ExactTrigger_Touch())
 840                                         Simple_TeleportPlayer(self, other); // NOT triggering targets by this!
 841                         }
 842                 }
 843
 844                 if(IS_NOT_A_CLIENT(e))
 845                 {
 846                         if(warpzone_warpzones_exist)
 847                                 for (; (e = nextent(e)); )
 848                                         WarpZone_StoreProjectileData(e);
 849                         break;
 850                 }
 851         }
 852         self = oldself;
 853         other = oldother;
 854 }
 855
 856 .float warpzone_reconnecting;
 857 float visible_to_some_client(entity ent)
 858 {
 859         entity e;
 860         for(e = nextent(world); !IS_NOT_A_CLIENT(e); e = nextent(e))
 861                 if(IS_PLAYER(e) && IS_REAL_CLIENT(e))
 862                         if(checkpvs(e.origin + e.view_ofs, ent))
 863                                 return 1;
 864         return 0;
 865 }
 866 void trigger_warpzone_reconnect_use()
 867 {
 868         entity e;
 869         e = self;
 870         // NOTE: this matches for target, not targetname, but of course
 871         // targetname must be set too on the other entities
 872         for(self = warpzone_first; self; self = self.warpzone_next)
 873                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && (visible_to_some_client(self) || visible_to_some_client(self.enemy))));
 874         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 875                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && visible_to_some_client(self)));
 876         for(self = warpzone_first; self; self = self.warpzone_next)
 877                 if(self.warpzone_reconnecting)
 878                         WarpZone_InitStep_ClearTarget();
 879         for(self = warpzone_first; self; self = self.warpzone_next)
 880                 if(self.warpzone_reconnecting)
 881                         WarpZone_InitStep_FindTarget();
 882         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 883                 if(self.warpzone_reconnecting)
 884                         WarpZoneCamera_InitStep_FindTarget();
 885         for(self = warpzone_first; self; self = self.warpzone_next)
 886                 if(self.warpzone_reconnecting || self.enemy.warpzone_reconnecting)
 887                         WarpZone_InitStep_FinalizeTransform();
 888         self = e;
 889 }
 890
 891 void spawnfunc_trigger_warpzone_reconnect()
 892 {
 893         self.use = trigger_warpzone_reconnect_use;
 894 }
 895
 896 void spawnfunc_target_warpzone_reconnect()
 897 {
 898         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 899 }
 900
 901 void WarpZone_PlayerPhysics_FixVAngle(void)
 902 {
 903 #ifndef WARPZONE_DONT_FIX_VANGLE
 904         if(IS_REAL_CLIENT(self))
 905         if(self.v_angle.z <= 360) // if not already adjusted
 906         if(time - self.ping * 0.001 < self.warpzone_teleport_time)
 907         {
 908                 self.v_angle = WarpZone_TransformVAngles(self.warpzone_teleport_zone, self.v_angle);
 909                 self.v_angle_z += 720; // mark as adjusted
 910         }
 911 #endif
 912 }