data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12         if(spectatee_status < 0)
  13                 return;
  14         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  15                 return;
  16         if(getstati(STAT_VORE_EATEN) && cvar("cl_vore_stomachmodel") >= 1 && !cvar("chase_active"))
  17                 return;
  18         if(ent.eaten)
  19                 return;
  20
  21         float sameteam;
  22         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  23                 sameteam = TRUE;
  24
  25         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  26         {
  27                 ent.origin_z += cvar("hud_shownames_offset");
  28
  29                 // offset the name by player scale, decided by health
  30                 if(g_healthsize_center >= 0)
  31                         ent.origin_z -= (g_healthsize_center - bound(g_healthsize_min, ent.healthvalue, g_healthsize_max)) * cvar("hud_shownames_offset_healthsize");
  32
  33                 traceline(ent.origin, view_origin, TRUE, ent);
  34
  35                 vector o, eo;
  36                 o = project_3d_to_2d(ent.origin);
  37                 float overlap;
  38
  39                 if(cvar("hud_shownames_antioverlap"))
  40                 {
  41                         // fade tag out if another tag that is closer to you overlaps
  42                         entity e;
  43                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  44                         {
  45                                 if(e == ent)
  46                                         continue;
  47                                 eo = project_3d_to_2d(e.origin);
  48                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  49                                 {
  50                                         eo_z = 0;
  51                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  52                                         {
  53                                                 overlap = TRUE;
  54                                                 break;
  55                                         }
  56                                 }
  57                         }
  58                 }
  59
  60                 if(trace_endpos != view_origin) // out of view, fade out
  61                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  62                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  63                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  64                 else if(overlap) // tag overlap detected, fade out
  65                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  66                 else // fade in
  67                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  68
  69                 if(!ent.alpha)
  70                         return;
  71
  72                 float dist;
  73                 dist = vlen(ent.origin - view_origin);
  74
  75                 float a;
  76                 a = cvar("hud_shownames_alpha");
  77                 a *= ent.alpha;
  78                 if(cvar("hud_shownames_maxdistance"))
  79                 {
  80                         if(dist >= cvar("hud_shownames_maxdistance"))
  81                                 return;
  82                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  83                 }
  84
  85                 if(!a)
  86                         return;
  87
  88                 float resize;
  89                 resize = 1;
  90                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  91                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  92
  93                 // draw the sprite image
  94                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  95                 {
  96                         o_z = 0;
  97
  98                         vector myPos, mySize;
  99                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
 100                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 101
 102                         // size scaling
 103                         mySize_x *= resize;
 104                         mySize_y *= resize;
 105
 106                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 107                         myPos_y += (mySize_y / resize - mySize_y);
 108
 109                         vector namepos; // this is where the origin of the string
 110                         float namewidth;
 111
 112                         namepos = myPos;
 113                         namewidth = mySize_x;
 114
 115                         string s;
 116                         s = GetPlayerName(ent.sv_entnum-1);
 117                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 118                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 119
 120                         drawfontscale = '1 1 0' * resize;
 121                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 122
 123                         if(sameteam && ent.healthvalue > 0)
 124                         {
 125                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 126                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 127                                 else if(cvar("hud_shownames_status") > 1)
 128                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 129
 130                                 // if team healing is enabled, mark the team mate as possible to heal
 131                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 132                                         s = strcat(s, "^7 [^5HEAL^7]");
 133                         }
 134
 135                         float width;
 136                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 137
 138                         if (width != namewidth)
 139                                 namepos_x += (namewidth - width) / 2;
 140                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 141                         drawfontscale = '1 1 0';
 142                 }
 143         }
 144 }
 145
 146 entity shownames_ent[255];
 147 void Draw_ShowNames_All()
 148 {
 149         float i;
 150         for(i = 0; i < maxclients; ++i)
 151         {
 152                 float t;
 153                 t = GetPlayerColor(i);
 154                 if(t == COLOR_SPECTATOR)
 155                         continue;
 156
 157                 entity e;
 158                 e = shownames_ent[i];
 159                 if(!e)
 160                 {
 161                         e = spawn();
 162                         e.classname = "shownames_tag";
 163                         e.sv_entnum = i+1;
 164                         shownames_ent[i] = e;
 165                 }
 166
 167                 entity entcs;
 168                 entcs = entcs_receiver[i];
 169                 if(entcs)
 170                 {
 171                         e.healthvalue = entcs.healthvalue;
 172                         e.armorvalue = entcs.armorvalue;
 173                         e.eaten = entcs.eaten;
 174                 }
 175                 else
 176                 {
 177                         e.healthvalue = 2342;
 178                         e.armorvalue = 0;
 179                         e.eaten = 0;
 180                 }
 181
 182                 e.origin = getplayerorigin(i);
 183                 if(e.origin == GETPLAYERORIGIN_ERROR)
 184                         continue;
 185
 186                 Draw_ShowNames(e);
 187         }
 188 }