data/qcsrc/server/cl_weaponsystem.qc

   1 /*\r
   2 ===========================================================================\r
   3 \r
   4   CLIENT WEAPONSYSTEM CODE\r
   5   Bring back W_Weaponframe\r
   6 \r
   7 ===========================================================================\r
   8 */\r
   9 \r
  10 .float weapon_frametime;\r
  11 \r
  12 float W_WeaponRateFactor()\r
  13 {\r
  14         float t;\r
  15         t = 1.0 / g_weaponratefactor;\r
  16 \r
  17         return t;\r
  18 }\r
  19 \r
  20 void W_SwitchWeapon_Force(entity e, float w)\r
  21 {\r
  22         e.cnt = e.switchweapon;\r
  23         e.switchweapon = w;\r
  24 }\r
  25 \r
  26 .float antilag_debug;\r
  27 \r
  28 // VorteX: static frame globals\r
  29 float WFRAME_DONTCHANGE = -1;\r
  30 float WFRAME_FIRE1 = 0;\r
  31 float WFRAME_FIRE2 = 1;\r
  32 float WFRAME_IDLE = 2;\r
  33 float WFRAME_RELOAD = 3;\r
  34 .float wframe;\r
  35 \r
  36 void(float fr, float t, void() func) weapon_thinkf;\r
  37 \r
  38 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)\r
  39 {\r
  40         vector ret;\r
  41         ret_x = screenright * v;\r
  42         ret_y = screenup * v;\r
  43         ret_z = screenforward * v;\r
  44         return ret;\r
  45 }\r
  46 \r
  47 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)\r
  48 {\r
  49         float i, j, k;\r
  50         vector mi, ma, thisv, myv, ret;\r
  51 \r
  52         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);\r
  53 \r
  54         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance\r
  55 \r
  56         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)\r
  57         {\r
  58                 thisv = targ.origin;\r
  59                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;\r
  60                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;\r
  61                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;\r
  62                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);\r
  63                 if(i || j || k)\r
  64                 {\r
  65                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;\r
  66                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;\r
  67                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;\r
  68                 }\r
  69                 else\r
  70                 {\r
  71                         // first run\r
  72                         mi = ma = thisv;\r
  73                 }\r
  74         }\r
  75 \r
  76         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);\r
  77         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);\r
  78         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);\r
  79         ret_z = thisv_z - myv_z;\r
  80         return ret;\r
  81 }\r
  82 \r
  83 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)\r
  84 {\r
  85         vector hitplot;\r
  86         vector org;\r
  87         float lag;\r
  88 \r
  89         if(player.hitplotfh >= 0)\r
  90         {\r
  91                 lag = ANTILAG_LATENCY(player);\r
  92                 if(lag < 0.001)\r
  93                         lag = 0;\r
  94                 if(clienttype(player) != CLIENTTYPE_REAL)\r
  95                         lag = 0; // only antilag for clients\r
  96 \r
  97                 org = player.origin + player.view_ofs;\r
  98                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);\r
  99                 if(trace_ent.flags & FL_CLIENT)\r
 100                 {\r
 101                         antilag_takeback(trace_ent, time - lag);\r
 102                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);\r
 103                         antilag_restore(trace_ent);\r
 104                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));\r
 105                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));\r
 106                 }\r
 107         }\r
 108 }\r
 109 \r
 110 vector w_shotorg;\r
 111 vector w_shotdir;\r
 112 \r
 113 // this function calculates w_shotorg and w_shotdir based on the weapon model\r
 114 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.\r
 115 // make sure you call makevectors first (FIXME?)\r
 116 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)\r
 117 {\r
 118         float nudge = 1; // added to traceline target and subtracted from result\r
 119         local vector trueaimpoint;\r
 120         local float oldsolid;\r
 121         vector vecs, dv;\r
 122         oldsolid = ent.dphitcontentsmask;\r
 123         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;\r
 124         if(antilag)\r
 125                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));\r
 126                 // passing world, because we do NOT want it to touch dphitcontentsmask\r
 127         else\r
 128                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);\r
 129         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;\r
 130 \r
 131         vector vf, vr, vu;\r
 132         vf = v_forward;\r
 133         vr = v_right;\r
 134         vu = v_up;\r
 135         trueaimpoint = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support\r
 136         v_forward = vf;\r
 137         v_right = vr;\r
 138         v_up = vu;\r
 139 \r
 140         // track max damage\r
 141         if not(inWarmupStage) {\r
 142                 entity w;\r
 143                 w = get_weaponinfo(ent.weapon);\r
 144                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage\r
 145                         ent.stats_fired[ent.weapon - 1] += maxdamage;\r
 146                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);\r
 147                 }\r
 148         }\r
 149 \r
 150         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);\r
 151 \r
 152         if(ent.weaponentity.movedir_x > 0)\r
 153         {\r
 154                 vecs = ent.weaponentity.movedir;\r
 155                 vecs_y = -vecs_y;\r
 156         }\r
 157         else\r
 158                 vecs = '0 0 0';\r
 159 \r
 160         if(debug_shotorg != '0 0 0')\r
 161                 vecs = debug_shotorg;\r
 162 \r
 163         dv = v_right * vecs_y + v_up * vecs_z;\r
 164         w_shotorg = ent.origin + ent.view_ofs + dv;\r
 165 \r
 166         // now move the shotorg forward as much as requested if possible\r
 167         if(antilag)\r
 168         {\r
 169                 if(ent.antilag_debug)\r
 170                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);\r
 171                 else\r
 172                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));\r
 173         }\r
 174         else\r
 175                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);\r
 176         w_shotorg = trace_endpos - v_forward * nudge;\r
 177         // calculate the shotdir from the chosen shotorg\r
 178         w_shotdir = normalize(trueaimpoint - w_shotorg);\r
 179 \r
 180         if (antilag)\r
 181         if (!ent.cvar_cl_noantilag)\r
 182         {\r
 183                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original\r
 184                 {\r
 185                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);\r
 186                         if (!trace_ent.takedamage)\r
 187                         {\r
 188                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));\r
 189                                 if (trace_ent.takedamage && trace_ent.classname == "player")\r
 190                                 {\r
 191                                         entity e;\r
 192                                         e = trace_ent;\r
 193                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);\r
 194                                         if(trace_ent == e)\r
 195                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);\r
 196                                 }\r
 197                         }\r
 198                 }\r
 199                 else if(cvar("g_antilag") == 3) // client side hitscan\r
 200                 {\r
 201                         // this part MUST use prydon cursor\r
 202                         if (ent.cursor_trace_ent)                 // client was aiming at someone\r
 203                         if (ent.cursor_trace_ent != ent)         // just to make sure\r
 204                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable\r
 205                         if (ent.cursor_trace_ent.classname == "player") // and actually a player\r
 206                         {\r
 207                                 // verify that the shot would miss without antilag\r
 208                                 // (avoids an issue where guns would always shoot at their origin)\r
 209                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);\r
 210                                 if (!trace_ent.takedamage)\r
 211                                 {\r
 212                                         // verify that the shot would hit if altered\r
 213                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);\r
 214                                         if (trace_ent == ent.cursor_trace_ent)\r
 215                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);\r
 216                                         else\r
 217                                                 print("antilag fail\n");\r
 218                                 }\r
 219                         }\r
 220                 }\r
 221         }\r
 222 \r
 223         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)\r
 224 \r
 225         if (!g_norecoil)\r
 226                 ent.punchangle_x = recoil * -1;\r
 227 \r
 228         if (snd != "")\r
 229         {\r
 230                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);\r
 231         }\r
 232 \r
 233         if (ent.items & IT_STRENGTH && maxdamage)\r
 234                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);\r
 235 };\r
 236 \r
 237 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)\r
 238 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)\r
 239 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)\r
 240 \r
 241 .string weaponname;\r
 242 \r
 243 float CL_Weaponentity_CustomizeEntityForClient()\r
 244 {\r
 245         self.viewmodelforclient = self.owner;\r
 246         if(other.classname == "spectator")\r
 247                 if(other.enemy == self.owner)\r
 248                         self.viewmodelforclient = other;\r
 249         return TRUE;\r
 250 }\r
 251 \r
 252 float CL_ExteriorWeaponentity_CustomizeEntityForClient()\r
 253 {\r
 254         // hide the exterior weapon entity of a predator from their prey\r
 255         // otherwise, the stomach model the predator is transformed in (see Client_customizeentityforclient) will have a weapon model attached to it\r
 256         if(self.owner.weaponname == "" || self.owner.deadflag != DEAD_NO)\r
 257                 return TRUE;\r
 258 \r
 259         float chase;\r
 260         chase = other.cvar_chase_active;\r
 261 \r
 262         if(other.spectatee_status && other.spectatee_status == num_for_edict(other.enemy))\r
 263                 other = other.enemy; // also do this for the player we are spectating\r
 264 \r
 265         if not(chase || other.classname == "observer") // the observer check prevents a bug\r
 266         if(other.predator == self.owner)\r
 267         {\r
 268                 setmodel(self, "");\r
 269                 return TRUE;\r
 270         }\r
 271 \r
 272         self.effects &~= EF_NODEPTHTEST;\r
 273         if not(self.owner.stat_eaten)\r
 274                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3"));\r
 275         else if(cvar("g_vore_neighborprey_distance") && other.predator == self.owner.predator && !(chase || other.classname == "observer"))\r
 276         {\r
 277                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // allow seeing neighboring prey's weapon model\r
 278                 self.effects |= EF_NODEPTHTEST; // don't hide behind the stomach's own EF_NODEPTHTEST\r
 279         }\r
 280         else\r
 281                 setmodel(self, ""); // hide prey's weapon model\r
 282         return TRUE;\r
 283 }\r
 284 \r
 285 float qcweaponanimation;\r
 286 vector weapon_offset = '0 -10 0';\r
 287 vector weapon_adjust = '10 0 -15';\r
 288 .vector weapon_morph0origin;\r
 289 .vector weapon_morph0angles;\r
 290 .float  weapon_morph0time;\r
 291 .vector weapon_morph1origin;\r
 292 .vector weapon_morph1angles;\r
 293 .float  weapon_morph1time;\r
 294 .vector weapon_morph2origin;\r
 295 .vector weapon_morph2angles;\r
 296 .float  weapon_morph2time;\r
 297 .vector weapon_morph3origin;\r
 298 .vector weapon_morph3angles;\r
 299 .float  weapon_morph3time;\r
 300 .vector weapon_morph4origin;\r
 301 .vector weapon_morph4angles;\r
 302 .float  weapon_morph4time;\r
 303 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)\r
 304 \r
 305 /*\r
 306  * supported formats:\r
 307  *\r
 308  * 1. simple animated model, muzzle flash handling on h_ model:\r
 309  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation\r
 310  *      tags:\r
 311  *        shot = muzzle end (shot origin, also used for muzzle flashes)\r
 312  *        shell = casings ejection point (must be on the right hand side of the gun)\r
 313  *        weapon = attachment for v_tuba.md3\r
 314  *    v_tuba.md3 - first and third person model\r
 315  *    g_tuba.md3 - pickup model\r
 316  *\r
 317  * 2. simple animated model, muzzle flash handling on v_ model:\r
 318  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation\r
 319  *      tags:\r
 320  *        weapon = attachment for v_tuba.md3\r
 321  *    v_tuba.md3 - first and third person model\r
 322  *      tags:\r
 323  *        shot = muzzle end (shot origin, also used for muzzle flashes)\r
 324  *        shell = casings ejection point (must be on the right hand side of the gun)\r
 325  *    g_tuba.md3 - pickup model\r
 326  *\r
 327  * 3. fully animated model, muzzle flash handling on h_ model:\r
 328  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model\r
 329  *      tags:\r
 330  *        shot = muzzle end (shot origin, also used for muzzle flashes)\r
 331  *        shell = casings ejection point (must be on the right hand side of the gun)\r
 332  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)\r
 333  *    v_tuba.md3 - third person model\r
 334  *    g_tuba.md3 - pickup model\r
 335  *\r
 336  * 4. fully animated model, muzzle flash handling on v_ model:\r
 337  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model\r
 338  *      tags:\r
 339  *        shot = muzzle end (shot origin)\r
 340  *        shell = casings ejection point (must be on the right hand side of the gun)\r
 341  *    v_tuba.md3 - third person model\r
 342  *      tags:\r
 343  *        shot = muzzle end (for muzzle flashes)\r
 344  *    g_tuba.md3 - pickup model\r
 345  */\r
 346 \r
 347 void CL_Weaponentity_Think()\r
 348 {\r
 349         float tb, v_shot_idx;\r
 350         self.nextthink = time;\r
 351         if (intermission_running)\r
 352                 self.frame = self.anim_idle_x;\r
 353         if (self.owner.weaponentity != self)\r
 354         {\r
 355                 if (self.weaponentity)\r
 356                         remove(self.weaponentity);\r
 357                 remove(self);\r
 358                 return;\r
 359         }\r
 360         if (self.owner.deadflag != DEAD_NO)\r
 361         {\r
 362                 self.model = "";\r
 363                 if (self.weaponentity)\r
 364                         self.weaponentity.model = "";\r
 365                 return;\r
 366         }\r
 367         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)\r
 368         if (substring(self.owner.model, -4, 4) != ".md3") // not a stomach model\r
 369         {\r
 370                 self.cnt = self.owner.weapon;\r
 371                 self.dmg = self.owner.modelindex;\r
 372                 self.deadflag = self.owner.deadflag;\r
 373 \r
 374                 string animfilename;\r
 375                 float animfile;\r
 376                 if (self.owner.weaponname != "")\r
 377                 {\r
 378                         // if there is a child entity, hide it until we're sure we use it\r
 379                         if (self.weaponentity)\r
 380                                 self.weaponentity.model = "";\r
 381                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below\r
 382                         v_shot_idx = gettagindex(self, "shot"); // used later\r
 383                         if(!v_shot_idx)\r
 384                                 v_shot_idx = gettagindex(self, "tag_shot");\r
 385 \r
 386                         if(qcweaponanimation)\r
 387                         {\r
 388                                 self.angles = '0 0 0';\r
 389                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');\r
 390                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;\r
 391                                 self.movedir_x += 32;\r
 392                                 self.spawnorigin = self.movedir;\r
 393                                 // oldorigin - not calculated here\r
 394                         }\r
 395                         else\r
 396                         {\r
 397                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".iqm")); // precision set below\r
 398                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".iqm.animinfo");\r
 399                                 animfile = fopen(animfilename, FILE_READ);\r
 400                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)\r
 401                                 self.anim_fire1  = '0 1 0.01';\r
 402                                 self.anim_fire2  = '1 1 0.01';\r
 403                                 self.anim_idle   = '2 1 0.01';\r
 404                                 self.anim_reload = '3 1 0.01';\r
 405                                 if (animfile >= 0)\r
 406                                 {\r
 407                                         animparseerror = FALSE;\r
 408                                         self.anim_fire1  = animparseline(animfile);\r
 409                                         self.anim_fire2  = animparseline(animfile);\r
 410                                         self.anim_idle   = animparseline(animfile);\r
 411                                         self.anim_reload = animparseline(animfile);\r
 412                                         fclose(animfile);\r
 413                                         if (animparseerror)\r
 414                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");\r
 415                                 }\r
 416 \r
 417                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)\r
 418                                 // if we don't, this is a "real" animated model\r
 419                                 if(gettagindex(self, "weapon"))\r
 420                                 {\r
 421                                         if (!self.weaponentity)\r
 422                                                 self.weaponentity = spawn();\r
 423                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter\r
 424                                         setattachment(self.weaponentity, self, "weapon");\r
 425                                 }\r
 426                                 else if(gettagindex(self, "tag_weapon"))\r
 427                                 {\r
 428                                         if (!self.weaponentity)\r
 429                                                 self.weaponentity = spawn();\r
 430                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter\r
 431                                         setattachment(self.weaponentity, self, "tag_weapon");\r
 432                                 }\r
 433                                 else\r
 434                                 {\r
 435                                         if(self.weaponentity)\r
 436                                                 remove(self.weaponentity);\r
 437                                         self.weaponentity = world;\r
 438                                 }\r
 439 \r
 440                                 setorigin(self,'0 0 0');\r
 441                                 self.angles = '0 0 0';\r
 442                                 self.frame = 0;\r
 443                                 self.viewmodelforclient = world;\r
 444 \r
 445                                 float idx;\r
 446 \r
 447                                 if(v_shot_idx) // v_ model attached to invisible h_ model\r
 448                                 {\r
 449                                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);\r
 450                                 }\r
 451                                 else\r
 452                                 {\r
 453                                         idx = gettagindex(self, "shot");\r
 454                                         if(!idx)\r
 455                                                 idx = gettagindex(self, "tag_shot");\r
 456                                         if(idx)\r
 457                                                 self.movedir = gettaginfo(self, idx);\r
 458                                         else\r
 459                                         {\r
 460                                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");\r
 461                                                 self.movedir = '0 0 0';\r
 462                                         }\r
 463                                 }\r
 464 \r
 465                                 if(self.weaponentity) // v_ model attached to invisible h_ model\r
 466                                 {\r
 467                                         idx = gettagindex(self.weaponentity, "shell");\r
 468                                         if(!idx)\r
 469                                                 idx = gettagindex(self.weaponentity, "tag_shell");\r
 470                                         if(idx)\r
 471                                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);\r
 472                                 }\r
 473                                 else\r
 474                                         idx = 0;\r
 475                                 if(!idx)\r
 476                                 {\r
 477                                         idx = gettagindex(self, "shell");\r
 478                                         if(!idx)\r
 479                                                 idx = gettagindex(self, "tag_shell");\r
 480                                         if(idx)\r
 481                                                 self.spawnorigin = gettaginfo(self, idx);\r
 482                                         else\r
 483                                         {\r
 484                                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");\r
 485                                                 self.spawnorigin = self.movedir;\r
 486                                         }\r
 487                                 }\r
 488 \r
 489                                 if(v_shot_idx)\r
 490                                 {\r
 491                                         self.oldorigin = '0 0 0'; // use regular attachment\r
 492                                 }\r
 493                                 else\r
 494                                 {\r
 495                                         if(self.weaponentity)\r
 496                                         {\r
 497                                                 idx = gettagindex(self, "weapon");\r
 498                                                 if(!idx)\r
 499                                                         idx = gettagindex(self, "tag_weapon");\r
 500                                         }\r
 501                                         else\r
 502                                         {\r
 503                                                 idx = gettagindex(self, "handle");\r
 504                                                 if(!idx)\r
 505                                                         idx = gettagindex(self, "tag_handle");\r
 506                                         }\r
 507                                         if(idx)\r
 508                                         {\r
 509                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);\r
 510                                         }\r
 511                                         else\r
 512                                         {\r
 513                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");\r
 514                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this\r
 515                                         }\r
 516                                 }\r
 517 \r
 518                                 self.viewmodelforclient = self.owner;\r
 519                         }\r
 520                 }\r
 521                 else\r
 522                 {\r
 523                         self.model = "";\r
 524                         if(self.weaponentity)\r
 525                                 remove(self.weaponentity);\r
 526                         self.weaponentity = world;\r
 527                         self.movedir = '0 0 0';\r
 528                         self.spawnorigin = '0 0 0';\r
 529                         self.oldorigin = '0 0 0';\r
 530                         self.anim_fire1  = '0 1 0.01';\r
 531                         self.anim_fire2  = '0 1 0.01';\r
 532                         self.anim_idle   = '0 1 0.01';\r
 533                         self.anim_reload = '0 1 0.01';\r
 534                 }\r
 535 \r
 536                 self.view_ofs = '0 0 0';\r
 537 \r
 538                 if(self.movedir_x >= 0)\r
 539                 {\r
 540                         vector v0;\r
 541                         v0 = self.movedir;\r
 542                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);\r
 543                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;\r
 544                 }\r
 545                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);\r
 546                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly\r
 547 \r
 548                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount\r
 549 \r
 550                 // check if an instant weapon switch occurred\r
 551                 if (qcweaponanimation)\r
 552                 {\r
 553                         if (self.state == WS_READY)\r
 554                         {\r
 555                                 self.angles = '0 0 0';\r
 556                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');\r
 557                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));\r
 558                         }\r
 559                 }\r
 560                 else\r
 561                         setorigin(self, self.view_ofs);\r
 562                 // reset animstate now\r
 563                 self.wframe = WFRAME_IDLE;\r
 564                 self.weapon_morph0time = 0;\r
 565                 self.weapon_morph1time = 0;\r
 566                 self.weapon_morph2time = 0;\r
 567                 self.weapon_morph3time = 0;\r
 568                 self.weapon_morph4time = 0;\r
 569                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);\r
 570         }\r
 571 \r
 572         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));\r
 573         self.effects = self.owner.effects & EFMASK_CHEAP;\r
 574         self.effects &~= EF_LOWPRECISION;\r
 575         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it\r
 576         self.effects &~= EF_TELEPORT_BIT;\r
 577         self.effects &~= EF_RESTARTANIM_BIT;\r
 578         self.effects |= tb;\r
 579 \r
 580         if(self.owner.alpha == default_player_alpha)\r
 581                 self.alpha = default_weapon_alpha;\r
 582         else if(self.owner.alpha != 0 && !self.owner.stat_eaten)\r
 583                 self.alpha = self.owner.alpha;\r
 584         else\r
 585                 self.alpha = 1;\r
 586 \r
 587         self.colormap = self.owner.colormap;\r
 588         self.colormod = self.owner.colormod;\r
 589         self.glowmod = self.owner.weaponentity_glowmod;\r
 590         if (self.weaponentity)\r
 591         {\r
 592                 self.weaponentity.effects = self.effects;\r
 593                 self.weaponentity.alpha = self.alpha;\r
 594                 self.weaponentity.colormap = self.colormap;\r
 595                 self.weaponentity.colormod = self.owner.colormod; // used by the regurgitating colors\r
 596                 self.weaponentity.glowmod = self.glowmod;\r
 597         }\r
 598 \r
 599         self.angles = '0 0 0';\r
 600         local float f;\r
 601         f = 0;\r
 602         if (self.state == WS_RAISE && !intermission_running)\r
 603         {\r
 604                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");\r
 605                 self.angles_x = -90 * f * f;\r
 606                 if (qcweaponanimation)\r
 607                 {\r
 608                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');\r
 609                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));\r
 610                 }\r
 611         }\r
 612         else if (self.state == WS_DROP && !intermission_running)\r
 613         {\r
 614                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");\r
 615                 self.angles_x = -90 * f * f;\r
 616                 if (qcweaponanimation)\r
 617                 {\r
 618                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');\r
 619                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));\r
 620                 }\r
 621         }\r
 622         else if (self.state == WS_CLEAR)\r
 623         {\r
 624                 f = 1;\r
 625                 self.angles_x = -90 * f * f;\r
 626                 if (qcweaponanimation)\r
 627                 {\r
 628                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');\r
 629                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));\r
 630                 }\r
 631         }\r
 632         else if (qcweaponanimation && time < self.owner.weapon_morph1time)\r
 633         {\r
 634                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);\r
 635                 f = 1 - pow(1 - f, 3);\r
 636                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;\r
 637                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);\r
 638         }\r
 639         else if (qcweaponanimation && time < self.owner.weapon_morph2time)\r
 640         {\r
 641                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);\r
 642                 f = 1 - pow(1 - f, 3);\r
 643                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;\r
 644                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);\r
 645         }\r
 646         else if (qcweaponanimation && time < self.owner.weapon_morph3time)\r
 647         {\r
 648                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);\r
 649                 f = 1 - pow(1 - f, 3);\r
 650                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;\r
 651                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);\r
 652         }\r
 653         else if (qcweaponanimation && time < self.owner.weapon_morph4time)\r
 654         {\r
 655                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);\r
 656                 f = 1 - pow(1 - f, 3);\r
 657                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;\r
 658                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);\r
 659         }\r
 660         else if (qcweaponanimation)\r
 661         {\r
 662                 // begin a new idle morph\r
 663                 self.owner.weapon_morph0time   = time;\r
 664                 self.owner.weapon_morph0angles = self.angles;\r
 665                 self.owner.weapon_morph0origin = self.origin;\r
 666 \r
 667                 float r;\r
 668                 float t;\r
 669 \r
 670                 r = random();\r
 671                 if (r < 0.1)\r
 672                 {\r
 673                         // turn gun to the left to look at it\r
 674                         t = 2;\r
 675                         self.owner.weapon_morph1time   = time + t * 0.2;\r
 676                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';\r
 677                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');\r
 678                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);\r
 679 \r
 680                         self.owner.weapon_morph2time   = time + t * 0.6;\r
 681                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';\r
 682                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');\r
 683                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);\r
 684 \r
 685                         self.owner.weapon_morph3time   = time + t;\r
 686                         self.owner.weapon_morph3angles = '0 0 0';\r
 687                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');\r
 688                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);\r
 689                 }\r
 690                 else if (r < 0.2)\r
 691                 {\r
 692                         // raise the gun a bit\r
 693                         t = 2;\r
 694                         self.owner.weapon_morph1time   = time + t * 0.2;\r
 695                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';\r
 696                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');\r
 697                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);\r
 698 \r
 699                         self.owner.weapon_morph2time   = time + t * 0.5;\r
 700                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';\r
 701                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');\r
 702                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);\r
 703 \r
 704                         self.owner.weapon_morph3time   = time + t;\r
 705                         self.owner.weapon_morph3angles = '0 0 0';\r
 706                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');\r
 707                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);\r
 708                 }\r
 709                 else if (r < 0.3)\r
 710                 {\r
 711                         // tweak it a bit\r
 712                         t = 5;\r
 713                         self.owner.weapon_morph1time   = time + t * 0.3;\r
 714                         self.owner.weapon_morph1angles = randomvec() * 6;\r
 715                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');\r
 716                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);\r
 717 \r
 718                         self.owner.weapon_morph2time   = time + t * 0.7;\r
 719                         self.owner.weapon_morph2angles = randomvec() * 6;\r
 720                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');\r
 721                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);\r
 722 \r
 723                         self.owner.weapon_morph3time   = time + t;\r
 724                         self.owner.weapon_morph3angles = '0 0 0';\r
 725                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');\r
 726                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);\r
 727                 }\r
 728                 else\r
 729                 {\r
 730                         // hold it mostly steady\r
 731                         t = random() * 6 + 4;\r
 732                         self.owner.weapon_morph1time   = time + t * 0.2;\r
 733                         self.owner.weapon_morph1angles = randomvec() * 1;\r
 734                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');\r
 735                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);\r
 736 \r
 737                         self.owner.weapon_morph2time   = time + t * 0.5;\r
 738                         self.owner.weapon_morph2angles = randomvec() * 1;\r
 739                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');\r
 740                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);\r
 741 \r
 742                         self.owner.weapon_morph3time   = time + t * 0.7;\r
 743                         self.owner.weapon_morph3angles = randomvec() * 1;\r
 744                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');\r
 745                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);\r
 746                 }\r
 747 \r
 748                 self.owner.weapon_morph4time   = time + t;\r
 749                 self.owner.weapon_morph4angles = '0 0 0';\r
 750                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');\r
 751                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);\r
 752 \r
 753         }\r
 754 \r
 755         // if we are a micro or macro, size the weapon model accordingly\r
 756         if(cvar("g_healthsize") && cvar("g_healthsize_weapon_scalefactor"))\r
 757         if(self.model != "")\r
 758         {\r
 759                 self.weaponentity.scale = (1 + cvar("g_healthsize_weapon_scalefactor")) - cvar("g_healthsize_weapon_scalefactor") * self.owner.scale;\r
 760                 if(self.weaponentity.scale < 0.1)\r
 761                         self.weaponentity.scale = 0.1; // stuff breaks if scale is smaller than this\r
 762                 self.weaponentity.origin_z = (1 - self.weaponentity.scale) * cvar("g_healthsize_weapon_scalefactor_pos");\r
 763         }\r
 764 };\r
 765 \r
 766 void CL_ExteriorWeaponentity_Think()\r
 767 {\r
 768         float tag_found;\r
 769         vector ang;\r
 770         self.nextthink = time;\r
 771         if (self.owner.exteriorweaponentity != self)\r
 772         {\r
 773                 remove(self);\r
 774                 return;\r
 775         }\r
 776         if (self.owner.deadflag != DEAD_NO)\r
 777         {\r
 778                 self.model = "";\r
 779                 return;\r
 780         }\r
 781         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)\r
 782         if (substring(self.owner.model, -4, 4) != ".md3") // not a stomach model\r
 783         {\r
 784                 self.cnt = self.owner.weapon;\r
 785                 self.dmg = self.owner.modelindex;\r
 786                 self.deadflag = self.owner.deadflag;\r
 787                 if (self.owner.weaponname != "")\r
 788                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below\r
 789                 else\r
 790                         self.model = "";\r
 791 \r
 792                 if((tag_found = gettagindex(self.owner, "tag_weapon")))\r
 793                 {\r
 794                         self.tag_index = tag_found;\r
 795                         self.tag_entity = self.owner;\r
 796                 }\r
 797                 else\r
 798                         setattachment(self, self.owner, "bip01 r hand");\r
 799 \r
 800                 // if that didn't find a tag, hide the exterior weapon model\r
 801                 if (!self.tag_index)\r
 802                         self.model = "";\r
 803         }\r
 804         self.effects = self.owner.effects;\r
 805         if(sv_pitch_min == sv_pitch_max)\r
 806                 self.effects |= EF_LOWPRECISION;\r
 807         else\r
 808                 self.effects &~= EF_LOWPRECISION;\r
 809         self.effects = self.effects & EFMASK_CHEAP; // eat performance\r
 810         if(self.owner.alpha == default_player_alpha)\r
 811                 self.alpha = default_weapon_alpha;\r
 812         else if(self.owner.alpha != 0)\r
 813                 self.alpha = self.owner.alpha;\r
 814         else\r
 815                 self.alpha = 1;\r
 816         self.colormod = self.owner.colormod; // used by the regurgitating colors\r
 817 \r
 818         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);\r
 819         ang_y = 0;\r
 820         ang_z = 0;\r
 821 \r
 822         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward\r
 823         {\r
 824                 ang_y = self.owner.v_angle_y;\r
 825                 makevectors(ang);\r
 826                 var vector v = v_forward;\r
 827                 var float t = self.tag_entity.frame1time;\r
 828                 var float f = self.tag_entity.frame;\r
 829                 self.tag_entity.frame1time = time;\r
 830                 self.tag_entity.frame = self.tag_entity.anim_idle_x;\r
 831                 gettaginfo(self.tag_entity, self.tag_index);\r
 832                 self.tag_entity.frame1time = t;\r
 833                 self.tag_entity.frame = f;\r
 834                 // untransform v according to this coordinate space\r
 835                 vector w;\r
 836                 w_x = v_forward * v;\r
 837                 w_y = -v_right * v;\r
 838                 w_z = v_up * v;\r
 839                 self.angles = vectoangles(w);\r
 840         }\r
 841         else\r
 842         {\r
 843                 ang_x = -/* don't ask */ang_x;\r
 844                 self.angles = ang;\r
 845         }\r
 846 \r
 847         // if we are a micro or macro, size the weapon model accordingly\r
 848         if(self.owner.scale && cvar("g_healthsize_exteriorweapon_scalefactor"))\r
 849         if(self.model != "")\r
 850         {\r
 851                 self.scale = 1 / self.owner.scale; // for some reason, the exterior weapon entity copies the player's scale somewhere else, so undo that first\r
 852                 self.scale = (1 - cvar("g_healthsize_exteriorweapon_scalefactor")) + cvar("g_healthsize_exteriorweapon_scalefactor") * self.scale;\r
 853         }\r
 854 \r
 855         self.colormap = self.owner.colormap;\r
 856         self.glowmod = self.owner.weaponentity_glowmod;\r
 857         self.customizeentityforclient = CL_ExteriorWeaponentity_CustomizeEntityForClient;\r
 858 };\r
 859 \r
 860 // spawning weaponentity for client\r
 861 void CL_SpawnWeaponentity()\r
 862 {\r
 863         self.weaponentity = spawn();\r
 864         self.weaponentity.classname = "weaponentity";\r
 865         self.weaponentity.solid = SOLID_NOT;\r
 866         self.weaponentity.owner = self;\r
 867         setmodel(self.weaponentity, ""); // precision set when changed\r
 868         setorigin(self.weaponentity, '0 0 0');\r
 869         self.weaponentity.angles = '0 0 0';\r
 870         self.weaponentity.viewmodelforclient = self;\r
 871         self.weaponentity.flags = 0;\r
 872         self.weaponentity.think = CL_Weaponentity_Think;\r
 873         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;\r
 874         self.weaponentity.nextthink = time;\r
 875 \r
 876         self.exteriorweaponentity = spawn();\r
 877         self.exteriorweaponentity.classname = "exteriorweaponentity";\r
 878         self.exteriorweaponentity.solid = SOLID_NOT;\r
 879         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;\r
 880         self.exteriorweaponentity.owner = self;\r
 881         setorigin(self.exteriorweaponentity, '0 0 0');\r
 882         self.exteriorweaponentity.angles = '0 0 0';\r
 883         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;\r
 884         self.exteriorweaponentity.nextthink = time;\r
 885 };\r
 886 \r
 887 .float hasweapon_complain_spam;\r
 888 \r
 889 float client_hasweapon(entity cl, float wpn, float andammo, float complain)\r
 890 {\r
 891         local float weaponbit;\r
 892         //local float weaponbit, f;\r
 893         //local entity oldself;\r
 894 \r
 895         if(time < self.hasweapon_complain_spam)\r
 896                 complain = 0;\r
 897         if(complain)\r
 898                 self.hasweapon_complain_spam = time + 0.2;\r
 899 \r
 900         if (wpn < WEP_FIRST || wpn > WEP_LAST)\r
 901         {\r
 902                 if (complain)\r
 903                         sprint(self, "Invalid weapon\n");\r
 904                 return FALSE;\r
 905         }\r
 906         weaponbit = W_WeaponBit(wpn);\r
 907         if (cl.weapons & weaponbit)\r
 908         {\r
 909                 // since we don't have an infinite ammo weapon in vore tournament, allow switching to the grabber even when it has no ammo\r
 910                 /*if (andammo)\r
 911                 {\r
 912                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)\r
 913                         {\r
 914                                 f = 1;\r
 915                         }\r
 916                         else\r
 917                         {\r
 918                                 oldself = self;\r
 919                                 self = cl;\r
 920                                 f = weapon_action(wpn, WR_CHECKAMMO1);\r
 921                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);\r
 922                                 self = oldself;\r
 923                         }\r
 924                         if (!f)\r
 925                         {\r
 926                                 if (complain)\r
 927                                 if(clienttype(cl) == CLIENTTYPE_REAL)\r
 928                                 {\r
 929                                         play2(cl, "misc/unavailable.wav");\r
 930                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));\r
 931                                 }\r
 932                                 return FALSE;\r
 933                         }\r
 934                 }*/\r
 935                 return TRUE;\r
 936         }\r
 937         if (complain)\r
 938         {\r
 939                 // DRESK - 3/16/07\r
 940                 // Report Proper Weapon Status / Modified Weapon Ownership Message\r
 941                 if(weaponsInMap & weaponbit)\r
 942                 {\r
 943                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );\r
 944 \r
 945                         if(cvar("g_showweaponspawns"))\r
 946                         {\r
 947                                 entity e;\r
 948                                 string s;\r
 949 \r
 950                                 e = get_weaponinfo(wpn);\r
 951                                 s = e.model2;\r
 952 \r
 953                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )\r
 954                                 {\r
 955                                         if(e.classname == "droppedweapon")\r
 956                                                 continue;\r
 957                                         if not(e.flags & FL_ITEM)\r
 958                                                 continue;\r
 959                                         WaypointSprite_Spawn(\r
 960                                                 s,\r
 961                                                 1, 0,\r
 962                                                 world, e.origin,\r
 963                                                 self, 0,\r
 964                                                 world, enemy,\r
 965                                                 0\r
 966                                         );\r
 967                                 }\r
 968                         }\r
 969                 }\r
 970                 else\r
 971                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );\r
 972 \r
 973                 play2(cl, "misc/unavailable.wav");\r
 974         }\r
 975         return FALSE;\r
 976 };\r
 977 \r
 978 // Weapon subs\r
 979 void w_clear()\r
 980 {\r
 981         if (self.weapon != -1)\r
 982                 self.weapon = 0;\r
 983         if (self.weaponentity)\r
 984         {\r
 985                 self.weaponentity.state = WS_CLEAR;\r
 986                 self.weaponentity.effects = 0;\r
 987         }\r
 988 };\r
 989 \r
 990 void w_ready()\r
 991 {\r
 992         if (self.weaponentity)\r
 993                 self.weaponentity.state = WS_READY;\r
 994         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);\r
 995 };\r
 996 \r
 997 // Setup weapon for client (after this raise frame will be launched)\r
 998 void weapon_setup(float windex)\r
 999 {\r
1000         entity e;\r
1001         qcweaponanimation = cvar("sv_qcweaponanimation");\r
1002         e = get_weaponinfo(windex);\r
1003         self.items &~= IT_AMMO;\r
1004         self.items = self.items | e.items;\r
1005 \r
1006         // the two weapon entities will notice this has changed and update their models\r
1007         self.weapon = windex;\r
1008         self.weaponname = e.mdl;\r
1009 };\r
1010 \r
1011 // perform weapon to attack (weaponstate and attack_finished check is here)\r
1012 void W_SwitchToOtherWeapon(entity pl)\r
1013 {\r
1014         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)\r
1015         float w, ww;\r
1016         w = W_WeaponBit(pl.weapon);\r
1017         pl.weapons &~= w;\r
1018         ww = w_getbestweapon(pl);\r
1019         pl.weapons |= w;\r
1020         if(ww)\r
1021                 W_SwitchWeapon_Force(pl, ww);\r
1022 }\r
1023 \r
1024 .float prevdryfire;\r
1025 float weapon_prepareattack_checkammo(float secondary)\r
1026 {\r
1027         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
1028         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))\r
1029         {\r
1030                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons\r
1031                 {\r
1032                         sound (self, CHAN_AUTO, "misc/unavailable.wav", VOL_BASE, ATTN_NORM);\r
1033                         self.prevdryfire = time;\r
1034                 }\r
1035 \r
1036                 // since we don't have an infinite ammo weapon in vore tournament, allow switching to the grabber even when it has no ammo\r
1037                 //W_SwitchToOtherWeapon(self);\r
1038                 return FALSE;\r
1039         }\r
1040         return TRUE;\r
1041 }\r
1042 .float race_penalty;\r
1043 float weapon_prepareattack_check(float secondary, float attacktime)\r
1044 {\r
1045         if(!weapon_prepareattack_checkammo(secondary))\r
1046                 return FALSE;\r
1047 \r
1048         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot\r
1049         //if all players readied up and the countdown is running\r
1050         if(time < game_starttime || time < self.race_penalty) {\r
1051                 return FALSE;\r
1052         }\r
1053 \r
1054         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused\r
1055                 return FALSE;\r
1056 \r
1057         // do not even think about shooting if switching\r
1058         if(self.switchweapon != self.weapon)\r
1059                 return FALSE;\r
1060 \r
1061         if(attacktime >= 0)\r
1062         {\r
1063                 // don't fire if previous attack is not finished\r
1064                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)\r
1065                         return FALSE;\r
1066                 // don't fire while changing weapon\r
1067                 if (self.weaponentity.state != WS_READY)\r
1068                         return FALSE;\r
1069         }\r
1070 \r
1071         return TRUE;\r
1072 }\r
1073 float weapon_prepareattack_do(float secondary, float attacktime)\r
1074 {\r
1075         self.weaponentity.state = WS_INUSE;\r
1076 \r
1077         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire\r
1078 \r
1079         // if the weapon hasn't been firing continuously, reset the timer\r
1080         if(attacktime >= 0)\r
1081         {\r
1082                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)\r
1083                 {\r
1084                         ATTACK_FINISHED(self) = time;\r
1085                         //dprint("resetting attack finished to ", ftos(time), "\n");\r
1086                 }\r
1087                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();\r
1088         }\r
1089         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");\r
1090         return TRUE;\r
1091 }\r
1092 float weapon_prepareattack(float secondary, float attacktime)\r
1093 {\r
1094         if(weapon_prepareattack_check(secondary, attacktime))\r
1095         {\r
1096                 weapon_prepareattack_do(secondary, attacktime);\r
1097                 return TRUE;\r
1098         }\r
1099         else\r
1100                 return FALSE;\r
1101 }\r
1102 \r
1103 void weapon_thinkf(float fr, float t, void() func)\r
1104 {\r
1105         vector a;\r
1106         vector of, or, ou;\r
1107         float restartanim;\r
1108 \r
1109         if(fr == WFRAME_DONTCHANGE)\r
1110         {\r
1111                 fr = self.weaponentity.wframe;\r
1112                 restartanim = FALSE;\r
1113         }\r
1114         else if (fr == WFRAME_IDLE)\r
1115                 restartanim = FALSE;\r
1116         else\r
1117                 restartanim = TRUE;\r
1118 \r
1119         of = v_forward;\r
1120         or = v_right;\r
1121         ou = v_up;\r
1122 \r
1123         if (self.weaponentity)\r
1124         {\r
1125                 self.weaponentity.wframe = fr;\r
1126                 if (qcweaponanimation)\r
1127                 {\r
1128                         if (fr != WFRAME_IDLE)\r
1129                         {\r
1130                                 self.weapon_morph0time = time;\r
1131                                 self.weapon_morph0angles = self.weaponentity.angles;\r
1132                                 self.weapon_morph0origin = self.weaponentity.origin;\r
1133 \r
1134                                 self.weapon_morph1angles = '0 0 0';\r
1135                                 self.weapon_morph1time = time + t;\r
1136                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');\r
1137                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1138 \r
1139                                 self.weapon_morph2angles = '0 0 0';\r
1140                                 self.weapon_morph2time = time + t;\r
1141                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');\r
1142                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1143 \r
1144                                 self.weapon_morph3angles = '0 0 0';\r
1145                                 self.weapon_morph3time = time + t;\r
1146                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');\r
1147                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1148 \r
1149                                 self.weapon_morph4angles = '0 0 0';\r
1150                                 self.weapon_morph4time = time + t;\r
1151                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');\r
1152                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1153 \r
1154                                 if (fr == WFRAME_FIRE1)\r
1155                                 {\r
1156                                         self.weapon_morph1angles = '5 0 0';\r
1157                                         self.weapon_morph1time = time + t * 0.1;\r
1158                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');\r
1159                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1160                                         self.weapon_morph4time = time + t + 1; // delay idle effect\r
1161                                 }\r
1162                                 else if (fr == WFRAME_FIRE2)\r
1163                                 {\r
1164                                         self.weapon_morph1angles = '10 0 0';\r
1165                                         self.weapon_morph1time = time + t * 0.1;\r
1166                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');\r
1167                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1168                                         self.weapon_morph4time = time + t + 1; // delay idle effect\r
1169                                 }\r
1170                                 else if (fr == WFRAME_RELOAD)\r
1171                                 {\r
1172                                         self.weapon_morph1time = time + t * 0.05;\r
1173                                         self.weapon_morph1angles = '-10 40 0';\r
1174                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');\r
1175                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1176 \r
1177                                         self.weapon_morph2time = time + t * 0.15;\r
1178                                         self.weapon_morph2angles = '-10 40 5';\r
1179                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');\r
1180                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1181 \r
1182                                         self.weapon_morph3time = time + t * 0.25;\r
1183                                         self.weapon_morph3angles = '-10 40 0';\r
1184                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');\r
1185                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);\r
1186                                 }\r
1187                         }\r
1188                 }\r
1189                 else\r
1190                 {\r
1191                         if (fr == WFRAME_IDLE)\r
1192                                 a = self.weaponentity.anim_idle;\r
1193                         else if (fr == WFRAME_FIRE1)\r
1194                                 a = self.weaponentity.anim_fire1;\r
1195                         else if (fr == WFRAME_FIRE2)\r
1196                                 a = self.weaponentity.anim_fire2;\r
1197                         else if (fr == WFRAME_RELOAD)\r
1198                                 a = self.weaponentity.anim_reload;\r
1199                         a_z *= g_weaponratefactor;\r
1200                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);\r
1201                 }\r
1202         }\r
1203 \r
1204         v_forward = of;\r
1205         v_right = or;\r
1206         v_up = ou;\r
1207 \r
1208         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)\r
1209         {\r
1210                 backtrace("Tried to override initial weapon think function - should this really happen?");\r
1211         }\r
1212 \r
1213         t *= W_WeaponRateFactor();\r
1214 \r
1215         // VorteX: haste can be added here\r
1216         if (self.weapon_think == w_ready)\r
1217         {\r
1218                 self.weapon_nextthink = time;\r
1219                 //dprint("started firing at ", ftos(time), "\n");\r
1220         }\r
1221         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)\r
1222         {\r
1223                 self.weapon_nextthink = time;\r
1224                 //dprint("reset weapon animation timer at ", ftos(time), "\n");\r
1225         }\r
1226         self.weapon_nextthink = self.weapon_nextthink + t;\r
1227         self.weapon_think = func;\r
1228         //dprint("next ", ftos(self.weapon_nextthink), "\n");\r
1229 \r
1230         if (restartanim)\r
1231         if (t)\r
1232         if (!self.crouch) // shoot anim stands up, this looks bad\r
1233         {\r
1234                 local vector anim;\r
1235                 anim = self.anim_shoot;\r
1236                 anim_z = anim_y / (t + sys_frametime);\r
1237                 setanim(self, anim, FALSE, TRUE, TRUE);\r
1238         }\r
1239 };\r
1240 \r
1241 void weapon_boblayer1(float spd, vector org)\r
1242 {\r
1243         // VorteX: haste can be added here\r
1244 };\r
1245 \r
1246 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)\r
1247 {\r
1248         vector mdirection;\r
1249         float mspeed;\r
1250         float outspeed;\r
1251         float nstyle;\r
1252         vector outvelocity;\r
1253 \r
1254         mvelocity = mvelocity * g_weaponspeedfactor;\r
1255 \r
1256         mdirection = normalize(mvelocity);\r
1257         mspeed = vlen(mvelocity);\r
1258 \r
1259         nstyle = cvar("g_projectiles_newton_style");\r
1260         if(nstyle == 0)\r
1261         {\r
1262                 // absolute velocity\r
1263                 outvelocity = mvelocity;\r
1264         }\r
1265         else if(nstyle == 1)\r
1266         {\r
1267                 // true Newtonian projectiles\r
1268                 outvelocity = pvelocity + mvelocity;\r
1269         }\r
1270         else if(nstyle == 2)\r
1271         {\r
1272                 // true Newtonian projectiles with automatic aim adjustment\r
1273                 //\r
1274                 // solve: |outspeed * mdirection - pvelocity| = mspeed\r
1275                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0\r
1276                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)\r
1277                 // PLUS SIGN!\r
1278                 // not defined?\r
1279                 // then...\r
1280                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2\r
1281                 // velocity without mdirection component > mspeed\r
1282                 // fire at smallest possible mspeed that works?\r
1283                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed\r
1284 \r
1285                 vector solution;\r
1286                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);\r
1287                 if(solution_z)\r
1288                         outspeed = solution_y; // the larger one\r
1289                 else\r
1290                 {\r
1291                         //outspeed = 0; // slowest possible shot\r
1292                         outspeed = solution_x; // the real part (that is, the average!)\r
1293                         //dprint("impossible shot, adjusting\n");\r
1294                 }\r
1295 \r
1296                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));\r
1297                 outvelocity = mdirection * outspeed;\r
1298         }\r
1299         else if(nstyle == 3)\r
1300         {\r
1301                 // pseudo-Newtonian:\r
1302                 outspeed = mspeed + mdirection * pvelocity;\r
1303                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);\r
1304                 outvelocity = mdirection * outspeed;\r
1305         }\r
1306         else if(nstyle == 4)\r
1307         {\r
1308                 // tZorkian:\r
1309                 outspeed = mspeed + vlen(pvelocity);\r
1310                 outvelocity = mdirection * outspeed;\r
1311         }\r
1312         else\r
1313                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");\r
1314 \r
1315         return outvelocity;\r
1316 }\r
1317 \r
1318 void W_AttachToShotorg(entity flash, vector offset)\r
1319 {\r
1320         entity xflash;\r
1321         flash.owner = self;\r
1322         flash.angles_z = random() * 360;\r
1323         if(qcweaponanimation)\r
1324         {\r
1325                 setorigin(flash, w_shotorg + w_shotdir * 50);\r
1326                 flash.angles = vectoangles(w_shotdir);\r
1327                 flash.angles_z = random() * 360;\r
1328         }\r
1329         else\r
1330         {\r
1331                 setattachment(flash, self.weaponentity, "shot");\r
1332                 setorigin(flash, offset);\r
1333 \r
1334                 xflash = spawn();\r
1335                 copyentity(flash, xflash);\r
1336 \r
1337                 flash.viewmodelforclient = self;\r
1338 \r
1339                 if(self.weaponentity.oldorigin_x > 0)\r
1340                 {\r
1341                         setattachment(xflash, self.exteriorweaponentity, "");\r
1342                         setorigin(xflash, self.weaponentity.oldorigin + offset);\r
1343                 }\r
1344                 else\r
1345                 {\r
1346                         setattachment(xflash, self.exteriorweaponentity, "shot");\r
1347                 }\r
1348         }\r
1349 }\r
1350 \r
1351 vector cliptoplane(vector v, vector p)\r
1352 {\r
1353         return v - (v * p) * p;\r
1354 }\r
1355 \r
1356 vector solve_cubic_pq(float p, float q)\r
1357 {\r
1358         float D, u, v, a;\r
1359         D = q*q/4.0 + p*p*p/27.0;\r
1360         if(D < 0)\r
1361         {\r
1362                 // irreducibilis\r
1363                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));\r
1364                 u = sqrt(-4.0/3.0 * p);\r
1365                 // a in range 0..pi/3\r
1366                 // cos(a)\r
1367                 // cos(a + 2pi/3)\r
1368                 // cos(a + 4pi/3)\r
1369                 return\r
1370                         u *\r
1371                         (\r
1372                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)\r
1373                                 +\r
1374                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)\r
1375                                 +\r
1376                                 '0 0 1' * cos(a)\r
1377                         );\r
1378         }\r
1379         else if(D == 0)\r
1380         {\r
1381                 // simple\r
1382                 if(p == 0)\r
1383                         return '0 0 0';\r
1384                 u = 3*q/p;\r
1385                 v = -u/2;\r
1386                 if(u >= v)\r
1387                         return '1 1 0' * v + '0 0 1' * u;\r
1388                 else\r
1389                         return '0 1 1' * v + '1 0 0' * u;\r
1390         }\r
1391         else\r
1392         {\r
1393                 // cardano\r
1394                 u = cbrt(-q/2.0 + sqrt(D));\r
1395                 v = cbrt(-q/2.0 - sqrt(D));\r
1396                 return '1 1 1' * (u + v);\r
1397         }\r
1398 }\r
1399 vector solve_cubic_abcd(float a, float b, float c, float d)\r
1400 {\r
1401         // y = 3*a*x + b\r
1402         // x = (y - b) / 3a\r
1403         float p, q;\r
1404         vector v;\r
1405         p = (9*a*c - 3*b*b);\r
1406         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);\r
1407         v = solve_cubic_pq(p, q);\r
1408         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));\r
1409         if(a < 0)\r
1410                 v += '1 0 -1' * (v_z - v_x); // swap x, z\r
1411         return v;\r
1412 }\r
1413 \r
1414 vector findperpendicular(vector v)\r
1415 {\r
1416         vector p;\r
1417         p_x = v_z;\r
1418         p_y = -v_x;\r
1419         p_z = v_y;\r
1420         return normalize(cliptoplane(p, v));\r
1421 }\r
1422 \r
1423 vector W_CalculateProjectileSpread(vector forward, float spread)\r
1424 {\r
1425         float sigma;\r
1426         vector v1, v2;\r
1427         float dx, dy, r;\r
1428         float sstyle;\r
1429         spread *= g_weaponspreadfactor;\r
1430         if(spread <= 0)\r
1431                 return forward;\r
1432         sstyle = cvar("g_projectiles_spread_style");\r
1433         \r
1434         if(sstyle == 0)\r
1435         {\r
1436                 // this is the baseline for the spread value!\r
1437                 // standard deviation: sqrt(2/5)\r
1438                 // density function: sqrt(1-r^2)\r
1439                 return forward + randomvec() * spread;\r
1440         }\r
1441         else if(sstyle == 1)\r
1442         {\r
1443                 // same thing, basically\r
1444                 return normalize(forward + cliptoplane(randomvec() * spread, forward));\r
1445         }\r
1446         else if(sstyle == 2)\r
1447         {\r
1448                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)\r
1449                 sigma = spread * 0.89442719099991587855; // match baseline stddev\r
1450                 v1 = findperpendicular(forward);\r
1451                 v2 = cross(forward, v1);\r
1452                 // random point on unit circle\r
1453                 dx = random() * 2 * M_PI;\r
1454                 dy = sin(dx);\r
1455                 dx = cos(dx);\r
1456                 // radius in our dist function\r
1457                 r = random();\r
1458                 r = sqrt(r);\r
1459                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);\r
1460         }\r
1461         else if(sstyle == 3) // gauss 3d\r
1462         {\r
1463                 sigma = spread * 0.44721359549996; // match baseline stddev\r
1464                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right\r
1465                 v1 = forward;\r
1466                 v1_x += gsl_ran_gaussian(sigma);\r
1467                 v1_y += gsl_ran_gaussian(sigma);\r
1468                 v1_z += gsl_ran_gaussian(sigma);\r
1469                 return v1;\r
1470         }\r
1471         else if(sstyle == 4) // gauss 2d\r
1472         {\r
1473                 sigma = spread * 0.44721359549996; // match baseline stddev\r
1474                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right\r
1475                 v1_x = gsl_ran_gaussian(sigma);\r
1476                 v1_y = gsl_ran_gaussian(sigma);\r
1477                 v1_z = gsl_ran_gaussian(sigma);\r
1478                 return normalize(forward + cliptoplane(v1, forward));\r
1479         }\r
1480         else if(sstyle == 5) // 1-r\r
1481         {\r
1482                 sigma = spread * 1.154700538379252; // match baseline stddev\r
1483                 v1 = findperpendicular(forward);\r
1484                 v2 = cross(forward, v1);\r
1485                 // random point on unit circle\r
1486                 dx = random() * 2 * M_PI;\r
1487                 dy = sin(dx);\r
1488                 dx = cos(dx);\r
1489                 // radius in our dist function\r
1490                 r = random();\r
1491                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';\r
1492                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);\r
1493         }\r
1494         else if(sstyle == 6) // 1-r^2\r
1495         {\r
1496                 sigma = spread * 1.095445115010332; // match baseline stddev\r
1497                 v1 = findperpendicular(forward);\r
1498                 v2 = cross(forward, v1);\r
1499                 // random point on unit circle\r
1500                 dx = random() * 2 * M_PI;\r
1501                 dy = sin(dx);\r
1502                 dx = cos(dx);\r
1503                 // radius in our dist function\r
1504                 r = random();\r
1505                 r = sqrt(1 - r);\r
1506                 r = sqrt(1 - r);\r
1507                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);\r
1508         }\r
1509         else if(sstyle == 7) // (1-r) (2-r)\r
1510         {\r
1511                 sigma = spread * 1.224744871391589; // match baseline stddev\r
1512                 v1 = findperpendicular(forward);\r
1513                 v2 = cross(forward, v1);\r
1514                 // random point on unit circle\r
1515                 dx = random() * 2 * M_PI;\r
1516                 dy = sin(dx);\r
1517                 dx = cos(dx);\r
1518                 // radius in our dist function\r
1519                 r = random();\r
1520                 r = 1 - sqrt(r);\r
1521                 r = 1 - sqrt(r);\r
1522                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);\r
1523         }\r
1524         else\r
1525                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");\r
1526         return '0 0 0';\r
1527         /*\r
1528          * how to derive falloff functions:\r
1529          * rho(r) := (2-r) * (1-r);\r
1530          * a : 0;\r
1531          * b : 1;\r
1532          * rhor(r) := r * rho(r);\r
1533          * cr(t) := integrate(rhor(r), r, a, t);\r
1534          * scr(t) := integrate(rhor(r) * r^2, r, a, t);\r
1535          * variance : scr(b) / cr(b);\r
1536          * solve(cr(r) = rand * cr(b), r), programmmode:false;\r
1537          * sqrt(0.4 / variance), numer;\r
1538          */\r
1539 }\r
1540 \r
1541 #if 0\r
1542 float mspercallsum;\r
1543 float mspercallsstyle;\r
1544 float mspercallcount;\r
1545 #endif\r
1546 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)\r
1547 {\r
1548         if(missile.owner == world)\r
1549                 error("Unowned missile");\r
1550 \r
1551         dir = dir + upDir * (pUpSpeed / pSpeed);\r
1552         dir_z += pZSpeed / pSpeed;\r
1553         pSpeed *= vlen(dir);\r
1554         dir = normalize(dir);\r
1555 \r
1556 #if 0\r
1557         if(cvar("g_projectiles_spread_style") != mspercallsstyle)\r
1558         {\r
1559                 mspercallsum = mspercallcount = 0;\r
1560                 mspercallsstyle = cvar("g_projectiles_spread_style");\r
1561         }\r
1562         mspercallsum -= gettime(GETTIME_HIRES);\r
1563 #endif\r
1564         dir = W_CalculateProjectileSpread(dir, spread);\r
1565 #if 0\r
1566         mspercallsum += gettime(GETTIME_HIRES);\r
1567         mspercallcount += 1;\r
1568         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");\r
1569 #endif\r
1570 \r
1571         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);\r
1572 }\r
1573 \r
1574 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)\r
1575 {\r
1576         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);\r
1577 }\r
1578 \r
1579 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))\r
1580 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))\r
1581 \r
1582 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)\r
1583 {\r
1584         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)\r
1585                 return;\r
1586 \r
1587         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo\r
1588         if(ammo_reload)\r
1589         {\r
1590                 self.clip_load -= ammo_use;\r
1591                 self.(weapon_load[self.weapon]) = self.clip_load;\r
1592         }\r
1593         else\r
1594                 self.(self.current_ammo) -= ammo_use;\r
1595 }\r
1596 \r
1597 // weapon reloading code\r
1598 \r
1599 .float reload_ammo_amount, reload_ammo_min, reload_time;\r
1600 .float reload_complain;\r
1601 .string reload_sound;\r
1602 \r
1603 void W_ReloadedAndReady()\r
1604 {\r
1605         // if we are inside the stomach, don't allow reloading, and schedule the weapon to reload once when we're out\r
1606         if(self.stat_eaten)\r
1607         {\r
1608                 self.clip_load = self.(weapon_load[self.weapon]) = -1;\r
1609                 w_ready(); // don't keep executing each frame\r
1610                 return;\r
1611         }\r
1612 \r
1613         // finish the reloading process, and do the ammo transfer\r
1614 \r
1615         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading\r
1616 \r
1617         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load\r
1618         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)\r
1619                 self.clip_load = self.reload_ammo_amount;\r
1620         else\r
1621         {\r
1622                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo) >= 1) // make sure we don't add more ammo than we have\r
1623                 {\r
1624                         self.clip_load += 1;\r
1625                         self.(self.current_ammo) -= 1;\r
1626                 }\r
1627         }\r
1628         self.(weapon_load[self.weapon]) = self.clip_load;\r
1629 \r
1630         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,\r
1631         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,\r
1632         // so your weapon is disabled for a few seconds without reason\r
1633 \r
1634         //ATTACK_FINISHED(self) -= self.reload_time - 1;\r
1635 \r
1636         w_ready();\r
1637 }\r
1638 \r
1639 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)\r
1640 {\r
1641         // if we are inside the stomach, don't allow reloading\r
1642         if(self.stat_eaten)\r
1643                 return;\r
1644 \r
1645         // set global values to work with\r
1646         self.reload_ammo_min = sent_ammo_min;\r
1647         self.reload_ammo_amount = sent_ammo_amount;\r
1648         self.reload_time = sent_time;\r
1649         self.reload_sound = sent_sound;\r
1650 \r
1651         // check if we meet the necessary conditions to reload\r
1652 \r
1653         entity e;\r
1654         e = get_weaponinfo(self.weapon);\r
1655 \r
1656         // don't reload weapons that don't have the RELOADABLE flag\r
1657         if not(e.spawnflags & WEP_FLAG_RELOADABLE)\r
1658         {\r
1659                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");\r
1660                 return;\r
1661         }\r
1662         // return if reloading is disabled for this weapon\r
1663         if(!self.reload_ammo_amount)\r
1664                 return;\r
1665         // our weapon is fully loaded, no need to reload\r
1666         if (self.clip_load >= self.reload_ammo_amount)\r
1667                 return;\r
1668         // no ammo, so nothing to load\r
1669         if(self.(self.current_ammo) < 1 && self.reload_ammo_min)\r
1670         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
1671         {\r
1672                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)\r
1673                 {\r
1674                         play2(self, "misc/unavailable.wav");\r
1675                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));\r
1676                         self.reload_complain = time + 1;\r
1677                 }\r
1678                 // switch away if the amount of ammo is not enough to keep using this weapon\r
1679                 // disabled since we only have one weapon in VT, so nothing else to switch to if we're out of ammo\r
1680                 /*if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))\r
1681                 {\r
1682                         self.clip_load = -1; // reload later\r
1683                         W_SwitchToOtherWeapon(self);\r
1684                 }*/\r
1685                 return;\r
1686         }\r
1687 \r
1688         if (self.weaponentity)\r
1689         {\r
1690                 if (self.weaponentity.wframe == WFRAME_RELOAD)\r
1691                         return;\r
1692 \r
1693                 // allow switching away while reloading, but this will cause a new reload!\r
1694                 self.weaponentity.state = WS_READY;\r
1695         }\r
1696 \r
1697         // now begin the reloading process\r
1698 \r
1699         // weapon reload effects\r
1700         if(self.weapon == WEP_GRABBER && self.clip_load >= 0) // only when we first begin reloading\r
1701         {\r
1702                 vector org;\r
1703                 org = self.origin + self.view_ofs + self.weaponentity.spawnorigin_x * v_forward - self.weaponentity.spawnorigin_y * v_right + self.weaponentity.spawnorigin_z * v_up;\r
1704                 SpawnCasing (org, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);\r
1705                 pointparticles(particleeffectnum("grabber_reload"), org, '0 0 0', 1);\r
1706         }\r
1707         sound (self, CHAN_WEAPON2, self.reload_sound, VOL_BASE, ATTN_NORM);\r
1708 \r
1709         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,\r
1710         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,\r
1711         // so your weapon is disabled for a few seconds without reason\r
1712 \r
1713         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;\r
1714 \r
1715         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);\r
1716 \r
1717         if(self.clip_load < 0)\r
1718                 self.clip_load = 0;\r
1719         self.old_clip_load = self.clip_load;\r
1720         self.clip_load = self.(weapon_load[self.weapon]) = -1;\r
1721 }