data/qcsrc/server/g_grabber.qc

   1 /*============================================\r
   2 \r
   3       Wazat's Voretournament Grabber\r
   4 \r
   5         Contact: Wazat1@gmail.com\r
   6 \r
   7 \r
   8 Installation instructions:\r
   9 --------------------------\r
  10 \r
  11 1. Place grabber.c in your gamec source directory with the other source files.\r
  12 \r
  13 2. Add this line to the bottom of progs.src:\r
  14 \r
  15 gamec/grabber.c\r
  16 \r
  17 3. Open defs.h and add these lines to the very bottom:\r
  18 \r
  19 // Wazat's grabber\r
  20 .entity         grabber;\r
  21 voidGrabberFrame();\r
  22 void RemoveGrabber(entity pl);\r
  23 void SetGrabberBindings();\r
  24 // grabber impulses\r
  25 float GRABBER_FIRE              = 20;\r
  26 float GRABBER_RELEASE           = 21;\r
  27 // (note: you can change the grabber impulse #'s to whatever you please)\r
  28 \r
  29 4. Open client.c and add this to the top of PutClientInServer():\r
  30 \r
  31         RemoveGrabber(self); // Wazat's Grabber\r
  32 \r
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:\r
  34 \r
  35         // Wazat's grabber\r
  36         SetGrabberBindings();\r
  37 \r
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:\r
  39 \r
  40         GrabberFrame();\r
  41 \r
  42 7. Build and test the mod.  You'll want to bind a key to "+grabber" like this:\r
  43 bind ctrl "+grabber"\r
  44 \r
  45 And you should be done!\r
  46 \r
  47 \r
  48 ============================================*/\r
  49 \r
  50 .string aiment_classname;\r
  51 .float aiment_deadflag;\r
  52 void SetMovetypeFollow(entity ent, entity e)\r
  53 {\r
  54         // FIXME this may not be warpzone aware\r
  55         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow\r
  56         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.\r
  57         ent.aiment = e; // make the hole follow bmodel\r
  58         ent.punchangle = e.angles; // the original angles of bmodel\r
  59         ent.view_ofs = ent.origin - e.origin; // relative origin\r
  60         ent.v_angle = ent.angles - e.angles; // relative angles\r
  61         ent.aiment_classname = strzone(e.classname);\r
  62         ent.aiment_deadflag = e.deadflag;\r
  63 }\r
  64 void UnsetMovetypeFollow(entity ent)\r
  65 {\r
  66         ent.movetype = MOVETYPE_FLY;\r
  67         PROJECTILE_MAKETRIGGER(ent);\r
  68         ent.aiment = world;\r
  69 }\r
  70 float LostMovetypeFollow(entity ent)\r
  71 {\r
  72 /*\r
  73         if(ent.movetype != MOVETYPE_FOLLOW)\r
  74                 if(ent.aiment)\r
  75                         error("???");\r
  76 */\r
  77         if(ent.aiment)\r
  78         {\r
  79                 if(ent.aiment.classname != ent.aiment_classname)\r
  80                         return 1;\r
  81                 if(ent.aiment.deadflag != ent.aiment_deadflag)\r
  82                         return 1;\r
  83         }\r
  84         return 0;\r
  85 }\r
  86 \r
  87 .float grabber_length;\r
  88 .float grabber_sendbeam;\r
  89 \r
  90 void RemoveGrabber(entity pl)\r
  91 {\r
  92         if(pl.grabber == world)\r
  93                 return;\r
  94         remove(pl.grabber);\r
  95         pl.grabber = world;\r
  96         if(pl.movetype == MOVETYPE_FLY)\r
  97                 pl.movetype = MOVETYPE_WALK;\r
  98 \r
  99         //pl.disableclientprediction = FALSE;\r
 100 }\r
 101 \r
 102 void GrabberThink();\r
 103 void Grabber_Stop()\r
 104 {\r
 105         pointparticles(particleeffectnum("grabber_impact"), self.origin, '0 0 0', 1);\r
 106         if(other.classname == "player")\r
 107                 sound (self, CHAN_PROJECTILE, "weapons/grabber_impact_player.wav", VOL_BASE, ATTN_NORM);\r
 108         else\r
 109         {\r
 110                 sound (self, CHAN_PROJECTILE, "weapons/grabber_impact_world.wav", VOL_BASE, ATTN_NORM);\r
 111                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)\r
 112                         pointparticles(particleeffectnum("ground_metal"), trace_endpos, '0 0 0', 1);\r
 113                 else\r
 114                         pointparticles(particleeffectnum("ground_dirt"), trace_endpos, '0 0 0', 1);\r
 115         }\r
 116 \r
 117         self.state = 1;\r
 118         self.think = GrabberThink;\r
 119         self.nextthink = time;\r
 120         self.touch = SUB_Null;\r
 121         self.velocity = '0 0 0';\r
 122         self.movetype = MOVETYPE_NONE;\r
 123         self.grabber_length = -1;\r
 124 }\r
 125 \r
 126 void GrabberThink()\r
 127 {\r
 128         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;\r
 129         vector dir, org, end, v0, dv, v, myorg;\r
 130         if(self.owner.health <= 0 || self.owner.grabber != self)        // how did that happen?\r
 131         {                                                                                                               // well, better fix it anyway\r
 132                 remove(self);\r
 133                 return;\r
 134         }\r
 135         if(LostMovetypeFollow(self))\r
 136         {\r
 137                 RemoveGrabber(self.owner);\r
 138                 return;\r
 139         }\r
 140         if(self.aiment)\r
 141                 WarpZone_RefSys_AddIncrementally(self, self.aiment);\r
 142 \r
 143         // prevent the grabber from sticking to a player that has been swallowed\r
 144         if(self.aiment.stat_eaten)\r
 145         {\r
 146                 // if the grabber is linked to a player that we swallowed, disconnect it (or the grabber will stick to us / the player inside us)\r
 147                 // otherwise, link the grabber to the player who ate our linked player\r
 148                 if(self.aiment.predator != self.owner)\r
 149                         SetMovetypeFollow(self, self.aiment.predator);\r
 150                 else\r
 151                         RemoveGrabber(self.owner);\r
 152         }\r
 153 \r
 154         self.nextthink = time;\r
 155 \r
 156         makevectors(self.owner.v_angle);\r
 157         org = self.owner.origin + self.owner.view_ofs + v_forward * grabber_shotorigin_x + v_right * grabber_shotorigin_y + v_up * grabber_shotorigin_z;\r
 158         myorg = WarpZone_RefSys_TransformOrigin(self.owner, self, org);\r
 159 \r
 160         if(self.grabber_length < 0)\r
 161                 self.grabber_length = vlen(myorg - self.origin);\r
 162 \r
 163         if(self.state == 1)\r
 164         {\r
 165                 pullspeed = cvar("g_balance_grabber_speed_pull");//2000;\r
 166                 // speed the rope is pulled with\r
 167 \r
 168                 rubberforce = cvar("g_balance_grabber_force_rubber");//2000;\r
 169                 // force the rope will use if it is stretched\r
 170 \r
 171                 rubberforce_overstretch = cvar("g_balance_grabber_force_rubber_overstretch");//1000;\r
 172                 // force the rope will use if it is stretched\r
 173 \r
 174                 minlength = cvar("g_balance_grabber_length_min");//100;\r
 175                 // minimal rope length\r
 176                 // if the rope goes below this length, it isn't pulled any more\r
 177 \r
 178                 ropestretch = cvar("g_balance_grabber_stretch");//400;\r
 179                 // if the rope is stretched by more than this amount, more rope is\r
 180                 // given to you again\r
 181 \r
 182                 ropeairfriction = cvar("g_balance_grabber_airfriction");//0.2\r
 183                 // while hanging on the rope, this friction component will help you a\r
 184                 // bit to control the rope\r
 185 \r
 186                 dir = self.origin - myorg;\r
 187                 dist = vlen(dir);\r
 188                 dir = normalize(dir);\r
 189 \r
 190                 if(cvar("g_grabber_tarzan"))\r
 191                 {\r
 192                         v = v0 = WarpZone_RefSys_TransformVelocity(self.owner, self, self.owner.velocity);\r
 193 \r
 194                         // first pull the rope...\r
 195                         if(self.owner.grabber_state & GRABBER_PULLING)\r
 196                         {\r
 197                                 newlength = self.grabber_length;\r
 198                                 newlength = max(newlength - pullspeed * frametime, minlength);\r
 199 \r
 200                                 if(newlength < dist - ropestretch) // overstretched?\r
 201                                 {\r
 202                                         newlength = dist - ropestretch;\r
 203                                         if(v * dir < 0) // only if not already moving in grabber direction\r
 204                                                 v = v + frametime * dir * rubberforce_overstretch;\r
 205                                 }\r
 206 \r
 207                                 self.grabber_length = newlength;\r
 208                         }\r
 209 \r
 210                         if(self.owner.grabber_state & GRABBER_RELEASING)\r
 211                         {\r
 212                                 newlength = dist;\r
 213                                 self.grabber_length = newlength;\r
 214                         }\r
 215                         else\r
 216                         {\r
 217                                 // then pull the player\r
 218                                 spd = bound(0, (dist - self.grabber_length) / ropestretch, 1);\r
 219                                 v = v * (1 - frametime * ropeairfriction);\r
 220                                 v = v + frametime * dir * spd * rubberforce;\r
 221 \r
 222                                 dv = ((v - v0) * dir) * dir;\r
 223                                 if(cvar("g_grabber_tarzan") >= 2)\r
 224                                 {\r
 225                                         if(self.aiment.movetype == MOVETYPE_WALK)\r
 226                                         {\r
 227                                                 v = v - dv * 0.5;\r
 228                                                 self.aiment.velocity = self.aiment.velocity - dv * 0.5;\r
 229                                                 self.aiment.flags &~= FL_ONGROUND;\r
 230                                                 self.aiment.pusher = self.owner;\r
 231                                                 self.aiment.pushltime = time + cvar("g_maxpushtime");\r
 232                                         }\r
 233                                 }\r
 234 \r
 235                                 self.owner.flags &~= FL_ONGROUND;\r
 236                         }\r
 237 \r
 238                         self.owner.velocity = WarpZone_RefSys_TransformVelocity(self, self.owner, v);\r
 239                 }\r
 240                 else\r
 241                 {\r
 242                         end = self.origin - dir*50;\r
 243                         dist = vlen(end - myorg);\r
 244                         if(dist < 200)\r
 245                                 spd = dist * (pullspeed / 200);\r
 246                         else\r
 247                                 spd = pullspeed;\r
 248                         if(spd < 50)\r
 249                                 spd = 0;\r
 250                         self.owner.velocity = dir*spd;\r
 251                         self.owner.movetype = MOVETYPE_FLY;\r
 252 \r
 253                         self.owner.flags &~= FL_ONGROUND;\r
 254                 }\r
 255         }\r
 256 \r
 257         if(self.grabber_sendbeam < time) // don't kill the bandwidth by sending this each frame\r
 258         {\r
 259                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');\r
 260                 te_beam(self.owner, WarpZone_RefSys_TransformOrigin(self, self.owner, self.origin) + v_forward * (-9), org);\r
 261                 self.grabber_sendbeam = time + cvar("sys_ticrate");\r
 262         }\r
 263 }\r
 264 \r
 265 void GrabberTouch (void)\r
 266 {\r
 267         if(SUB_OwnerCheck())\r
 268                 return;\r
 269         if(SUB_NoImpactCheck())\r
 270         {\r
 271                 RemoveGrabber(self.owner);\r
 272                 return;\r
 273         }\r
 274         PROJECTILE_TOUCH;\r
 275 \r
 276         Grabber_Stop();\r
 277 \r
 278         if(other)\r
 279                 if(other.movetype != MOVETYPE_NONE)\r
 280                 {\r
 281                         if(other.classname == "player")\r
 282                         {\r
 283                                 if(other.BUTTON_CHAT)\r
 284                                         self.owner.typehitsound += 1;\r
 285                                 else\r
 286                                         self.owner.hitsound += 1; // play this for team mates too, as we could be grabbing them to heal them\r
 287                                 W_Grabber_UpdateStats(self.owner, FALSE, TRUE); // count this as a hit\r
 288                         }\r
 289 \r
 290                         SetMovetypeFollow(self, other);\r
 291                         WarpZone_RefSys_BeginAddingIncrementally(self, self.aiment);\r
 292                 }\r
 293 \r
 294         //self.owner.disableclientprediction = TRUE;\r
 295 }\r
 296 \r
 297 void Grabber_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)\r
 298 {\r
 299         if(self.health > 0)\r
 300         {\r
 301                 self.health = self.health - damage;\r
 302                 if (self.health <= 0)\r
 303                 {\r
 304                         if(attacker != self.owner)\r
 305                         {\r
 306                                 self.owner.pusher = attacker;\r
 307                                 self.owner.pushltime = time + cvar("g_maxpushtime");\r
 308                         }\r
 309                         RemoveGrabber(self.owner);\r
 310                 }\r
 311         }\r
 312 }\r
 313 \r
 314 void FireGrabber (void)\r
 315 {\r
 316         local entity missile;\r
 317         local vector org;\r
 318 \r
 319         W_Grabber_UpdateStats(self, TRUE, FALSE);\r
 320 \r
 321         if((arena_roundbased && time < warmup) || (time < game_starttime))\r
 322                 return;\r
 323 \r
 324         makevectors(self.v_angle);\r
 325 \r
 326         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds\r
 327         sound (self, CHAN_WEAPON2, "weapons/grabber_fire.wav", VOL_BASE, ATTN_NORM);\r
 328         org = self.origin + self.view_ofs + v_forward * grabber_shotorigin_x + v_right * grabber_shotorigin_y + v_up * grabber_shotorigin_z;\r
 329         pointparticles(particleeffectnum("grabber_muzzleflash"), org, '0 0 0', 1);\r
 330 \r
 331         missile = WarpZone_RefSys_SpawnSameRefSys(self);\r
 332         missile.owner = self;\r
 333         self.grabber = missile;\r
 334         missile.classname = "grabber";\r
 335 \r
 336         missile.movetype = MOVETYPE_FLY;\r
 337         PROJECTILE_MAKETRIGGER(missile);\r
 338 \r
 339         setmodel (missile, "models/grabber.md3"); // precision set below\r
 340         setsize (missile, '-3 -3 -3', '3 3 3');\r
 341         setorigin (missile, org);\r
 342 \r
 343         missile.state = 0; // not latched onto anything\r
 344 \r
 345         W_SetupProjectileVelocityEx(missile, v_forward, v_up, cvar("g_balance_grabber_speed_fly"), 0, 0, 0);\r
 346 \r
 347         missile.angles = vectoangles (missile.velocity);\r
 348         //missile.glow_color = 250; // 244, 250\r
 349         //missile.glow_size = 120;\r
 350         missile.touch =GrabberTouch;\r
 351         missile.think =GrabberThink;\r
 352         missile.nextthink = time + 0.1;\r
 353 \r
 354         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;\r
 355 \r
 356         missile.health = cvar("g_balance_grabber_health");//120\r
 357         missile.event_damage =Grabber_Damage;\r
 358         missile.takedamage = DAMAGE_AIM;\r
 359         missile.damageforcescale = 0;\r
 360 }\r
 361 \r
 362 void GrabberFrame()\r
 363 {\r
 364         if(timeoutStatus != 2 && self.weapon != WEP_GRABBER)\r
 365         {\r
 366                 self.grabber_state |= GRABBER_REMOVING;\r
 367                 self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
 368 \r
 369                 self.grabber_state &~= GRABBER_RELEASING;\r
 370                 self.grabber_state |= GRABBER_PULLING;\r
 371         }\r
 372 \r
 373         if(self.weapon != WEP_GRABBER)\r
 374         {\r
 375                 self.grabber_state &~= GRABBER_FIRING;\r
 376                 self.grabber_state |= GRABBER_REMOVING;\r
 377         }\r
 378 \r
 379         if (self.grabber_state & GRABBER_FIRING)\r
 380         {\r
 381                 if (self.grabber)\r
 382                         RemoveGrabber(self);\r
 383                 FireGrabber();\r
 384                 self.grabber_state &~= GRABBER_FIRING;\r
 385         }\r
 386         else if(self.grabber_state & GRABBER_REMOVING)\r
 387         {\r
 388                 if (self.grabber)\r
 389                         RemoveGrabber(self);\r
 390                 self.grabber_state &~= GRABBER_REMOVING;\r
 391         }\r
 392 \r
 393         /*\r
 394         // if I have no grabber or it's not pulling yet, make sure I'm not flying!\r
 395         if((self.grabber == world || !self.grabber.state) && self.movetype == MOVETYPE_FLY)\r
 396         {\r
 397                 self.movetype = MOVETYPE_WALK;\r
 398         }\r
 399         if(self.impulse == GRABBER_FIRE && self.grabber_time <= time)\r
 400         {\r
 401                 // fire grabber\r
 402                 FireGrabber();\r
 403                 return;\r
 404         }\r
 405         else if(self.grabberimpulse == GRABBER_RELEASE)\r
 406         {\r
 407                 // remove grabber, reset movement type\r
 408                 RemoveGrabber(self);\r
 409                 return;\r
 410         }\r
 411         */\r
 412         /*else // make sure the player's movetype is correct\r
 413         {\r
 414                 //if(self.grabber == world && self.movetype == MOVETYPE_FLY)\r
 415                 if((self.grabber == world || !self.grabber.state) && self.movetype == MOVETYPE_FLY)\r
 416                 {\r
 417                         self.movetype = MOVETYPE_WALK;\r
 418                 }\r
 419         }*/\r
 420         // note: The grabber entity does the actual pulling\r
 421 }\r
 422 \r
 423 void GrabberInit()\r
 424 {\r
 425         grabber_shotorigin = shotorg_adjust('26.2148 9.2059 -15.9772', TRUE, FALSE);\r
 426 }\r
 427 \r
 428 void SetGrabberBindings()\r
 429 {\r
 430         // this function has been modified for Voretournament\r
 431         // don't remove these lines! old server or demos coud overwrite the new aliases\r
 432         stuffcmd(self, "alias +grabber +button6\n");\r
 433         stuffcmd(self, "alias -grabber -button6\n");\r
 434 }\r