data/qcsrc/server/sv_main.qc

   1 \r
   2 void CreatureFrame (void)\r
   3 {\r
   4         local entity oldself;\r
   5         local float dm;\r
   6         oldself = self;\r
   7         self = findfloat(world, iscreature, TRUE);\r
   8         while (self)\r
   9         {\r
  10                 if (self.movetype != MOVETYPE_NOCLIP)\r
  11                 {\r
  12                         if (self.waterlevel)\r
  13                         {\r
  14                                 if (!(self.flags & FL_INWATER))\r
  15                                 {\r
  16                                         self.flags |= FL_INWATER;\r
  17                                         self.dmgtime = 0;\r
  18                                 }\r
  19                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)\r
  20                                 {\r
  21                                         if(self.air_finished < time + 9)\r
  22                                                 PlayerSound(self, playersound_gasp, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
  23                                         self.air_finished = time + 12;\r
  24                                         self.dmg = 2;\r
  25                                 }\r
  26                                 else if (self.air_finished < time)\r
  27                                 {       // drown!\r
  28                                         if (!self.deadflag)\r
  29                                         if (self.pain_finished < time)\r
  30                                         {\r
  31                                                 Damage (self, world, world, 5, DEATH_DROWN, self.origin, '0 0 0');\r
  32                                                 self.pain_finished = time + 0.5;\r
  33                                         }\r
  34                                 }\r
  35                                 if (self.dmgtime < time)\r
  36                                 {\r
  37                                         self.dmgtime = time + 0.1;\r
  38                                         if (self.watertype == CONTENT_LAVA)\r
  39                                         {\r
  40                                                 if (self.watersound_finished < time)\r
  41                                                 {\r
  42                                                         self.watersound_finished = time + 0.5;\r
  43                                                         sound (self, CHAN_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);\r
  44                                                 }\r
  45                                                 Damage (self, world, world, 6 * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');\r
  46                                         }\r
  47                                         else if (self.watertype == CONTENT_SLIME)\r
  48                                         {\r
  49                                                 if (self.watersound_finished < time)\r
  50                                                 {\r
  51                                                         self.watersound_finished = time + 0.5;\r
  52                                                         sound (self, CHAN_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);\r
  53                                                 }\r
  54                                                 Damage (self, world, world, 2 * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');\r
  55                                         }\r
  56                                 }\r
  57                         }\r
  58                         else\r
  59                         {\r
  60                                 if (self.flags & FL_INWATER)\r
  61                                 {\r
  62                                         // play leave water sound\r
  63                                         self.flags &~= FL_INWATER;\r
  64                                         self.dmgtime = 0;\r
  65                                 }\r
  66                                 self.air_finished = time + 12;\r
  67                                 self.dmg = 2;\r
  68                         }\r
  69                         // check for falling damage\r
  70                         if(!(g_cts && !cvar("g_cts_selfdamage")))\r
  71                         {\r
  72                                 dm = vlen(self.oldvelocity) - vlen(self.velocity); // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.\r
  73                                 if (self.deadflag)\r
  74                                         dm = (dm - cvar("g_balance_falldamage_deadminspeed")) * cvar("g_balance_falldamage_factor");\r
  75                                 else\r
  76                                         dm = min((dm - cvar("g_balance_falldamage_minspeed")) * cvar("g_balance_falldamage_factor"), cvar("g_balance_falldamage_maxdamage"));\r
  77                                 if(cvar("g_healthsize")) // if we are smaller or larger, we take more or less falling damage\r
  78                                         dm *= (1 + cvar("g_healthsize_movementfactor")) - cvar("g_healthsize_movementfactor") * self.scale; \r
  79                                 if (dm > 0)\r
  80                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');\r
  81                                 else if(vlen(self.velocity) > 100000 && cvar("developer"))\r
  82                                 {\r
  83                                         dprint(strcat(self.netname, " became too fast, please investigate: ", vtos(self.spawnorigin), "\n"));\r
  84                                         Damage (self, world, world, 50000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');\r
  85                                 }\r
  86                         }\r
  87 \r
  88                         // play stupid sounds\r
  89                         if (g_footsteps)\r
  90                         if (!gameover)\r
  91                         if (self.flags & FL_ONGROUND)\r
  92                         if (vlen(self.velocity) > sv_maxspeed * 0.6)\r
  93                         if (!self.deadflag)\r
  94                         if (time < self.lastground + 0.2)\r
  95                         {\r
  96                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))\r
  97                                 {\r
  98                                         self.nextstep = time + 0.3 + random() * 0.1;\r
  99                                         trace_dphitq3surfaceflags = 0;\r
 100                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);\r
 101                                         /*\r
 102                                         if(trace_fraction == 1)\r
 103                                                 dprint("nohit\n");\r
 104                                         else\r
 105                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");\r
 106                                         */\r
 107                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)\r
 108                                         {\r
 109                                                 // if healthsize is enabled, play effects based on player size\r
 110                                                 if(cvar("g_healthsize"))\r
 111                                                 {\r
 112                                                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)\r
 113                                                                 GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND, bound(0, VOL_BASE * (1 - playersize_micro(self)), 1));\r
 114                                                         else\r
 115                                                                 GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND, bound(0, VOL_BASE * (1 - playersize_micro(self)), 1));\r
 116                                                         sound(self, CHAN_AUTO, "misc/macro_footstep.wav", bound(0, VOL_BASE * playersize_macro(self), 1), ATTN_NORM);\r
 117 \r
 118                                                         // earthquake effect for nearby players when a macro walks by\r
 119                                                         if(cvar("g_healthsize_quake_step"))\r
 120                                                         {\r
 121                                                                 entity head;\r
 122                                                                 for(head = findradius(self.origin, cvar("g_healthsize_quake_step_radius")); head; head = head.chain)\r
 123                                                                 {\r
 124                                                                         if not(head.classname == "player" || head.classname == "spectator")\r
 125                                                                                 continue;\r
 126                                                                         if(head == self || head.spectatee_status == num_for_edict(self))\r
 127                                                                                 continue; // not for self\r
 128                                                                         if not(head.flags & FL_ONGROUND)\r
 129                                                                                 continue; // we only feel the ground shaking if we are sitting on it\r
 130 \r
 131                                                                         float shake;\r
 132                                                                         shake = vlen(head.origin - self.origin);\r
 133                                                                         if(shake)\r
 134                                                                                 shake = 1 - bound(0, shake / cvar("g_healthsize_quake_step_radius"), 1);\r
 135                                                                         shake *= cvar("g_healthsize_quake_step");\r
 136 \r
 137                                                                         head.punchvector_x += crandom() * shake;\r
 138                                                                         head.punchvector_y += crandom() * shake;\r
 139                                                                         head.punchvector_z += crandom() * shake;\r
 140                                                                 }\r
 141                                                         }\r
 142                                                 }\r
 143                                                 else\r
 144                                                 {\r
 145                                                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)\r
 146                                                                 GlobalSound(globalsound_metalstep, CHAN_PLAYER, VOICETYPE_PLAYERSOUND, VOL_BASE);\r
 147                                                         else\r
 148                                                                 GlobalSound(globalsound_step, CHAN_PLAYER, VOICETYPE_PLAYERSOUND, VOL_BASE);\r
 149                                                 }\r
 150                                         }\r
 151                                 }\r
 152                         }\r
 153                         self.oldvelocity = self.velocity;\r
 154                 }\r
 155                 self = findfloat(self, iscreature, TRUE);\r
 156         }\r
 157         self = oldself;\r
 158 }\r
 159 \r
 160 \r
 161 /*\r
 162 =============\r
 163 StartFrame\r
 164 \r
 165 Called before each frame by the server\r
 166 =============\r
 167 */\r
 168 \r
 169 float game_delay;\r
 170 float game_delay_last;\r
 171 \r
 172 float RedirectionThink();\r
 173 entity SelectSpawnPoint (float anypoint);\r
 174 void StartFrame (void)\r
 175 {\r
 176         remove = remove_unsafely; // not during spawning!\r
 177         serverprevtime = servertime;\r
 178         servertime = time;\r
 179         serverframetime = frametime;\r
 180 \r
 181 #ifdef PROFILING\r
 182         if(time > client_cefc_accumulatortime + 1)\r
 183         {\r
 184                 float t, pp, c_seeing, c_seen;\r
 185                 entity cl;\r
 186                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);\r
 187                 print("CEFC time: ", ftos(t * 1000), "ms; ");\r
 188                 c_seeing = 0;\r
 189                 c_seen = 0;\r
 190                 FOR_EACH_CLIENT(cl)\r
 191                 {\r
 192                         if(clienttype(cl) == CLIENTTYPE_REAL)\r
 193                                 ++c_seeing;\r
 194                         if(cl.classname == "player")\r
 195                                 ++c_seen;\r
 196                 }\r
 197                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");\r
 198                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");\r
 199 \r
 200                 client_cefc_accumulatortime = time;\r
 201                 client_cefc_accumulator = 0;\r
 202         }\r
 203 #endif\r
 204 \r
 205         entity e;\r
 206         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )\r
 207                 CSQCProjectile_Check(e);\r
 208 \r
 209         if(RedirectionThink())\r
 210                 return;\r
 211 \r
 212         UncustomizeEntitiesRun();\r
 213         InitializeEntitiesRun();\r
 214 \r
 215         WarpZone_StartFrame();\r
 216 \r
 217         sv_gravity = cvar("sv_gravity");\r
 218         sv_maxairspeed = cvar("sv_maxairspeed");\r
 219         sv_maxspeed = cvar ("sv_maxspeed");\r
 220         sv_friction = cvar ("sv_friction");\r
 221         sv_accelerate = cvar ("sv_accelerate");\r
 222         sv_airaccelerate = cvar("sv_airaccelerate");\r
 223         sv_airaccel_sideways_friction = cvar("sv_airaccel_sideways_friction");\r
 224         sv_airaccel_qw = cvar("sv_airaccel_qw");\r
 225         sv_stopspeed = cvar ("sv_stopspeed");\r
 226         sv_airstopaccelerate = cvar("sv_airstopaccelerate");\r
 227         sv_airstrafeaccelerate = cvar("sv_airstrafeaccelerate");\r
 228         sv_maxairstrafespeed = cvar("sv_maxairstrafespeed");\r
 229         sv_aircontrol = cvar("sv_aircontrol");\r
 230         sv_warsowbunny_airforwardaccel = cvar("sv_warsowbunny_airforwardaccel");\r
 231         sv_warsowbunny_accel = cvar("sv_warsowbunny_accel");\r
 232         sv_warsowbunny_topspeed = cvar("sv_warsowbunny_topspeed");\r
 233         sv_warsowbunny_turnaccel = cvar("sv_warsowbunny_turnaccel");\r
 234         sv_warsowbunny_backtosideratio = cvar("sv_warsowbunny_backtosideratio");\r
 235         teamplay = cvar ("teamplay");\r
 236         sys_frametime = cvar("sys_ticrate") * cvar("slowmo");\r
 237 \r
 238         if (timeoutStatus == 1) // just before the timeout (when timeoutStatus will be 2)\r
 239                 orig_slowmo = cvar("slowmo"); // slowmo will be restored after the timeout\r
 240 \r
 241         if(teams_matter && !teamplay)\r
 242                 teamplay = 3;\r
 243         if(!teams_matter && teamplay)\r
 244                 teamplay = 0;\r
 245 \r
 246         skill = cvar("skill");\r
 247 \r
 248         Spawnqueue_Check();\r
 249 \r
 250 \r
 251         // detect when the pre-game countdown (if any) has ended and the game has started\r
 252         game_delay = (time < game_starttime) ? TRUE : FALSE;\r
 253 \r
 254         if(game_delay_last == TRUE)\r
 255         if(game_delay == FALSE)\r
 256         if(cvar("sv_eventlog"))\r
 257                         GameLogEcho(":startdelay_ended");\r
 258 \r
 259         game_delay_last = game_delay;\r
 260 \r
 261         // if in warmup stage and limit for warmup is hit start match\r
 262         if (inWarmupStage)\r
 263         if ((g_warmup_limit > 0 && time >= g_warmup_limit)\r
 264          || (g_warmup_limit == 0 && cvar("timelimit") != 0 && time >= cvar("timelimit") * 60))\r
 265         {\r
 266                 ReadyRestart();\r
 267                 return;\r
 268         }\r
 269 \r
 270         CreatureFrame ();\r
 271         CheckRules_World ();\r
 272 \r
 273         AuditTeams();\r
 274 \r
 275         bot_serverframe();\r
 276 \r
 277         if(cvar("spawn_debugview"))\r
 278         {\r
 279                 RandomSelection_Init();\r
 280                 for(self = world; (self = find(self, classname, "player")); )\r
 281                         RandomSelection_Add(self, 0, string_null, 1, 0);\r
 282                 self = RandomSelection_chosen_ent;\r
 283                 SelectSpawnPoint(0);\r
 284         }\r
 285 \r
 286         FOR_EACH_PLAYER(self)\r
 287                 self.porto_forbidden = max(0, self.porto_forbidden - 1);\r
 288 }\r
 289 \r
 290 .vector originjitter;\r
 291 .vector anglesjitter;\r
 292 .float anglejitter;\r
 293 .string gametypefilter;\r
 294 .string cvarfilter;\r
 295 void SV_OnEntityPreSpawnFunction()\r
 296 {\r
 297         if(self.gametypefilter != "")\r
 298         if not(isGametypeInFilter(game, teams_matter, self.gametypefilter))\r
 299         {\r
 300                 remove(self);\r
 301                 return;\r
 302         }\r
 303         if(self.cvarfilter != "")\r
 304         {\r
 305                 float n, i, o, inv;\r
 306                 string s, k, v;\r
 307                 inv = 0;\r
 308 \r
 309                 s = self.cvarfilter;\r
 310                 if(substring(s, 0, 1) == "+")\r
 311                 {\r
 312                         s = substring(s, 1, -1);\r
 313                 }\r
 314                 else if(substring(s, 0, 1) == "-")\r
 315                 {\r
 316                         inv = 1;\r
 317                         s = substring(s, 1, -1);\r
 318                 }\r
 319 \r
 320                 n = tokenize(s);\r
 321                 for(i = 0; i < n; ++i)\r
 322                 {\r
 323                         s = argv(i);\r
 324                         // syntax:\r
 325                         // var>x\r
 326                         // var<x\r
 327                         // var>=x\r
 328                         // var<=x\r
 329                         // var==x\r
 330                         // var!=x\r
 331                         // var===x\r
 332                         // var!==x\r
 333                         if((o = strstrofs(s, ">=", 0)) >= 0)\r
 334                         {\r
 335                                 k = substring(s, 0, o);\r
 336                                 v = substring(s, o+2, -1);\r
 337                                 if(cvar(k) < stof(v))\r
 338                                         goto cvar_fail;\r
 339                         }\r
 340                         else if((o = strstrofs(s, "<=", 0)) >= 0)\r
 341                         {\r
 342                                 k = substring(s, 0, o);\r
 343                                 v = substring(s, o+2, -1);\r
 344                                 if(cvar(k) > stof(v))\r
 345                                         goto cvar_fail;\r
 346                         }\r
 347                         else if((o = strstrofs(s, ">", 0)) >= 0)\r
 348                         {\r
 349                                 k = substring(s, 0, o);\r
 350                                 v = substring(s, o+1, -1);\r
 351                                 if(cvar(k) <= stof(v))\r
 352                                         goto cvar_fail;\r
 353                         }\r
 354                         else if((o = strstrofs(s, "<", 0)) >= 0)\r
 355                         {\r
 356                                 k = substring(s, 0, o);\r
 357                                 v = substring(s, o+1, -1);\r
 358                                 if(cvar(k) >= stof(v))\r
 359                                         goto cvar_fail;\r
 360                         }\r
 361                         else if((o = strstrofs(s, "==", 0)) >= 0)\r
 362                         {\r
 363                                 k = substring(s, 0, o);\r
 364                                 v = substring(s, o+2, -1);\r
 365                                 if(cvar(k) != stof(v))\r
 366                                         goto cvar_fail;\r
 367                         }\r
 368                         else if((o = strstrofs(s, "!=", 0)) >= 0)\r
 369                         {\r
 370                                 k = substring(s, 0, o);\r
 371                                 v = substring(s, o+2, -1);\r
 372                                 if(cvar(k) == stof(v))\r
 373                                         goto cvar_fail;\r
 374                         }\r
 375                         else if((o = strstrofs(s, "===", 0)) >= 0)\r
 376                         {\r
 377                                 k = substring(s, 0, o);\r
 378                                 v = substring(s, o+2, -1);\r
 379                                 if(cvar_string(k) != v)\r
 380                                         goto cvar_fail;\r
 381                         }\r
 382                         else if((o = strstrofs(s, "!==", 0)) >= 0)\r
 383                         {\r
 384                                 k = substring(s, 0, o);\r
 385                                 v = substring(s, o+2, -1);\r
 386                                 if(cvar_string(k) == v)\r
 387                                         goto cvar_fail;\r
 388                         }\r
 389                         else if(substring(s, 0, 1) == "!")\r
 390                         {\r
 391                                 k = substring(s, 1, -1);\r
 392                                 if(cvar(k))\r
 393                                         goto cvar_fail;\r
 394                         }\r
 395                         else\r
 396                         {\r
 397                                 k = s;\r
 398                                 if not(cvar(k))\r
 399                                         goto cvar_fail;\r
 400                         }\r
 401                 }\r
 402                 inv = !inv;\r
 403 :cvar_fail\r
 404                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it\r
 405                 if not(inv)\r
 406                 {\r
 407                         //print("cvarfilter fail\n");\r
 408                         remove(self);\r
 409                         return;\r
 410                 }\r
 411         }\r
 412 \r
 413         // support special -1 and -2 angle from radiant\r
 414         if (self.angles == '0 -1 0')\r
 415                 self.angles = '-90 0 0';\r
 416         else if (self.angles == '0 -2 0')\r
 417                 self.angles = '+90 0 0';\r
 418 \r
 419         if(self.originjitter_x != 0)\r
 420                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;\r
 421         if(self.originjitter_y != 0)\r
 422                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;\r
 423         if(self.originjitter_z != 0)\r
 424                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;\r
 425         if(self.anglesjitter_x != 0)\r
 426                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;\r
 427         if(self.anglesjitter_y != 0)\r
 428                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;\r
 429         if(self.anglesjitter_z != 0)\r
 430                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;\r
 431         if(self.anglejitter != 0)\r
 432                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;\r
 433 }\r