data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity swallow_model;\r
 203 void Vore_SwallowModel_Think()\r
 204 {\r
 205         //update the position of the swallow model to match our swallow progress\r
 206         float dist;\r
 207         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 208         if(cvar("g_healthsize"))\r
 209                 dist *= self.scale;\r
 210         self.view_ofs = '1 0 0' * dist;\r
 211 \r
 212         // if our swallow progress is gone, the swallow model also goes\r
 213         if(!self.owner.swallow_progress_prey)\r
 214         {\r
 215                 remove(self.owner.swallow_model);\r
 216                 self.owner.swallow_model = world;\r
 217                 return;\r
 218         }\r
 219 \r
 220         // properties that should update whenever possible, but when the predator is not available\r
 221         self.alpha = self.owner.cvar_cl_vore_stomachmodel;\r
 222         self.nextthink = time;\r
 223 }\r
 224 \r
 225 void Vore_SwallowModel_Update(entity prey)\r
 226 {\r
 227         // if we don't have a swallow model already, spawn one\r
 228         if(!prey.swallow_model)\r
 229         {\r
 230                 prey.swallow_model = spawn();\r
 231 \r
 232                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 233                 prey.swallow_model.solid = SOLID_NOT;\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
 237                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 238                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
 239                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
 240 \r
 241                 prey.swallow_model.owner = prey; // owned by the prey\r
 242                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 243                 prey.swallow_model.nextthink = time;\r
 244         }\r
 245 \r
 246         // properties that should update whenever possible, but when the predator is available\r
 247         string player_swallowmodel;\r
 248         player_swallowmodel = strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 249         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 250                 setmodel(prey.swallow_model, player_swallowmodel);\r
 251         if(prey.swallow_model.skin != self.skin) // player skin can be changed while the predator is active\r
 252                 prey.swallow_model.skin = self.skin;\r
 253         if(cvar("g_healthsize"))\r
 254                 prey.swallow_model.scale = self.scale / prey.scale; // player size difference\r
 255         if(prey.swallow_model.enemy != self)\r
 256                 prey.swallow_model.enemy = self; // enemy is the predator\r
 257 }\r
 258 \r
 259 .entity pusher;\r
 260 .float pushltime;\r
 261 void Vore_Swallow(entity e)\r
 262 {\r
 263         // this player is being swallowed by another player, apply the proper changes\r
 264 \r
 265         e.vore_oldmovetype = e.movetype;\r
 266         e.vore_oldsolid = e.solid;\r
 267 \r
 268         e.predator = self;\r
 269         setorigin(e, e.predator.origin);\r
 270         e.velocity = '0 0 0';\r
 271         e.movetype = MOVETYPE_FOLLOW;\r
 272         e.solid = SOLID_NOT;\r
 273         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 274 \r
 275         // drop keys (KH) and flags (CTF) when we get swallowed\r
 276         kh_Key_DropAll(e, FALSE);\r
 277         if(e.flagcarried)\r
 278                 DropFlag(e.flagcarried, world, e.predator);\r
 279 \r
 280         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 281                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 282 \r
 283         if(teams_matter && e.team == e.predator.team)\r
 284         {\r
 285                 if(cvar("g_vore_kick"))\r
 286                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 287                 if(cvar("g_vore_digestion"))\r
 288                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 289         }\r
 290 \r
 291         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 292         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 293         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 294         e.predator.stomach_load += 1;\r
 295         e.predator.regurgitate_prepare = 0;\r
 296         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 297         Vore_WeightApply(e.predator);\r
 298         Vore_AutoDigest(e.predator);\r
 299 \r
 300         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 301         e.predator.weapon_delay = time + button_delay_time;\r
 302         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 303         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 304         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 305 }\r
 306 \r
 307 void Vore_SwallowStep(entity e)\r
 308 {\r
 309         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 310         {\r
 311                 Vore_Swallow(e);\r
 312                 return;\r
 313         }\r
 314 \r
 315         Vore_SwallowModel_Update(e);\r
 316 \r
 317         // increase the progress value until it reaches 1, then swallow the player\r
 318         if(e.swallow_progress_prey < 1)\r
 319         {\r
 320                 float fill;\r
 321                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 322                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 323                         fill *= (self.scale / e.scale);\r
 324                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 325                         fill /= e.stomach_load;\r
 326 \r
 327                 e.swallow_progress_prey += fill;\r
 328         }\r
 329         else\r
 330         {\r
 331                 Vore_Swallow(e);\r
 332                 e.swallow_progress_prey = 0;\r
 333         }\r
 334 \r
 335         // the predator's progress is how much the prey got swallowed\r
 336         self.swallow_progress_pred = e.swallow_progress_prey;\r
 337 }\r
 338 \r
 339 void Vore_Regurgitate(entity e)\r
 340 {\r
 341         // this player is being regurgitated by their predator, apply the proper changes\r
 342 \r
 343         e.movetype = e.vore_oldmovetype;\r
 344         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 345                 e.solid = e.vore_oldsolid;\r
 346         e.view_ofs_z = PL_VIEW_OFS_z;\r
 347 \r
 348         // apply velocities\r
 349         local vector oldforward, oldright, oldup;\r
 350         oldforward = v_forward;\r
 351         oldright = v_right;\r
 352         oldup = v_up;\r
 353         makevectors(e.predator.v_angle);\r
 354         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 355         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 356         v_forward = oldforward;\r
 357         v_right = oldright;\r
 358         v_up = oldup;\r
 359 \r
 360         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 361         e.pushltime = time + cvar("g_maxpushtime");\r
 362 \r
 363         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 364         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 365                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 366 \r
 367         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 368         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 369         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 370         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 371         e.predator.stomach_load -= 1;\r
 372         e.predator.regurgitate_prepare = 0;\r
 373         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 374         Vore_WeightApply(e.predator);\r
 375 \r
 376         // block firing for a small amount of time, or we'll be firing the next frame\r
 377         e.weapon_delay = time + button_delay_time;\r
 378         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 379         e.predator = world;\r
 380 }\r
 381 \r
 382 void Vore_DeadPrey_Configure(entity e)\r
 383 {\r
 384         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 385 \r
 386         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 387                 return;\r
 388 \r
 389         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 390         e.fakepredator = e.predator;\r
 391         e.fakeprey = TRUE;\r
 392 \r
 393         // first release the prey from the predator, as dead prey needs to be attached differently\r
 394         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 395         e.predator.stomach_load -= 1;\r
 396         Vore_WeightApply(e.predator);\r
 397         e.predator = world;\r
 398 \r
 399         // now put our dead prey inside the predator's stomach, but only as an effect\r
 400         e.movetype = MOVETYPE_FOLLOW;\r
 401         e.takedamage = DAMAGE_NO;\r
 402         e.solid = SOLID_NOT;\r
 403         e.aiment = e.fakepredator;\r
 404 }\r
 405 \r
 406 void Vore_DeadPrey_Detach(entity e)\r
 407 {\r
 408         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 409         // should only execute after Vore_DeadPrey_Configure has ran first\r
 410 \r
 411         if not(cvar("g_vore_keepdeadprey"))\r
 412                 return;\r
 413 \r
 414         e.fakepredator = world;\r
 415         e.fakeprey = TRUE; // keep fakeprey status\r
 416         e.stat_eaten = 0;\r
 417         e.aiment = world;\r
 418         e.movetype = MOVETYPE_TOSS;\r
 419 }\r
 420 \r
 421 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 422 {\r
 423         if(pred_disconnect)\r
 424         {\r
 425                 if(e.fakeprey)\r
 426                         Vore_DeadPrey_Detach(e);\r
 427                 else\r
 428                         Vore_Regurgitate(e);\r
 429         }\r
 430         else if(self.stat_eaten && !self.fakeprey)\r
 431         {\r
 432                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 433                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 434                         Vore_DeadPrey_Configure(e);\r
 435                 else\r
 436                         Vore_Regurgitate(e);\r
 437         }\r
 438 }\r
 439 \r
 440 void Vore_Disconnect()\r
 441 {\r
 442         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 443 \r
 444         // prey disconnects or goes spectating while inside someone's belly\r
 445         if(self.stat_eaten)\r
 446                 Vore_PreyRelease(self, TRUE);\r
 447 \r
 448         // pred disconnects or goes spectating with players in their belly\r
 449         entity head;\r
 450         FOR_EACH_PLAYER(head)\r
 451         {\r
 452                 if(head.predator == self || head.fakepredator == self)\r
 453                         Vore_PreyRelease(head, TRUE);\r
 454         }\r
 455         Vore_GurgleSound(); // stop the gurgling sound\r
 456 \r
 457         self.stomach_load = self.gravity = 0; // prevents a bug\r
 458 }\r
 459 \r
 460 .float digestion_step;\r
 461 void Vore_Digest()\r
 462 {\r
 463         // apply digestion to prey\r
 464 \r
 465         if(time > self.digestion_step)\r
 466         {\r
 467                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 468                 float reduce;\r
 469                 if(cvar("g_balance_vore_digestion_distribute"))\r
 470                         reduce = self.predator.stomach_load;\r
 471                 else\r
 472                         reduce = 1;\r
 473 \r
 474                 float damage;\r
 475                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 476 \r
 477                 // apply player scale to digestion damage\r
 478                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 479                         damage *= (self.predator.scale / self.scale);\r
 480 \r
 481                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 482                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 483                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 484 \r
 485                 if (self.predator.digestsound_finished < time)\r
 486                 {\r
 487                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 488                         self.predator.digestsound_finished = time + 0.5;\r
 489                 }\r
 490                 self.digestion_step = time + steptime;\r
 491         }\r
 492 \r
 493         if(self.deadflag != DEAD_NO)\r
 494         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 495                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 496 }\r
 497 \r
 498 .float teamheal_step;\r
 499 void Vore_Teamheal()\r
 500 {\r
 501         // apply teamheal\r
 502 \r
 503         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 504         if(time > self.teamheal_step)\r
 505         {\r
 506                 self.health += cvar("g_balance_vore_teamheal");\r
 507                 self.teamheal_step = time + steptime;\r
 508 \r
 509                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 510                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 511                 {\r
 512                         play2(self, "misc/beep.wav");\r
 513                         play2(self.predator, "misc/beep.wav");\r
 514                 }\r
 515         }\r
 516 }\r
 517 \r
 518 void Vore_StomachKick()\r
 519 {\r
 520         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 521 \r
 522         if(time > self.stomachkick_delay)\r
 523         {\r
 524                 float damage;\r
 525                 vector force;\r
 526                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 527                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 528 \r
 529                 // apply player scale to the damage / force of the kick\r
 530                 if(cvar("g_balance_vore_kick_scalediff"))\r
 531                 {\r
 532                         damage *= (self.scale / self.predator.scale);\r
 533                         force *= (self.scale / self.predator.scale);\r
 534                 }\r
 535 \r
 536                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 537                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 538                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 539                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 540 \r
 541                 // abort the predator's scheduled regurgitation\r
 542                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 543                         self.predator.regurgitate_prepare = 0;\r
 544 \r
 545                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 546         }\r
 547 }\r
 548 \r
 549 void Vore_StomachLeave()\r
 550 {\r
 551         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 552 \r
 553         if(Vore_CanLeave())\r
 554                 Vore_Regurgitate(self);\r
 555         else if(time > self.complain_vore)\r
 556         {\r
 557                 play2(self, "misc/forbidden.wav");\r
 558                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 559                 self.complain_vore = time + complain_delay_time;\r
 560         }\r
 561 }\r
 562 \r
 563 void Vore_AutoTaunt()\r
 564 {\r
 565         // triggers ambient vore taunts, for both pred and prey\r
 566 \r
 567         float taunt_time;\r
 568 \r
 569         // predator taunts\r
 570         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 571         {\r
 572                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 573                 {\r
 574                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 575                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 576                 }\r
 577         }\r
 578         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 579         {\r
 580                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 581                 SetAutoTaunt(self, 0, 0);\r
 582         }\r
 583 \r
 584         // prey taunts\r
 585         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 586         {\r
 587                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 588                 {\r
 589                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 590                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 591                 }\r
 592         }\r
 593         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 594         {\r
 595                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 596                 SetAutoTaunt(self, 0, 0);\r
 597         }\r
 598 }\r
 599 \r
 600 void Vore_SetSbarRings()\r
 601 {\r
 602         // first clear the ring stats, then configure them if needed\r
 603         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 604         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 605 \r
 606         if(self.stat_eaten)\r
 607         {\r
 608                 if(time <= self.stomachkick_delay)\r
 609                 {\r
 610                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 611                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 612                 }\r
 613         }\r
 614         else\r
 615         {\r
 616                 if(self.swallow_progress_pred)\r
 617                 {\r
 618                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 619                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 620                 }\r
 621                 else if(time <= self.action_delay)\r
 622                 {\r
 623                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 624                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 625                 }\r
 626 \r
 627                 if(self.swallow_progress_prey)\r
 628                 {\r
 629                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 630                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 631                 }\r
 632                 else if(time <= self.regurgitate_prepare)\r
 633                 {\r
 634                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 635                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 636                 }\r
 637         }\r
 638 }\r
 639 \r
 640 void Vore()\r
 641 {\r
 642         // main vore code, this is where it all happens\r
 643 \r
 644         if(!cvar("g_vore")) // the vore system is disabled\r
 645         {\r
 646                 Vore_Disconnect();\r
 647                 return;\r
 648         }\r
 649 \r
 650         Vore_AutoTaunt();\r
 651 \r
 652         // wash the goo away from players once they leave the stomach\r
 653         if(!self.stat_eaten)\r
 654         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 655         if(self.colormod)\r
 656         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 657         {\r
 658                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 659                 if(self.colormod_x > 1)\r
 660                         self.colormod_x = 1;\r
 661                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 662                 if(self.colormod_y > 1)\r
 663                         self.colormod_y = 1;\r
 664                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 665                 if(self.colormod_z > 1)\r
 666                         self.colormod_z = 1;\r
 667         }\r
 668 \r
 669         // set all vore stats\r
 670         Vore_SetSbarRings();\r
 671         if(self.fakepredator.classname == "player")\r
 672                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 673         else if(self.predator.classname == "player")\r
 674         {\r
 675                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 676                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 677                 self.stat_eaten = num_for_edict(self.predator);\r
 678         }\r
 679         else\r
 680         {\r
 681                 self.stat_stomachload = self.stomach_load;\r
 682                 self.stat_digesting = self.digesting;\r
 683                 self.stat_eaten = 0;\r
 684         }\r
 685         self.stat_canleave = Vore_CanLeave();\r
 686 \r
 687         // don't allow a player inside a player inside another player :)\r
 688         // prevent this by checking if such has happened, and taking the proper measures\r
 689         // this code has a high priority and must not be stopped by any delay, so run it here\r
 690         if(self.predator.stat_eaten)\r
 691         {\r
 692                 entity target_predator, target_predator_predator, oldself;\r
 693                 target_predator = self.predator;\r
 694                 target_predator_predator = self.predator.predator;\r
 695 \r
 696                 Vore_Regurgitate(self);\r
 697 \r
 698                 // now steal our prey's prey if this probability applies\r
 699                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 700                 {\r
 701                         oldself = self;\r
 702                         self = target_predator_predator;\r
 703                         if(Swallow_condition_check(oldself))\r
 704                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 705                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 706                                 Vore_Swallow(oldself);\r
 707                         self = oldself;\r
 708                 }\r
 709         }\r
 710 \r
 711         // the swallow progress of prey and preds idly decrease by this amount\r
 712         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 713         {\r
 714                 if(self.swallow_progress_pred)\r
 715                 {\r
 716                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 717                         if(self.swallow_progress_pred < 0)\r
 718                                 self.swallow_progress_pred = 0;\r
 719                 }\r
 720                 if(self.swallow_progress_prey)\r
 721                 {\r
 722                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 723                         if(self.swallow_progress_prey < 0)\r
 724                                 self.swallow_progress_prey = 0;\r
 725                 }\r
 726         }\r
 727 \r
 728         // apply delays and skip the vore system under some circumstances\r
 729         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 730         {\r
 731                 Vore_Disconnect();\r
 732                 return;\r
 733         }\r
 734         if(self.spectatee_status)\r
 735                 return;\r
 736         if(time < self.system_delay)\r
 737                 return;\r
 738 \r
 739 // --------------------------------\r
 740 // Code that addresses predators:\r
 741 // --------------------------------\r
 742 \r
 743         entity prey;\r
 744         prey = Swallow_player_check();\r
 745 \r
 746         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 747         self.stat_canswallow = 0;\r
 748         if(Swallow_condition_check(prey))\r
 749         {\r
 750                 // canswallow stat, used by the HUD\r
 751                 if(teams_matter && prey.team == self.team)\r
 752                         self.stat_canswallow = 2;\r
 753                 else\r
 754                         self.stat_canswallow = 1;\r
 755 \r
 756                 if(self.BUTTON_ATCK)\r
 757                         Vore_SwallowStep(prey);\r
 758         }\r
 759         else if(prey != world)\r
 760                 self.stat_canswallow = -1;\r
 761 \r
 762         // toggle digestion, if the player has someone in their stomach\r
 763         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 764         {\r
 765                 if(self.stomach_load)\r
 766                 {\r
 767                         if(time > self.digest_button_delay_time)\r
 768                         {\r
 769                                 self.digesting = !self.digesting;\r
 770                                 self.digest_button_delay_time = time + button_delay_time;\r
 771                         }\r
 772                 }\r
 773                 else if(time > self.complain_vore)\r
 774                 {\r
 775                         play2(self, "misc/forbidden.wav");\r
 776                         sprint(self, "There is nothing to digest\n");\r
 777                         self.complain_vore = time + complain_delay_time;\r
 778                 }\r
 779         }\r
 780         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 781                 self.digesting = FALSE;\r
 782 \r
 783         // predator wishes to regurgitate his prey\r
 784         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 785         {\r
 786                 if(self.stomach_load)\r
 787                 {\r
 788                         if(time > self.regurgitate_button_delay_time)\r
 789                         {\r
 790                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 791                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 792                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 793                         }\r
 794                 }\r
 795                 else if(time > self.complain_vore)\r
 796                 {\r
 797                         play2(self, "misc/forbidden.wav");\r
 798                         sprint(self, "There is nothing to regurgitate\n");\r
 799                         self.complain_vore = time + complain_delay_time;\r
 800                 }\r
 801         }\r
 802 \r
 803         if(cvar("g_vore_gurglesound"))\r
 804                 Vore_GurgleSound();\r
 805 \r
 806 // --------------------------------\r
 807 // Code that addresses the prey:\r
 808 // --------------------------------\r
 809 \r
 810         Vore_SetPreyPositions();\r
 811 \r
 812         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 813         if(self.fakeprey)\r
 814         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 815                 Vore_DeadPrey_Detach(self);\r
 816 \r
 817         if(!self.stat_eaten)\r
 818                 return;\r
 819 \r
 820         if(self.deadflag != DEAD_NO)\r
 821         {\r
 822                 Vore_PreyRelease(self, FALSE);\r
 823                 return;\r
 824         }\r
 825 \r
 826         if(self.predator.deadflag != DEAD_NO)\r
 827                 Vore_Regurgitate(self);\r
 828         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 829                 Vore_Regurgitate(self);\r
 830 \r
 831         // apply delayed regurgitating if it was scheduled\r
 832         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 833         {\r
 834                 self.predator.regurgitate_prepare = 0;\r
 835                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 836                 Vore_Regurgitate(self);\r
 837         }\r
 838 \r
 839         // execute digesting and team healing\r
 840         if(self.predator.digesting == TRUE)\r
 841                 Vore_Digest();\r
 842         if(teams_matter && self.team == self.predator.team)\r
 843         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 844                 Vore_Teamheal();\r
 845 \r
 846         // execute prey commands\r
 847         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 848                 Vore_StomachKick();\r
 849         if(self.BUTTON_JUMP)\r
 850                 Vore_StomachLeave();\r
 851 \r
 852         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 853         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 854         kh_Key_DropAll(self, FALSE);\r
 855 }