data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Vore_CanLeave()\r
  93 {\r
  94         if(self.stat_eaten)\r
  95         {\r
  96                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  97                         return TRUE;\r
  98                 if(teams_matter && self.team == self.predator.team)\r
  99                         return TRUE;\r
 100                 if(g_rpg && cvar("g_rpg_canleave"))\r
 101                         return TRUE;\r
 102         }\r
 103         return FALSE;\r
 104 }\r
 105 \r
 106 // position the camera properly for prey\r
 107 void Vore_SetPreyPositions(entity pred)\r
 108 {\r
 109         // pred is the predator and head is the prey\r
 110 \r
 111         local entity head;\r
 112         local vector origin_apply;\r
 113 \r
 114         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 115         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 116         FOR_EACH_PLAYER(head)\r
 117         {\r
 118                 if(head.predator == pred)\r
 119                 {\r
 120                         origin_apply_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 121                         origin_apply_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 122                         origin_apply_z = PL_PREY_VIEW_OFS_z;\r
 123 \r
 124                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 125                         head.view_ofs = origin_apply;\r
 126                         head.view_ofs_z *= pred.scale; // stomach center depends on predator scale\r
 127 \r
 128                         // change prey height based on scale\r
 129                         float prey_height;\r
 130                                 prey_height = (head.scale - pred.scale) * cvar("g_healthsize_vore_pos");\r
 131                         head.view_ofs_z += prey_height;\r
 132                 }\r
 133         }\r
 134 }\r
 135 \r
 136 .float gurgle_oldstomachload;\r
 137 void Vore_GurgleSound()\r
 138 {\r
 139         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 140         {\r
 141                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 142 \r
 143                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 144                 self.gurgle_oldstomachload = self.stomach_load;\r
 145         }\r
 146 }\r
 147 \r
 148 void Vore_StomachLoad_Apply()\r
 149 {\r
 150         // apply stomach weight that makes you heavier and larger the more you eat\r
 151         // slowing the player is done in cl_physics.qc\r
 152 \r
 153         entity e;\r
 154         float prey_mass;\r
 155 \r
 156         // apply the stomach capacity of the predator\r
 157         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 158         if(cvar("g_healthsize"))\r
 159                 self.stomach_maxload *= self.scale;\r
 160         self.stomach_maxload = floor(self.stomach_maxload);\r
 161 \r
 162         self.stomach_load = 0; // start from zero\r
 163         FOR_EACH_PLAYER(e)\r
 164         {\r
 165                 if(e.predator == self)\r
 166                 {\r
 167                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 168                         if(cvar("g_healthsize"))\r
 169                                 prey_mass *= e.scale;\r
 170                         self.stomach_load += floor(prey_mass);\r
 171                 }\r
 172         }\r
 173 \r
 174         // apply weight\r
 175         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 176         if(!self.gravity && self.stomach_load)\r
 177                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 178 }\r
 179 \r
 180 void Vore_AutoDigest(entity e)\r
 181 {\r
 182         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 183 \r
 184         if(!cvar("g_vore_digestion") || e.digesting)\r
 185                 return;\r
 186         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 187                 return; // this feature is only for players, not bots\r
 188         if(e.stomach_load > 1)\r
 189                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 190         if(Stomach_TeamMates_check(e))\r
 191                 return; // never begin automatic digestion if we've swallowed a team mate\r
 192 \r
 193         e.digesting = TRUE;\r
 194 }\r
 195 \r
 196 .entity swallow_model;\r
 197 float Vore_SwallowModel_CustomizeEntityForClient()\r
 198 {\r
 199         // use the same system as the weapon model\r
 200 \r
 201         self.viewmodelforclient = self.owner;\r
 202         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 203 \r
 204         if(other.classname == "spectator")\r
 205         if(other.enemy == self.owner)\r
 206         {\r
 207                 self.viewmodelforclient = other;\r
 208                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 209         }\r
 210 \r
 211         return TRUE;\r
 212 }\r
 213 \r
 214 void Vore_SwallowModel_Think()\r
 215 {\r
 216         // update the position of the swallow model to match our swallow progress\r
 217         float dist;\r
 218         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 219         if(cvar("g_healthsize"))\r
 220                 dist *= self.scale;\r
 221         self.view_ofs = '1 0 0' * dist;\r
 222 \r
 223         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 224         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 225         {\r
 226                 remove(self.owner.swallow_model);\r
 227                 self.owner.swallow_model = world;\r
 228                 return;\r
 229         }\r
 230 \r
 231         // properties that should update whenever possible, but when the predator is not available\r
 232         self.nextthink = time;\r
 233 }\r
 234 \r
 235 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 236 {\r
 237         // if we don't have a swallow model already, spawn one\r
 238         if(!prey.swallow_model)\r
 239         {\r
 240                 prey.swallow_model = spawn();\r
 241                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 242                 prey.swallow_model.solid = SOLID_NOT;\r
 243                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 244                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 245                 prey.swallow_model.owner = prey;\r
 246                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 247                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 248                 prey.swallow_model.nextthink = time;\r
 249         }\r
 250 \r
 251         // properties that should update whenever possible, but when the predator is available\r
 252         string player_swallowmodel;\r
 253         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 254         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 255                 setmodel(prey.swallow_model, player_swallowmodel);\r
 256         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 257                 prey.swallow_model.skin = pred.skin;\r
 258         if(cvar("g_healthsize"))\r
 259                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 260         if(prey.swallow_model.enemy != pred)\r
 261                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 262         if(prey.swallow_model.colormap != pred.colormap)\r
 263                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 264         if(prey.swallow_model.glowmod != pred.glowmod)\r
 265                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 266 }\r
 267 \r
 268 .entity pusher;\r
 269 .float pushltime;\r
 270 void Vore_Swallow(entity e)\r
 271 {\r
 272         // this player is being swallowed by another player, apply the proper changes\r
 273 \r
 274         e.vore_oldmovetype = e.movetype;\r
 275         e.vore_oldsolid = e.solid;\r
 276 \r
 277         e.predator = self;\r
 278         setorigin(e, e.predator.origin);\r
 279         e.velocity = '0 0 0';\r
 280         e.movetype = MOVETYPE_FOLLOW;\r
 281         e.solid = SOLID_NOT;\r
 282         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 283 \r
 284         // drop keys (KH) and flags (CTF) when we get swallowed\r
 285         kh_Key_DropAll(e, FALSE);\r
 286         if(e.flagcarried)\r
 287                 DropFlag(e.flagcarried, world, e.predator);\r
 288 \r
 289         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 290                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 291 \r
 292         if(teams_matter && e.team == e.predator.team)\r
 293         {\r
 294                 if(cvar("g_vore_kick"))\r
 295                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 296                 if(cvar("g_vore_digestion"))\r
 297                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 298         }\r
 299 \r
 300         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 301         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 302         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 303         e.predator.regurgitate_prepare = 0;\r
 304         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 305         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 306         Vore_AutoDigest(e.predator);\r
 307         Vore_SetPreyPositions(e.predator);\r
 308 \r
 309         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 310         e.predator.weapon_delay = time + button_delay_time;\r
 311         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 312         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 313         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 314 }\r
 315 \r
 316 void Vore_SwallowStep(entity e)\r
 317 {\r
 318         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 319         {\r
 320                 Vore_Swallow(e);\r
 321                 return;\r
 322         }\r
 323 \r
 324         Vore_SwallowModel_Update(e, self);\r
 325 \r
 326         // increase the progress value until it reaches 1, then swallow the player\r
 327         if(e.swallow_progress_prey < 1)\r
 328         {\r
 329                 float fill;\r
 330                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 331                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 332                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 333                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 334                         fill /= e.stomach_load;\r
 335 \r
 336                 e.swallow_progress_prey += fill;\r
 337         }\r
 338         else\r
 339         {\r
 340                 Vore_Swallow(e);\r
 341                 e.swallow_progress_prey = 0;\r
 342         }\r
 343 \r
 344         // the predator's progress is how much the prey got swallowed\r
 345         self.swallow_progress_pred = e.swallow_progress_prey;\r
 346 }\r
 347 \r
 348 void Vore_Regurgitate(entity e)\r
 349 {\r
 350         // this player is being regurgitated by their predator, apply the proper changes\r
 351 \r
 352         e.movetype = e.vore_oldmovetype;\r
 353         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 354                 e.solid = e.vore_oldsolid;\r
 355         e.view_ofs_z = PL_VIEW_OFS_z;\r
 356 \r
 357         // apply velocities\r
 358         local vector oldforward, oldright, oldup;\r
 359         oldforward = v_forward;\r
 360         oldright = v_right;\r
 361         oldup = v_up;\r
 362         makevectors(e.predator.v_angle);\r
 363         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 364         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 365         v_forward = oldforward;\r
 366         v_right = oldright;\r
 367         v_up = oldup;\r
 368 \r
 369         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 370         e.pushltime = time + cvar("g_maxpushtime");\r
 371 \r
 372         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 373         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 374         {\r
 375                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 376                 Vore_SwallowModel_Update(e, e.predator);\r
 377         }\r
 378 \r
 379         // apply regurgitation damage to the predator\r
 380         if(cvar("g_balance_vore_regurgitate_damage"))\r
 381         {\r
 382                 float regurgitate_dmg;\r
 383                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 384                 if(cvar("g_healthsize"))\r
 385                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 386                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 387         }\r
 388 \r
 389         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 390         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 391         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 392         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 393         e.predator.regurgitate_prepare = 0;\r
 394         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 395         Vore_SetPreyPositions(e.predator);\r
 396 \r
 397         // block firing for a small amount of time, or we'll be firing the next frame\r
 398         e.weapon_delay = time + button_delay_time;\r
 399         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 400         e.predator = world;\r
 401 }\r
 402 \r
 403 void Vore_Disconnect()\r
 404 {\r
 405         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 406 \r
 407         // prey disconnects or goes spectating while inside someone's belly\r
 408         if(self.stat_eaten)\r
 409                 Vore_Regurgitate(self);\r
 410 \r
 411         // pred disconnects or goes spectating with players in their belly\r
 412         entity head;\r
 413         FOR_EACH_PLAYER(head)\r
 414         {\r
 415                 if(head.predator == self)\r
 416                         Vore_Regurgitate(head);\r
 417         }\r
 418         Vore_GurgleSound(); // stop the gurgling sound\r
 419 \r
 420         self.stomach_load = self.gravity = 0; // prevents a bug\r
 421 }\r
 422 \r
 423 .float digestion_step;\r
 424 void Vore_Digest()\r
 425 {\r
 426         // apply digestion to prey\r
 427 \r
 428         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 429                 return;\r
 430 \r
 431         if(time > self.digestion_step)\r
 432         {\r
 433                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 434                 float damage, damage_offset;\r
 435 \r
 436                 damage_offset = 1;\r
 437                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 438                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 439                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 440                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 441                 damage_offset = ceil(damage_offset);\r
 442 \r
 443                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 444                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 445                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 446 \r
 447                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 448                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 449                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 450 \r
 451                 if (self.predator.digestsound_finished < time)\r
 452                 {\r
 453                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 454                         self.predator.digestsound_finished = time + 0.5;\r
 455                 }\r
 456                 self.digestion_step = time + steptime;\r
 457         }\r
 458 \r
 459         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 460                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 461 }\r
 462 \r
 463 .float teamheal_step;\r
 464 void Vore_Teamheal()\r
 465 {\r
 466         // apply teamheal\r
 467 \r
 468         if(self.deadflag != DEAD_NO)\r
 469                 return;\r
 470 \r
 471         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 472         if(time > self.teamheal_step)\r
 473         {\r
 474                 self.health += cvar("g_balance_vore_teamheal");\r
 475                 self.teamheal_step = time + steptime;\r
 476 \r
 477                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 478                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 479                 {\r
 480                         play2(self, "misc/beep.wav");\r
 481                         play2(self.predator, "misc/beep.wav");\r
 482                 }\r
 483         }\r
 484 }\r
 485 \r
 486 .float kick_pressed;\r
 487 void Vore_StomachKick()\r
 488 {\r
 489         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 490 \r
 491         if(self.deadflag != DEAD_NO)\r
 492                 return;\r
 493 \r
 494         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 495         {\r
 496                 float damage, vol;\r
 497                 vector force;\r
 498                 damage = cvar("g_balance_vore_kick_damage");\r
 499                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 500                 vol = VOL_BASE;\r
 501 \r
 502                 // apply player scale to the damage / force of the kick\r
 503                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 504                 {\r
 505                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 506                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 507                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 508                 }\r
 509                 vol = bound(0, vol, 1);\r
 510 \r
 511                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 512                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 513                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 514                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 515 \r
 516                 // abort the predator's scheduled regurgitation\r
 517                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 518                         self.predator.regurgitate_prepare = 0;\r
 519 \r
 520                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 521                 if(cvar("g_balance_vore_kick_repress"))\r
 522                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 523                         self.kick_pressed = TRUE;\r
 524         }\r
 525 }\r
 526 \r
 527 void Vore_StomachLeave()\r
 528 {\r
 529         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 530 \r
 531         if(self.deadflag != DEAD_NO)\r
 532                 return;\r
 533 \r
 534         if(Vore_CanLeave())\r
 535                 Vore_Regurgitate(self);\r
 536         else if(time > self.complain_vore)\r
 537         {\r
 538                 play2(self, "misc/forbidden.wav");\r
 539                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 540                 self.complain_vore = time + complain_delay_time;\r
 541         }\r
 542 }\r
 543 \r
 544 void Vore_AutoTaunt()\r
 545 {\r
 546         // triggers ambient vore taunts, for both pred and prey\r
 547 \r
 548         float taunt_time;\r
 549 \r
 550         // predator taunts\r
 551         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 552         {\r
 553                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 554                 {\r
 555                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 556                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 557                 }\r
 558         }\r
 559         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 560         {\r
 561                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 562                 SetAutoTaunt(self, 0, 0);\r
 563         }\r
 564 \r
 565         // prey taunts\r
 566         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 567         {\r
 568                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 569                 {\r
 570                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 571                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 572                 }\r
 573         }\r
 574         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 575         {\r
 576                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 577                 SetAutoTaunt(self, 0, 0);\r
 578         }\r
 579 }\r
 580 \r
 581 void Vore_SetSbarRings()\r
 582 {\r
 583         // first clear the ring stats, then configure them if needed\r
 584         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 585         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 586 \r
 587         if(self.stat_eaten)\r
 588         {\r
 589                 if(time <= self.stomachkick_delay)\r
 590                 {\r
 591                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 592                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 593                 }\r
 594         }\r
 595         else\r
 596         {\r
 597                 if(self.swallow_progress_pred)\r
 598                 {\r
 599                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 600                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 601                 }\r
 602                 else if(time <= self.action_delay)\r
 603                 {\r
 604                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 605                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 606                 }\r
 607 \r
 608                 if(self.swallow_progress_prey)\r
 609                 {\r
 610                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 611                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 612                 }\r
 613                 else if(time <= self.regurgitate_prepare)\r
 614                 {\r
 615                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 616                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 617                 }\r
 618         }\r
 619 }\r
 620 \r
 621 .float regurgitatecolor_particles_tick;\r
 622 void Vore()\r
 623 {\r
 624         // main vore code, this is where it all happens\r
 625 \r
 626         Vore_AutoTaunt();\r
 627 \r
 628         if(!self.stat_eaten)\r
 629         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 630         if(self.colormod)\r
 631         if(self.colormod != '1 1 1')\r
 632         {\r
 633                 // slowly wash stomach fluids off players once they're out of the stomach\r
 634                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 635                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 636                 {\r
 637                         float goo_fade;\r
 638                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 639                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 640 \r
 641                         self.colormod_x += goo_fade;\r
 642                         if(self.colormod_x > 1)\r
 643                                 self.colormod_x = 1;\r
 644                         self.colormod_y += goo_fade;\r
 645                         if(self.colormod_y > 1)\r
 646                                 self.colormod_y = 1;\r
 647                         self.colormod_z += goo_fade;\r
 648                         if(self.colormod_z > 1)\r
 649                                 self.colormod_z = 1;\r
 650                 }\r
 651 \r
 652                 // constant particles falling off dirty players\r
 653                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 654                 if(self.regurgitatecolor_particles_tick < time)\r
 655                 {\r
 656                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 657                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 658                 }\r
 659         }\r
 660 \r
 661         // set all vore stats\r
 662         Vore_SetSbarRings();\r
 663         if(self.predator.classname == "player")\r
 664         {\r
 665                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 666                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 667                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 668                 self.stat_eaten = num_for_edict(self.predator);\r
 669         }\r
 670         else\r
 671         {\r
 672                 self.stat_stomachload = self.stomach_load;\r
 673                 self.stat_stomachmaxload = self.stomach_maxload;\r
 674                 self.stat_digesting = self.digesting;\r
 675                 self.stat_eaten = 0;\r
 676         }\r
 677         self.stat_canleave = Vore_CanLeave();\r
 678 \r
 679         // don't allow a player inside a player inside another player :)\r
 680         // prevent this by checking if such has happened, and taking the proper measures\r
 681         // this code has a high priority and must not be stopped by any delay, so run it here\r
 682         if(self.predator.stat_eaten)\r
 683         {\r
 684                 entity target_predator, target_predator_predator, oldself;\r
 685                 target_predator = self.predator;\r
 686                 target_predator_predator = self.predator.predator;\r
 687 \r
 688                 Vore_Regurgitate(self);\r
 689 \r
 690                 // now steal our prey's prey if this probability applies\r
 691                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 692                 {\r
 693                         oldself = self;\r
 694                         self = target_predator_predator;\r
 695                         if(Swallow_condition_check(oldself))\r
 696                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 697                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 698                                 Vore_Swallow(oldself);\r
 699                         self = oldself;\r
 700                 }\r
 701         }\r
 702 \r
 703         // the swallow progress of prey and preds idly decrease by this amount\r
 704         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 705         {\r
 706                 if(self.swallow_progress_pred)\r
 707                 {\r
 708                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 709                         if(self.swallow_progress_pred < 0)\r
 710                                 self.swallow_progress_pred = 0;\r
 711                 }\r
 712                 if(self.swallow_progress_prey)\r
 713                 {\r
 714                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 715                         if(self.swallow_progress_prey < 0)\r
 716                                 self.swallow_progress_prey = 0;\r
 717                 }\r
 718         }\r
 719 \r
 720         // set the predator's stomach load and capacity\r
 721         Vore_StomachLoad_Apply();\r
 722 \r
 723         // apply delays and skip the vore system under some circumstances\r
 724         if(!cvar("g_vore")) // the vore system is disabled\r
 725         {\r
 726                 Vore_Disconnect();\r
 727                 return;\r
 728         }\r
 729         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 730         {\r
 731                 Vore_Disconnect();\r
 732                 return;\r
 733         }\r
 734         if(self.spectatee_status)\r
 735                 return;\r
 736         if(time < self.system_delay)\r
 737                 return;\r
 738 \r
 739 // --------------------------------\r
 740 // Code that addresses predators:\r
 741 // --------------------------------\r
 742 \r
 743         entity prey;\r
 744         prey = Swallow_player_check();\r
 745 \r
 746         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 747         self.stat_canswallow = 0;\r
 748         if(Swallow_condition_check(prey))\r
 749         {\r
 750                 // canswallow stat, used by the HUD\r
 751                 if(teams_matter && prey.team == self.team)\r
 752                         self.stat_canswallow = 2;\r
 753                 else\r
 754                         self.stat_canswallow = 1;\r
 755 \r
 756                 if(self.BUTTON_ATCK)\r
 757                         Vore_SwallowStep(prey);\r
 758         }\r
 759         else if(prey != world)\r
 760                 self.stat_canswallow = -1;\r
 761 \r
 762         // toggle digestion, if the player has someone in their stomach\r
 763         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 764         {\r
 765                 if(self.stomach_load)\r
 766                 {\r
 767                         if(time > self.digest_button_delay_time)\r
 768                         {\r
 769                                 self.digesting = !self.digesting;\r
 770                                 self.digest_button_delay_time = time + button_delay_time;\r
 771                         }\r
 772                 }\r
 773                 else if(time > self.complain_vore)\r
 774                 {\r
 775                         play2(self, "misc/forbidden.wav");\r
 776                         sprint(self, "There is nothing to digest\n");\r
 777                         self.complain_vore = time + complain_delay_time;\r
 778                 }\r
 779         }\r
 780         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 781                 self.digesting = FALSE;\r
 782 \r
 783         // predator wishes to regurgitate his prey\r
 784         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 785         {\r
 786                 if(self.stomach_load)\r
 787                 {\r
 788                         if(time > self.regurgitate_button_delay_time)\r
 789                         {\r
 790                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 791                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 792                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 793                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 794                         }\r
 795                 }\r
 796                 else if(time > self.complain_vore)\r
 797                 {\r
 798                         play2(self, "misc/forbidden.wav");\r
 799                         sprint(self, "There is nothing to regurgitate\n");\r
 800                         self.complain_vore = time + complain_delay_time;\r
 801                 }\r
 802         }\r
 803 \r
 804         if(cvar("g_vore_gurglesound"))\r
 805                 Vore_GurgleSound();\r
 806 \r
 807 // --------------------------------\r
 808 // Code that addresses the prey:\r
 809 // --------------------------------\r
 810 \r
 811         if(!self.stat_eaten)\r
 812                 return;\r
 813 \r
 814         // automatically regurgitate prey that has reached their digestion limit\r
 815         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 816         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 817         {\r
 818                 Vore_Regurgitate(self);\r
 819                 return;\r
 820         }\r
 821 \r
 822         if(self.predator.deadflag != DEAD_NO) // do we want to be in a dead furry x_x\r
 823         {\r
 824                 Vore_Regurgitate(self);\r
 825                 return;\r
 826         }\r
 827         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 828         {\r
 829                 Vore_Regurgitate(self);\r
 830                 return;\r
 831         }\r
 832         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 833         {\r
 834                 Vore_Regurgitate(self);\r
 835                 return;\r
 836         }\r
 837 \r
 838         // apply delayed regurgitating if it was scheduled\r
 839         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 840         {\r
 841                 self.predator.regurgitate_prepare = 0;\r
 842                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 843                 Vore_Regurgitate(self);\r
 844         }\r
 845 \r
 846         // execute digesting and team healing\r
 847         if(self.predator.digesting == TRUE)\r
 848                 Vore_Digest();\r
 849         if(teams_matter && self.team == self.predator.team)\r
 850         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 851                 Vore_Teamheal();\r
 852 \r
 853         // execute prey commands\r
 854         if(self.BUTTON_ATCK)\r
 855         {\r
 856                 if(cvar("g_vore_kick"))\r
 857                         Vore_StomachKick();\r
 858         }\r
 859         else\r
 860                 self.kick_pressed = FALSE;\r
 861         if(self.BUTTON_JUMP)\r
 862                 Vore_StomachLeave();\r
 863 \r
 864         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 865         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 866         kh_Key_DropAll(self, FALSE);\r
 867 }