CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  27 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  28 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  29
  30 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  32 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  33
  34 if (FHS_INSTALL)
  35     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  36     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  37     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  38 endif ()
  39
  40 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  41
  42 #-----------------------------------------------------------------------
  43 # Version
  44 #-----------------------------------------------------------------------
  45
  46 # CMake 3.0+ would allow this in project()
  47 set(RADIANT_VERSION_MAJOR 1)
  48 set(RADIANT_VERSION_MINOR 5)
  49 set(RADIANT_VERSION_PATCH 0)
  50 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  51
  52 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  53
  54 find_package(Git REQUIRED)
  55
  56 execute_process(
  57      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  58      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  59      OUTPUT_VARIABLE GIT_VERSION
  60      OUTPUT_STRIP_TRAILING_WHITESPACE
  61 )
  62
  63 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  64
  65 if (GIT_VERSION)
  66     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  67 endif ()
  68
  69 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  70
  71 #-----------------------------------------------------------------------
  72 # Language standard
  73 #-----------------------------------------------------------------------
  74
  75 if (BUILD_BINARIES)
  76     set(CMAKE_CXX_STANDARD 11)
  77     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  78     set(CMAKE_CXX_EXTENSIONS OFF)
  79
  80     if (CMAKE_VERSION VERSION_LESS "3.1")
  81         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  82             include(CheckCXXCompilerFlag)
  83             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  84             if (STD_CXX)
  85                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  86             else ()
  87                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  88             endif ()
  89         else ()
  90             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  91         endif ()
  92     endif ()
  93 endif ()
  94
  95 #-----------------------------------------------------------------------
  96 # Flags
  97 #-----------------------------------------------------------------------
  98
  99 if (BUILD_BINARIES)
 100     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 101
 102     macro (addflags_c args)
 103         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 104     endmacro ()
 105
 106     macro (addflags_cxx args)
 107         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 108     endmacro ()
 109
 110     macro (addflags args)
 111         addflags_c("${args}")
 112         addflags_cxx("${args}")
 113     endmacro ()
 114
 115     addflags("-fno-strict-aliasing")
 116     if (NOT WIN32)
 117         addflags("-fvisibility=hidden")
 118     endif ()
 119
 120     if (USE_WERROR)
 121         addflags("-Werror")
 122         addflags("-pedantic-errors")
 123     endif ()
 124
 125     addflags("-Wall")
 126     addflags("-Wextra")
 127     addflags("-pedantic")
 128
 129     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 130
 131     addflags("-Wno-unused-function")
 132     addflags("-Wno-unused-variable")
 133     addflags("-Wno-unused-parameter")
 134
 135     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 136 endif ()
 137
 138 if (BUILD_RADIANT)
 139     set(GTK_TARGET 2 CACHE STRING "GTK target")
 140     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 141
 142     if (GTK_TARGET EQUAL 2 AND WIN32)
 143         add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 144     endif ()
 145 endif ()
 146
 147 #-----------------------------------------------------------------------
 148 # Defs
 149 #-----------------------------------------------------------------------
 150
 151 if (BUILD_BINARIES)
 152     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 153     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 154
 155     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 156         add_definitions(-D_DEBUG=1)
 157     endif ()
 158 endif ()
 159
 160 if (BUILD_RADIANT)
 161     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 162
 163     macro (disable_deprecated name gtk2only)
 164         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 165         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 166             add_definitions(-D${name}_DISABLE_DEPRECATED)
 167         endif ()
 168     endmacro ()
 169
 170     disable_deprecated(ATK 0)
 171     disable_deprecated(G 0)
 172     disable_deprecated(GDK 0)
 173     disable_deprecated(GDK_PIXBUF 0)
 174     disable_deprecated(GTK 1)
 175     disable_deprecated(PANGO 0)
 176 endif ()
 177
 178 if (BUILD_BINARIES)
 179     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 180         link_directories(
 181             /usr/local/lib
 182         )
 183     endif ()
 184
 185     if (WIN32)
 186         add_definitions(
 187             -DWIN32=1
 188             -D_WIN32=1
 189         )
 190     else ()
 191         add_definitions(
 192             -DPOSIX=1
 193         )
 194     endif ()
 195 endif ()
 196
 197 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 198     set(XWINDOWS ON)
 199     find_package(X11 REQUIRED)
 200     include_directories(${X11_INCLUDE_DIR})
 201     add_definitions(-DXWINDOWS=1)
 202 endif ()
 203
 204 if (BUILD_BINARIES)
 205     include_directories("${PROJECT_SOURCE_DIR}/include")
 206     include_directories("${PROJECT_SOURCE_DIR}/libs")
 207
 208     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 209         set(BUNDLE_LIBRARIES_DEFAULT ON)
 210     else ()
 211         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 212     endif ()
 213
 214     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 215
 216     macro (copy_dlls target)
 217         if (BUNDLE_LIBRARIES AND WIN32)
 218             add_custom_command(TARGET ${target} POST_BUILD
 219                 COMMAND bash
 220                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 221                 VERBATIM
 222         )
 223         endif ()
 224     endmacro ()
 225
 226     macro (bundle_stuff target)
 227         if (BUNDLE_LIBRARIES AND WIN32)
 228             add_custom_command(TARGET ${target} POST_BUILD
 229                 COMMAND bash
 230                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 231                 VERBATIM
 232         )
 233
 234         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 235
 236         install(FILES
 237             ${DLL_FILES}
 238             DESTINATION ${CMAKE_INSTALL_PREFIX}
 239         )
 240
 241         install(DIRECTORY
 242             ${PROJECT_BINARY_DIR}/lib
 243             ${PROJECT_BINARY_DIR}/share
 244             DESTINATION ${CMAKE_INSTALL_PREFIX}
 245         )
 246         endif ()
 247     endmacro ()
 248 endif ()
 249
 250 #-----------------------------------------------------------------------
 251 # Libraries
 252 #-----------------------------------------------------------------------
 253
 254 if (BUILD_BINARIES)
 255     add_subdirectory(libs)
 256 endif ()
 257
 258 if (BUILD_RADIANT)
 259     add_subdirectory(include)
 260 endif ()
 261
 262 #-----------------------------------------------------------------------
 263 # Plugins
 264 #-----------------------------------------------------------------------
 265
 266 if (BUILD_RADIANT)
 267     add_subdirectory(contrib)
 268 endif ()
 269
 270 #-----------------------------------------------------------------------
 271 # Modules
 272 #-----------------------------------------------------------------------
 273
 274 if (BUILD_RADIANT)
 275     add_subdirectory(plugins)
 276 endif ()
 277
 278 #-----------------------------------------------------------------------
 279 # Radiant
 280 #-----------------------------------------------------------------------
 281
 282 if (BUILD_BINARIES)
 283     if (CMAKE_EXECUTABLE_SUFFIX)
 284         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 285     endif ()
 286
 287     macro (radiant_tool name)
 288         add_executable(${name} ${ARGN})
 289
 290         copy_dlls(${name})
 291
 292         install(
 293             TARGETS ${name}
 294             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 295         )
 296     endmacro ()
 297
 298     if (BUILD_RADIANT)
 299         add_subdirectory(radiant)
 300         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 301         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 302     )
 303     endif ()
 304 endif ()
 305
 306 #-----------------------------------------------------------------------
 307 # Tools
 308 #-----------------------------------------------------------------------
 309
 310 if (BUILD_TOOLS)
 311     add_subdirectory(tools)
 312
 313     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 314
 315     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 316         # Copy data files from sources to the build directory
 317         message(STATUS "Copying data files")
 318         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 319     endif ()
 320 endif ()
 321
 322 #-----------------------------------------------------------------------
 323 # Game packs
 324 #-----------------------------------------------------------------------
 325
 326 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 327 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 328
 329 if (DOWNLOAD_GAMEPACKS)
 330     add_custom_target(game_packs ALL
 331        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 332        COMMENT "Downloading game packs"
 333     )
 334 endif ()
 335
 336 #-----------------------------------------------------------------------
 337 # Install
 338 #-----------------------------------------------------------------------
 339
 340 if (BUILD_BINARIES)
 341     install(DIRECTORY
 342         setup/data/tools/base
 343         setup/data/tools/bitmaps
 344         setup/data/tools/gl
 345         setup/data/tools/plugins
 346         docs
 347         DESTINATION ${RADIANT_DATA_DIR}
 348     )
 349 endif ()
 350
 351 if (DOWNLOAD_GAMEPACKS)
 352     if (FHS_INSTALL)
 353        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 354     else ()
 355        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 356     endif ()
 357
 358     install(DIRECTORY
 359         ${PROJECT_BINARY_DIR}/gamepacks
 360         DESTINATION ${RADIANT_DATA_DIR}
 361     )
 362 endif ()
 363
 364 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 365     install(FILES
 366         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 367         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 368     )
 369     install(FILES
 370         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 371         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 372     )
 373     install(FILES
 374         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 375         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 376     )
 377 endif ()
 378
 379 include(cmake/scripts/package.cmake)