CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3
   4 project(NetRadiant C CXX)
   5 option(BUILD_RADIANT "Build the gui" ON)
   6
   7 if (NOT CMAKE_INSTALL_PREFIX)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install")
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 # For some reason the above flags don't really work...
  48 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49     include(CheckCXXCompilerFlag)
  50     check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51     if (STD_CXX)
  52         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53     else ()
  54         message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55     endif ()
  56 else ()
  57     message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58 endif ()
  59
  60 #-----------------------------------------------------------------------
  61 # Flags
  62 #-----------------------------------------------------------------------
  63
  64 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  65 macro(addflags args)
  66     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  67     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  68 endmacro()
  69 addflags("-fno-strict-aliasing")
  70 if (NOT WIN32)
  71     addflags("-fvisibility=hidden")
  72 endif ()
  73
  74 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
  75 set(GTK_NS "GTK2" CACHE STRING "GTK variable prefix")
  76
  77 #-----------------------------------------------------------------------
  78 # Defs
  79 #-----------------------------------------------------------------------
  80
  81 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
  82 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
  83 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
  84 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
  85
  86 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
  87
  88 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
  89     add_definitions(-D_DEBUG=1)
  90 endif ()
  91
  92 if (APPLE)
  93     option(XWINDOWS "Build against X11" ON)
  94     add_definitions(
  95             -DPOSIX=1
  96     )
  97 elseif (WIN32)
  98     add_definitions(
  99             -DWIN32=1
 100             -D_WIN32=1
 101     )
 102 else ()
 103     set(XWINDOWS ON)
 104     add_definitions(
 105             -DPOSIX=1
 106     )
 107 endif ()
 108
 109 if (XWINDOWS)
 110     find_package(X11 REQUIRED)
 111     include_directories(${X11_INCLUDE_DIR})
 112     add_definitions(-DXWINDOWS=1)
 113 endif ()
 114
 115 include_directories("${PROJECT_SOURCE_DIR}/include")
 116 include_directories("${PROJECT_SOURCE_DIR}/libs")
 117
 118 macro(copy_dlls target)
 119     if (WIN32)
 120         add_custom_command(TARGET ${target} POST_BUILD
 121                 COMMAND bash
 122                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 123                 VERBATIM
 124                 )
 125     endif ()
 126 endmacro()
 127
 128 #-----------------------------------------------------------------------
 129 # Libraries
 130 #-----------------------------------------------------------------------
 131
 132 add_subdirectory(libs)
 133 add_subdirectory(include)
 134
 135 #-----------------------------------------------------------------------
 136 # Plugins
 137 #-----------------------------------------------------------------------
 138
 139 if (BUILD_RADIANT)
 140     add_subdirectory(contrib)
 141 endif ()
 142
 143 #-----------------------------------------------------------------------
 144 # Modules
 145 #-----------------------------------------------------------------------
 146
 147 if (BUILD_RADIANT)
 148     add_subdirectory(plugins)
 149 endif ()
 150
 151 #-----------------------------------------------------------------------
 152 # Radiant
 153 #-----------------------------------------------------------------------
 154
 155 if (BUILD_RADIANT)
 156     add_subdirectory(radiant build)
 157 endif ()
 158
 159 if (CMAKE_EXECUTABLE_SUFFIX)
 160     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 161 else ()
 162     execute_process(
 163             COMMAND uname -m
 164             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 165             OUTPUT_STRIP_TRAILING_WHITESPACE
 166     )
 167 endif ()
 168
 169 if (BUILD_RADIANT)
 170     set_target_properties(radiant PROPERTIES
 171             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 172             )
 173 endif ()
 174
 175 #-----------------------------------------------------------------------
 176 # Tools
 177 #-----------------------------------------------------------------------
 178
 179 add_subdirectory(tools)
 180
 181 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 182 file(GLOB DOCS_FILES "${PROJECT_SOURCE_DIR}/docs/*")
 183
 184 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 185     # Copy data files from sources to the build directory
 186     message(STATUS "Copying data files")
 187     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 188     file(COPY ${DOCS_FILES} DESTINATION "${PROJECT_BINARY_DIR}/docs")
 189 endif ()
 190
 191 #-----------------------------------------------------------------------
 192 # Game packs
 193 #-----------------------------------------------------------------------
 194
 195 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 196 add_custom_target(game_packs
 197         COMMAND ${CMAKE_COMMAND} -E make_directory games
 198         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 199         COMMENT "Downloading game packs"
 200         )
 201 if (DOWNLOAD_GAMEPACKS)
 202     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 203 endif ()
 204
 205 #-----------------------------------------------------------------------
 206 # Install
 207 #-----------------------------------------------------------------------
 208
 209 install(
 210         FILES
 211         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 212         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 213         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 214         DESTINATION ${CMAKE_INSTALL_PREFIX}
 215 )
 216 file(GLOB GAME_FILES "${PROJECT_SOURCE_DIR}/games/*")
 217 unset(_tmp)
 218 foreach (it ${GAME_FILES})
 219     list(APPEND _tmp "${it}/games")
 220     file(GLOB GAME_DIR "${it}/*.game")
 221     list(APPEND _tmp "${GAME_DIR}")
 222 endforeach ()
 223 set(GAME_FILES ${_tmp})
 224
 225 install(
 226         DIRECTORY
 227         ${PROJECT_SOURCE_DIR}/setup/data/tools/
 228         ${PROJECT_SOURCE_DIR}/docs
 229         ${GAME_FILES}
 230         DESTINATION ${CMAKE_INSTALL_PREFIX}
 231 )
 232