CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 #-----------------------------------------------------------------------
  57 # Build options
  58 #-----------------------------------------------------------------------
  59
  60 option(BUILD_RADIANT "Build the GUI" ON)
  61 option(BUILD_TOOLS "Build the tools" ON)
  62 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  63 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  64 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  65 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  66 option(FHS_INSTALL_ABSOLUTE "Install using absolute paths (requires FHS_INSTALL)" OFF)
  67
  68 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  69 if (BUILD_RADIANT OR BUILD_TOOLS)
  70     set(BUILD_BINARIES ON)
  71 endif ()
  72
  73 if (BUILD_BINARIES)
  74     if (WIN32
  75         OR APPLE
  76         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  77         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  78         set(BUNDLING_SUPPORTED ON)
  79     endif()
  80
  81     if (BUNDLING_SUPPORTED)
  82         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  83             set(BUNDLE_LIBRARIES_DEFAULT ON)
  84         else ()
  85             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  86         endif ()
  87
  88         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  89     endif ()
  90
  91     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  92         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES is enabled" FORCE)
  93     endif ()
  94
  95     if (NOT FHS_INSTALL AND FHS_INSTALL_ABSOLUTE)
  96         set(FHS_INSTALL_ABSOLUTE OFF CACHE PATH "Disabled because of FHS_INSTALL is disabled" FORCE)
  97     endif ()
  98 endif ()
  99
 100 #-----------------------------------------------------------------------
 101 # Paths
 102 #-----------------------------------------------------------------------
 103
 104 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 105     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 106 endif ()
 107
 108 if (APPLE)
 109     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 110     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 111 else ()
 112     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 113 endif ()
 114
 115 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 116 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 117 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 118 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 119
 120 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 121 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 122 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 123 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 124 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 125
 126 if (FHS_INSTALL)
 127     add_definitions(-DRADIANT_FHS_INSTALL='ON')
 128
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE})
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 133     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 134     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE})
 135
 136     if (FHS_INSTALL_ABSOLUTE)
 137         add_definitions(-DRADIANT_ADDONS_DIR="${RADIANT_ADDONS_DIR}")
 138         add_definitions(-DRADIANT_DATA_DIR="${RADIANT_DATA_DIR}")
 139     else ()
 140         add_definitions(-DRADIANT_LIB_ARCH="${CMAKE_LIBRARY_ARCHITECTURE}")
 141     endif ()
 142 endif ()
 143
 144
 145 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 146
 147 #-----------------------------------------------------------------------
 148 # Version
 149 #-----------------------------------------------------------------------
 150
 151 # CMake 3.0+ would allow this in project()
 152 set(RADIANT_VERSION_MAJOR 1)
 153 set(RADIANT_VERSION_MINOR 5)
 154 set(RADIANT_VERSION_PATCH 0)
 155 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 156
 157 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 158
 159 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 160
 161 if (NOT DEFINED GIT_VERSION)
 162      find_package(Git REQUIRED)
 163
 164      execute_process(
 165           COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 166           WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 167           OUTPUT_VARIABLE GIT_VERSION
 168           OUTPUT_STRIP_TRAILING_WHITESPACE
 169      )
 170
 171      if (GIT_VERSION)
 172          set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 173      endif ()
 174 endif ()
 175
 176 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 177
 178 #-----------------------------------------------------------------------
 179 # Language standard
 180 #-----------------------------------------------------------------------
 181
 182 if (BUILD_BINARIES)
 183     set(CMAKE_CXX_STANDARD 11)
 184     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 185     set(CMAKE_CXX_EXTENSIONS OFF)
 186
 187     if (CMAKE_VERSION VERSION_LESS "3.1")
 188         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 189             include(CheckCXXCompilerFlag)
 190             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 191             if (STD_CXX)
 192                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 193             else ()
 194                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 195             endif ()
 196         else ()
 197             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 198         endif ()
 199     endif ()
 200 endif ()
 201
 202 #-----------------------------------------------------------------------
 203 # Flags
 204 #-----------------------------------------------------------------------
 205
 206 if (BUILD_BINARIES)
 207     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 208
 209     macro (addflags_c args)
 210         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 211     endmacro ()
 212
 213     macro (addflags_cxx args)
 214         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 215     endmacro ()
 216
 217     macro (addflags args)
 218         addflags_c("${args}")
 219         addflags_cxx("${args}")
 220     endmacro ()
 221
 222     addflags("-fno-strict-aliasing")
 223     if (NOT WIN32)
 224         addflags("-fvisibility=hidden")
 225     endif ()
 226
 227     if (USE_WERROR)
 228         addflags("-Werror")
 229         addflags("-pedantic-errors")
 230     endif ()
 231
 232     addflags("-Wall")
 233     addflags("-Wextra")
 234     addflags("-pedantic")
 235
 236     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 237
 238     addflags("-Wno-unused-function")
 239     addflags("-Wno-unused-variable")
 240     addflags("-Wno-unused-parameter")
 241
 242     if (APPLE)
 243         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 244     endif()
 245
 246     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 247 endif ()
 248
 249 if (BUILD_RADIANT)
 250     set(GTK_TARGET 2 CACHE STRING "GTK target")
 251     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 252
 253     if (WIN32)
 254         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 255
 256         if (GTK_TARGET EQUAL 2)
 257             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 258         endif ()
 259     endif ()
 260
 261     if (APPLE)
 262         if (GTK_TARGET EQUAL 2)
 263             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 264             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 265             add_definitions(-DWORKAROUND_MACOS_GTK2_LAGGYPOINTER=1)
 266         endif ()
 267     endif ()
 268 endif ()
 269
 270 #-----------------------------------------------------------------------
 271 # Defs
 272 #-----------------------------------------------------------------------
 273
 274 if (BUILD_BINARIES)
 275     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 276     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 277
 278     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 279         add_definitions(-D_DEBUG=1)
 280     endif ()
 281 endif ()
 282
 283 if (BUILD_RADIANT)
 284     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 285
 286     macro (disable_deprecated name gtk2only)
 287         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 288         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 289             add_definitions(-D${name}_DISABLE_DEPRECATED)
 290         endif ()
 291     endmacro ()
 292
 293     disable_deprecated(ATK 0)
 294     disable_deprecated(G 0)
 295     disable_deprecated(GDK 0)
 296     disable_deprecated(GDK_PIXBUF 0)
 297     disable_deprecated(GTK 1)
 298     disable_deprecated(PANGO 0)
 299 endif ()
 300
 301 if (BUILD_BINARIES)
 302     add_custom_target(binaries ALL)
 303
 304     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 305         link_directories(
 306             /usr/local/lib
 307         )
 308     endif ()
 309
 310     if (WIN32)
 311         add_definitions(
 312             -DWIN32=1
 313             -D_WIN32=1
 314         )
 315     else ()
 316         add_definitions(
 317             -DPOSIX=1
 318         )
 319     endif ()
 320 endif ()
 321
 322 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 323     set(XWINDOWS ON)
 324     find_package(X11 REQUIRED)
 325     include_directories(${X11_INCLUDE_DIR})
 326     add_definitions(-DXWINDOWS=1)
 327 endif ()
 328
 329 if (BUILD_BINARIES)
 330     include_directories("${PROJECT_SOURCE_DIR}/include")
 331     include_directories("${PROJECT_SOURCE_DIR}/libs")
 332
 333     macro (copy_dlls target)
 334         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 335             add_custom_command(TARGET ${target} POST_BUILD
 336                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 337                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 338                 VERBATIM
 339             )
 340             add_dependencies(bundle ${target})
 341         endif ()
 342     endmacro ()
 343 endif ()
 344
 345 #-----------------------------------------------------------------------
 346 # Bundle
 347 #-----------------------------------------------------------------------
 348
 349 if (BUILD_BINARIES)
 350     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 351         add_subdirectory(bundle)
 352     endif ()
 353 endif ()
 354
 355 #-----------------------------------------------------------------------
 356 # Builtins: targets
 357 #-----------------------------------------------------------------------
 358
 359 add_custom_target(builtins)
 360
 361 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 362     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 363 endif ()
 364
 365 if (BUILTIN_GTKGLEXT)
 366     set(GTKGLEXT_PKGNAMES "gdk-2.0 gtk+-2.0 glib-2.0")
 367
 368     if (NOT APPLE)
 369         set(GTKGLEXT_PKGNAMES "${GTKGLEXT_PKGNAMES} gl")
 370     endif ()
 371
 372     execute_process(COMMAND pkg-config --libs ${GTKGLEXT_PKGNAMES}
 373         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 374         OUTPUT_STRIP_TRAILING_WHITESPACE
 375     )
 376
 377     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 378
 379     execute_process(COMMAND pkg-config --cflags ${GTKGLEXT_PKGNAMES}
 380         OUTPUT_VARIABLE GTKGLEXT_CFLAGS
 381         OUTPUT_STRIP_TRAILING_WHITESPACE
 382     )
 383
 384     set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} ${GTKGLEXT_CFLAGS}")
 385
 386
 387     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf --disable-dependency-tracking --without-x)
 388
 389     if (CMAKE_BUILD_TYPE MATCHES Release)
 390         set(CONFIGURE_OPTIONS ${CONFIGURE_OPTIONS} --disable-debug)
 391     endif ()
 392
 393     if (APPLE)
 394         set(GTKGLEXT_GIT_TAG macos)
 395     else ()
 396         set(GTKGLEXT_GIT_TAG fixes)
 397     endif ()
 398
 399     if (APPLE)
 400         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1 -Wno-deprecated-declarations")
 401     endif ()
 402
 403     ExternalProject_Add(gtkglext
 404         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 405         GIT_TAG ${GTKGLEXT_GIT_TAG}
 406         BUILD_IN_SOURCE ON
 407         CONFIGURE_COMMAND export CCFLAGS=${GTKGLEXT_CFLAGS}
 408         CONFIGURE_COMMAND && export LDFLAGS=${GTKGLEXT_LDFLAGS}
 409         CONFIGURE_COMMAND && export NOCONFIGURE=1
 410         CONFIGURE_COMMAND && ./autogen.sh
 411         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 412         BUILD_COMMAND $(MAKE)
 413         BUILD_COMMAND CFLAGS=${GTKGLEXT_CFLAGS}
 414         BUILD_COMMAND LDFLAGS=${GTKGLEXT_LDFLAGS}
 415         INSTALL_COMMAND $(MAKE) install
 416     )
 417
 418     include_directories("${BUILTINS_INCLUDE_DIR}/gtkglext-1.0")
 419     include_directories("${BUILTINS_LIB_DIR}/gtkglext-1.0/include")
 420
 421     add_dependencies(builtins gtkglext)
 422     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 423 endif ()
 424
 425 if (BUNDLE_LIBRARIES)
 426     # It was required to tell cmake to not patch rpath on macos builtins.
 427     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 428     # Patching rpath is done in library_bundler instead so we can skip this
 429     # step entirely when bundling.
 430     set(CMAKE_SKIP_RPATH ON)
 431 endif()
 432
 433 if (BUILTIN_GTKTHEME_MOJAVE)
 434     ExternalProject_Add(gtktheme-mojave
 435         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 436         GIT_TAG master
 437         BUILD_IN_SOURCE ON
 438         CONFIGURE_COMMAND echo
 439         BUILD_COMMAND echo
 440         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 441     )
 442     add_dependencies(builtins gtktheme-mojave)
 443     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 444 endif ()
 445
 446 #-----------------------------------------------------------------------
 447 # Libraries
 448 #-----------------------------------------------------------------------
 449
 450 if (BUILD_BINARIES)
 451     add_subdirectory(libs)
 452 endif ()
 453
 454 if (BUILD_RADIANT)
 455     add_subdirectory(include)
 456 endif ()
 457
 458 #-----------------------------------------------------------------------
 459 # Plugins
 460 #-----------------------------------------------------------------------
 461
 462 if (BUILD_RADIANT)
 463     add_subdirectory(contrib)
 464 endif ()
 465
 466 #-----------------------------------------------------------------------
 467 # Modules
 468 #-----------------------------------------------------------------------
 469
 470 if (BUILD_RADIANT)
 471     add_subdirectory(plugins)
 472 endif ()
 473
 474 #-----------------------------------------------------------------------
 475 # Radiant
 476 #-----------------------------------------------------------------------
 477
 478 if (BUILD_BINARIES)
 479     macro (radiant_tool name)
 480         add_dependencies(binaries ${name})
 481
 482         if (WIN32)
 483             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 484         else ()
 485             add_executable(${name} ${ARGN})
 486         endif()
 487
 488         copy_dlls(${name})
 489
 490         install(
 491             TARGETS ${name}
 492             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 493         )
 494     endmacro ()
 495
 496     if (BUILD_RADIANT)
 497         add_subdirectory(radiant)
 498     endif ()
 499 endif ()
 500
 501 #-----------------------------------------------------------------------
 502 # Tools
 503 #-----------------------------------------------------------------------
 504
 505 if (BUILD_TOOLS)
 506     add_subdirectory(tools)
 507
 508     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 509
 510     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 511         # Copy data files from sources to the build directory
 512         message(STATUS "Copying data files")
 513         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 514     endif ()
 515 endif ()
 516
 517 #-----------------------------------------------------------------------
 518 # Game packs
 519 #-----------------------------------------------------------------------
 520
 521 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 522 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 523
 524 if (DOWNLOAD_GAMEPACKS)
 525     add_custom_target(gamepacks ALL
 526        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 527        COMMENT "Downloading game packs"
 528     )
 529 endif ()
 530
 531 #-----------------------------------------------------------------------
 532 # Install
 533 #-----------------------------------------------------------------------
 534
 535 if (BUILD_BINARIES)
 536     install(DIRECTORY
 537         setup/data/tools/base
 538         setup/data/tools/bitmaps
 539         setup/data/tools/gl
 540         setup/data/tools/plugins
 541         docs
 542         DESTINATION ${RADIANT_DATA_DIR}
 543     )
 544
 545     install(FILES
 546         setup/data/tools/global.xlink
 547         DESTINATION ${RADIANT_DATA_DIR}
 548     )
 549 endif ()
 550
 551 if (DOWNLOAD_GAMEPACKS)
 552     install(DIRECTORY
 553         ${PROJECT_BINARY_DIR}/gamepacks
 554         DESTINATION ${RADIANT_DATA_DIR}
 555     )
 556 endif ()
 557
 558 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 559     install(FILES
 560         icons/netradiant.png
 561         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 562     )
 563     install(FILES
 564         icons/netradiant.desktop
 565         DESTINATION ${RADIANT_SHARE_DIR}/applications
 566     )
 567     install(FILES
 568         icons/x-netradiant-map.xml
 569         DESTINATION ${RADIANT_SHARE_DIR}/mime/application
 570     )
 571 endif ()
 572
 573 if (APPLE)
 574     install(DIRECTORY
 575         setup/macos/Contents
 576         DESTINATION ${APPLE_INSTALL_PREFIX}
 577     )
 578     install(DIRECTORY
 579     ${PROJECT_BINARY_DIR}/themes
 580         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 581     )
 582     install(PROGRAMS
 583         setup/macos/NetRadiant
 584         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 585     )
 586 endif ()
 587
 588 include(cmake/scripts/package.cmake)