CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_INSTALL_DIR}/lib/pkgconfig/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  57     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  58 else ()
  59     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  60 endif ()
  61
  62 #-----------------------------------------------------------------------
  63 # Build options
  64 #-----------------------------------------------------------------------
  65
  66 option(BUILD_RADIANT "Build the GUI" ON)
  67 option(BUILD_TOOLS "Build the tools" ON)
  68 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  69 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  70 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  71 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  72 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  73
  74 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  75 if (BUILD_RADIANT OR BUILD_TOOLS)
  76     set(BUILD_BINARIES ON)
  77 endif ()
  78
  79 if (BUILD_BINARIES)
  80     if (WIN32 OR APPLE
  81         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  82         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  83         set(BUNDLING_SUPPORTED ON)
  84     endif()
  85
  86     if (BUNDLING_SUPPORTED)
  87         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  88             set(BUNDLE_LIBRARIES_DEFAULT ON)
  89         else ()
  90             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  91         endif ()
  92
  93         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  94     endif ()
  95
  96     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  97         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Paths
 103 #-----------------------------------------------------------------------
 104
 105 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 107 endif ()
 108
 109 if (APPLE)
 110     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 111     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 112 else ()
 113     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 114 endif ()
 115
 116 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 117 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 118 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 119 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 120
 121 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 122 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 123 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 124 set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc CACHE INTERNAL "...")
 125 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 126 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 127
 128 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib)
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc)
 133     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 134     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 135 endif ()
 136
 137 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 138
 139 #-----------------------------------------------------------------------
 140 # Version
 141 #-----------------------------------------------------------------------
 142
 143 # CMake 3.0+ would allow this in project()
 144 set(RADIANT_VERSION_MAJOR 1)
 145 set(RADIANT_VERSION_MINOR 5)
 146 set(RADIANT_VERSION_PATCH 0)
 147 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 148
 149 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 150
 151 find_package(Git REQUIRED)
 152
 153 execute_process(
 154      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 155      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 156      OUTPUT_VARIABLE GIT_VERSION
 157      OUTPUT_STRIP_TRAILING_WHITESPACE
 158 )
 159
 160 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 161
 162 if (GIT_VERSION)
 163     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 164 endif ()
 165
 166 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 167
 168 #-----------------------------------------------------------------------
 169 # Language standard
 170 #-----------------------------------------------------------------------
 171
 172 if (BUILD_BINARIES)
 173     set(CMAKE_CXX_STANDARD 11)
 174     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 175     set(CMAKE_CXX_EXTENSIONS OFF)
 176
 177     if (CMAKE_VERSION VERSION_LESS "3.1")
 178         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 179             include(CheckCXXCompilerFlag)
 180             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 181             if (STD_CXX)
 182                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 183             else ()
 184                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 185             endif ()
 186         else ()
 187             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 188         endif ()
 189     endif ()
 190 endif ()
 191
 192 #-----------------------------------------------------------------------
 193 # Flags
 194 #-----------------------------------------------------------------------
 195
 196 if (BUILD_BINARIES)
 197     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 198
 199     macro (addflags_c args)
 200         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 201     endmacro ()
 202
 203     macro (addflags_cxx args)
 204         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 205     endmacro ()
 206
 207     macro (addflags args)
 208         addflags_c("${args}")
 209         addflags_cxx("${args}")
 210     endmacro ()
 211
 212     addflags("-fno-strict-aliasing")
 213     if (NOT WIN32)
 214         addflags("-fvisibility=hidden")
 215     endif ()
 216
 217     if (USE_WERROR)
 218         addflags("-Werror")
 219         addflags("-pedantic-errors")
 220     endif ()
 221
 222     addflags("-Wall")
 223     addflags("-Wextra")
 224     addflags("-pedantic")
 225
 226     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 227
 228     addflags("-Wno-unused-function")
 229     addflags("-Wno-unused-variable")
 230     addflags("-Wno-unused-parameter")
 231
 232     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 233 endif ()
 234
 235 if (BUILD_RADIANT)
 236     set(GTK_TARGET 2 CACHE STRING "GTK target")
 237     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 238
 239     if (WIN32)
 240         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 241
 242         if (GTK_TARGET EQUAL 2)
 243             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 244         endif ()
 245     endif ()
 246
 247     if (APPLE)
 248         if (GTK_TARGET EQUAL 2)
 249             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 250             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 251         endif ()
 252     endif ()
 253 endif ()
 254
 255 #-----------------------------------------------------------------------
 256 # Defs
 257 #-----------------------------------------------------------------------
 258
 259 if (BUILD_BINARIES)
 260     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 261     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 262
 263     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 264         add_definitions(-D_DEBUG=1)
 265     endif ()
 266 endif ()
 267
 268 if (BUILD_RADIANT)
 269     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 270
 271     macro (disable_deprecated name gtk2only)
 272         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 273         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 274             add_definitions(-D${name}_DISABLE_DEPRECATED)
 275         endif ()
 276     endmacro ()
 277
 278     disable_deprecated(ATK 0)
 279     disable_deprecated(G 0)
 280     disable_deprecated(GDK 0)
 281     disable_deprecated(GDK_PIXBUF 0)
 282     disable_deprecated(GTK 1)
 283     disable_deprecated(PANGO 0)
 284 endif ()
 285
 286 if (BUILD_BINARIES)
 287     add_custom_target(binaries ALL)
 288
 289     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 290         link_directories(
 291             /usr/local/lib
 292         )
 293     endif ()
 294
 295     if (WIN32)
 296         add_definitions(
 297             -DWIN32=1
 298             -D_WIN32=1
 299         )
 300     else ()
 301         add_definitions(
 302             -DPOSIX=1
 303         )
 304     endif ()
 305 endif ()
 306
 307 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 308     set(XWINDOWS ON)
 309     find_package(X11 REQUIRED)
 310     include_directories(${X11_INCLUDE_DIR})
 311     add_definitions(-DXWINDOWS=1)
 312 endif ()
 313
 314 if (BUILD_BINARIES)
 315     include_directories("${PROJECT_SOURCE_DIR}/include")
 316     include_directories("${PROJECT_SOURCE_DIR}/libs")
 317
 318     macro (copy_dlls target)
 319         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 320             add_custom_command(TARGET ${target} POST_BUILD
 321                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 322                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 323                 VERBATIM
 324             )
 325             add_dependencies(bundle ${target})
 326         endif ()
 327     endmacro ()
 328 endif ()
 329
 330 #-----------------------------------------------------------------------
 331 # Bundle
 332 #-----------------------------------------------------------------------
 333
 334 if (BUILD_BINARIES)
 335     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 336         add_subdirectory(bundle)
 337     endif ()
 338 endif ()
 339
 340 #-----------------------------------------------------------------------
 341 # Builtins: targets
 342 #-----------------------------------------------------------------------
 343
 344 add_custom_target(builtins)
 345
 346 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 347     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 348 endif ()
 349
 350 if (BUILTIN_GTKGLEXT)
 351     execute_process(COMMAND pkg-config --libs gdk-2.0 gtk+-2.0 glib-2.0 gl
 352         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 353         OUTPUT_STRIP_TRAILING_WHITESPACE
 354     )
 355     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 356
 357     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 358         set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} -g")
 359     else ()
 360         set(GTKGLEXT_CFLAGS "$ENV{CFLAGS}")
 361     endif()
 362
 363     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf)
 364
 365     if (APPLE)
 366         set(GTKGLEXT_GIT_TAG macos)
 367     else ()
 368         set(GTKGLEXT_GIT_TAG fixes)
 369     endif ()
 370
 371     ExternalProject_Add(gtkglext
 372         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 373         GIT_TAG ${GTKGLEXT_GIT_TAG}
 374         BUILD_IN_SOURCE ON
 375         CONFIGURE_COMMAND export LDFLAGS=${GTKGLEXT_LDFLAGS}
 376         CONFIGURE_COMMAND && NOCONFIGURE=1 ./autogen.sh
 377         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 378         BUILD_COMMAND GL_SILENCE_DEPRECATION=1
 379         BUILD_COMMAND && $(MAKE) CFLAGS=${GTKGLEXT_CFLAGS} LDFLAGS=${GTKGLEXT_LDFLAGS}
 380         INSTALL_COMMAND $(MAKE) install
 381     )
 382
 383     include_directories("${BUILTINS_INSTALL_DIR}/lib/gtkglext-1.0/include")
 384     include_directories("${BUILTINS_INSTALL_DIR}/include/gtkglext-1.0")
 385
 386     add_dependencies(builtins gtkglext)
 387     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 388 endif ()
 389
 390 if (BUNDLE_LIBRARIES)
 391     # It was required to tell cmake to not patch rpath on macos builtins.
 392     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 393     # Patching rpath is done in library_bundler instead so we can skip this
 394     # step entirely when bundling.
 395     set(CMAKE_SKIP_RPATH ON)
 396 endif()
 397
 398 if (BUILTIN_GTKTHEME_MOJAVE)
 399     ExternalProject_Add(gtktheme-mojave
 400         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 401         GIT_TAG master
 402         BUILD_IN_SOURCE ON
 403         CONFIGURE_COMMAND echo
 404         BUILD_COMMAND echo
 405         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 406     )
 407     add_dependencies(builtins gtktheme-mojave)
 408     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 409 endif ()
 410
 411 #-----------------------------------------------------------------------
 412 # Libraries
 413 #-----------------------------------------------------------------------
 414
 415 if (BUILD_BINARIES)
 416     add_subdirectory(libs)
 417 endif ()
 418
 419 if (BUILD_RADIANT)
 420     add_subdirectory(include)
 421 endif ()
 422
 423 #-----------------------------------------------------------------------
 424 # Plugins
 425 #-----------------------------------------------------------------------
 426
 427 if (BUILD_RADIANT)
 428     add_subdirectory(contrib)
 429 endif ()
 430
 431 #-----------------------------------------------------------------------
 432 # Modules
 433 #-----------------------------------------------------------------------
 434
 435 if (BUILD_RADIANT)
 436     add_subdirectory(plugins)
 437 endif ()
 438
 439 #-----------------------------------------------------------------------
 440 # Radiant
 441 #-----------------------------------------------------------------------
 442
 443 if (BUILD_BINARIES)
 444     macro (radiant_tool name)
 445         add_dependencies(binaries ${name})
 446
 447         if (WIN32)
 448             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 449         else ()
 450             add_executable(${name} ${ARGN})
 451         endif()
 452
 453         copy_dlls(${name})
 454
 455         install(
 456             TARGETS ${name}
 457             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 458         )
 459     endmacro ()
 460
 461     if (BUILD_RADIANT)
 462         add_subdirectory(radiant)
 463     endif ()
 464 endif ()
 465
 466 #-----------------------------------------------------------------------
 467 # Tools
 468 #-----------------------------------------------------------------------
 469
 470 if (BUILD_TOOLS)
 471     add_subdirectory(tools)
 472
 473     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 474
 475     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 476         # Copy data files from sources to the build directory
 477         message(STATUS "Copying data files")
 478         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 479     endif ()
 480 endif ()
 481
 482 #-----------------------------------------------------------------------
 483 # Game packs
 484 #-----------------------------------------------------------------------
 485
 486 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 487 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 488
 489 if (DOWNLOAD_GAMEPACKS)
 490     add_custom_target(gamepacks ALL
 491        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 492        COMMENT "Downloading game packs"
 493     )
 494 endif ()
 495
 496 #-----------------------------------------------------------------------
 497 # Install
 498 #-----------------------------------------------------------------------
 499
 500 if (BUILD_BINARIES)
 501     install(DIRECTORY
 502         setup/data/tools/base
 503         setup/data/tools/bitmaps
 504         setup/data/tools/gl
 505         setup/data/tools/plugins
 506         docs
 507         DESTINATION ${RADIANT_DATA_DIR}
 508     )
 509
 510     install(FILES
 511         setup/data/tools/global.xlink
 512         DESTINATION ${RADIANT_DATA_DIR}
 513     )
 514 endif ()
 515
 516 if (DOWNLOAD_GAMEPACKS)
 517     install(DIRECTORY
 518         ${PROJECT_BINARY_DIR}/gamepacks
 519         DESTINATION ${RADIANT_DATA_DIR}
 520     )
 521 endif ()
 522
 523 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 524     install(FILES
 525         icons/netradiant.png
 526         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 527     )
 528     install(FILES
 529         icons/netradiant.desktop
 530         DESTINATION ${RADIANT_SHARE_DIR}/applications
 531     )
 532     install(FILES
 533         icons/mime/map.xml
 534         DESTINATION ${RADIANT_SHARE_DIR}/mime/model
 535     )
 536 endif ()
 537
 538 if (APPLE)
 539     install(DIRECTORY
 540         setup/macos/Contents
 541         DESTINATION ${APPLE_INSTALL_PREFIX}
 542     )
 543     install(DIRECTORY
 544     ${PROJECT_BINARY_DIR}/themes
 545         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 546     )
 547     install(PROGRAMS
 548         setup/macos/NetRadiant
 549         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 550     )
 551 endif ()
 552
 553 include(cmake/scripts/package.cmake)