CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  57     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  58 else ()
  59     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  60 endif ()
  61
  62 #-----------------------------------------------------------------------
  63 # Build options
  64 #-----------------------------------------------------------------------
  65
  66 option(BUILD_RADIANT "Build the GUI" ON)
  67 option(BUILD_TOOLS "Build the tools" ON)
  68 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  69 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  70 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  71 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  72 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  73
  74 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  75 if (BUILD_RADIANT OR BUILD_TOOLS)
  76     set(BUILD_BINARIES ON)
  77 endif ()
  78
  79 if (BUILD_BINARIES)
  80     if (WIN32 OR APPLE
  81         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  82         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  83         set(BUNDLING_SUPPORTED ON)
  84     endif()
  85
  86     if (BUNDLING_SUPPORTED)
  87         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  88             set(BUNDLE_LIBRARIES_DEFAULT ON)
  89         else ()
  90             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  91         endif ()
  92
  93         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  94     endif ()
  95
  96     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  97         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Paths
 103 #-----------------------------------------------------------------------
 104
 105 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 107 endif ()
 108
 109 if (APPLE)
 110     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 111     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 112 else ()
 113     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 114 endif ()
 115
 116 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 117 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 118 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 119 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 120
 121 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 122 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 123 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 124 set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc CACHE INTERNAL "...")
 125 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 126 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 127
 128 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib)
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc)
 133     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 134     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 135 endif ()
 136
 137 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 138
 139 #-----------------------------------------------------------------------
 140 # Version
 141 #-----------------------------------------------------------------------
 142
 143 # CMake 3.0+ would allow this in project()
 144 set(RADIANT_VERSION_MAJOR 1)
 145 set(RADIANT_VERSION_MINOR 5)
 146 set(RADIANT_VERSION_PATCH 0)
 147 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 148
 149 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 150
 151 find_package(Git REQUIRED)
 152
 153 execute_process(
 154      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 155      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 156      OUTPUT_VARIABLE GIT_VERSION
 157      OUTPUT_STRIP_TRAILING_WHITESPACE
 158 )
 159
 160 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 161
 162 if (GIT_VERSION)
 163     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 164 endif ()
 165
 166 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 167
 168 #-----------------------------------------------------------------------
 169 # Language standard
 170 #-----------------------------------------------------------------------
 171
 172 if (BUILD_BINARIES)
 173     set(CMAKE_CXX_STANDARD 11)
 174     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 175     set(CMAKE_CXX_EXTENSIONS OFF)
 176
 177     if (CMAKE_VERSION VERSION_LESS "3.1")
 178         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 179             include(CheckCXXCompilerFlag)
 180             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 181             if (STD_CXX)
 182                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 183             else ()
 184                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 185             endif ()
 186         else ()
 187             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 188         endif ()
 189     endif ()
 190 endif ()
 191
 192 #-----------------------------------------------------------------------
 193 # Flags
 194 #-----------------------------------------------------------------------
 195
 196 if (BUILD_BINARIES)
 197     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 198
 199     macro (addflags_c args)
 200         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 201     endmacro ()
 202
 203     macro (addflags_cxx args)
 204         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 205     endmacro ()
 206
 207     macro (addflags args)
 208         addflags_c("${args}")
 209         addflags_cxx("${args}")
 210     endmacro ()
 211
 212     addflags("-fno-strict-aliasing")
 213     if (NOT WIN32)
 214         addflags("-fvisibility=hidden")
 215     endif ()
 216
 217     if (USE_WERROR)
 218         addflags("-Werror")
 219         addflags("-pedantic-errors")
 220     endif ()
 221
 222     addflags("-Wall")
 223     addflags("-Wextra")
 224     addflags("-pedantic")
 225
 226     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 227
 228     addflags("-Wno-unused-function")
 229     addflags("-Wno-unused-variable")
 230     addflags("-Wno-unused-parameter")
 231
 232     if (APPLE)
 233         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 234     endif ()
 235
 236     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 237 endif ()
 238
 239 if (BUILD_RADIANT)
 240     set(GTK_TARGET 2 CACHE STRING "GTK target")
 241     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 242
 243     if (WIN32)
 244         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 245
 246         if (GTK_TARGET EQUAL 2)
 247             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 248         endif ()
 249     endif ()
 250
 251     if (APPLE)
 252         set(UNSUPPORTED_GL_SHARED_CONTEXT ON CACHE INTERNAL "...")
 253
 254         if (GTK_TARGET EQUAL 2)
 255             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 256             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 257             add_definitions(-DWORKAROUND_MACOS_GTK2_LAGGYPOINTER=1)
 258         endif ()
 259     endif ()
 260
 261         if (UNSUPPORTED_GL_SHARED_CONTEXT)
 262                 set(DEFAULT_GL_SHARED_CONTEXT ON)
 263         else ()
 264                 set(DEFAULT_GL_SHARED_CONTEXT OFF)
 265         endif ()
 266
 267     option(USE_GL_UNSHARED_CONTEXT "Do not share GL Contexts" ${DEFAULT_GL_SHARED_CONTEXT})
 268
 269     if (USE_GL_UNSHARED_CONTEXT)
 270         add_definitions(-DGL_UNSHARED_CONTEXT=1)
 271     endif ()
 272 endif ()
 273
 274 #-----------------------------------------------------------------------
 275 # Defs
 276 #-----------------------------------------------------------------------
 277
 278 if (BUILD_BINARIES)
 279     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 280     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 281
 282     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 283         add_definitions(-D_DEBUG=1)
 284     endif ()
 285 endif ()
 286
 287 if (BUILD_RADIANT)
 288     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 289
 290     macro (disable_deprecated name gtk2only)
 291         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 292         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 293             add_definitions(-D${name}_DISABLE_DEPRECATED)
 294         endif ()
 295     endmacro ()
 296
 297     disable_deprecated(ATK 0)
 298     disable_deprecated(G 0)
 299     disable_deprecated(GDK 0)
 300     disable_deprecated(GDK_PIXBUF 0)
 301     disable_deprecated(GTK 1)
 302     disable_deprecated(PANGO 0)
 303 endif ()
 304
 305 if (BUILD_BINARIES)
 306     add_custom_target(binaries ALL)
 307
 308     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 309         link_directories(
 310             /usr/local/lib
 311         )
 312     endif ()
 313
 314     if (WIN32)
 315         add_definitions(
 316             -DWIN32=1
 317             -D_WIN32=1
 318         )
 319     else ()
 320         add_definitions(
 321             -DPOSIX=1
 322         )
 323     endif ()
 324 endif ()
 325
 326 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 327     set(XWINDOWS ON)
 328     find_package(X11 REQUIRED)
 329     include_directories(${X11_INCLUDE_DIR})
 330     add_definitions(-DXWINDOWS=1)
 331 endif ()
 332
 333 if (BUILD_BINARIES)
 334     include_directories("${PROJECT_SOURCE_DIR}/include")
 335     include_directories("${PROJECT_SOURCE_DIR}/libs")
 336
 337     macro (copy_dlls target)
 338         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 339             add_custom_command(TARGET ${target} POST_BUILD
 340                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 341                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 342                 VERBATIM
 343             )
 344             add_dependencies(bundle ${target})
 345         endif ()
 346     endmacro ()
 347 endif ()
 348
 349 #-----------------------------------------------------------------------
 350 # Bundle
 351 #-----------------------------------------------------------------------
 352
 353 if (BUILD_BINARIES)
 354     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 355         add_subdirectory(bundle)
 356     endif ()
 357 endif ()
 358
 359 #-----------------------------------------------------------------------
 360 # Builtins: targets
 361 #-----------------------------------------------------------------------
 362
 363 add_custom_target(builtins)
 364
 365 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 366     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 367 endif ()
 368
 369 if (BUILTIN_GTKGLEXT)
 370     set(GTKGLEXT_PKGNAMES "gdk-2.0 gtk+-2.0 glib-2.0")
 371
 372     if (NOT APPLE)
 373         set(GTKGLEXT_PKGNAMES "${GTKGLEXT_PKGNAMES} gl")
 374     endif ()
 375
 376     execute_process(COMMAND pkg-config --libs ${GTKGLEXT_PKGNAMES}
 377         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 378         OUTPUT_STRIP_TRAILING_WHITESPACE
 379     )
 380
 381     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 382
 383     execute_process(COMMAND pkg-config --cflags ${GTKGLEXT_PKGNAMES}
 384         OUTPUT_VARIABLE GTKGLEXT_CFLAGS
 385         OUTPUT_STRIP_TRAILING_WHITESPACE
 386     )
 387
 388     set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} ${GTKGLEXT_CFLAGS}")
 389
 390     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 391         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -g")
 392     endif ()
 393
 394     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf)
 395
 396     if (APPLE)
 397         set(GTKGLEXT_GIT_TAG macos)
 398     else ()
 399         set(GTKGLEXT_GIT_TAG fixes)
 400     endif ()
 401
 402     if (APPLE)
 403         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1")
 404         # FIXME: OpenGL deprecation warnings are not silenced
 405         # in Objective C code.
 406     endif ()
 407
 408     ExternalProject_Add(gtkglext
 409         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 410         GIT_TAG ${GTKGLEXT_GIT_TAG}
 411         BUILD_IN_SOURCE ON
 412         CONFIGURE_COMMAND export CFLAGS=${GTKGLEXT_LDFLAGS}
 413         CONFIGURE_COMMAND && export LDFLAGS=${GTKGLEXT_CFLAGS}
 414         CONFIGURE_COMMAND && export NOCONFIGURE=1
 415         CONFIGURE_COMMAND && ./autogen.sh
 416         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 417         BUILD_COMMAND $(MAKE)
 418         BUILD_COMMAND CFLAGS=${GTKGLEXT_CFLAGS}
 419         BUILD_COMMAND LDFLAGS=${GTKGLEXT_LDFLAGS}
 420         INSTALL_COMMAND $(MAKE) install
 421     )
 422
 423     include_directories("${BUILTINS_INCLUDE_DIR}/gtkglext-1.0")
 424     include_directories("${BUILTINS_LIB_DIR}/gtkglext-1.0/include")
 425
 426     add_dependencies(builtins gtkglext)
 427     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 428 endif ()
 429
 430 if (BUNDLE_LIBRARIES)
 431     # It was required to tell cmake to not patch rpath on macos builtins.
 432     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 433     # Patching rpath is done in library_bundler instead so we can skip this
 434     # step entirely when bundling.
 435     set(CMAKE_SKIP_RPATH ON)
 436 endif()
 437
 438 if (BUILTIN_GTKTHEME_MOJAVE)
 439     ExternalProject_Add(gtktheme-mojave
 440         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 441         GIT_TAG master
 442         BUILD_IN_SOURCE ON
 443         CONFIGURE_COMMAND echo
 444         BUILD_COMMAND echo
 445         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 446     )
 447     add_dependencies(builtins gtktheme-mojave)
 448     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 449 endif ()
 450
 451 #-----------------------------------------------------------------------
 452 # Libraries
 453 #-----------------------------------------------------------------------
 454
 455 if (BUILD_BINARIES)
 456     add_subdirectory(libs)
 457 endif ()
 458
 459 if (BUILD_RADIANT)
 460     add_subdirectory(include)
 461 endif ()
 462
 463 #-----------------------------------------------------------------------
 464 # Plugins
 465 #-----------------------------------------------------------------------
 466
 467 if (BUILD_RADIANT)
 468     add_subdirectory(contrib)
 469 endif ()
 470
 471 #-----------------------------------------------------------------------
 472 # Modules
 473 #-----------------------------------------------------------------------
 474
 475 if (BUILD_RADIANT)
 476     add_subdirectory(plugins)
 477 endif ()
 478
 479 #-----------------------------------------------------------------------
 480 # Radiant
 481 #-----------------------------------------------------------------------
 482
 483 if (BUILD_BINARIES)
 484     macro (radiant_tool name)
 485         add_dependencies(binaries ${name})
 486
 487         if (WIN32)
 488             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 489         else ()
 490             add_executable(${name} ${ARGN})
 491         endif()
 492
 493         copy_dlls(${name})
 494
 495         install(
 496             TARGETS ${name}
 497             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 498         )
 499     endmacro ()
 500
 501     if (BUILD_RADIANT)
 502         add_subdirectory(radiant)
 503     endif ()
 504 endif ()
 505
 506 #-----------------------------------------------------------------------
 507 # Tools
 508 #-----------------------------------------------------------------------
 509
 510 if (BUILD_TOOLS)
 511     add_subdirectory(tools)
 512
 513     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 514
 515     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 516         # Copy data files from sources to the build directory
 517         message(STATUS "Copying data files")
 518         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 519     endif ()
 520 endif ()
 521
 522 #-----------------------------------------------------------------------
 523 # Game packs
 524 #-----------------------------------------------------------------------
 525
 526 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 527 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 528
 529 if (DOWNLOAD_GAMEPACKS)
 530     add_custom_target(gamepacks ALL
 531        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 532        COMMENT "Downloading game packs"
 533     )
 534 endif ()
 535
 536 #-----------------------------------------------------------------------
 537 # Install
 538 #-----------------------------------------------------------------------
 539
 540 if (BUILD_BINARIES)
 541     install(DIRECTORY
 542         setup/data/tools/base
 543         setup/data/tools/bitmaps
 544         setup/data/tools/gl
 545         setup/data/tools/plugins
 546         docs
 547         DESTINATION ${RADIANT_DATA_DIR}
 548     )
 549
 550     install(FILES
 551         setup/data/tools/global.xlink
 552         DESTINATION ${RADIANT_DATA_DIR}
 553     )
 554 endif ()
 555
 556 if (DOWNLOAD_GAMEPACKS)
 557     install(DIRECTORY
 558         ${PROJECT_BINARY_DIR}/gamepacks
 559         DESTINATION ${RADIANT_DATA_DIR}
 560     )
 561 endif ()
 562
 563 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 564     install(FILES
 565         icons/netradiant.png
 566         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 567     )
 568     install(FILES
 569         icons/netradiant.desktop
 570         DESTINATION ${RADIANT_SHARE_DIR}/applications
 571     )
 572     install(FILES
 573         icons/mime/map.xml
 574         DESTINATION ${RADIANT_SHARE_DIR}/mime/model
 575     )
 576 endif ()
 577
 578 if (APPLE)
 579     install(DIRECTORY
 580         setup/macos/Contents
 581         DESTINATION ${APPLE_INSTALL_PREFIX}
 582     )
 583     install(DIRECTORY
 584     ${PROJECT_BINARY_DIR}/themes
 585         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 586     )
 587     install(PROGRAMS
 588         setup/macos/NetRadiant
 589         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 590     )
 591 endif ()
 592
 593 include(cmake/scripts/package.cmake)