CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  57     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  58 else ()
  59     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  60 endif ()
  61
  62 #-----------------------------------------------------------------------
  63 # Build options
  64 #-----------------------------------------------------------------------
  65
  66 option(BUILD_RADIANT "Build the GUI" ON)
  67 option(BUILD_TOOLS "Build the tools" ON)
  68 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  69 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  70 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  71 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  72 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  73
  74 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  75 if (BUILD_RADIANT OR BUILD_TOOLS)
  76     set(BUILD_BINARIES ON)
  77 endif ()
  78
  79 if (BUILD_BINARIES)
  80     if (WIN32 OR APPLE
  81         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  82         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  83         set(BUNDLING_SUPPORTED ON)
  84     endif()
  85
  86     if (BUNDLING_SUPPORTED)
  87         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  88             set(BUNDLE_LIBRARIES_DEFAULT ON)
  89         else ()
  90             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  91         endif ()
  92
  93         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  94     endif ()
  95
  96     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  97         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Paths
 103 #-----------------------------------------------------------------------
 104
 105 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 107 endif ()
 108
 109 if (APPLE)
 110     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 111     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 112 else ()
 113     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 114 endif ()
 115
 116 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 117 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 118 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 119 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 120
 121 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 122 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE} CACHE INTERNAL "...")
 123 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 124 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 125 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 126
 127 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 128     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 129     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE})
 130     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 131     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 132     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 133 endif ()
 134
 135 add_definitions(-DRADIANT_ADDONS_DIR="${RADIANT_ADDONS_DIR}")
 136 add_definitions(-DRADIANT_DATA_DIR="${RADIANT_DATA_DIR}")
 137
 138 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 139
 140 #-----------------------------------------------------------------------
 141 # Version
 142 #-----------------------------------------------------------------------
 143
 144 # CMake 3.0+ would allow this in project()
 145 set(RADIANT_VERSION_MAJOR 1)
 146 set(RADIANT_VERSION_MINOR 5)
 147 set(RADIANT_VERSION_PATCH 0)
 148 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 149
 150 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 151
 152 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 153
 154 if (NOT DEFINED GIT_VERSION)
 155      find_package(Git REQUIRED)
 156
 157      execute_process(
 158           COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 159           WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 160           OUTPUT_VARIABLE GIT_VERSION
 161           OUTPUT_STRIP_TRAILING_WHITESPACE
 162      )
 163
 164      if (GIT_VERSION)
 165          set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 166      endif ()
 167 endif ()
 168
 169 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 170
 171 #-----------------------------------------------------------------------
 172 # Language standard
 173 #-----------------------------------------------------------------------
 174
 175 if (BUILD_BINARIES)
 176     set(CMAKE_CXX_STANDARD 11)
 177     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 178     set(CMAKE_CXX_EXTENSIONS OFF)
 179
 180     if (CMAKE_VERSION VERSION_LESS "3.1")
 181         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 182             include(CheckCXXCompilerFlag)
 183             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 184             if (STD_CXX)
 185                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 186             else ()
 187                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 188             endif ()
 189         else ()
 190             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 191         endif ()
 192     endif ()
 193 endif ()
 194
 195 #-----------------------------------------------------------------------
 196 # Flags
 197 #-----------------------------------------------------------------------
 198
 199 if (BUILD_BINARIES)
 200     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 201
 202     macro (addflags_c args)
 203         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 204     endmacro ()
 205
 206     macro (addflags_cxx args)
 207         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 208     endmacro ()
 209
 210     macro (addflags args)
 211         addflags_c("${args}")
 212         addflags_cxx("${args}")
 213     endmacro ()
 214
 215     addflags("-fno-strict-aliasing")
 216     if (NOT WIN32)
 217         addflags("-fvisibility=hidden")
 218     endif ()
 219
 220     if (USE_WERROR)
 221         addflags("-Werror")
 222         addflags("-pedantic-errors")
 223     endif ()
 224
 225     addflags("-Wall")
 226     addflags("-Wextra")
 227     addflags("-pedantic")
 228
 229     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 230
 231     addflags("-Wno-unused-function")
 232     addflags("-Wno-unused-variable")
 233     addflags("-Wno-unused-parameter")
 234
 235     if (APPLE)
 236         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 237     endif()
 238
 239     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 240 endif ()
 241
 242 if (BUILD_RADIANT)
 243     set(GTK_TARGET 2 CACHE STRING "GTK target")
 244     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 245
 246     if (WIN32)
 247         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 248
 249         if (GTK_TARGET EQUAL 2)
 250             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 251         endif ()
 252     endif ()
 253
 254     if (APPLE)
 255         if (GTK_TARGET EQUAL 2)
 256             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 257             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 258             add_definitions(-DWORKAROUND_MACOS_GTK2_LAGGYPOINTER=1)
 259         endif ()
 260     endif ()
 261 endif ()
 262
 263 #-----------------------------------------------------------------------
 264 # Defs
 265 #-----------------------------------------------------------------------
 266
 267 if (BUILD_BINARIES)
 268     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 269     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 270
 271     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 272         add_definitions(-D_DEBUG=1)
 273     endif ()
 274 endif ()
 275
 276 if (BUILD_RADIANT)
 277     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 278
 279     macro (disable_deprecated name gtk2only)
 280         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 281         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 282             add_definitions(-D${name}_DISABLE_DEPRECATED)
 283         endif ()
 284     endmacro ()
 285
 286     disable_deprecated(ATK 0)
 287     disable_deprecated(G 0)
 288     disable_deprecated(GDK 0)
 289     disable_deprecated(GDK_PIXBUF 0)
 290     disable_deprecated(GTK 1)
 291     disable_deprecated(PANGO 0)
 292 endif ()
 293
 294 if (BUILD_BINARIES)
 295     add_custom_target(binaries ALL)
 296
 297     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 298         link_directories(
 299             /usr/local/lib
 300         )
 301     endif ()
 302
 303     if (WIN32)
 304         add_definitions(
 305             -DWIN32=1
 306             -D_WIN32=1
 307         )
 308     else ()
 309         add_definitions(
 310             -DPOSIX=1
 311         )
 312     endif ()
 313 endif ()
 314
 315 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 316     set(XWINDOWS ON)
 317     find_package(X11 REQUIRED)
 318     include_directories(${X11_INCLUDE_DIR})
 319     add_definitions(-DXWINDOWS=1)
 320 endif ()
 321
 322 if (BUILD_BINARIES)
 323     include_directories("${PROJECT_SOURCE_DIR}/include")
 324     include_directories("${PROJECT_SOURCE_DIR}/libs")
 325
 326     macro (copy_dlls target)
 327         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 328             add_custom_command(TARGET ${target} POST_BUILD
 329                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 330                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 331                 VERBATIM
 332             )
 333             add_dependencies(bundle ${target})
 334         endif ()
 335     endmacro ()
 336 endif ()
 337
 338 #-----------------------------------------------------------------------
 339 # Bundle
 340 #-----------------------------------------------------------------------
 341
 342 if (BUILD_BINARIES)
 343     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 344         add_subdirectory(bundle)
 345     endif ()
 346 endif ()
 347
 348 #-----------------------------------------------------------------------
 349 # Builtins: targets
 350 #-----------------------------------------------------------------------
 351
 352 add_custom_target(builtins)
 353
 354 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 355     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 356 endif ()
 357
 358 if (BUILTIN_GTKGLEXT)
 359     set(GTKGLEXT_PKGNAMES "gdk-2.0 gtk+-2.0 glib-2.0")
 360
 361     if (NOT APPLE)
 362         set(GTKGLEXT_PKGNAMES "${GTKGLEXT_PKGNAMES} gl")
 363     endif ()
 364
 365     execute_process(COMMAND pkg-config --libs ${GTKGLEXT_PKGNAMES}
 366         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 367         OUTPUT_STRIP_TRAILING_WHITESPACE
 368     )
 369
 370     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 371
 372     execute_process(COMMAND pkg-config --cflags ${GTKGLEXT_PKGNAMES}
 373         OUTPUT_VARIABLE GTKGLEXT_CFLAGS
 374         OUTPUT_STRIP_TRAILING_WHITESPACE
 375     )
 376
 377     set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} ${GTKGLEXT_CFLAGS}")
 378
 379
 380     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf --disable-dependency-tracking --without-x)
 381
 382     if (CMAKE_BUILD_TYPE MATCHES Release)
 383         set(CONFIGURE_OPTIONS ${CONFIGURE_OPTIONS} --disable-debug)
 384     endif ()
 385
 386     if (APPLE)
 387         set(GTKGLEXT_GIT_TAG macos)
 388     else ()
 389         set(GTKGLEXT_GIT_TAG fixes)
 390     endif ()
 391
 392     if (APPLE)
 393         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1 -Wno-deprecated-declarations")
 394     endif ()
 395
 396     ExternalProject_Add(gtkglext
 397         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 398         GIT_TAG ${GTKGLEXT_GIT_TAG}
 399         BUILD_IN_SOURCE ON
 400         CONFIGURE_COMMAND export CCFLAGS=${GTKGLEXT_CFLAGS}
 401         CONFIGURE_COMMAND && export LDFLAGS=${GTKGLEXT_LDFLAGS}
 402         CONFIGURE_COMMAND && export NOCONFIGURE=1
 403         CONFIGURE_COMMAND && ./autogen.sh
 404         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 405         BUILD_COMMAND $(MAKE)
 406         BUILD_COMMAND CFLAGS=${GTKGLEXT_CFLAGS}
 407         BUILD_COMMAND LDFLAGS=${GTKGLEXT_LDFLAGS}
 408         INSTALL_COMMAND $(MAKE) install
 409     )
 410
 411     include_directories("${BUILTINS_INCLUDE_DIR}/gtkglext-1.0")
 412     include_directories("${BUILTINS_LIB_DIR}/gtkglext-1.0/include")
 413
 414     add_dependencies(builtins gtkglext)
 415     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 416 endif ()
 417
 418 if (BUNDLE_LIBRARIES)
 419     # It was required to tell cmake to not patch rpath on macos builtins.
 420     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 421     # Patching rpath is done in library_bundler instead so we can skip this
 422     # step entirely when bundling.
 423     set(CMAKE_SKIP_RPATH ON)
 424 endif()
 425
 426 if (BUILTIN_GTKTHEME_MOJAVE)
 427     ExternalProject_Add(gtktheme-mojave
 428         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 429         GIT_TAG master
 430         BUILD_IN_SOURCE ON
 431         CONFIGURE_COMMAND echo
 432         BUILD_COMMAND echo
 433         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 434     )
 435     add_dependencies(builtins gtktheme-mojave)
 436     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 437 endif ()
 438
 439 #-----------------------------------------------------------------------
 440 # Libraries
 441 #-----------------------------------------------------------------------
 442
 443 if (BUILD_BINARIES)
 444     add_subdirectory(libs)
 445 endif ()
 446
 447 if (BUILD_RADIANT)
 448     add_subdirectory(include)
 449 endif ()
 450
 451 #-----------------------------------------------------------------------
 452 # Plugins
 453 #-----------------------------------------------------------------------
 454
 455 if (BUILD_RADIANT)
 456     add_subdirectory(contrib)
 457 endif ()
 458
 459 #-----------------------------------------------------------------------
 460 # Modules
 461 #-----------------------------------------------------------------------
 462
 463 if (BUILD_RADIANT)
 464     add_subdirectory(plugins)
 465 endif ()
 466
 467 #-----------------------------------------------------------------------
 468 # Radiant
 469 #-----------------------------------------------------------------------
 470
 471 if (BUILD_BINARIES)
 472     macro (radiant_tool name)
 473         add_dependencies(binaries ${name})
 474
 475         if (WIN32)
 476             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 477         else ()
 478             add_executable(${name} ${ARGN})
 479         endif()
 480
 481         copy_dlls(${name})
 482
 483         install(
 484             TARGETS ${name}
 485             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 486         )
 487     endmacro ()
 488
 489     if (BUILD_RADIANT)
 490         add_subdirectory(radiant)
 491     endif ()
 492 endif ()
 493
 494 #-----------------------------------------------------------------------
 495 # Tools
 496 #-----------------------------------------------------------------------
 497
 498 if (BUILD_TOOLS)
 499     add_subdirectory(tools)
 500
 501     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 502
 503     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 504         # Copy data files from sources to the build directory
 505         message(STATUS "Copying data files")
 506         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 507     endif ()
 508 endif ()
 509
 510 #-----------------------------------------------------------------------
 511 # Game packs
 512 #-----------------------------------------------------------------------
 513
 514 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 515 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 516
 517 if (DOWNLOAD_GAMEPACKS)
 518     add_custom_target(gamepacks ALL
 519        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 520        COMMENT "Downloading game packs"
 521     )
 522 endif ()
 523
 524 #-----------------------------------------------------------------------
 525 # Install
 526 #-----------------------------------------------------------------------
 527
 528 if (BUILD_BINARIES)
 529     install(DIRECTORY
 530         setup/data/tools/base
 531         setup/data/tools/bitmaps
 532         setup/data/tools/gl
 533         setup/data/tools/plugins
 534         docs
 535         DESTINATION ${RADIANT_DATA_DIR}
 536     )
 537
 538     install(FILES
 539         setup/data/tools/global.xlink
 540         DESTINATION ${RADIANT_DATA_DIR}
 541     )
 542 endif ()
 543
 544 if (DOWNLOAD_GAMEPACKS)
 545     install(DIRECTORY
 546         ${PROJECT_BINARY_DIR}/gamepacks
 547         DESTINATION ${RADIANT_DATA_DIR}
 548     )
 549 endif ()
 550
 551 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 552     install(FILES
 553         icons/netradiant.png
 554         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 555     )
 556     install(FILES
 557         icons/netradiant.desktop
 558         DESTINATION ${RADIANT_SHARE_DIR}/applications
 559     )
 560     install(FILES
 561         icons/x-netradiant-map.xml
 562         DESTINATION ${RADIANT_SHARE_DIR}/mime/application
 563     )
 564 endif ()
 565
 566 if (APPLE)
 567     install(DIRECTORY
 568         setup/macos/Contents
 569         DESTINATION ${APPLE_INSTALL_PREFIX}
 570     )
 571     install(DIRECTORY
 572     ${PROJECT_BINARY_DIR}/themes
 573         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 574     )
 575     install(PROGRAMS
 576         setup/macos/NetRadiant
 577         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 578     )
 579 endif ()
 580
 581 include(cmake/scripts/package.cmake)