qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         gametype = 0;
  91
  92         // hud_fields uses strunzone on the titles!
  93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  94                 hud_title[i] = strzone("(null)");
  95
  96         postinit = false;
  97
  98         calledhooks = 0;
  99
 100         teams = Sort_Spawn();
 101         players = Sort_Spawn();
 102
 103         GetTeam(NUM_SPECTATOR, true); // add specs first
 104
 105         // needs to be done so early because of the constants they create
 106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 107         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 108         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 109         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 110         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 111
 112         WaypointSprite_Load();
 113
 114         // precaches
 115         precache_model("null");
 116         precache_sound("misc/hit.wav");
 117         precache_sound("misc/typehit.wav");
 118
 119         Projectile_Precache();
 120         Hook_Precache();
 121         GibSplash_Precache();
 122         Casings_Precache();
 123         DamageInfo_Precache();
 124         Vehicles_Precache();
 125         turrets_precache();
 126         Tuba_Precache();
 127         CSQCPlayer_Precache();
 128
 129         if(autocvar_cl_reticle)
 130         {
 131                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 132                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 133         }
 134
 135         get_mi_min_max_texcoords(1); // try the CLEVER way first
 136         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 137         shortmapname = mi_shortname;
 138
 139         if(precache_pic(minimapname) == "")
 140         {
 141                 // but maybe we have a non-clever minimap
 142                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 143                 if(precache_pic(minimapname) == "")
 144                         minimapname = ""; // FAIL
 145                 else
 146                         get_mi_min_max_texcoords(0); // load new texcoords
 147         }
 148
 149         mi_center = (mi_min + mi_max) * 0.5;
 150         mi_scale = mi_max - mi_min;
 151         minimapname = strzone(minimapname);
 152
 153         WarpZone_Init();
 154
 155         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 156         hud_configure_prev = -1;
 157
 158         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 159
 160
 161         //// WIP - zykure
 162
 163         PlayerInfo_Init();
 164         PlayerInfo_Retrieve(self.owner);
 165 }
 166
 167 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 168 void Shutdown(void)
 169 {
 170 #ifdef USE_FTE
 171 #pragma TARGET id
 172         if(!__engine_check)
 173                 return 0;
 174 #pragma TARGET fte
 175 #endif
 176
 177         WarpZone_Shutdown();
 178
 179         remove(teams);
 180         remove(players);
 181         db_close(binddb);
 182         db_close(tempdb);
 183         if(autocvar_cl_db_saveasdump)
 184                 db_dump(ClientProgsDB, "client.db");
 185         else
 186                 db_save(ClientProgsDB, "client.db");
 187         db_close(ClientProgsDB);
 188
 189         if(camera_active)
 190                 cvar_set("chase_active",ftos(chase_active_backup));
 191
 192         // unset the event chasecam's chase_active
 193         if(autocvar_chase_active < 0)
 194                 cvar_set("chase_active", "0");
 195
 196         if not(isdemo())
 197         {
 198                 if not(calledhooks & HOOK_START)
 199                         localcmd("\n_cl_hook_gamestart nop\n");
 200                 if not(calledhooks & HOOK_END)
 201                         localcmd("\ncl_hook_gameend\n");
 202         }
 203 }
 204
 205 .float has_team;
 206 float SetTeam(entity o, float Team)
 207 {
 208         entity tm;
 209         if(teamplay)
 210         {
 211                 switch(Team)
 212                 {
 213                         case -1:
 214                         case NUM_TEAM_1:
 215                         case NUM_TEAM_2:
 216                         case NUM_TEAM_3:
 217                         case NUM_TEAM_4:
 218                                 break;
 219                         default:
 220                                 if(GetTeam(Team, false) == world)
 221                                 {
 222                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 223                                         Team = NUM_SPECTATOR;
 224                                 }
 225                                 break;
 226                 }
 227         }
 228         else
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case 0:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         if(Team == -1) // leave
 245         {
 246                 if(o.has_team)
 247                 {
 248                         tm = GetTeam(o.team, false);
 249                         tm.team_size -= 1;
 250                         o.has_team = 0;
 251                         return TRUE;
 252                 }
 253         }
 254         else
 255         {
 256                 if not(o.has_team)
 257                 {
 258                         o.team = Team;
 259                         tm = GetTeam(Team, true);
 260                         tm.team_size += 1;
 261                         o.has_team = 1;
 262                         return TRUE;
 263                 }
 264                 else if(Team != o.team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         return TRUE;
 272                 }
 273         }
 274         return FALSE;
 275 }
 276
 277 void Playerchecker_Think()
 278 {
 279         float i;
 280         entity e;
 281         for(i = 0; i < maxclients; ++i)
 282         {
 283                 e = playerslots[i];
 284                 if(GetPlayerName(i) == "")
 285                 {
 286                         if(e.sort_prev)
 287                         {
 288                                 // player disconnected
 289                                 SetTeam(e, -1);
 290                                 RemovePlayer(e);
 291                                 e.sort_prev = world;
 292                                 //e.gotscores = 0;
 293                         }
 294                 }
 295                 else
 296                 {
 297                         if not(e.sort_prev)
 298                         {
 299                                 // player connected
 300                                 if not(e)
 301                                         playerslots[i] = e = spawn();
 302                                 e.sv_entnum = i;
 303                                 e.ping = 0;
 304                                 e.ping_packetloss = 0;
 305                                 e.ping_movementloss = 0;
 306                                 //e.gotscores = 0; // we might already have the scores...
 307                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 308                                 RegisterPlayer(e);
 309                                 HUD_UpdatePlayerPos(e);
 310                         }
 311                 }
 312         }
 313         self.nextthink = time + 0.2;
 314 }
 315
 316 void Porto_Init();
 317 void TrueAim_Init();
 318 void PostInit(void)
 319 {
 320         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 321
 322         entity playerchecker;
 323         playerchecker = spawn();
 324         playerchecker.think = Playerchecker_Think;
 325         playerchecker.nextthink = time + 0.2;
 326
 327         Porto_Init();
 328         TrueAim_Init();
 329
 330         postinit = true;
 331 }
 332
 333 float button_zoom;
 334
 335 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 336 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 337 // All keys are in ascii.
 338 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 339 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 340 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 341 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 342 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 343 {
 344         float bSkipKey;
 345         bSkipKey = false;
 346
 347         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 348                 return true;
 349
 350         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 351                 return true;
 352
 353         if(menu_visible && menu_action)
 354                 if(menu_action(bInputType, nPrimary, nSecondary))
 355                         return TRUE;
 356
 357         return bSkipKey;
 358 }
 359
 360 // END REQUIRED CSQC FUNCTIONS
 361 // --------------------------------------------------------------------------
 362
 363 // --------------------------------------------------------------------------
 364 // BEGIN OPTIONAL CSQC FUNCTIONS
 365 void Ent_RemoveEntCS()
 366 {
 367         entcs_receiver[self.sv_entnum] = world;
 368 }
 369 void Ent_ReadEntCS()
 370 {
 371         float sf;
 372         InterpolateOrigin_Undo();
 373
 374         self.classname = "entcs_receiver";
 375         sf = ReadByte();
 376
 377         if(sf & 1)
 378                 self.sv_entnum = ReadByte();
 379         if(sf & 2)
 380         {
 381                 self.origin_x = ReadShort();
 382                 self.origin_y = ReadShort();
 383                 self.origin_z = ReadShort();
 384                 setorigin(self, self.origin);
 385         }
 386         if(sf & 4)
 387         {
 388                 self.angles_y = ReadByte() * 360.0 / 256;
 389                 self.angles_x = self.angles_z = 0;
 390         }
 391         if(sf & 8)
 392                 self.healthvalue = ReadByte() * 10;
 393         if(sf & 16)
 394                 self.armorvalue = ReadByte() * 10;
 395
 396         entcs_receiver[self.sv_entnum] = self;
 397         self.entremove = Ent_RemoveEntCS;
 398         self.iflags |= IFLAG_ORIGIN;
 399
 400         InterpolateOrigin_Note();
 401 }
 402
 403 void Ent_Remove();
 404
 405 void Ent_RemovePlayerScore()
 406 {
 407         float i;
 408
 409         if(self.owner)
 410         {
 411                 SetTeam(self.owner, -1);
 412                 self.owner.gotscores = 0;
 413                 for(i = 0; i < MAX_SCORE; ++i)
 414                         self.owner.(scores[i]) = 0; // clear all scores
 415         }
 416 }
 417
 418 void Ent_ReadPlayerScore()
 419 {
 420         float i, n;
 421         float isNew;
 422         entity o;
 423
 424         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 425         // (no I've never heard of M-x replace-string, sed, or anything like that)
 426         isNew = !self.owner; // workaround for DP bug
 427         n = ReadByte()-1;
 428
 429 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 430         if(!isNew && n != self.sv_entnum)
 431         {
 432                 //print("A CSQC entity changed its owner!\n");
 433                 print(sprintf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname));
 434                 isNew = true;
 435                 Ent_Remove();
 436                 self.enttype = ENT_CLIENT_SCORES;
 437         }
 438 #endif
 439
 440         self.sv_entnum = n;
 441
 442         if not(playerslots[self.sv_entnum])
 443                 playerslots[self.sv_entnum] = spawn();
 444         o = self.owner = playerslots[self.sv_entnum];
 445         o.sv_entnum = self.sv_entnum;
 446         o.gotscores = 1;
 447
 448         //if not(o.sort_prev)
 449         //      RegisterPlayer(o);
 450         //playerchecker will do this for us later, if it has not already done so
 451
 452         float sf, lf;
 453 #if MAX_SCORE <= 8
 454         sf = ReadByte();
 455         lf = ReadByte();
 456 #else
 457         sf = ReadShort();
 458         lf = ReadShort();
 459 #endif
 460         float p;
 461         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 462                 if(sf & p)
 463                 {
 464                         if(lf & p)
 465                                 o.(scores[i]) = ReadInt24_t();
 466                         else
 467                                 o.(scores[i]) = ReadChar();
 468                 }
 469
 470         if(o.sort_prev)
 471                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 472
 473         self.entremove = Ent_RemovePlayerScore;
 474 }
 475
 476 void Ent_ReadTeamScore()
 477 {
 478         float i;
 479         entity o;
 480
 481         self.team = ReadByte();
 482         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 483
 484         float sf, lf;
 485 #if MAX_TEAMSCORE <= 8
 486         sf = ReadByte();
 487         lf = ReadByte();
 488 #else
 489         sf = ReadShort();
 490         lf = ReadShort();
 491 #endif
 492         float p;
 493         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 494                 if(sf & p)
 495                 {
 496                         if(lf & p)
 497                                 o.(teamscores[i]) = ReadInt24_t();
 498                         else
 499                                 o.(teamscores[i]) = ReadChar();
 500                 }
 501
 502         HUD_UpdateTeamPos(o);
 503 }
 504
 505 void Ent_ClientData()
 506 {
 507         float f;
 508         float newspectatee_status;
 509
 510         f = ReadByte();
 511
 512         scoreboard_showscores_force = (f & 1);
 513
 514         if(f & 2)
 515         {
 516                 newspectatee_status = ReadByte();
 517                 if(newspectatee_status == player_localnum + 1)
 518                         newspectatee_status = -1; // observing
 519         }
 520         else
 521                 newspectatee_status = 0;
 522
 523         spectatorbutton_zoom = (f & 4);
 524
 525         if(f & 8)
 526         {
 527                 angles_held_status = 1;
 528                 angles_held_x = ReadAngle();
 529                 angles_held_y = ReadAngle();
 530                 angles_held_z = 0;
 531         }
 532         else
 533                 angles_held_status = 0;
 534
 535         if(newspectatee_status != spectatee_status)
 536         {
 537                 // clear race stuff
 538                 race_laptime = 0;
 539                 race_checkpointtime = 0;
 540         }
 541         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 542         {
 543                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 544                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 545                 )
 546                         prev_p_health = -1;
 547                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 548                         prev_health = -1;
 549         }
 550         spectatee_status = newspectatee_status;
 551
 552         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 553 }
 554
 555 void Ent_Nagger()
 556 {
 557         float nags, i, j, b, f;
 558
 559         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 560
 561         if(!(nags & 4))
 562         {
 563                 if(vote_called_vote)
 564                         strunzone(vote_called_vote);
 565                 vote_called_vote = string_null;
 566                 vote_active = 0;
 567         }
 568         else
 569         {
 570                 vote_active = 1;
 571         }
 572
 573         if(nags & 64)
 574         {
 575                 vote_yescount = ReadByte();
 576                 vote_nocount = ReadByte();
 577                 vote_needed = ReadByte();
 578                 vote_highlighted = ReadChar();
 579         }
 580
 581         if(nags & 128)
 582         {
 583                 if(vote_called_vote)
 584                         strunzone(vote_called_vote);
 585                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 586         }
 587
 588         if(nags & 1)
 589         {
 590                 for(j = 0; j < maxclients; ++j)
 591                         if(playerslots[j])
 592                                 playerslots[j].ready = 1;
 593                 for(i = 1; i <= maxclients; i += 8)
 594                 {
 595                         f = ReadByte();
 596                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 597                                 if not(f & b)
 598                                         if(playerslots[j])
 599                                                 playerslots[j].ready = 0;
 600                 }
 601         }
 602
 603         ready_waiting = (nags & 1);
 604         ready_waiting_for_me = (nags & 2);
 605         vote_waiting = (nags & 4);
 606         vote_waiting_for_me = (nags & 8);
 607         warmup_stage = (nags & 16);
 608 }
 609
 610 void Ent_RandomSeed()
 611 {
 612         float s;
 613         prandom_debug();
 614         s = ReadShort();
 615         psrandom(s);
 616 }
 617
 618 void Ent_ReadAccuracy(void)
 619 {
 620         float sf, f, w, b;
 621         sf = ReadInt24_t();
 622         if(sf == 0)
 623         {
 624                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 625                         weapon_accuracy[w] = -1;
 626                 return;
 627         }
 628
 629         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 630         {
 631                 if(sf & f)
 632                 {
 633                         b = ReadByte();
 634                         if(b == 0)
 635                                 weapon_accuracy[w] = -1;
 636                         else if(b == 255)
 637                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 638                         else
 639                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 640                 }
 641                 if(f == 0x800000)
 642                         f = 1;
 643                 else
 644                         f *= 2;
 645         }
 646 }
 647
 648 void Spawn_Draw(void)
 649 {
 650         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 651 }
 652
 653 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 654 {
 655         float teamnum = (ReadByte() - 1);
 656         vector spn_origin;
 657         spn_origin_x = ReadShort();
 658         spn_origin_y = ReadShort();
 659         spn_origin_z = ReadShort();
 660
 661         if(is_new)
 662         {
 663                 self.origin = spn_origin;
 664                 setsize(self, PL_MIN, PL_MAX);
 665                 droptofloor();
 666
 667                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 668                 {
 669                         self.mdl = "models/spawnpoint.md3";
 670                         self.colormod = Team_ColorRGB(teamnum);
 671                         precache_model(self.mdl);
 672                         setmodel(self, self.mdl);
 673                         self.drawmask = MASK_NORMAL;
 674                         //self.movetype = MOVETYPE_NOCLIP;
 675                         //self.draw = Spawn_Draw;
 676                 }*/
 677                 if(autocvar_cl_spawn_point_particles)
 678                 {
 679                         if((serverflags & SERVERFLAG_TEAMPLAY))
 680                         {
 681                                 switch(teamnum)
 682                                 {
 683                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 684                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 685                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 686                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 687                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 688                                 }
 689                         }
 690                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 691
 692                         self.draw = Spawn_Draw;
 693                 }
 694         }
 695
 696         //print(sprintf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt));
 697 }
 698
 699 void Ent_ReadSpawnEvent(float is_new)
 700 {
 701         // If entnum is 0, ONLY do the local spawn actions
 702         // this way the server can disable the sending of
 703         // spawn origin or such to clients if wanted.
 704         float entnum = ReadByte();
 705
 706         if(entnum)
 707         {
 708                 self.origin_x = ReadShort();
 709                 self.origin_y = ReadShort();
 710                 self.origin_z = ReadShort();
 711
 712                 if(is_new)
 713                 {
 714                         float teamnum = GetPlayerColor(entnum - 1);
 715
 716                         if(autocvar_cl_spawn_event_particles)
 717                         {
 718                                 switch(teamnum)
 719                                 {
 720                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 721                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 722                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 723                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 724                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 725                                 }
 726                         }
 727                         if(autocvar_cl_spawn_event_sound)
 728                         {
 729                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 730                         }
 731                 }
 732         }
 733
 734         // local spawn actions
 735         if(is_new && (!entnum || (entnum == player_localentnum)))
 736         {
 737                 zoomin_effect = 1;
 738                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 739
 740                 if(autocvar_cl_unpress_zoom_on_spawn)
 741                 {
 742                         localcmd("-zoom\n");
 743                         button_zoom = FALSE;
 744                 }
 745         }
 746
 747         //print(sprintf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum));
 748 }
 749
 750 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 751 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 752 void Ent_RadarLink();
 753 void Ent_Init();
 754 void Ent_ScoresInfo();
 755 void CSQC_Ent_Update(float bIsNewEntity)
 756 {
 757         float t;
 758         float savetime;
 759         t = ReadByte();
 760
 761         if(autocvar_developer_csqcentities)
 762                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 763
 764         // set up the "time" global for received entities to be correct for interpolation purposes
 765         savetime = time;
 766         if(servertime)
 767         {
 768                 time = servertime;
 769         }
 770         else
 771         {
 772                 serverprevtime = time;
 773                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 774                 time = serverprevtime + serverdeltatime;
 775         }
 776
 777 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 778         if(self.enttype)
 779         {
 780                 if(t != self.enttype || bIsNewEntity)
 781                 {
 782                         //print("A CSQC entity changed its type!\n");
 783                         print(sprintf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t));
 784                         Ent_Remove();
 785                         clearentity(self);
 786                         bIsNewEntity = 1;
 787                 }
 788         }
 789         else
 790         {
 791                 if(!bIsNewEntity)
 792                 {
 793                         print(sprintf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t));
 794                         bIsNewEntity = 1;
 795                 }
 796         }
 797 #endif
 798         self.enttype = t;
 799         switch(t)
 800         {
 801                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 802                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 803                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 804                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 805                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 806                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 807                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 808                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 809                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 810                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 811                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 812                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 813                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 814                 case ENT_CLIENT_INIT: Ent_Init(); break;
 815                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 816                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 817                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 818                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 819                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 820                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 821                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 822                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 823                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 824                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 825                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 826                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 827                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 828                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 829                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 830                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 831                 case ENT_CLIENT_TURRET: ent_turret(); break;
 832                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 833                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 834                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 835                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 836                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 837                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 838
 839                 default:
 840                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 841                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 842                         break;
 843         }
 844
 845         time = savetime;
 846 }
 847 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 848 // used when an entity changes its type. For an entity that someone interacts
 849 // with others, make sure it can no longer do so.
 850 void Ent_Remove()
 851 {
 852         if(self.entremove)
 853                 self.entremove();
 854
 855         if(self.skeletonindex)
 856         {
 857                 skel_delete(self.skeletonindex);
 858                 self.skeletonindex = 0;
 859         }
 860
 861         if(self.snd_looping > 0)
 862         {
 863                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 864                 self.snd_looping = 0;
 865         }
 866
 867         self.enttype = 0;
 868         self.classname = "";
 869         self.draw = menu_sub_null;
 870         self.entremove = menu_sub_null;
 871         // TODO possibly set more stuff to defaults
 872 }
 873 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 874 void CSQC_Ent_Remove()
 875 {
 876         if(autocvar_developer_csqcentities)
 877                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 878
 879         if(wasfreed(self))
 880         {
 881                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 882                 return;
 883         }
 884         if(self.enttype)
 885                 Ent_Remove();
 886         remove(self);
 887 }
 888
 889 void Gamemode_Init()
 890 {
 891         if not(isdemo())
 892         {
 893                 if(!(calledhooks & HOOK_START))
 894                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 895                 calledhooks |= HOOK_START;
 896         }
 897 }
 898 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 899 void CSQC_Parse_StuffCmd(string strMessage)
 900 {
 901         if(autocvar_developer_csqcentities)
 902                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 903
 904         localcmd(strMessage);
 905 }
 906 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 907 void CSQC_Parse_Print(string strMessage)
 908 {
 909         if(autocvar_developer_csqcentities)
 910                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 911
 912         print(ColorTranslateRGB(strMessage));
 913 }
 914
 915 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 916 void CSQC_Parse_CenterPrint(string strMessage)
 917 {
 918         if(autocvar_developer_csqcentities)
 919                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 920
 921         centerprint_hud(strMessage);
 922 }
 923
 924 string notranslate_fogcmd1 = "\nfog ";
 925 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 926 void Fog_Force()
 927 {
 928         // TODO somehow thwart prvm_globalset client ...
 929
 930         if(forcefog != "")
 931                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 932 }
 933
 934 void Gamemode_Init();
 935 void Ent_ScoresInfo()
 936 {
 937         float i;
 938         self.classname = "ent_client_scores_info";
 939         gametype = ReadInt24_t();
 940         for(i = 0; i < MAX_SCORE; ++i)
 941         {
 942                 scores_label[i] = strzone(ReadString());
 943                 scores_flags[i] = ReadByte();
 944         }
 945         for(i = 0; i < MAX_TEAMSCORE; ++i)
 946         {
 947                 teamscores_label[i] = strzone(ReadString());
 948                 teamscores_flags[i] = ReadByte();
 949         }
 950         HUD_InitScores();
 951         Gamemode_Init();
 952 }
 953
 954 void Ent_Init()
 955 {
 956         self.classname = "ent_client_init";
 957
 958         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 959
 960         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 961         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 962         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 964         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 965         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 966         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 967         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 968         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 969         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 970         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 971         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 972
 973         if(forcefog)
 974                 strunzone(forcefog);
 975         forcefog = strzone(ReadString());
 976
 977         armorblockpercent = ReadByte() / 255.0;
 978
 979         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 980         g_balance_grenadelauncher_bouncestop = ReadCoord();
 981         g_balance_electro_secondary_bouncefactor = ReadCoord();
 982         g_balance_electro_secondary_bouncestop = ReadCoord();
 983
 984         nex_scope = !ReadByte();
 985         rifle_scope = !ReadByte();
 986
 987         serverflags = ReadByte();
 988
 989         minelayer_maxmines = ReadByte();
 990
 991         hagar_maxrockets = ReadByte();
 992
 993         g_trueaim_minrange = ReadCoord();
 994         g_balance_porto_secondary = ReadByte();
 995
 996         if(!postinit)
 997                 PostInit();
 998 }
 999
1000 void Net_ReadRace()
1001 {
1002         float b;
1003
1004         b = ReadByte();
1005
1006         switch(b)
1007         {
1008                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1009                         race_checkpoint = ReadByte();
1010                         race_time = ReadInt24_t();
1011                         race_previousbesttime = ReadInt24_t();
1012                         if(race_previousbestname)
1013                                 strunzone(race_previousbestname);
1014                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1015
1016                         race_checkpointtime = time;
1017
1018                         if(race_checkpoint == 0 || race_checkpoint == 254)
1019                         {
1020                                 race_penaltyaccumulator = 0;
1021                                 race_laptime = time; // valid
1022                         }
1023
1024                         break;
1025
1026                 case RACE_NET_CHECKPOINT_CLEAR:
1027                         race_laptime = 0;
1028                         race_checkpointtime = 0;
1029                         break;
1030
1031                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1032                         race_laptime = ReadCoord();
1033                         race_checkpointtime = -99999;
1034                         // fall through
1035                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1036                         race_nextcheckpoint = ReadByte();
1037
1038                         race_nextbesttime = ReadInt24_t();
1039                         if(race_nextbestname)
1040                                 strunzone(race_nextbestname);
1041                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1042                         break;
1043
1044                 case RACE_NET_CHECKPOINT_HIT_RACE:
1045                         race_mycheckpoint = ReadByte();
1046                         race_mycheckpointtime = time;
1047                         race_mycheckpointdelta = ReadInt24_t();
1048                         race_mycheckpointlapsdelta = ReadByte();
1049                         if(race_mycheckpointlapsdelta >= 128)
1050                                 race_mycheckpointlapsdelta -= 256;
1051                         if(race_mycheckpointenemy)
1052                                 strunzone(race_mycheckpointenemy);
1053                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1054                         break;
1055
1056                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1057                         race_othercheckpoint = ReadByte();
1058                         race_othercheckpointtime = time;
1059                         race_othercheckpointdelta = ReadInt24_t();
1060                         race_othercheckpointlapsdelta = ReadByte();
1061                         if(race_othercheckpointlapsdelta >= 128)
1062                                 race_othercheckpointlapsdelta -= 256;
1063                         if(race_othercheckpointenemy)
1064                                 strunzone(race_othercheckpointenemy);
1065                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1066                         break;
1067
1068                 case RACE_NET_PENALTY_RACE:
1069                         race_penaltyeventtime = time;
1070                         race_penaltytime = ReadShort();
1071                         //race_penaltyaccumulator += race_penaltytime;
1072                         if(race_penaltyreason)
1073                                 strunzone(race_penaltyreason);
1074                         race_penaltyreason = strzone(ReadString());
1075                         break;
1076
1077                 case RACE_NET_PENALTY_QUALIFYING:
1078                         race_penaltyeventtime = time;
1079                         race_penaltytime = ReadShort();
1080                         race_penaltyaccumulator += race_penaltytime;
1081                         if(race_penaltyreason)
1082                                 strunzone(race_penaltyreason);
1083                         race_penaltyreason = strzone(ReadString());
1084                         break;
1085
1086                 case RACE_NET_SERVER_RECORD:
1087                         race_server_record = ReadInt24_t();
1088                         break;
1089                 case RACE_NET_SPEED_AWARD:
1090                         race_speedaward = ReadInt24_t();
1091                         if(race_speedaward_holder)
1092                                 strunzone(race_speedaward_holder);
1093                         race_speedaward_holder = strzone(ReadString());
1094                         break;
1095                 case RACE_NET_SPEED_AWARD_BEST:
1096                         race_speedaward_alltimebest = ReadInt24_t();
1097                         if(race_speedaward_alltimebest_holder)
1098                                 strunzone(race_speedaward_alltimebest_holder);
1099                         race_speedaward_alltimebest_holder = strzone(ReadString());
1100                         break;
1101                 case RACE_NET_SERVER_RANKINGS:
1102                         float pos, prevpos, del;
1103                         pos = ReadShort();
1104                         prevpos = ReadShort();
1105                         del = ReadShort();
1106
1107                         // move other rankings out of the way
1108                         float i;
1109                         if (prevpos) {
1110                                 for (i=prevpos-1;i>pos-1;--i) {
1111                                         grecordtime[i] = grecordtime[i-1];
1112                                         if(grecordholder[i])
1113                                                 strunzone(grecordholder[i]);
1114                                         grecordholder[i] = strzone(grecordholder[i-1]);
1115                                 }
1116                         } else if (del) { // a record has been deleted by the admin
1117                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1118                                         if (i == RANKINGS_CNT-1) { // clear out last record
1119                                                 grecordtime[i] = 0;
1120                                                 if (grecordholder[i])
1121                                                         strunzone(grecordholder[i]);
1122                                                 grecordholder[i] = string_null;
1123                                         }
1124                                         else {
1125                                                 grecordtime[i] = grecordtime[i+1];
1126                                                 if (grecordholder[i])
1127                                                         strunzone(grecordholder[i]);
1128                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1129                                         }
1130                                 }
1131                         } else { // player has no ranked record yet
1132                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1133                                         grecordtime[i] = grecordtime[i-1];
1134                                         if(grecordholder[i])
1135                                                 strunzone(grecordholder[i]);
1136                                         grecordholder[i] = strzone(grecordholder[i-1]);
1137                                 }
1138                         }
1139
1140                         // store new ranking
1141                         if(grecordholder[pos-1] != "")
1142                                 strunzone(grecordholder[pos-1]);
1143                         grecordholder[pos-1] = strzone(ReadString());
1144                         grecordtime[pos-1] = ReadInt24_t();
1145                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1146                                 race_myrank = pos;
1147                         break;
1148                 case RACE_NET_SERVER_STATUS:
1149                         race_status = ReadShort();
1150                         if(race_status_name)
1151                                 strunzone(race_status_name);
1152                         race_status_name = strzone(ReadString());
1153         }
1154 }
1155
1156 void Net_TeamNagger()
1157 {
1158         teamnagger = 1;
1159 }
1160
1161 void Net_ReadPingPLReport()
1162 {
1163         float e, pi, pl, ml;
1164         e = ReadByte();
1165         pi = ReadShort();
1166         pl = ReadByte();
1167         ml = ReadByte();
1168         if not(playerslots[e])
1169                 return;
1170         playerslots[e].ping = pi;
1171         playerslots[e].ping_packetloss = pl / 255.0;
1172         playerslots[e].ping_movementloss = ml / 255.0;
1173 }
1174
1175 void Net_WeaponComplain()
1176 {
1177         complain_weapon = ReadByte();
1178
1179         if(complain_weapon_name)
1180                 strunzone(complain_weapon_name);
1181         complain_weapon_name = strzone(ReadString());
1182
1183         complain_weapon_type = ReadByte();
1184
1185         complain_weapon_time = time;
1186         weapontime = time; // ping the weapon panel
1187
1188         switch(complain_weapon_type)
1189         {
1190                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1191                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1192                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1193         }
1194 }
1195
1196 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1197 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1198 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1199 float CSQC_Parse_TempEntity()
1200 {
1201         float bHandled;
1202                 bHandled  = true;
1203         // Acquire TE ID
1204         float nTEID;
1205                 nTEID = ReadByte();
1206
1207         if(autocvar_developer_csqcentities)
1208                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1209
1210                 // NOTE: Could just do return instead of break...
1211         switch(nTEID)
1212         {
1213                 case TE_CSQC_TARGET_MUSIC:
1214                         Net_TargetMusic();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_PICTURE:
1218                         Net_MapVote_Picture();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_RACE:
1222                         Net_ReadRace();
1223                         bHandled = true;
1224                         break;
1225                 case TE_CSQC_ZCURVEPARTICLES:
1226                         Net_ReadZCurveParticles();
1227                         bHandled = true;
1228                         break;
1229                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1230                         Net_ReadNexgunBeamParticle();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_TEAMNAGGER:
1234                         Net_TeamNagger();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_LIGHTNINGARC:
1238                         Net_ReadLightningarc();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_PINGPLREPORT:
1242                         Net_ReadPingPLReport();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_WEAPONCOMPLAIN:
1246                         Net_WeaponComplain();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_VEHICLESETUP:
1250                         Net_VehicleSetup();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_SVNOTICE:
1254                         cl_notice_read();
1255                         bHandled = true;
1256                         break;
1257                 default:
1258                         // No special logic for this temporary entity; return 0 so the engine can handle it
1259                         bHandled = false;
1260                         break;
1261         }
1262
1263         return bHandled;
1264 }
1265
1266 string getcommandkey(string text, string command)
1267 {
1268         string keys;
1269         float n, j, k, l = 0;
1270
1271         if (!autocvar_hud_showbinds)
1272                 return text;
1273
1274         keys = db_get(binddb, command);
1275         if (keys == "")
1276         {
1277                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1278                 for(j = 0; j < n; ++j)
1279                 {
1280                         k = stof(argv(j));
1281                         if(k != -1)
1282                         {
1283                                 if ("" == keys)
1284                                         keys = keynumtostring(k);
1285                                 else
1286                                         keys = strcat(keys, ", ", keynumtostring(k));
1287
1288                                 ++l;
1289                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1290                                         break;
1291                         }
1292
1293                 }
1294                 if (keys == "")
1295                         keys = "NO_KEY";
1296                 db_put(binddb, command, keys);
1297         }
1298
1299         if (keys == "NO_KEY") {
1300                 if (autocvar_hud_showbinds > 1)
1301                         return sprintf(_("%s (not bound)"), text);
1302                 else
1303                         return text;
1304         }
1305         else if (autocvar_hud_showbinds > 1)
1306                 return sprintf(_("%s (%s)"), text, keys);
1307         else
1308                 return keys;
1309 }