qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard ();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 void CSQC_UpdateView(float w, float h)
 353 {
 354         entity e;
 355         float fov;
 356         float f, i, j;
 357         vector v, vo;
 358         vector vf_size, vf_min;
 359
 360         vf_size = R_SetView3fv(VF_SIZE);
 361         vf_min = R_SetView3fv(VF_MIN);
 362         vid_width = vf_size_x;
 363         vid_height = vf_size_y;
 364
 365         vector reticle_pos, reticle_size;
 366
 367         WaypointSprite_Load();
 368
 369         if(spectatee_status)
 370                 myteam = GetPlayerColor(spectatee_status - 1);
 371         else
 372                 myteam = GetPlayerColor(player_localentnum - 1);
 373
 374         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 375         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 376
 377         warpzone_fixview_origin = pmove_org + vo;
 378         warpzone_fixview_cl_viewangles = input_angles;
 379         warpzone_fixview_angles = view_angles;
 380         WarpZone_FixView();
 381         pmove_org = warpzone_fixview_origin - vo;
 382         input_angles = warpzone_fixview_cl_viewangles;
 383         view_angles = warpzone_fixview_angles;
 384
 385         if(cvar("cl_lockview") || autocvar__hud_configure)
 386         {
 387                 pmove_org = freeze_pmove_org;
 388                 input_angles = view_angles = freeze_input_angles;
 389                 R_SetView(VF_ORIGIN, pmove_org + vo);
 390                 R_SetView(VF_ANGLES, view_angles);
 391                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 392         }
 393         freeze_pmove_org = pmove_org;
 394         freeze_input_angles = input_angles;
 395
 396         // Render the Scene
 397         if(!intermission || !view_set)
 398         {
 399                 view_origin = pmove_org + vo;
 400                 view_angles = input_angles;
 401                 makevectors(view_angles);
 402                 view_forward = v_forward;
 403                 view_right = v_right;
 404                 view_up = v_up;
 405                 view_set = 1;
 406         }
 407
 408 #ifdef BLURTEST
 409         if(time > blurtest_time0 && time < blurtest_time1)
 410         {
 411                 float r, t;
 412
 413                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 414                 r = t * blurtest_radius;
 415                 f = 1 / pow(t, blurtest_power) - 1;
 416
 417                 cvar_set("r_glsl_postprocess", "1");
 418                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 419         }
 420         else
 421         {
 422                 cvar_set("r_glsl_postprocess", "0");
 423                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 424         }
 425 #endif
 426
 427         TargetMusic_Advance();
 428         Fog_Force();
 429
 430         drawframetime = max(0.000001, time - drawtime);
 431         drawtime = time;
 432
 433         // watch for gametype changes here...
 434         // in ParseStuffCMD the cmd isn't executed yet :/
 435         // might even be better to add the gametype to TE_CSQC_INIT...?
 436         if(!postinit)
 437                 PostInit();
 438
 439         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 440                 if(calledhooks & HOOK_START)
 441                 {
 442                         localcmd("\ncl_hook_gameend\n");
 443                         calledhooks |= HOOK_END;
 444                 }
 445
 446         CheckForGamestartChange();
 447         serverAnnouncer();
 448         maptimeAnnouncer();
 449         carrierAnnouncer();
 450
 451         fov = cvar("fov");
 452         if(button_zoom || fov <= 59.5)
 453         {
 454                 if(!zoomscript_caught)
 455                 {
 456                         localcmd("+button4\n");
 457                         zoomscript_caught = 1;
 458                         ignore_plus_zoom += 1;
 459                 }
 460         }
 461         else
 462         {
 463                 if(zoomscript_caught)
 464                 {
 465                         localcmd("-button4\n");
 466                         zoomscript_caught = 0;
 467                         ignore_minus_zoom += 1;
 468                 }
 469         }
 470
 471         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 472         ColorTranslateMode = cvar("cl_stripcolorcodes");
 473         activeweapon = getstati(STAT_SWITCHWEAPON);
 474         f = cvar("teamplay");
 475         if(f != teamplay)
 476         {
 477                 teamplay = f;
 478                 HUD_InitScores();
 479         }
 480
 481         if(last_weapon != activeweapon) {
 482                 weapontime = time;
 483                 last_weapon = activeweapon;
 484
 485                 e = get_weaponinfo(activeweapon);
 486                 if(e.netname != "")
 487                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 488                 else
 489                         localcmd("\ncl_hook_activeweapon none\n");
 490         }
 491
 492         // ALWAYS Clear Current Scene First
 493         R_ClearScene();
 494
 495         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 496         R_SetView(VF_SIZE, vf_size);
 497         R_SetView(VF_MIN, vf_min);
 498
 499         // Assign Standard Viewflags
 500         // Draw the World (and sky)
 501         R_SetView(VF_DRAWWORLD, 1);
 502
 503         // Set the console size vars
 504         vid_conwidth = cvar("vid_conwidth");
 505         vid_conheight = cvar("vid_conheight");
 506         vid_pixelheight = cvar("vid_pixelheight");
 507
 508         R_SetView(VF_FOV, GetCurrentFov(fov));
 509
 510         // Camera for demo playback
 511         if(camera_active)
 512         {
 513                 if(cvar("camera_enable"))
 514                         CSQC_Demo_Camera();
 515                 else
 516                 {
 517                         cvar_set("chase_active", ftos(chase_active_backup));
 518                         cvar_set("cl_demo_mousegrab", "0");
 519                         camera_active = FALSE;
 520                 }
 521         }
 522 #ifdef CAMERATEST
 523         else if(cvar("camera_enable"))
 524 #else
 525         else if(cvar("camera_enable") && isdemo())
 526 #endif
 527         {
 528                 // Enable required Darkplaces cvars
 529                 chase_active_backup = cvar("chase_active");
 530                 cvar_set("chase_active", "2");
 531                 cvar_set("cl_demo_mousegrab", "1");
 532                 camera_active = TRUE;
 533                 camera_mode = FALSE;
 534         }
 535
 536         // Draw the Crosshair
 537         float scoreboard_active;
 538         scoreboard_active = HUD_WouldDrawScoreboard();
 539         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 540
 541         // Draw the Engine Status Bar (the default Quake HUD)
 542         R_SetView(VF_DRAWENGINEHUD, 0);
 543
 544         // fetch this one only once per frame
 545         hud_showbinds = cvar("hud_showbinds");
 546         hud_showbinds_limit = cvar("hud_showbinds_limit");
 547
 548         // Update the mouse position
 549         /*
 550            mousepos_x = vid_conwidth;
 551            mousepos_y = vid_conheight;
 552            mousepos = mousepos*0.5 + getmousepos();
 553          */
 554
 555         e = self;
 556         for(self = world; (self = nextent(self)); )
 557                 if(self.draw)
 558                         self.draw();
 559         self = e;
 560
 561         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 562         R_RenderScene();
 563
 564         // now switch to 2D drawing mode by calling a 2D drawing function
 565         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 566         // next R_RenderScene call
 567         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 568
 569         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright"))
 570         {
 571                 // apply night vision effect
 572                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 573                 float a;
 574
 575                 if(!nightvision_noise)
 576                 {
 577                         nightvision_noise = spawn();
 578                         nightvision_noise.classname = "nightvision_noise";
 579                 }
 580                 if(!nightvision_noise2)
 581                 {
 582                         nightvision_noise2 = spawn();
 583                         nightvision_noise2.classname = "nightvision_noise2";
 584                 }
 585
 586                 // color tint in yellow
 587                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 588
 589                 // draw BG
 590                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 591                 rgb = '1 1 1';
 592                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 593                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 594                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 595                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 596                 tc_11 = tc_01 + tc_10 - tc_00;
 597                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 598                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 601                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 602                 R_EndPolygon();
 603
 604                 // draw FG
 605                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 606                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 607                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 608                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 609                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 610                 tc_11 = tc_01 + tc_10 - tc_00;
 611                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 612                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 615                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 616                 R_EndPolygon();
 617         }
 618
 619         // Draw the aiming reticle for weapons that use it
 620         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 621         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 622         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 623         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 624                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 625         else if(button_zoom || zoomscript_caught)
 626                 reticle_type = 1; // normal zoom
 627         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 628                 reticle_type = 2; // nex zoom
 629
 630         if(cvar("cl_reticle_stretch"))
 631         {
 632                 reticle_size_x = vid_conwidth;
 633                 reticle_size_y = vid_conheight;
 634                 reticle_pos_x = 0;
 635                 reticle_pos_y = 0;
 636         }
 637         else
 638         {
 639                 reticle_size_x = max(vid_conwidth, vid_conheight);
 640                 reticle_size_y = max(vid_conwidth, vid_conheight);
 641                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 642                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 643         }
 644
 645         f = current_zoomfraction;
 646         if(zoomscript_caught)
 647                 f = 1;
 648         if(cvar("cl_reticle_item_normal"))
 649         {
 650                 precache_pic("gfx/reticle_normal");
 651                 if(reticle_type == 1 && f)
 652                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 653         }
 654         if(cvar("cl_reticle_item_nex"))
 655         {
 656                 precache_pic("gfx/reticle_nex");
 657                 if(reticle_type == 2 && f)
 658                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 659         }
 660
 661         // Draw the mouse cursor
 662         // NOTE: drawpic must happen after R_RenderScene for some reason
 663         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 664         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 665         //self = edict_num(player_localnum);
 666         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 667         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 668         // as long as the ctf part isn't in, this is useless
 669         if(menu_visible)
 670                 menu_show();
 671
 672         /*if(gametype == GAME_CTF)
 673           {
 674           ctf_view();
 675           } else */
 676
 677         // draw 2D entities
 678         e = self;
 679         for(self = world; (self = nextent(self)); )
 680                 if(self.draw2d)
 681                         self.draw2d();
 682         self = e;
 683
 684         float hud;
 685         hud = getstati(STAT_HUD);
 686         if(hud == HUD_SPIDERBOT)
 687         {
 688                 CSQC_SPIDER_HUD();
 689         }
 690         else if(hud == HUD_WAKIZASHI)
 691         CSQC_WAKIZASHI_HUD();
 692     else if(hud == HUD_RAPTOR)
 693         CSQC_RAPTOR_HUD();
 694         else
 695         {
 696                 if(cvar("r_letterbox") == 0)
 697                         if(cvar("viewsize") < 120)
 698                                 CSQC_common_hud();
 699
 700
 701                 // ring around crosshair representing velocity-dependent damage for the nex
 702                 if (activeweapon == WEP_NEX)
 703                 {
 704                         float f, a, curvel;
 705                         vector rgb;
 706
 707                         rgb_x = cvar("crosshair_nexvelocity_color_red");
 708                         rgb_y = cvar("crosshair_nexvelocity_color_green");
 709                         rgb_z = cvar("crosshair_nexvelocity_color_blue");
 710                         a = cvar("crosshair_nexvelocity_alpha");
 711
 712                         curvel = vlen('1 0 0' * pmove_vel_x + '0 1 0' * pmove_vel_y);
 713                         f = bound(0, (curvel - nex_minvelocity) / (nex_maxvelocity - nex_minvelocity), 1);
 714
 715                         DrawCircleClippedPic('0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight, 0.1 * vid_conheight, "gfx/nex_ring.tga", f, rgb, a, DRAWFLAG_ADDITIVE);
 716                 }
 717
 718                 // crosshair goes VERY LAST
 719                 if(!scoreboard_active && !camera_active && intermission != 2) {
 720                         // TrueAim check
 721                         float shottype;
 722                         float bullets, ring_scale;
 723                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 724                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 725                         wcross_origin_z = 0;
 726                         if(cvar("crosshair_hittest"))
 727                         {
 728                                 vector wcross_oldorigin;
 729                                 wcross_oldorigin = wcross_origin;
 730                                 shottype = TrueAimCheck();
 731                                 if(shottype == SHOTTYPE_HITWORLD)
 732                                 {
 733                                         v = wcross_origin - wcross_oldorigin;
 734                                         v_x /= vid_conwidth;
 735                                         v_y /= vid_conheight;
 736                                         if(vlen(v) > 0.01)
 737                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 738                                 }
 739                                 if(!cvar("crosshair_hittest_showimpact"))
 740                                         wcross_origin = wcross_oldorigin;
 741                         }
 742                         else
 743                                 shottype = SHOTTYPE_HITWORLD;
 744
 745                         string wcross_style;
 746                         wcross_style = cvar_string("crosshair");
 747
 748                         if (wcross_style != "0") {
 749                                 vector wcross_color, wcross_size;
 750                                 string wcross_wep, wcross_name;
 751                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 752
 753                                 wcross_color_x = cvar("crosshair_color_red");
 754                                 wcross_color_y = cvar("crosshair_color_green");
 755                                 wcross_color_z = cvar("crosshair_color_blue");
 756                                 wcross_alpha = cvar("crosshair_color_alpha");
 757                                 wcross_resolution = cvar("crosshair_size");
 758                                 if (cvar("crosshair_per_weapon")) {
 759                                         e = get_weaponinfo(activeweapon);
 760                                         if (e && e.netname != "")
 761                                         {
 762                                                 wcross_wep = e.netname;
 763                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 764                                                 if(wcross_style == "")
 765                                                         wcross_style = e.netname;
 766
 767                                                 if(!cvar("crosshair_color_override"))
 768                                                 {
 769                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 770                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 771                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 772                                                 }
 773
 774                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 775                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 776                                         }
 777                                 }
 778
 779                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 780
 781                                 if(cvar("crosshair_effect_scalefade"))
 782                                 {
 783                                         wcross_scale = wcross_resolution;
 784                                         wcross_resolution = 1;
 785                                 }
 786                                 else
 787                                 {
 788                                         wcross_scale = 1;
 789                                 }
 790
 791                                 if(shottype == SHOTTYPE_HITENEMY)
 792                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 793                                 if(shottype == SHOTTYPE_HITTEAM)
 794                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 795
 796                                 f = cvar("crosshair_effect_speed");
 797                                 if(f < 0)
 798                                         f *= -2 * g_weaponswitchdelay;
 799                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 800                                 {
 801                                         wcross_changedonetime = time + f;
 802                                 }
 803                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 804                                 {
 805                                         wcross_name_changestarttime = time;
 806                                         wcross_name_changedonetime = time + f;
 807                                         if(wcross_name_goal_prev_prev)
 808                                                 strunzone(wcross_name_goal_prev_prev);
 809                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 810                                         wcross_name_goal_prev = strzone(wcross_name);
 811                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 812                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 813                                         wcross_resolution_goal_prev = wcross_resolution;
 814                                 }
 815
 816                                 wcross_scale_goal_prev = wcross_scale;
 817                                 wcross_alpha_goal_prev = wcross_alpha;
 818                                 wcross_color_goal_prev = wcross_color;
 819
 820                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 821                                 {
 822                                         wcross_blur = 1;
 823                                         wcross_alpha *= 0.75;
 824                                 }
 825                                 else
 826                                         wcross_blur = 0;
 827                                 // *_prev is at time-frametime
 828                                 // * is at wcross_changedonetime+f
 829                                 // what do we have at time?
 830                                 if(time < wcross_changedonetime)
 831                                 {
 832                                         f = frametime / (wcross_changedonetime - time + frametime);
 833                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 834                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 835                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 836                                 }
 837
 838                                 wcross_scale_prev = wcross_scale;
 839                                 wcross_alpha_prev = wcross_alpha;
 840                                 wcross_color_prev = wcross_color;
 841
 842                                 wcross_scale *= 1 - cvar("_menu_alpha");
 843                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 844
 845                                 // ring around crosshair representing bullets left in camping rifle clip
 846                                 if (activeweapon == WEP_CAMPINGRIFLE)
 847                                 {
 848                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 849                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 4);
 850                                 }
 851                                 else
 852                                         bullets = 0;
 853
 854 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 855                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 856
 857 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 858                                 do \
 859                                 { \
 860                                         if(wcross_blur > 0) \
 861                                         { \
 862                                                 for(i = -2; i <= 2; ++i) \
 863                                                         for(j = -2; j <= 2; ++j) \
 864                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 865                                         } \
 866                                         else \
 867                                         { \
 868                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 869                                         } \
 870                                 } \
 871                                 while(0)
 872
 873 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 874                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 875
 876 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 877                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 878
 879                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 880                                 {
 881                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 882                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 883                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 884                                         f = 1 - f;
 885                                 }
 886                                 else
 887                                 {
 888                                         f = 1;
 889                                 }
 890
 891                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 892                                 if(bullets)
 893                                 {
 894                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 895                                 }
 896
 897                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 898
 899                                 if(cvar("crosshair_dot"))
 900                                         CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 901
 902                                 wcross_name_alpha_goal_prev = f;
 903                         }
 904                 }
 905                 else
 906                 {
 907                         wcross_scale_prev = 0;
 908                         wcross_alpha_prev = 0;
 909                         wcross_scale_goal_prev = 0;
 910                         wcross_alpha_goal_prev = 0;
 911                         wcross_changedonetime = 0;
 912                         if(wcross_name_goal_prev)
 913                                 strunzone(wcross_name_goal_prev);
 914                         wcross_name_goal_prev = string_null;
 915                         if(wcross_name_goal_prev_prev)
 916                                 strunzone(wcross_name_goal_prev_prev);
 917                         wcross_name_goal_prev_prev = string_null;
 918                         wcross_name_changestarttime = 0;
 919                         wcross_name_changedonetime = 0;
 920                         wcross_name_alpha_goal_prev = 0;
 921                         wcross_name_alpha_goal_prev_prev = 0;
 922                         wcross_resolution_goal_prev = 0;
 923                         wcross_resolution_goal_prev_prev = 0;
 924                 }
 925         }
 926
 927         if(NextFrameCommand)
 928         {
 929                 localcmd("\n", NextFrameCommand, "\n");
 930                 NextFrameCommand = string_null;
 931         }
 932
 933         // we must do this check AFTER a frame was rendered, or it won't work
 934         if(cs_project_is_b0rked == 0)
 935         {
 936                 string w0, h0;
 937                 w0 = cvar_string("vid_conwidth");
 938                 h0 = cvar_string("vid_conheight");
 939                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 940                 //R_SetView(VF_FOV, '90 90 0');
 941                 R_SetView(VF_ORIGIN, '0 0 0');
 942                 R_SetView(VF_ANGLES, '0 0 0');
 943                 R_SetView(VF_PERSPECTIVE, 1);
 944                 makevectors('0 0 0');
 945                 vector v1, v2;
 946                 cvar_set("vid_conwidth", "800");
 947                 cvar_set("vid_conheight", "600");
 948                 v1 = cs_project(v_forward);
 949                 cvar_set("vid_conwidth", "640");
 950                 cvar_set("vid_conheight", "480");
 951                 v2 = cs_project(v_forward);
 952                 if(v1 == v2)
 953                         cs_project_is_b0rked = 1;
 954                 else
 955                         cs_project_is_b0rked = -1;
 956                 cvar_set("vid_conwidth", w0);
 957                 cvar_set("vid_conheight", h0);
 958         }
 959
 960         if(autocvar__hud_configure)
 961                 HUD_Panel_Mouse();
 962
 963         // let's reset the view back to normal for the end
 964         R_SetView(VF_MIN, '0 0 0');
 965         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 966
 967         // be safe against triggerbots until everyone has the fixed engine
 968         // this call is meant to overwrite the trace globals by something
 969         // unsuspicious
 970         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 971 }
 972
 973 #define spider_h "gfx/vehicles/hud_bg.tga"
 974 #define spider_b "gfx/vehicles/sbot.tga"
 975 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 976 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 977 #define spider_s "gfx/vehicles/shiled.tga"
 978 #define spider_a1 "gfx/hud/sb_rocket.tga"
 979 #define spider_a2 "gfx/sb_bullets.tga"
 980
 981 void CSQC_SPIDER_HUD()
 982 {
 983         float rockets, reload, heat, hp, shield;
 984         vector picsize, hudloc;
 985
 986     // Fetch health & ammo stats
 987     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 988         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 989         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 990         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 991         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 992
 993     // Draw the crosshairs
 994     picsize = drawgetimagesize(SPIDER_CROSS);
 995     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 996     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 997     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 998
 999     hudloc_y =  4;
1000     hudloc_x = 4;
1001
1002     picsize = drawgetimagesize(spider_h) * 0.5;
1003     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1004
1005     picsize = drawgetimagesize(spider_a2) * 0.5;
1006     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1007
1008     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1009     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1010     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1011
1012     picsize = drawgetimagesize(spider_a1) * 0.85;
1013     if(rockets == 9)
1014     {
1015         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1016         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1017     }
1018     else
1019     {
1020         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1021         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1022     }
1023
1024     picsize = drawgetimagesize(spider_b) * 0.5;
1025     hudloc_y = 10.5;
1026     hudloc_x = 10.5;
1027
1028     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1029     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1030     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1031     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1032
1033
1034         /*
1035         // Draw health bar
1036         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1037         p = p + '0 1 0' * vid_conheight - '0 32 0';
1038         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1039         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1040         p_y += 8;
1041         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1042         p_x += 256 * hp;
1043         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1044
1045         // Draw minigun heat indicator
1046         p = '0.5 0 0' * (vid_conwidth - 256);
1047         p = p + '0 1 0' * vid_conheight - '0 34  0';
1048         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1049         p_x += 256 * (1-heat);
1050         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1051
1052
1053         // Draw rocket icons for loaded/empty tubes.
1054         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1055         pp += '0 1 0' * vid_conheight - '0 64 0';
1056         for(i = 0; i < 8; ++i)
1057         {
1058                 p = pp + '1 0 0' * (rkt_size * i);
1059                 if(rockets == 8)
1060                 {
1061                         if(floor(reload * 8) == i)
1062                         {
1063                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1064                         }
1065                         else if(i < reload * 8)
1066                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1067                         else
1068                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1069                 }
1070                 else
1071                 {
1072                         if(i < rockets)
1073                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1074                         else
1075                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1076                 }
1077         }
1078         */
1079
1080         if (scoreboard_showscores)
1081         {
1082                 HUD_DrawScoreboard();
1083                 HUD_DrawCenterPrint();
1084         }
1085
1086 }
1087
1088 #define raptor_h "gfx/vehicles/hud_bg.tga"
1089 #define raptor_b "gfx/vehicles/raptor.tga"
1090 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1091 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1092 #define raptor_s "gfx/vehicles/shiled.tga"
1093
1094 void CSQC_RAPTOR_HUD()
1095 {
1096         float rockets, reload, heat, hp, shield, energy;
1097         vector picsize, hudloc;
1098
1099     // Fetch health & ammo stats
1100     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1101         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1102         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1103         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1104
1105     // Draw the crosshairs
1106     picsize = drawgetimagesize(SPIDER_CROSS);
1107     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1108     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1109     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1110
1111     hudloc_y =  4;
1112     hudloc_x = 4;
1113
1114     picsize = drawgetimagesize(raptor_h) * 0.5;
1115     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1116
1117     picsize = drawgetimagesize(spider_a2) * 0.5;
1118     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1119
1120     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1121     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1122     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1123
1124
1125     picsize = drawgetimagesize(spider_a1) * 0.85;
1126     if(reload == 1)
1127     {
1128         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1129         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1130     }
1131     else
1132     {
1133         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1134         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1135     }
1136
1137     picsize = drawgetimagesize(raptor_b) * 0.5;
1138     hudloc_y = 10.5;
1139     hudloc_x = 10.5;
1140
1141     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1142     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1143     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1144     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1145
1146
1147         if (scoreboard_showscores)
1148         {
1149                 HUD_DrawScoreboard();
1150                 HUD_DrawCenterPrint();
1151         }
1152
1153 }
1154
1155 #define waki_h "gfx/vehicles/hud_bg.tga"
1156 #define waki_b "gfx/vehicles/waki.tga"
1157 #define waki_e "gfx/vehicles/waki_e.tga"
1158 #define waki_g "gfx/vehicles/waki_guns.tga"
1159 #define waki_r "gfx/vehicles/waki_rockets.tga"
1160 #define waki_s "gfx/vehicles/shiled.tga"
1161
1162 #define waki_a1 "gfx/hud/sb_rocket.tga"
1163 #define waki_a2 "gfx/sb_cells.tga"
1164
1165 void CSQC_WAKIZASHI_HUD()
1166 {
1167         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1168         float health, shield, energy, rockets;
1169         vector picsize, hudloc;
1170
1171     picsize = drawgetimagesize(SPIDER_CROSS);
1172     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1173     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1174     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1175
1176 /*
1177 const float STAT_VEHICLESTAT_HEALTH  = 60;
1178 const float STAT_VEHICLESTAT_SHIELD  = 61;
1179 const float STAT_VEHICLESTAT_ENERGY  = 62;
1180 const float STAT_VEHICLESTAT_AMMO1   = 63;
1181 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1182 const float STAT_VEHICLESTAT_AMMO2   = 65;
1183 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1184 */
1185     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1186         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1187         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1188         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1189
1190     hudloc_y =  4;
1191     hudloc_x = 4;
1192
1193     picsize = drawgetimagesize(waki_h) * 0.5;
1194     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1195
1196     picsize = drawgetimagesize(waki_a2) * 0.7;
1197     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1198
1199
1200     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1201     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1202
1203     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1204
1205     picsize = drawgetimagesize(waki_a1) * 0.75;
1206     if(rockets == 1)
1207     {
1208         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1209         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1210     }
1211     else
1212     {
1213         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1214         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1215         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1216     }
1217
1218     picsize = drawgetimagesize(waki_b) * 0.5;
1219     hudloc_y = 10.5;
1220     hudloc_x = 10.5;
1221
1222     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1223     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1224     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1225     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1226
1227
1228
1229         /*
1230         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1231         p = p + '0 1 0' * vid_conheight - '0 32 0';
1232
1233         // Draw health bar
1234         p_y += 8;
1235         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1236         p_x += 256 * health;
1237         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1238
1239         // Draw shiled bar
1240         p_x -= 256 * health;
1241         p_y += 4;
1242         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1243
1244         // Draw energy
1245         //p_x -= 256 * health;
1246         p_y -= 8;
1247         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1248
1249         // Draw rockets bar
1250         p_y += 12;
1251         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1252         */
1253
1254
1255
1256
1257         if (scoreboard_showscores)
1258         {
1259                 HUD_DrawScoreboard();
1260                 HUD_DrawCenterPrint();
1261         }
1262
1263 }
1264
1265
1266 void CSQC_common_hud(void)
1267 {
1268         // HUD_SortFrags(); done in HUD_Draw
1269         float hud;
1270         hud = getstati(STAT_HUD);
1271
1272         //hud = 10;
1273         switch(hud)
1274         {
1275                 case HUD_NORMAL:
1276                         // do some accuracy var caching
1277                         float i;
1278                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1279                         {
1280                                 acc_levels = tokenize(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1281                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1282                                         acc_levels = MAX_ACCURACY_LEVELS;
1283
1284                                 for (i = 0; i < acc_levels; ++i)
1285                                         acc_lev[i] = stof(argv(i));
1286                         }
1287
1288                         HUD_Main(); // always run these functions for alpha checks
1289                         HUD_DrawScoreboard();
1290
1291                         if (scoreboard_showscores || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1) // scoreboard/accuracy
1292                         {
1293                                 HUD_Reset();
1294                                 // HUD_DrawScoreboard takes care of centerprint_start
1295                         }
1296                         else if (intermission == 2) // map voting screen
1297                         {
1298                                 HUD_FinaleOverlay();
1299                                 HUD_Reset();
1300
1301                                 centerprint_start_x = 0;
1302                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1303                         }
1304                         else // hud
1305                         {
1306                                 centerprint_start_x = 0;
1307                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1308                         }
1309
1310                         HUD_DrawCenterPrint();
1311                         break;
1312
1313                 case HUD_SPIDERBOT:
1314                         CSQC_SPIDER_HUD();
1315                         break;
1316
1317                 case HUD_WAKIZASHI:
1318                         CSQC_WAKIZASHI_HUD();
1319                         break;
1320         }
1321 }
1322
1323
1324 // following vectors must be global to allow seamless switching between camera modes
1325 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1326 void CSQC_Demo_Camera()
1327 {
1328         float speed, attenuation, dimensions;
1329         vector tmp, delta;
1330
1331         if( cvar("camera_reset") || !camera_mode )
1332         {
1333                 camera_offset = '0 0 0';
1334                 current_angles = '0 0 0';
1335                 camera_direction = '0 0 0';
1336                 camera_offset_z += 30;
1337                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1338                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1339                 current_origin = view_origin;
1340                 current_camera_offset  = camera_offset;
1341                 cvar_set("camera_reset", "0");
1342                 camera_mode = CAMERA_CHASE;
1343         }
1344
1345         // Camera angles
1346         if( camera_roll )
1347                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1348
1349         if(cvar("camera_look_player"))
1350         {
1351                 local vector dir;
1352                 local float n;
1353
1354                 dir = normalize(view_origin - current_position);
1355                 n = mouse_angles_z;
1356                 mouse_angles = vectoangles(dir);
1357                 mouse_angles_x = mouse_angles_x * -1;
1358                 mouse_angles_z = n;
1359         }
1360         else
1361         {
1362                 tmp = getmousepos() * 0.1;
1363                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1364                 {
1365                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1366                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1367                 }
1368         }
1369
1370         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1371         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1372         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1373         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1374
1375         // Fix difference when angles don't have the same sign
1376         delta = '0 0 0';
1377         if(mouse_angles_y < -60 && current_angles_y > 60)
1378                 delta = '0 360 0';
1379         if(mouse_angles_y > 60 && current_angles_y < -60)
1380                 delta = '0 -360 0';
1381
1382         if(cvar("camera_look_player"))
1383                 attenuation = cvar("camera_look_attenuation");
1384         else
1385                 attenuation = cvar("camera_speed_attenuation");
1386
1387         attenuation = 1 / max(1, attenuation);
1388         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1389
1390         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1391         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1392         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1393         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1394
1395         // Camera position
1396         tmp = '0 0 0';
1397         dimensions = 0;
1398
1399         if( camera_direction_x )
1400         {
1401                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1402                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1403                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1404                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1405                 ++dimensions;
1406         }
1407
1408         if( camera_direction_y )
1409         {
1410                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1411                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1412                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1413                 ++dimensions;
1414         }
1415
1416         if( camera_direction_z )
1417         {
1418                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1419                 ++dimensions;
1420         }
1421
1422         if(cvar("camera_free"))
1423                 speed = cvar("camera_speed_free");
1424         else
1425                 speed = cvar("camera_speed_chase");
1426
1427         if(dimensions)
1428         {
1429                 speed = speed * sqrt(1 / dimensions);
1430                 camera_offset += tmp * speed;
1431         }
1432
1433         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1434
1435         // Camera modes
1436         if( cvar("camera_free") )
1437         {
1438                 if ( camera_mode == CAMERA_CHASE )
1439                 {
1440                         current_camera_offset = current_origin + current_camera_offset;
1441                         camera_offset = current_origin + camera_offset;
1442                 }
1443
1444                 camera_mode = CAMERA_FREE;
1445                 current_position = current_camera_offset;
1446         }
1447         else
1448         {
1449                 if ( camera_mode == CAMERA_FREE )
1450                 {
1451                         current_origin = view_origin;
1452                         camera_offset = camera_offset - current_origin;
1453                         current_camera_offset = current_camera_offset - current_origin;
1454                 }
1455
1456                 camera_mode = CAMERA_CHASE;
1457
1458                 if(cvar("camera_chase_smoothly"))
1459                         current_origin += (view_origin - current_origin) * attenuation;
1460                 else
1461                         current_origin = view_origin;
1462
1463                 current_position = current_origin + current_camera_offset;
1464         }
1465
1466         R_SetView(VF_ANGLES, current_angles);
1467         R_SetView(VF_ORIGIN, current_position);
1468 }