qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float chase_current_distance;
 370
 371 void CSQC_UpdateView(float w, float h)
 372 {
 373         entity e;
 374         float fov;
 375         float f, i, j;
 376         vector v, vo;
 377         vector vf_size, vf_min;
 378         float a;
 379
 380         vf_size = R_SetView3fv(VF_SIZE);
 381         vf_min = R_SetView3fv(VF_MIN);
 382         vid_width = vf_size_x;
 383         vid_height = vf_size_y;
 384
 385         vector reticle_pos, reticle_size;
 386         vector splash_pos, splash_size;
 387
 388         WaypointSprite_Load();
 389
 390         if(spectatee_status)
 391                 myteam = GetPlayerColor(spectatee_status - 1);
 392         else
 393                 myteam = GetPlayerColor(player_localentnum - 1);
 394
 395         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 396         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 397
 398         warpzone_fixview_origin = pmove_org + vo;
 399         warpzone_fixview_cl_viewangles = input_angles;
 400         warpzone_fixview_angles = view_angles;
 401         WarpZone_FixView();
 402         pmove_org = warpzone_fixview_origin - vo;
 403         input_angles = warpzone_fixview_cl_viewangles;
 404         view_angles = warpzone_fixview_angles;
 405
 406         // event chase cam
 407         if(spectatee_status >= 0 && (autocvar_cl_chase_death || autocvar_cl_chase_intermission))
 408         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually
 409         {
 410                 if((autocvar_cl_chase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_chase_intermission && intermission) && intermission <= 1) // not during the map voting screen
 411                 {
 412                         if(!autocvar_chase_active)
 413                                 cvar_set("chase_active", "-1"); // -1 enables chase_active as well as marking it as enabled by this code, and not by the user (which would be 1)
 414
 415                         // make the camera smooth back
 416                         if(autocvar_cl_chase_speed && chase_current_distance < autocvar_cl_chase_distance)
 417                                 chase_current_distance += autocvar_cl_chase_speed * (autocvar_cl_chase_distance - chase_current_distance) * frametime;
 418                         else if(chase_current_distance != autocvar_cl_chase_distance)
 419                                 chase_current_distance = autocvar_cl_chase_distance;
 420
 421                         makevectors(view_angles);
 422                         R_SetView(VF_ORIGIN, pmove_org - view_forward * chase_current_distance);
 423                 }
 424                 else if(autocvar_chase_active < 0)
 425                 {
 426                         cvar_set("chase_active", "0");
 427                         chase_current_distance = 0; // start from 0
 428                 }
 429         }
 430
 431         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 432         {
 433                 pmove_org = freeze_pmove_org;
 434                 input_angles = view_angles = freeze_input_angles;
 435                 R_SetView(VF_ORIGIN, pmove_org + vo);
 436                 R_SetView(VF_ANGLES, view_angles);
 437                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 438         }
 439         freeze_pmove_org = pmove_org;
 440         freeze_input_angles = input_angles;
 441
 442         // Render the Scene
 443         if(!intermission || !view_set)
 444         {
 445                 view_origin = pmove_org + vo;
 446                 view_angles = input_angles;
 447                 makevectors(view_angles);
 448                 view_forward = v_forward;
 449                 view_right = v_right;
 450                 view_up = v_up;
 451                 view_set = 1;
 452         }
 453
 454 #ifdef BLURTEST
 455         if(time > blurtest_time0 && time < blurtest_time1)
 456         {
 457                 float r, t;
 458
 459                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 460                 r = t * blurtest_radius;
 461                 f = 1 / pow(t, blurtest_power) - 1;
 462
 463                 cvar_set("r_glsl_postprocess", "1");
 464                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 465         }
 466         else
 467         {
 468                 cvar_set("r_glsl_postprocess", "0");
 469                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 470         }
 471 #endif
 472
 473         TargetMusic_Advance();
 474         Fog_Force();
 475
 476         drawframetime = max(0.000001, time - drawtime);
 477         drawtime = time;
 478
 479         // watch for gametype changes here...
 480         // in ParseStuffCMD the cmd isn't executed yet :/
 481         // might even be better to add the gametype to TE_CSQC_INIT...?
 482         if(!postinit)
 483                 PostInit();
 484
 485         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 486                 if(calledhooks & HOOK_START)
 487                 {
 488                         localcmd("\ncl_hook_gameend\n");
 489                         calledhooks |= HOOK_END;
 490                 }
 491
 492         CheckForGamestartChange();
 493         serverAnnouncer();
 494         maptimeAnnouncer();
 495         carrierAnnouncer();
 496
 497         fov = autocvar_fov;
 498         if(button_zoom || fov <= 59.5)
 499         {
 500                 if(!zoomscript_caught)
 501                 {
 502                         localcmd("+button4\n");
 503                         zoomscript_caught = 1;
 504                         ignore_plus_zoom += 1;
 505                 }
 506         }
 507         else
 508         {
 509                 if(zoomscript_caught)
 510                 {
 511                         localcmd("-button4\n");
 512                         zoomscript_caught = 0;
 513                         ignore_minus_zoom += 1;
 514                 }
 515         }
 516
 517         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 518         activeweapon = getstati(STAT_SWITCHWEAPON);
 519         f = (serverflags & SERVERFLAG_TEAMPLAY);
 520         if(f != teamplay)
 521         {
 522                 teamplay = f;
 523                 HUD_InitScores();
 524         }
 525
 526         if(last_weapon != activeweapon) {
 527                 weapontime = time;
 528                 last_weapon = activeweapon;
 529
 530                 e = get_weaponinfo(activeweapon);
 531                 if(e.netname != "")
 532                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 533                 else
 534                         localcmd("\ncl_hook_activeweapon none\n");
 535         }
 536
 537         // ALWAYS Clear Current Scene First
 538         R_ClearScene();
 539
 540         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 541         R_SetView(VF_SIZE, vf_size);
 542         R_SetView(VF_MIN, vf_min);
 543
 544         // Assign Standard Viewflags
 545         // Draw the World (and sky)
 546         R_SetView(VF_DRAWWORLD, 1);
 547
 548         // Set the console size vars
 549         vid_conwidth = autocvar_vid_conwidth;
 550         vid_conheight = autocvar_vid_conheight;
 551         vid_pixelheight = autocvar_vid_pixelheight;
 552
 553         R_SetView(VF_FOV, GetCurrentFov(fov));
 554
 555         // Camera for demo playback
 556         if(camera_active)
 557         {
 558                 if(autocvar_camera_enable)
 559                         CSQC_Demo_Camera();
 560                 else
 561                 {
 562                         cvar_set("chase_active", ftos(chase_active_backup));
 563                         cvar_set("cl_demo_mousegrab", "0");
 564                         camera_active = FALSE;
 565                 }
 566         }
 567 #ifdef CAMERATEST
 568         else if(autocvar_camera_enable)
 569 #else
 570         else if(autocvar_camera_enable && isdemo())
 571 #endif
 572         {
 573                 // Enable required Darkplaces cvars
 574                 chase_active_backup = autocvar_chase_active;
 575                 cvar_set("chase_active", "2");
 576                 cvar_set("cl_demo_mousegrab", "1");
 577                 camera_active = TRUE;
 578                 camera_mode = FALSE;
 579         }
 580
 581         // Draw the Crosshair
 582         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 583
 584         // Draw the Engine Status Bar (the default Quake HUD)
 585         R_SetView(VF_DRAWENGINEHUD, 0);
 586
 587         // fetch this one only once per frame
 588         hud_showbinds = autocvar_hud_showbinds;
 589         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 590
 591         // Update the mouse position
 592         /*
 593            mousepos_x = vid_conwidth;
 594            mousepos_y = vid_conheight;
 595            mousepos = mousepos*0.5 + getmousepos();
 596          */
 597
 598         e = self;
 599         for(self = world; (self = nextent(self)); )
 600                 if(self.draw)
 601                         self.draw();
 602         self = e;
 603
 604         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 605         R_RenderScene();
 606
 607         // now switch to 2D drawing mode by calling a 2D drawing function
 608         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 609         // next R_RenderScene call
 610         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 611
 612         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 613         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 614         {
 615                 // apply night vision effect
 616                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 617
 618                 if(!nightvision_noise)
 619                 {
 620                         nightvision_noise = spawn();
 621                         nightvision_noise.classname = "nightvision_noise";
 622                 }
 623                 if(!nightvision_noise2)
 624                 {
 625                         nightvision_noise2 = spawn();
 626                         nightvision_noise2.classname = "nightvision_noise2";
 627                 }
 628
 629                 // color tint in yellow
 630                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 631
 632                 // draw BG
 633                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 634                 rgb = '1 1 1';
 635                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 636                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 637                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 638                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 639                 tc_11 = tc_01 + tc_10 - tc_00;
 640                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 641                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 642                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 643                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 644                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 645                 R_EndPolygon();
 646
 647                 // draw FG
 648                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 649                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 650                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 651                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 652                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 653                 tc_11 = tc_01 + tc_10 - tc_00;
 654                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 655                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 656                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 657                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 658                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 659                 R_EndPolygon();
 660         }
 661
 662         // Draw the aiming reticle for weapons that use it
 663         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 664         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 665         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 666         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 667                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 668         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 669                 reticle_type = 2; // nex zoom
 670         else if(button_zoom || zoomscript_caught)
 671                 reticle_type = 1; // normal zoom
 672         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 673                 reticle_type = 2; // nex zoom
 674
 675         if (reticle_type)
 676         {
 677                 if(autocvar_cl_reticle_stretch)
 678                 {
 679                         reticle_size_x = vid_conwidth;
 680                         reticle_size_y = vid_conheight;
 681                         reticle_pos_x = 0;
 682                         reticle_pos_y = 0;
 683                 }
 684                 else
 685                 {
 686                         reticle_size_x = max(vid_conwidth, vid_conheight);
 687                         reticle_size_y = max(vid_conwidth, vid_conheight);
 688                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 689                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 690                 }
 691
 692                 f = current_zoomfraction;
 693                 if(zoomscript_caught)
 694                         f = 1;
 695                 if(autocvar_cl_reticle_item_normal)
 696                 {
 697                         if(reticle_type == 1 && f)
 698                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 699                 }
 700                 if(autocvar_cl_reticle_item_nex)
 701                 {
 702                         if(reticle_type == 2 && f)
 703                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 704                 }
 705         }
 706
 707
 708         // improved polyblend
 709         vector rgb;
 710         if(autocvar_hud_contents)
 711         {
 712                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 713                 vector liquidcolor;
 714
 715                 switch(pointcontents(view_origin))
 716                 {
 717                         case CONTENT_WATER:
 718                                 liquidalpha = autocvar_hud_contents_water_alpha;
 719                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 720                                 incontent = 1;
 721                                 break;
 722
 723                         case CONTENT_LAVA:
 724                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 725                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 726                                 incontent = 1;
 727                                 break;
 728
 729                         case CONTENT_SLIME:
 730                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 731                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 732                                 incontent = 1;
 733                                 break;
 734
 735                         default:
 736                                 liquidalpha = 0;
 737                                 liquidcolor = '0 0 0';
 738                                 incontent = 0;
 739                                 break;
 740                 }
 741
 742                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 743                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 744                         contentfadetime = autocvar_hud_contents_fadeintime;
 745                         liquidalpha_prev = liquidalpha;
 746                         liquidcolor_prev = liquidcolor;
 747                 }
 748                 else
 749                         contentfadetime = autocvar_hud_contents_fadeouttime;
 750
 751                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 752                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 753
 754                 if(contentavgalpha)
 755                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 756         }
 757
 758         if(autocvar_hud_damage)
 759         {
 760                 splash_size_x = max(vid_conwidth, vid_conheight);
 761                 splash_size_y = max(vid_conwidth, vid_conheight);
 762                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 763                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 764
 765                 float myhealth_flash_temp;
 766                 myhealth = getstati(STAT_HEALTH);
 767
 768                 // fade out
 769                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 770                 // add new damage
 771                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 772
 773                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 774                 pain_threshold = autocvar_hud_damage_pain_threshold;
 775                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 776                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 777
 778                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 779                 {
 780                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 781                 }
 782
 783                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 784
 785                 if(myhealth_prev < 1)
 786                 {
 787                         if(myhealth >= 1)
 788                         {
 789                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 790                                 myhealth_flash_temp = 0;
 791                         }
 792                         else
 793                         {
 794                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 795                         }
 796                 }
 797
 798                 if(spectatee_status == -1 || intermission)
 799                 {
 800                         myhealth_flash = 0; // observing, or match ended
 801                         myhealth_flash_temp = 0;
 802                 }
 803
 804                 myhealth_prev = myhealth;
 805
 806                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 807                 {
 808                         if(autocvar_cl_gentle_damage == 2)
 809                         {
 810                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 811                                 {
 812                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 813                                 }
 814                         }
 815                         else
 816                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 817
 818                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 819                 }
 820                 else
 821                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 822         }
 823
 824         // Draw the mouse cursor
 825         // NOTE: drawpic must happen after R_RenderScene for some reason
 826         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 827         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 828         //self = edict_num(player_localnum);
 829         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 830         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 831         // as long as the ctf part isn't in, this is useless
 832         if(menu_visible)
 833                 menu_show();
 834
 835         /*if(gametype == GAME_CTF)
 836           {
 837           ctf_view();
 838           } else */
 839
 840         // draw 2D entities
 841         e = self;
 842         for(self = world; (self = nextent(self)); )
 843                 if(self.draw2d)
 844                         self.draw2d();
 845         self = e;
 846
 847         scoreboard_active = HUD_WouldDrawScoreboard();
 848
 849         hit_time = getstatf(STAT_HIT_TIME);
 850         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 851         {
 852                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 853                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 854         }
 855         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 856         if(typehit_time > nextsound_typehit_time)
 857         {
 858                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 859                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 860         }
 861
 862         float hud;
 863         hud = getstati(STAT_HUD);
 864         if(hud == HUD_SPIDERBOT)
 865                 CSQC_SPIDER_HUD();
 866         else if(hud == HUD_WAKIZASHI)
 867         CSQC_WAKIZASHI_HUD();
 868     else if(hud == HUD_RAPTOR)
 869         CSQC_RAPTOR_HUD();
 870         else
 871         {
 872                 if(gametype == GAME_FREEZETAG)
 873                 {
 874                         if(getstati(STAT_FROZEN))
 875                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 876                         if(getstatf(STAT_REVIVE_PROGRESS))
 877                         {
 878                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 879                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 880                         }
 881                 }
 882
 883                 if(autocvar_r_letterbox == 0)
 884                         if(autocvar_viewsize < 120)
 885                                 CSQC_common_hud();
 886
 887                 // crosshair goes VERY LAST
 888                 if(!scoreboard_active && !camera_active && intermission != 2) {
 889                         string wcross_style;
 890                         float wcross_alpha, wcross_resolution;
 891                         wcross_style = autocvar_crosshair;
 892                         if (wcross_style == "0")
 893                                 return;
 894                         wcross_resolution = autocvar_crosshair_size;
 895                         if (wcross_resolution == 0)
 896                                 return;
 897                         wcross_alpha = autocvar_crosshair_alpha;
 898                         if (wcross_alpha == 0)
 899                                 return;
 900
 901                         // TrueAim check
 902                         float shottype;
 903
 904                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 905                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 906                         wcross_origin_z = 0;
 907                         if(autocvar_crosshair_hittest)
 908                         {
 909                                 vector wcross_oldorigin;
 910                                 wcross_oldorigin = wcross_origin;
 911                                 shottype = TrueAimCheck();
 912                                 if(shottype == SHOTTYPE_HITWORLD)
 913                                 {
 914                                         v = wcross_origin - wcross_oldorigin;
 915                                         v_x /= vid_conwidth;
 916                                         v_y /= vid_conheight;
 917                                         if(vlen(v) > 0.01)
 918                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 919                                 }
 920                                 if(!autocvar_crosshair_hittest_showimpact)
 921                                         wcross_origin = wcross_oldorigin;
 922                         }
 923                         else
 924                                 shottype = SHOTTYPE_HITWORLD;
 925
 926                         vector wcross_color, wcross_size;
 927                         string wcross_wep, wcross_name;
 928                         float wcross_scale, wcross_blur;
 929
 930                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 931                                 e = get_weaponinfo(activeweapon);
 932                                 if (e && e.netname != "")
 933                                 {
 934                                         wcross_wep = e.netname;
 935                                         if(autocvar_crosshair_per_weapon)
 936                                         {
 937                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 938                                                 if (wcross_resolution == 0)
 939                                                         return;
 940                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 941                                                 if (wcross_alpha == 0)
 942                                                         return;
 943
 944                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 945                                                 if(wcross_style == "" || wcross_style == "0")
 946                                                         wcross_style = wcross_wep;
 947                                         }
 948                                 }
 949                         }
 950                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 951                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 952                         else if(autocvar_crosshair_color_by_health)
 953                         {
 954                                 local float x = getstati(STAT_HEALTH);
 955
 956                                 //x = red
 957                                 //y = green
 958                                 //z = blue
 959
 960                                 wcross_color_z = 0;
 961
 962                                 if(x > 200)
 963                                 {
 964                                         wcross_color_x = 0;
 965                                         wcross_color_y = 1;
 966                                 }
 967                                 else if(x > 150)
 968                                 {
 969                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 970                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 971                                 }
 972                                 else if(x > 100)
 973                                 {
 974                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 975                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 976                                         wcross_color_z = 1 - (x-100)*0.02;
 977                                 }
 978                                 else if(x > 50)
 979                                 {
 980                                         wcross_color_x = 1;
 981                                         wcross_color_y = 1;
 982                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 983                                 }
 984                                 else if(x > 20)
 985                                 {
 986                                         wcross_color_x = 1;
 987                                         wcross_color_y = (x-20)*90/27/100;
 988                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 989                                 }
 990                                 else
 991                                 {
 992                                         wcross_color_x = 1;
 993                                         wcross_color_y = 0;
 994                                 }
 995                         }
 996                         else
 997                                 wcross_color = stov(autocvar_crosshair_color);
 998
 999                         wcross_name = strcat("gfx/crosshair", wcross_style);
1000
1001                         if(autocvar_crosshair_effect_scalefade)
1002                         {
1003                                 wcross_scale = wcross_resolution;
1004                                 wcross_resolution = 1;
1005                         }
1006                         else
1007                         {
1008                                 wcross_scale = 1;
1009                         }
1010
1011                         if(autocvar_crosshair_pickup)
1012                         {
1013                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1014                                 {
1015                                         pickup_crosshair_size = 1;
1016                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1017                                 }
1018
1019                                 if(pickup_crosshair_size > 0)
1020                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1021                                 else
1022                                         pickup_crosshair_size = 0;
1023
1024                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1025                         }
1026
1027                         vector hitindication_color;
1028                         if(autocvar_crosshair_hitindication)
1029                         {
1030                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1031                                 if(hitindication_crosshair_time < hit_time)
1032                                 {
1033                                         hitindication_crosshair_size = 1;
1034                                         hitindication_crosshair_time = hit_time;
1035                                 }
1036
1037                                 if(hitindication_crosshair_size > 0)
1038                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1039                                 else
1040                                         hitindication_crosshair_size = 0;
1041
1042                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1043                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1044                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1045                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1046                         }
1047
1048                         if(shottype == SHOTTYPE_HITENEMY)
1049                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1050                         if(shottype == SHOTTYPE_HITTEAM)
1051                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1052
1053                         f = autocvar_crosshair_effect_speed;
1054                         if(f < 0)
1055                                 f *= -2 * g_weaponswitchdelay;
1056                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1057                         {
1058                                 wcross_changedonetime = time + f;
1059                         }
1060                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1061                         {
1062                                 wcross_name_changestarttime = time;
1063                                 wcross_name_changedonetime = time + f;
1064                                 if(wcross_name_goal_prev_prev)
1065                                         strunzone(wcross_name_goal_prev_prev);
1066                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1067                                 wcross_name_goal_prev = strzone(wcross_name);
1068                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1069                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1070                                 wcross_resolution_goal_prev = wcross_resolution;
1071                         }
1072
1073                         wcross_scale_goal_prev = wcross_scale;
1074                         wcross_alpha_goal_prev = wcross_alpha;
1075                         wcross_color_goal_prev = wcross_color;
1076
1077                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1078                         {
1079                                 wcross_blur = 1;
1080                                 wcross_alpha *= 0.75;
1081                         }
1082                         else
1083                                 wcross_blur = 0;
1084                         // *_prev is at time-frametime
1085                         // * is at wcross_changedonetime+f
1086                         // what do we have at time?
1087                         if(time < wcross_changedonetime)
1088                         {
1089                                 f = frametime / (wcross_changedonetime - time + frametime);
1090                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1091                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1092                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1093                         }
1094
1095                         wcross_scale_prev = wcross_scale;
1096                         wcross_alpha_prev = wcross_alpha;
1097                         wcross_color_prev = wcross_color;
1098
1099                         wcross_scale *= 1 - autocvar__menu_alpha;
1100                         wcross_alpha *= 1 - autocvar__menu_alpha;
1101                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1102
1103                         // crosshair rings for weapon stats
1104                         if ((autocvar_crosshair_ring) || (autocvar_crosshair_ring_reload))
1105                         {
1106                                 // declarations and stats
1107                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1108                                 string ring_image, ring_inner_image;
1109                                 vector ring_rgb, ring_inner_rgb;
1110
1111                                 ring_scale = autocvar_crosshair_ring_size;
1112
1113                                 float weapon_clipload, weapon_clipsize;
1114                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1115                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1116
1117                                 float nex_charge, nex_chargepool;
1118                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1119                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1120
1121                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1122                                         nex_charge_movingavg = nex_charge;
1123
1124
1125                                 // handle the values
1126                                 if (activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1127                                 {
1128                                         if (nex_chargepool || use_nex_chargepool) {
1129                                                 use_nex_chargepool = 1;
1130                                                 ring_inner_value = nex_chargepool;
1131                                         } else {
1132                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1133                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1134                                         }
1135
1136                                         ring_inner_alpha = wcross_alpha * autocvar_crosshair_ring_nex_inner_alpha;
1137                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1138                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1139
1140                                         // draw the outer ring to show the current charge of the weapon
1141                                         ring_value = nex_charge;
1142                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_nex_alpha;
1143                                         ring_rgb = wcross_color;
1144                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1145                                 }
1146                                 else if (activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1147                                 {
1148                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1149                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_minelayer_alpha;
1150                                         ring_rgb = wcross_color;
1151                                         ring_image = "gfx/crosshair_ring.tga";
1152                                 }
1153
1154                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1155                                 {
1156                                         // if the main ring is already used by another weapon, instead use the inner one for ammo.
1157                                         // inner ring is secondary anyway and doesn't matter as much as main ring, so overriding it is no issue.
1158                                         if(ring_value && autocvar_crosshair_ring_reload_inner)
1159                                         {
1160                                                 ring_inner_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1161                                                 ring_inner_alpha = autocvar_crosshair_ring_reload_alpha;
1162                                                 ring_inner_rgb = wcross_color;
1163                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1164                                         }
1165                                         else
1166                                         {
1167                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1168                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1169                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1170                                                 ring_rgb = wcross_color;
1171
1172                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1173                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1174                                                 if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1175                                                         ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1176                                                 else
1177                                                         ring_image = "gfx/crosshair_ring.tga";
1178                                         }
1179                                 }
1180
1181                                 if ((autocvar_crosshair_ring_inner || autocvar_crosshair_ring_reload_inner) && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1182                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, ring_inner_alpha, DRAWFLAG_ADDITIVE);
1183
1184                                 if (ring_value)
1185                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, ring_alpha, DRAWFLAG_ADDITIVE);
1186                         }
1187
1188 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1189                         do \
1190                         { \
1191                                 if(wcross_blur > 0) \
1192                                 { \
1193                                         for(i = -2; i <= 2; ++i) \
1194                                                 for(j = -2; j <= 2; ++j) \
1195                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1196                                 } \
1197                                 else \
1198                                 { \
1199                                         M(0,0,sz,wcross_name,wcross_alpha); \
1200                                 } \
1201                         } \
1202                         while(0)
1203
1204 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1205                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1206
1207 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1208                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1209
1210                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1211                         {
1212                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1213                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1214                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1215                                 f = 1 - f;
1216                         }
1217                         else
1218                         {
1219                                 f = 1;
1220                         }
1221
1222                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1223                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1224
1225                         if(autocvar_crosshair_dot)
1226             {
1227                 vector wcross_color_old;
1228                 wcross_color_old = wcross_color;
1229                 if(autocvar_crosshair_dot_color != "0")
1230                     wcross_color = stov(autocvar_crosshair_dot_color);
1231                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1232                 wcross_color = wcross_color_old;
1233             }
1234
1235                         wcross_name_alpha_goal_prev = f;
1236                 }
1237                 else
1238                 {
1239                         wcross_scale_prev = 0;
1240                         wcross_alpha_prev = 0;
1241                         wcross_scale_goal_prev = 0;
1242                         wcross_alpha_goal_prev = 0;
1243                         wcross_changedonetime = 0;
1244                         if(wcross_name_goal_prev)
1245                                 strunzone(wcross_name_goal_prev);
1246                         wcross_name_goal_prev = string_null;
1247                         if(wcross_name_goal_prev_prev)
1248                                 strunzone(wcross_name_goal_prev_prev);
1249                         wcross_name_goal_prev_prev = string_null;
1250                         wcross_name_changestarttime = 0;
1251                         wcross_name_changedonetime = 0;
1252                         wcross_name_alpha_goal_prev = 0;
1253                         wcross_name_alpha_goal_prev_prev = 0;
1254                         wcross_resolution_goal_prev = 0;
1255                         wcross_resolution_goal_prev_prev = 0;
1256                 }
1257         }
1258
1259         if(NextFrameCommand)
1260         {
1261                 localcmd("\n", NextFrameCommand, "\n");
1262                 NextFrameCommand = string_null;
1263         }
1264
1265         // we must do this check AFTER a frame was rendered, or it won't work
1266         if(cs_project_is_b0rked == 0)
1267         {
1268                 string w0, h0;
1269                 w0 = ftos(autocvar_vid_conwidth);
1270                 h0 = ftos(autocvar_vid_conheight);
1271                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1272                 //R_SetView(VF_FOV, '90 90 0');
1273                 R_SetView(VF_ORIGIN, '0 0 0');
1274                 R_SetView(VF_ANGLES, '0 0 0');
1275                 R_SetView(VF_PERSPECTIVE, 1);
1276                 makevectors('0 0 0');
1277                 vector v1, v2;
1278                 cvar_set("vid_conwidth", "800");
1279                 cvar_set("vid_conheight", "600");
1280                 v1 = cs_project(v_forward);
1281                 cvar_set("vid_conwidth", "640");
1282                 cvar_set("vid_conheight", "480");
1283                 v2 = cs_project(v_forward);
1284                 if(v1 == v2)
1285                         cs_project_is_b0rked = 1;
1286                 else
1287                         cs_project_is_b0rked = -1;
1288                 cvar_set("vid_conwidth", w0);
1289                 cvar_set("vid_conheight", h0);
1290         }
1291
1292         if(autocvar__hud_configure)
1293                 HUD_Panel_Mouse();
1294
1295         // let's reset the view back to normal for the end
1296         R_SetView(VF_MIN, '0 0 0');
1297         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1298 }
1299
1300 #define spider_h "gfx/vehicles/hud_bg.tga"
1301 #define spider_b "gfx/vehicles/sbot.tga"
1302 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1303 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1304 #define spider_s "gfx/vehicles/shiled.tga"
1305 #define spider_a1 "gfx/hud/sb_rocket.tga"
1306 #define spider_a2 "gfx/sb_bullets.tga"
1307
1308 void CSQC_SPIDER_HUD()
1309 {
1310         float rockets, reload, heat, hp, shield;
1311         vector picsize, hudloc;
1312
1313     // Fetch health & ammo stats
1314     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1315         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1316         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1317         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1318         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1319
1320     // Draw the crosshairs
1321     picsize = drawgetimagesize(SPIDER_CROSS);
1322     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1323     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1324     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1325
1326     hudloc_y =  4;
1327     hudloc_x = 4;
1328
1329     picsize = drawgetimagesize(spider_h) * 0.5;
1330     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1331
1332     picsize = drawgetimagesize(spider_a2) * 0.5;
1333     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1334
1335     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1336     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1337     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1338
1339     picsize = drawgetimagesize(spider_a1) * 0.85;
1340     if(rockets == 9)
1341     {
1342         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1343         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1344     }
1345     else
1346     {
1347         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1348         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1349     }
1350
1351     picsize = drawgetimagesize(spider_b) * 0.5;
1352     hudloc_y = 10.5;
1353     hudloc_x = 10.5;
1354
1355     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1356     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1357     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1358     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1359
1360
1361         /*
1362         // Draw health bar
1363         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1364         p = p + '0 1 0' * vid_conheight - '0 32 0';
1365         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1366         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1367         p_y += 8;
1368         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1369         p_x += 256 * hp;
1370         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1371
1372         // Draw minigun heat indicator
1373         p = '0.5 0 0' * (vid_conwidth - 256);
1374         p = p + '0 1 0' * vid_conheight - '0 34  0';
1375         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1376         p_x += 256 * (1-heat);
1377         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1378
1379
1380         // Draw rocket icons for loaded/empty tubes.
1381         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1382         pp += '0 1 0' * vid_conheight - '0 64 0';
1383         for(i = 0; i < 8; ++i)
1384         {
1385                 p = pp + '1 0 0' * (rkt_size * i);
1386                 if(rockets == 8)
1387                 {
1388                         if(floor(reload * 8) == i)
1389                         {
1390                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1391                         }
1392                         else if(i < reload * 8)
1393                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1394                         else
1395                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1396                 }
1397                 else
1398                 {
1399                         if(i < rockets)
1400                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1401                         else
1402                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1403                 }
1404         }
1405         */
1406
1407         if (scoreboard_showscores)
1408         {
1409                 HUD_DrawScoreboard();
1410                 HUD_DrawCenterPrint();
1411         }
1412
1413 }
1414
1415 #define raptor_h "gfx/vehicles/hud_bg.tga"
1416 #define raptor_b "gfx/vehicles/raptor.tga"
1417 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1418 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1419 #define raptor_s "gfx/vehicles/shiled.tga"
1420
1421 void CSQC_RAPTOR_HUD()
1422 {
1423         float reload, hp, shield, energy;
1424         vector picsize, hudloc;
1425
1426     // Fetch health & ammo stats
1427     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1428         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1429         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1430         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1431
1432     // Draw the crosshairs
1433     picsize = drawgetimagesize(SPIDER_CROSS);
1434     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1435     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1436     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1437
1438     hudloc_y =  4;
1439     hudloc_x = 4;
1440
1441     picsize = drawgetimagesize(raptor_h) * 0.5;
1442     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1443
1444     picsize = drawgetimagesize(spider_a2) * 0.5;
1445     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1446
1447     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1448     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1449     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1450
1451
1452     picsize = drawgetimagesize(spider_a1) * 0.85;
1453     if(reload == 1)
1454     {
1455         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1456         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1457     }
1458     else
1459     {
1460         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1461         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1462     }
1463
1464     picsize = drawgetimagesize(raptor_b) * 0.5;
1465     hudloc_y = 10.5;
1466     hudloc_x = 10.5;
1467
1468     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1469     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1470     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1471     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1472
1473
1474         if (scoreboard_showscores)
1475         {
1476                 HUD_DrawScoreboard();
1477                 HUD_DrawCenterPrint();
1478         }
1479
1480 }
1481
1482 #define waki_h "gfx/vehicles/hud_bg.tga"
1483 #define waki_b "gfx/vehicles/waki.tga"
1484 #define waki_e "gfx/vehicles/waki_e.tga"
1485 #define waki_g "gfx/vehicles/waki_guns.tga"
1486 #define waki_r "gfx/vehicles/waki_rockets.tga"
1487 #define waki_s "gfx/vehicles/shiled.tga"
1488
1489 #define waki_a1 "gfx/hud/sb_rocket.tga"
1490 #define waki_a2 "gfx/sb_cells.tga"
1491
1492 void CSQC_WAKIZASHI_HUD()
1493 {
1494         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1495         float health, shield, energy, rockets;
1496         vector picsize, hudloc;
1497
1498     picsize = drawgetimagesize(SPIDER_CROSS);
1499     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1500     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1501     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1502
1503 /*
1504 const float STAT_VEHICLESTAT_HEALTH  = 60;
1505 const float STAT_VEHICLESTAT_SHIELD  = 61;
1506 const float STAT_VEHICLESTAT_ENERGY  = 62;
1507 const float STAT_VEHICLESTAT_AMMO1   = 63;
1508 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1509 const float STAT_VEHICLESTAT_AMMO2   = 65;
1510 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1511 */
1512     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1513         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1514         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1515         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1516
1517     hudloc_y =  4;
1518     hudloc_x = 4;
1519
1520     picsize = drawgetimagesize(waki_h) * 0.5;
1521     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1522
1523     picsize = drawgetimagesize(waki_a2) * 0.7;
1524     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1525
1526
1527     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1528     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1529
1530     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1531
1532     picsize = drawgetimagesize(waki_a1) * 0.75;
1533     if(rockets == 1)
1534     {
1535         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1536         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1537     }
1538     else
1539     {
1540         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1541         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1542         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1543     }
1544
1545     picsize = drawgetimagesize(waki_b) * 0.5;
1546     hudloc_y = 10.5;
1547     hudloc_x = 10.5;
1548
1549     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1550     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1551     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1552     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1553
1554
1555
1556         /*
1557         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1558         p = p + '0 1 0' * vid_conheight - '0 32 0';
1559
1560         // Draw health bar
1561         p_y += 8;
1562         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1563         p_x += 256 * health;
1564         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1565
1566         // Draw shiled bar
1567         p_x -= 256 * health;
1568         p_y += 4;
1569         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1570
1571         // Draw energy
1572         //p_x -= 256 * health;
1573         p_y -= 8;
1574         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1575
1576         // Draw rockets bar
1577         p_y += 12;
1578         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1579         */
1580
1581
1582
1583
1584         if (scoreboard_showscores)
1585         {
1586                 HUD_DrawScoreboard();
1587                 HUD_DrawCenterPrint();
1588         }
1589
1590 }
1591
1592
1593 void CSQC_common_hud(void)
1594 {
1595         // HUD_SortFrags(); done in HUD_Draw
1596         float hud;
1597         hud = getstati(STAT_HUD);
1598
1599         //hud = 10;
1600         switch(hud)
1601         {
1602                 case HUD_NORMAL:
1603                         // do some accuracy var caching
1604                         float i;
1605                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1606                         {
1607                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1608                                 {
1609                                         if(acc_color_levels)
1610                                                 strunzone(acc_color_levels);
1611                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1612                                         acc_levels = tokenize(acc_color_levels);
1613                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1614                                                 acc_levels = MAX_ACCURACY_LEVELS;
1615
1616                                         for (i = 0; i < acc_levels; ++i)
1617                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1618                                 }
1619                                 // let know that acc_col[] needs to be loaded
1620                                 acc_col_x[0] = -1;
1621                         }
1622
1623                         HUD_Main(); // always run these functions for alpha checks
1624                         HUD_DrawScoreboard();
1625
1626                         if (scoreboard_active) // scoreboard/accuracy
1627                         {
1628                                 HUD_Reset();
1629                                 // HUD_DrawScoreboard takes care of centerprint_start
1630                         }
1631                         else if (intermission == 2) // map voting screen
1632                         {
1633                                 HUD_FinaleOverlay();
1634                                 HUD_Reset();
1635
1636                                 centerprint_start_x = 0;
1637                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1638                         }
1639                         else // hud
1640                         {
1641                                 centerprint_start_x = 0;
1642                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1643                         }
1644
1645                         HUD_DrawCenterPrint();
1646                         break;
1647
1648                 case HUD_SPIDERBOT:
1649                         CSQC_SPIDER_HUD();
1650                         break;
1651
1652                 case HUD_WAKIZASHI:
1653                         CSQC_WAKIZASHI_HUD();
1654                         break;
1655         }
1656 }
1657
1658
1659 // following vectors must be global to allow seamless switching between camera modes
1660 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1661 void CSQC_Demo_Camera()
1662 {
1663         float speed, attenuation, dimensions;
1664         vector tmp, delta;
1665
1666         if( autocvar_camera_reset || !camera_mode )
1667         {
1668                 camera_offset = '0 0 0';
1669                 current_angles = '0 0 0';
1670                 camera_direction = '0 0 0';
1671                 camera_offset_z += 30;
1672                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1673                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1674                 current_origin = view_origin;
1675                 current_camera_offset  = camera_offset;
1676                 cvar_set("camera_reset", "0");
1677                 camera_mode = CAMERA_CHASE;
1678         }
1679
1680         // Camera angles
1681         if( camera_roll )
1682                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1683
1684         if(autocvar_camera_look_player)
1685         {
1686                 local vector dir;
1687                 local float n;
1688
1689                 dir = normalize(view_origin - current_position);
1690                 n = mouse_angles_z;
1691                 mouse_angles = vectoangles(dir);
1692                 mouse_angles_x = mouse_angles_x * -1;
1693                 mouse_angles_z = n;
1694         }
1695         else
1696         {
1697                 tmp = getmousepos() * 0.1;
1698                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1699                 {
1700                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1701                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1702                 }
1703         }
1704
1705         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1706         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1707         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1708         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1709
1710         // Fix difference when angles don't have the same sign
1711         delta = '0 0 0';
1712         if(mouse_angles_y < -60 && current_angles_y > 60)
1713                 delta = '0 360 0';
1714         if(mouse_angles_y > 60 && current_angles_y < -60)
1715                 delta = '0 -360 0';
1716
1717         if(autocvar_camera_look_player)
1718                 attenuation = autocvar_camera_look_attenuation;
1719         else
1720                 attenuation = autocvar_camera_speed_attenuation;
1721
1722         attenuation = 1 / max(1, attenuation);
1723         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1724
1725         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1726         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1727         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1728         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1729
1730         // Camera position
1731         tmp = '0 0 0';
1732         dimensions = 0;
1733
1734         if( camera_direction_x )
1735         {
1736                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1737                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1738                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1739                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1740                 ++dimensions;
1741         }
1742
1743         if( camera_direction_y )
1744         {
1745                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1746                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1747                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1748                 ++dimensions;
1749         }
1750
1751         if( camera_direction_z )
1752         {
1753                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1754                 ++dimensions;
1755         }
1756
1757         if(autocvar_camera_free)
1758                 speed = autocvar_camera_speed_free;
1759         else
1760                 speed = autocvar_camera_speed_chase;
1761
1762         if(dimensions)
1763         {
1764                 speed = speed * sqrt(1 / dimensions);
1765                 camera_offset += tmp * speed;
1766         }
1767
1768         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1769
1770         // Camera modes
1771         if( autocvar_camera_free )
1772         {
1773                 if ( camera_mode == CAMERA_CHASE )
1774                 {
1775                         current_camera_offset = current_origin + current_camera_offset;
1776                         camera_offset = current_origin + camera_offset;
1777                 }
1778
1779                 camera_mode = CAMERA_FREE;
1780                 current_position = current_camera_offset;
1781         }
1782         else
1783         {
1784                 if ( camera_mode == CAMERA_FREE )
1785                 {
1786                         current_origin = view_origin;
1787                         camera_offset = camera_offset - current_origin;
1788                         current_camera_offset = current_camera_offset - current_origin;
1789                 }
1790
1791                 camera_mode = CAMERA_CHASE;
1792
1793                 if(autocvar_camera_chase_smoothly)
1794                         current_origin += (view_origin - current_origin) * attenuation;
1795                 else
1796                         current_origin = view_origin;
1797
1798                 current_position = current_origin + current_camera_offset;
1799         }
1800
1801         R_SetView(VF_ANGLES, current_angles);
1802         R_SetView(VF_ORIGIN, current_position);
1803 }