qcsrc/client/bgmscript.qc

   1 #include "bgmscript.qh"
   2 #include "_all.qh"
   3
   4 #include "../common/util.qh"
   5
   6 #define CONSTANT_SPEED_DECAY
   7
   8 float bgmscriptbuf;
   9 float bgmscriptbufsize;
  10 float bgmscriptbufloaded;
  11
  12 class(BGMScript) .float bgmscriptline;
  13 class(BGMScript) .float bgmscriptline0;
  14 class(BGMScript) .float bgmscriptvolume;
  15 class(BGMScript) .float bgmscripttime;
  16 class(BGMScript) .float bgmscriptstate;
  17 class(BGMScript) .float bgmscriptstatetime;
  18
  19 float GetAttackDecaySustainAmplitude(float a, float d, float s, float t)
  20 {
  21         // phase:
  22         //   attack: from 0 to 1, in time a for a full length
  23         //   decay: from 1 to s, in time d
  24         //   sustain: s
  25
  26         if(t < 0)
  27                 return 0;
  28
  29         if(a)
  30                 if(t <= a)
  31                         return t / a;
  32
  33         if(d)
  34                 if(t <= a + d)
  35                         return ((t - a) / d) * (s - 1) + 1;
  36
  37         return s;
  38 }
  39
  40 float GetReleaseAmplitude(float d, float s, float r, float t)
  41 {
  42         float decayval, releaseval;
  43
  44         if(!r)
  45                 return 0;
  46
  47         if(t > r)
  48                 return 0;
  49
  50         releaseval = s * (1 - t / r);
  51
  52         if(t < -d)
  53                 return 1;
  54
  55         if(t < 0 && t >= -d)
  56         {
  57                 // pre-time decay
  58                 // value is s at time  0
  59                 //          1 at time -d
  60                 decayval = ((t + d) / d) * (s - 1) + 1;
  61                 return max(decayval, releaseval);
  62         }
  63
  64         return releaseval;
  65 }
  66
  67 float GetAttackTime(float a, float amp)
  68 {
  69         return amp * a;
  70 }
  71
  72 float GetReleaseTime(float d, float s, float r, float amp)
  73 {
  74         float decaytime, releasetime;
  75
  76         if(!s)
  77                 return 0;
  78
  79         // if amp > s, we may be in the attack or in the prolonged decay curve
  80         releasetime = (1 - amp / s) * r;
  81
  82         if(amp > s)
  83         {
  84                 if(s == 1) // gracefully handle division by zero here
  85                         return 0;
  86
  87                 // pre-time decay
  88                 // value is s at time  0
  89                 //          1 at time -d
  90                 decaytime = (amp - 1) / (s - 1) * d - d;
  91                 return max(decaytime, releasetime);
  92         }
  93
  94         return releasetime;
  95 }
  96
  97 void BGMScript_Init()
  98 {
  99         string s;
 100         float fh;
 101         bgmscriptbuf = bgmscriptbufsize = 0;
 102         bgmscriptbufloaded = 1;
 103         s = strcat("maps/", mi_shortname, ".bgs");
 104         fh = fopen(s, FILE_READ);
 105         if(fh < 0)
 106                 return;
 107         bgmscriptbuf = buf_create();
 108         while((s = fgets(fh)))
 109         {
 110                 bufstr_set(bgmscriptbuf, bgmscriptbufsize, s);
 111                 ++bgmscriptbufsize;
 112         }
 113         fclose(fh);
 114 }
 115
 116 void BGMScript_InitEntity(entity e)
 117 {
 118         float l;
 119         string m;
 120         if(e.bgmscript != "")
 121         {
 122                 if(!bgmscriptbufloaded)
 123                         BGMScript_Init();
 124
 125                 float i;
 126
 127                 m = strcat(e.bgmscript, " ");
 128                 l = strlen(m);
 129
 130                 e.bgmscriptline0 = -1;
 131                 for(i = 0; i < bgmscriptbufsize; ++i)
 132                 {
 133                         if(substring(bufstr_get(bgmscriptbuf, i), 0, l) == m)
 134                                 break;
 135                 }
 136                 e.bgmscriptline = e.bgmscriptline0 = i;
 137                 if(i >= bgmscriptbufsize)
 138                 {
 139                         printf("ERROR: bgmscript does not define %s\n", e.bgmscript);
 140                         strunzone(e.bgmscript);
 141                         e.bgmscript = string_null;
 142                 }
 143         }
 144 }
 145
 146 float GetCurrentAmplitude(entity e, float trel)
 147 {
 148         if(e.bgmscriptstate)
 149                 return GetAttackDecaySustainAmplitude(e.bgmscriptattack, e.bgmscriptdecay, e.bgmscriptsustain, trel) * e.bgmscriptvolume;
 150         else
 151         {
 152 #ifdef CONSTANT_SPEED_DECAY
 153                 return GetReleaseAmplitude(e.bgmscriptdecay, e.bgmscriptsustain * e.bgmscriptvolume, e.bgmscriptrelease, trel);
 154 #else
 155                 return GetReleaseAmplitude(e.bgmscriptdecay, e.bgmscriptsustain, e.bgmscriptrelease, trel) * e.bgmscriptvolume;
 156 #endif
 157         }
 158 }
 159
 160 float GetTimeForAmplitude(entity e, float amp)
 161 {
 162         if(e.bgmscriptstate)
 163                 return GetAttackTime(e.bgmscriptattack, amp / e.bgmscriptvolume);
 164         else
 165         {
 166 #ifdef CONSTANT_SPEED_DECAY
 167                 return GetReleaseTime(e.bgmscriptdecay, e.bgmscriptsustain * e.bgmscriptvolume, e.bgmscriptrelease, amp);
 168 #else
 169                 return GetReleaseTime(e.bgmscriptdecay, e.bgmscriptsustain, e.bgmscriptrelease, amp / e.bgmscriptvolume);
 170 #endif
 171         }
 172 }
 173
 174 float doBGMScript(entity e)
 175 {
 176         float amp, vel;
 177
 178         if(e.bgmscript == "")
 179                 return 1;
 180
 181         if(autocvar_bgmvolume <= 0)
 182                 return -1;
 183
 184         e.just_toggled = false;
 185
 186         if(bgmtime < 0)
 187                 return -1;
 188
 189         if(bgmtime < e.bgmscripttime)
 190         {
 191                 amp = GetCurrentAmplitude(e, e.bgmscripttime - e.bgmscriptstatetime + drawframetime);
 192
 193                 e.bgmscriptline = e.bgmscriptline0;
 194                 e.bgmscripttime = bgmtime;
 195
 196                 // treat this as a stop event for all notes, to prevent sticking keys
 197                 e.bgmscriptstate = false;
 198                 e.bgmscriptvolume = 1;
 199                 e.bgmscriptstatetime = bgmtime - GetTimeForAmplitude(e, amp);
 200         }
 201
 202         // find the CURRENT line
 203         for (;;)
 204         {
 205                 tokenize_console(bufstr_get(bgmscriptbuf, e.bgmscriptline));
 206                 if(stof(argv(1)) >= bgmtime || argv(0) != e.bgmscript)
 207                 {
 208                         e.bgmscripttime = bgmtime;
 209                         return GetCurrentAmplitude(e, bgmtime - e.bgmscriptstatetime);
 210                 }
 211                 else if(bgmtime >= stof(argv(1)))
 212                 {
 213                         e.bgmscriptline += 1;
 214                         e.bgmscripttime = stof(argv(1));
 215
 216                         amp = GetCurrentAmplitude(e, e.bgmscripttime - e.bgmscriptstatetime);
 217
 218                         // time code reached!
 219                         vel = stof(argv(2));
 220                         if(vel > 0)
 221                         {
 222                                 e.just_toggled = e.bgmscriptstate = true;
 223                                 e.bgmscriptvolume = vel;
 224                         }
 225                         else
 226                                 e.just_toggled = e.bgmscriptstate = false;
 227
 228                         e.bgmscriptstatetime = e.bgmscripttime - GetTimeForAmplitude(e, amp);
 229                 }
 230         }
 231 }
 232