qcsrc/client/casings.qc

   1 #if defined(CSQC)
   2         #include "autocvars.qh"
   3         #include "../common/util.qh"
   4         #include "defs.qh"
   5         #include "main.qh"
   6         #include "movetypes.qh"
   7         #include "prandom.qh"
   8         #include "rubble.qh"
   9
  10         .float cnt;
  11         .float alpha;
  12         .int state;
  13 #elif defined(MENUQC)
  14 #elif defined(SVQC)
  15 #endif
  16
  17 entityclass(Casing)
  18 class(Casing) .bool silent;
  19
  20 void Casing_Delete()
  21 {
  22     remove(self);
  23 }
  24
  25 void Casing_Draw()
  26 {
  27         if(self.move_flags & FL_ONGROUND)
  28         {
  29                 self.move_angles_x = 0;
  30                 self.move_angles_z = 0;
  31                 self.flags &= ~FL_ONGROUND;
  32         }
  33
  34         Movetype_Physics_MatchTicrate(autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
  35         if(wasfreed(self))
  36                 return; // deleted by touch function
  37
  38         self.renderflags = 0;
  39         self.alpha = bound(0, self.cnt - time, 1);
  40
  41         if(self.alpha < ALPHA_MIN_VISIBLE)
  42         {
  43                 Casing_Delete();
  44                 self.drawmask = 0;
  45         }
  46 }
  47
  48 void Casing_Touch()
  49 {
  50         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  51         {
  52                 Casing_Delete();
  53                 return;
  54         }
  55
  56         if(!self.silent)
  57         if(!trace_ent || trace_ent.solid == SOLID_BSP)
  58         {
  59                 if(vlen(self.velocity) > 50)
  60                 {
  61                         if(time >= self.nextthink)
  62                         {
  63                                 string s;
  64                                 int f = floor(prandom() * 3) + 1;
  65
  66                                 switch(self.state)
  67                                 {
  68                                         case 1:
  69                                                 s = strcat("weapons/casings", itos(f), ".wav");
  70                                                 break;
  71                                         default:
  72                                                 s = strcat("weapons/brass", itos(f), ".wav");
  73                                                 break;
  74                                 }
  75
  76                                 sound (self, CH_SHOTS, s, VOL_BASE, ATTEN_LARGE);
  77                         }
  78                 }
  79         }
  80
  81         self.nextthink = time + 0.2;
  82 }
  83
  84 void Casing_Damage(float thisdmg, int hittype, vector org, vector thisforce)
  85 {
  86         if(thisforce.z < 0)
  87                 thisforce.z = 0;
  88         self.move_velocity = self.move_velocity + thisforce + '0 0 100';
  89         self.move_flags &= ~FL_ONGROUND;
  90 }
  91
  92 void Ent_Casing(float isNew)
  93 {
  94         entity casing;
  95
  96         casing = RubbleNew("casing");
  97         casing.state = ReadByte();
  98         casing.silent = (casing.state & 0x80);
  99         casing.state = (casing.state & 0x7F);
 100         casing.origin_x = ReadCoord();
 101         casing.origin_y = ReadCoord();
 102         casing.origin_z = ReadCoord();
 103         setorigin(casing, casing.origin);
 104         casing.velocity = decompressShortVector(ReadShort());
 105         casing.angles_x = ReadByte() * 360 / 256;
 106         casing.angles_y = ReadByte() * 360 / 256;
 107         casing.angles_z = ReadByte() * 360 / 256;
 108         casing.drawmask = MASK_NORMAL;
 109
 110         if(autocvar_cl_casings && isNew) {
 111                 casing.draw = Casing_Draw;
 112                 casing.move_origin = casing.origin;
 113                 casing.move_velocity = casing.velocity + 2 * prandomvec();
 114                 casing.move_angles = casing.angles;
 115                 casing.move_avelocity = '0 250 0' + 100 * prandomvec();
 116                 casing.move_movetype = MOVETYPE_BOUNCE;
 117                 casing.move_touch = Casing_Touch;
 118                 casing.move_time = time;
 119                 casing.event_damage = Casing_Damage;
 120                 casing.solid = SOLID_TRIGGER;
 121
 122                 switch(casing.state)
 123                 {
 124                         case 1:
 125                                 setmodel(casing, "models/casing_shell.mdl");
 126                                 casing.cnt = time + autocvar_cl_casings_shell_time;
 127                                 break;
 128                         default:
 129                                 setmodel(casing, "models/casing_bronze.iqm");
 130                                 casing.cnt = time + autocvar_cl_casings_bronze_time;
 131                                 break;
 132                 }
 133
 134                 setsize(casing, '0 0 -1', '0 0 -1');
 135
 136                 RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
 137         }
 138         else
 139         {
 140                 entity oldself = self;
 141                 self = casing;
 142                 Casing_Delete(); // yes, this IS stupid, but I don't need to duplicate all the read* stuff then
 143                 self = oldself;
 144         }
 145 }
 146
 147 void Casings_Precache()
 148 {
 149         precache_model("models/casing_shell.mdl");
 150         precache_model("models/casing_bronze.iqm");
 151         precache_sound("weapons/brass1.wav");
 152         precache_sound("weapons/brass2.wav");
 153         precache_sound("weapons/brass3.wav");
 154         precache_sound("weapons/casings1.wav");
 155         precache_sound("weapons/casings2.wav");
 156         precache_sound("weapons/casings3.wav");
 157 }