qcsrc/client/commands/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 #include "../../common/command/command.qh"
   7 #include "cl_cmd.qh"
   8
   9 #include "../autocvars.qh"
  10 #include "../defs.qh"
  11 #include "../hud/all.qh"
  12 #include "../main.qh"
  13 #include "../mapvoting.qh"
  14 #include "../miscfunctions.qh"
  15
  16 #include "../mutators/events.qh"
  17
  18 #include "../../common/mapinfo.qh"
  19
  20 #include "../../common/command/generic.qh"
  21
  22 void DrawDebugModel(entity this)
  23 {
  24         if (time - floor(time) > 0.5)
  25         {
  26                 PolyDrawModel(self);
  27                 self.drawmask = 0;
  28         }
  29         else
  30         {
  31                 self.renderflags = 0;
  32                 self.drawmask = MASK_NORMAL;
  33         }
  34 }
  35
  36
  37 // =======================
  38 //  Command Sub-Functions
  39 // =======================
  40
  41 void LocalCommand_blurtest(int request)
  42 {
  43         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  44         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  45
  46         #ifdef BLURTEST
  47         switch (request)
  48         {
  49                 case CMD_REQUEST_COMMAND:
  50                 {
  51                         blurtest_time0 = time;
  52                         blurtest_time1 = time + stof(argv(1));
  53                         blurtest_radius = stof(argv(2));
  54                         blurtest_power = stof(argv(3));
  55                         LOG_INFO("Enabled blurtest\n");
  56                         return;
  57                 }
  58
  59                 default:
  60                 case CMD_REQUEST_USAGE:
  61                 {
  62                         LOG_INFO("\nUsage:^3 cl_cmd blurtest\n");
  63                         LOG_INFO("  No arguments required.\n");
  64                         return;
  65                 }
  66         }
  67         #else
  68         if (request)
  69         {
  70                 LOG_INFO("Blurtest is not enabled on this client.\n");
  71                 return;
  72         }
  73         #endif
  74 }
  75
  76 void LocalCommand_boxparticles(int request, int argc)
  77 {
  78         switch (request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if (argc == 9)
  83                         {
  84                                 int effect = _particleeffectnum(argv(1));
  85                                 if (effect >= 0)
  86                                 {
  87                                         int index = stoi(argv(2));
  88                                         entity own;
  89                                         if (index <= 0)
  90                                                 own = entitybyindex(-index);
  91                                         else
  92                                                 own = findfloat(world, entnum, index);
  93                                         vector org_from = stov(argv(3));
  94                                         vector org_to = stov(argv(4));
  95                                         vector dir_from = stov(argv(5));
  96                                         vector dir_to = stov(argv(6));
  97                                         int countmultiplier = stoi(argv(7));
  98                                         int flags = stoi(argv(8));
  99                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
 100                                         return;
 101                                 }
 102                         }
 103                 }
 104
 105                 default:
 106                 {
 107                         LOG_INFO("Incorrect parameters for ^2boxparticles^7\n");
 108                 }
 109                 case CMD_REQUEST_USAGE:
 110                 {
 111                         LOG_INFO("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
 112                         LOG_INFO("  'effectname' is the name of a particle effect in effectinfo.txt\n");
 113                         LOG_INFO("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
 114                         LOG_INFO("  'org_from' is the starting origin of the box\n");
 115                         LOG_INFO("  'org_to' is the ending origin of the box\n");
 116                         LOG_INFO("  'dir_from' is the minimum velocity\n");
 117                         LOG_INFO("  'dir_to' is the maximum velocity\n");
 118                         LOG_INFO("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 119                         LOG_INFO("  'flags' can contain:\n");
 120                         LOG_INFO("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 121                         LOG_INFO("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 122                         LOG_INFO("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 123                         LOG_INFO("    128 to draw a trail, not a box\n");
 124                         return;
 125                 }
 126         }
 127 }
 128
 129 void LocalCommand_create_scrshot_ent(int request)
 130 {
 131         switch (request)
 132         {
 133                 case CMD_REQUEST_COMMAND:
 134                 {
 135                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 136                         int fh = fopen(filename, FILE_WRITE);
 137
 138                         if (fh >= 0)
 139                         {
 140                                 fputs(fh, "{\n");
 141                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 142                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin.x), " ", ftos(view_origin.y), " ", ftos(view_origin.z)), "\"\n"));
 143                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles.x), " ", ftos(view_angles.y), " ", ftos(view_angles.z)), "\"\n"));
 144                                 fputs(fh, "}\n");
 145
 146                                 LOG_INFO("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 147
 148                                 fclose(fh);
 149                         }
 150                         else
 151                         {
 152                                 LOG_INFO("^1Error: ^7Could not dump to file!\n");
 153                         }
 154                         return;
 155                 }
 156
 157                 default:
 158                 case CMD_REQUEST_USAGE:
 159                 {
 160                         LOG_INFO("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 161                         LOG_INFO("  No arguments required.\n");
 162                         return;
 163                 }
 164         }
 165 }
 166
 167 void LocalCommand_debugmodel(int request, int argc)
 168 {
 169         switch (request)
 170         {
 171                 case CMD_REQUEST_COMMAND:
 172                 {
 173                         string modelname = argv(1);
 174
 175                         entity debugmodel_entity = new(debugmodel);
 176                         precache_model(modelname);
 177                         _setmodel(debugmodel_entity, modelname);
 178                         setorigin(debugmodel_entity, view_origin);
 179                         debugmodel_entity.angles = view_angles;
 180                         debugmodel_entity.draw = DrawDebugModel;
 181
 182                         return;
 183                 }
 184
 185                 default:
 186                 case CMD_REQUEST_USAGE:
 187                 {
 188                         LOG_INFO("\nUsage:^3 cl_cmd debugmodel model\n");
 189                         LOG_INFO("  Where 'model' is a string of the model name to use for the debug model.\n");
 190                         return;
 191                 }
 192         }
 193 }
 194
 195 void LocalCommand_handlevote(int request, int argc)
 196 {
 197         switch (request)
 198         {
 199                 case CMD_REQUEST_COMMAND:
 200                 {
 201                         int vote_selection;
 202                         string vote_string;
 203
 204                         if (InterpretBoolean(argv(1)))
 205                         {
 206                                 vote_selection = 2;
 207                                 vote_string = "yes";
 208                         }
 209                         else
 210                         {
 211                                 vote_selection = 1;
 212                                 vote_string = "no";
 213                         }
 214
 215                         if (vote_selection)
 216                         {
 217                                 if (uid2name_dialog)  // handled by "uid2name" option
 218                                 {
 219                                         vote_active = 0;
 220                                         vote_prev = 0;
 221                                         vote_change = -9999;
 222                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 223                                         uid2name_dialog = 0;
 224                                 }
 225                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 226
 227                                 return;
 228                         }
 229                 }
 230
 231                 default:
 232                 {
 233                         LOG_INFO("Incorrect parameters for ^2handlevote^7\n");
 234                 }
 235                 case CMD_REQUEST_USAGE:
 236                 {
 237                         LOG_INFO("\nUsage:^3 cl_cmd handlevote vote\n");
 238                         LOG_INFO("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 239                         return;
 240                 }
 241         }
 242 }
 243
 244 bool QuickMenu_IsOpened();
 245 void QuickMenu_Close();
 246 bool QuickMenu_Open(string mode, string submenu);
 247
 248 bool HUD_MinigameMenu_IsOpened();
 249 void HUD_MinigameMenu_Close();
 250 void HUD_MinigameMenu_Open();
 251
 252 void HUD_Radar_Show_Maximized(bool doshow, bool clickable);
 253
 254 void LocalCommand_hud(int request, int argc)
 255 {
 256         switch (request)
 257         {
 258                 case CMD_REQUEST_COMMAND:
 259                 {
 260                         if(MUTATOR_CALLHOOK(HUD_Command, argc))
 261                                 return;
 262
 263                         switch (argv(1))
 264                         {
 265                                 case "configure":
 266                                 {
 267                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 268                                         return;
 269                                 }
 270
 271                                 case "quickmenu":
 272                                 {
 273                                         if (argv(2) == "help")
 274                                         {
 275                                                 LOG_INFO(" quickmenu [[default | file | \"\"] submenu]\n");
 276                                                 LOG_INFO("Called without options (or with \"\") loads either the default quickmenu or a quickmenu file if hud_panel_quickmenu_file is set to a valid filename.\n");
 277                                                 LOG_INFO("A submenu name can be given to open the quickmenu directly in a submenu; it requires to specify 'default', 'file' or '\"\"' option.\n");
 278                                                 return;
 279                                         }
 280                                         if (QuickMenu_IsOpened())
 281                                                 QuickMenu_Close();
 282                                         else
 283                                                 QuickMenu_Open(argv(2), argv(3));  // mode, submenu
 284                                         return;
 285                                 }
 286
 287                                 case "minigame":
 288                                 {
 289                                         if (HUD_MinigameMenu_IsOpened())
 290                                                 HUD_MinigameMenu_Close();
 291                                         else
 292                                                 HUD_MinigameMenu_Open();
 293                                         return;
 294                                 }
 295
 296                                 case "save":
 297                                 {
 298                                         if (argv(2))
 299                                         {
 300                                                 HUD_Panel_ExportCfg(argv(2));
 301                                                 return;
 302                                         }
 303                                         else
 304                                         {
 305                                                 break;  // go to usage, we're missing the paramater needed here.
 306                                         }
 307                                 }
 308
 309                                 case "scoreboard_columns_set":
 310                                 {
 311                                         Cmd_HUD_SetFields(argc);
 312                                         return;
 313                                 }
 314
 315                                 case "scoreboard_columns_help":
 316                                 {
 317                                         Cmd_HUD_Help();
 318                                         return;
 319                                 }
 320
 321                                 case "radar":
 322                                 {
 323                                         if (argv(2))
 324                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)), 0);
 325                                         else
 326                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized, 0);
 327                                         return;
 328                                 }
 329
 330                                 case "clickradar":
 331                                 {
 332                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse, 1);
 333                                         return;
 334                                 }
 335                         }
 336                 }
 337
 338                 default:
 339                 {
 340                         LOG_INFO("Incorrect parameters for ^2hud^7\n");
 341                 }
 342                 case CMD_REQUEST_USAGE:
 343                 {
 344                         LOG_INFO("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 345                         LOG_INFO("  Where 'action' is the command to complete,\n");
 346                         LOG_INFO("  'configname' is the name to save to for \"save\" action,\n");
 347                         LOG_INFO("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 348                         LOG_INFO("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 349                         LOG_INFO("  Full list of commands here: \"configure, quickmenu, minigame, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 void LocalCommand_localprint(int request, int argc)
 356 {
 357         switch (request)
 358         {
 359                 case CMD_REQUEST_COMMAND:
 360                 {
 361                         if (argv(1))
 362                         {
 363                                 centerprint_hud(argv(1));
 364                                 return;
 365                         }
 366                 }
 367
 368                 default:
 369                 {
 370                         LOG_INFO("Incorrect parameters for ^2localprint^7\n");
 371                 }
 372                 case CMD_REQUEST_USAGE:
 373                 {
 374                         LOG_INFO("\nUsage:^3 cl_cmd localprint \"message\"\n");
 375                         LOG_INFO("  'message' is the centerprint message to send to yourself.\n");
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 void LocalCommand_mv_download(int request, int argc)
 382 {
 383         switch (request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         if (argv(1))
 388                         {
 389                                 Cmd_MapVote_MapDownload(argc);
 390                                 return;
 391                         }
 392                 }
 393
 394                 default:
 395                 {
 396                         LOG_INFO("Incorrect parameters for ^2mv_download^7\n");
 397                 }
 398                 case CMD_REQUEST_USAGE:
 399                 {
 400                         LOG_INFO("\nUsage:^3 cl_cmd mv_download mapid\n");
 401                         LOG_INFO("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 402                         return;
 403                 }
 404         }
 405 }
 406
 407 void LocalCommand_find(int request, int argc)
 408 {
 409         switch (request)
 410         {
 411                 case CMD_REQUEST_COMMAND:
 412                 {
 413                         FOREACH_ENTITY_CLASS(argv(1), true, LAMBDA(LOG_INFO(etos(it), "\n")));
 414                         return;
 415                 }
 416
 417                 default:
 418                 {
 419                         LOG_INFO("Incorrect parameters for ^2find^7\n");
 420                 }
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         LOG_INFO("\nUsage:^3 cl_cmd find classname\n");
 424                         LOG_INFO("  Where 'classname' is the classname to search for.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void LocalCommand_sendcvar(int request, int argc)
 431 {
 432         switch (request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if (argv(1))
 437                         {
 438                                 // W_FixWeaponOrder will trash argv, so save what we need.
 439                                 string thiscvar = strzone(argv(1));
 440                                 string s = cvar_string(thiscvar);
 441
 442                                 if (thiscvar == "cl_weaponpriority")
 443                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 444                                 else if (substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 445                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 446
 447                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 448                                 strunzone(thiscvar);
 449                                 return;
 450                         }
 451                 }
 452
 453                 default:
 454                 {
 455                         LOG_INFO("Incorrect parameters for ^2sendcvar^7\n");
 456                 }
 457                 case CMD_REQUEST_USAGE:
 458                 {
 459                         LOG_INFO("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 460                         LOG_INFO("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 461                         return;
 462                 }
 463         }
 464 }
 465
 466 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 467 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 468 void LocalCommand_(int request)
 469 {
 470     switch(request)
 471     {
 472         case CMD_REQUEST_COMMAND:
 473         {
 474
 475             return;
 476         }
 477
 478         default:
 479         case CMD_REQUEST_USAGE:
 480         {
 481             print("\nUsage:^3 cl_cmd \n");
 482             print("  No arguments required.\n");
 483             return;
 484         }
 485     }
 486 }
 487 */
 488
 489
 490 // ==================================
 491 //  Macro system for client commands
 492 // ==================================
 493
 494 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 495 CLIENT_COMMAND(blurtest, "Feature for testing blur postprocessing") { LocalCommand_blurtest(request); }
 496 CLIENT_COMMAND(boxparticles, "Spawn particles manually") { LocalCommand_boxparticles(request, arguments); }
 497 CLIENT_COMMAND(create_scrshot_ent, "Create an entity at this location for automatic screenshots") { LocalCommand_create_scrshot_ent(request); }
 498 CLIENT_COMMAND(debugmodel, "Spawn a debug model manually") { LocalCommand_debugmodel(request, arguments); }
 499 CLIENT_COMMAND(handlevote, "System to handle selecting a vote or option") { LocalCommand_handlevote(request, arguments); }
 500 CLIENT_COMMAND(hud, "Commands regarding/controlling the HUD system") { LocalCommand_hud(request, arguments); }
 501 CLIENT_COMMAND(localprint, "Create your own centerprint sent to yourself") { LocalCommand_localprint(request, arguments); }
 502 CLIENT_COMMAND(find, "Search through entities for matching classname") { LocalCommand_find(request, arguments); }
 503 CLIENT_COMMAND(mv_download, "Retrieve mapshot picture from the server") { LocalCommand_mv_download(request, arguments); }
 504 CLIENT_COMMAND(sendcvar, "Send a cvar to the server (like weaponpriority)") { LocalCommand_sendcvar(request, arguments); }
 505
 506 void LocalCommand_macro_help()
 507 {
 508         FOREACH(CLIENT_COMMANDS, true, LAMBDA(LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description)));
 509 }
 510
 511 bool LocalCommand_macro_command(int argc, string command)
 512 {
 513         string c = strtolower(argv(0));
 514         FOREACH(CLIENT_COMMANDS, it.m_name == c, LAMBDA(
 515                 it.m_invokecmd(CMD_REQUEST_COMMAND, NULL, argc, command);
 516                 return true;
 517         ));
 518         return false;
 519 }
 520
 521 bool LocalCommand_macro_usage(int argc)
 522 {
 523         string c = strtolower(argv(1));
 524         FOREACH(CLIENT_COMMANDS, it.m_name == c, LAMBDA(
 525                 it.m_invokecmd(CMD_REQUEST_USAGE, NULL, argc, "");
 526                 return true;
 527         ));
 528         return false;
 529 }
 530
 531 void LocalCommand_macro_write_aliases(int fh)
 532 {
 533         FOREACH(CLIENT_COMMANDS, true, LAMBDA(CMD_Write_Alias("qc_cmd_cl", it.m_name, it.m_description)));
 534 }
 535
 536
 537 // =========================================
 538 //  Main Function Called By Engine (cl_cmd)
 539 // =========================================
 540 // If this function exists, client code handles gamecommand instead of the engine code.
 541
 542 void GameCommand(string command)
 543 {
 544         int argc = tokenize_console(command);
 545
 546         // Guide for working with argc arguments by example:
 547         // argc:   1    - 2      - 3     - 4
 548         // argv:   0    - 1      - 2     - 3
 549         // cmd     vote - master - login - password
 550         string s = strtolower(argv(0));
 551         if (s == "help")
 552         {
 553                 if (argc == 1)
 554                 {
 555                         LOG_INFO("\nClient console commands:\n");
 556                         LocalCommand_macro_help();
 557
 558                         LOG_INFO("\nGeneric commands shared by all programs:\n");
 559                         GenericCommand_macro_help();
 560
 561                         LOG_INFO("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 562                         LOG_INFO("For help about a specific command, type cl_cmd help COMMAND\n");
 563
 564                         return;
 565                 }
 566                 else if (GenericCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
 567                 {
 568                         return;
 569                 }
 570                 else if (LocalCommand_macro_usage(argc))  // now try for normal commands too
 571                 {
 572                         return;
 573                 }
 574         }
 575         // continue as usual and scan for normal commands
 576         if (GenericCommand(command)                                    // handled by common/command/generic.qc
 577             || LocalCommand_macro_command(argc, command)               // handled by one of the above LocalCommand_* functions
 578             || MUTATOR_CALLHOOK(CSQC_ConsoleCommand, s, argc, command) // handled by a mutator
 579            ) return;
 580
 581         // nothing above caught the command, must be invalid
 582         LOG_INFO(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 583 }
 584
 585
 586 // ===================================
 587 //  Macro system for console commands
 588 // ===================================
 589
 590 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 591 // Please add client commands to the function above this, as this is only for special reasons.
 592 #define CONSOLE_COMMANDS_NORMAL() \
 593         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = true; }) \
 594         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = false; }) \
 595         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = true; }) \
 596         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = false; }) \
 597         /* nothing */
 598
 599 #define CONSOLE_COMMANDS_MOVEMENT() \
 600         CONSOLE_COMMAND("+forward", { ++camera_direction.x; }) \
 601         CONSOLE_COMMAND("-forward", { --camera_direction.x; }) \
 602         CONSOLE_COMMAND("+back", { --camera_direction.x; }) \
 603         CONSOLE_COMMAND("-back", { ++camera_direction.x; }) \
 604         CONSOLE_COMMAND("+moveup", { ++camera_direction.z; }) \
 605         CONSOLE_COMMAND("-moveup", { --camera_direction.z; }) \
 606         CONSOLE_COMMAND("+movedown", { --camera_direction.z; }) \
 607         CONSOLE_COMMAND("-movedown", { ++camera_direction.z; }) \
 608         CONSOLE_COMMAND("+moveright", { --camera_direction.y; }) \
 609         CONSOLE_COMMAND("-moveright", { ++camera_direction.y; }) \
 610         CONSOLE_COMMAND("+moveleft", { ++camera_direction.y; }) \
 611         CONSOLE_COMMAND("-moveleft", { --camera_direction.y; }) \
 612         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 613         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 614         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 615         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 616         /* nothing */
 617
 618 void ConsoleCommand_macro_init()
 619 {
 620         // first init normal commands
 621         #define CONSOLE_COMMAND(name, execution) \
 622                 { registercommand(name); }
 623
 624         CONSOLE_COMMANDS_NORMAL();
 625         #undef CONSOLE_COMMAND
 626
 627         // then init movement commands
 628         #ifndef CAMERATEST
 629         if (isdemo())
 630         {
 631         #endif
 632         #define CONSOLE_COMMAND(name, execution) \
 633                 registercommand(name);
 634
 635         CONSOLE_COMMANDS_MOVEMENT();
 636                 #undef CONSOLE_COMMAND
 637         #ifndef CAMERATEST
 638 }
 639         #endif
 640 }
 641
 642 bool ConsoleCommand_macro_normal(string s, int argc)
 643 {
 644         #define CONSOLE_COMMAND(name, execution) \
 645                 { if (name == s) { { execution } return true; } }
 646
 647         CONSOLE_COMMANDS_NORMAL();
 648         #undef CONSOLE_COMMAND
 649
 650         return false;
 651 }
 652
 653 bool ConsoleCommand_macro_movement(string s, int argc)
 654 {
 655         if (camera_active)
 656         {
 657                 #define CONSOLE_COMMAND(name, execution) \
 658                         { if (name == s) { { execution } return true; } }
 659
 660                 CONSOLE_COMMANDS_MOVEMENT();
 661                 #undef CONSOLE_COMMAND
 662         }
 663
 664         return false;
 665 }
 666
 667
 668 // ======================================================
 669 //  Main Function Called By Engine (registered commands)
 670 // ======================================================
 671 // Used to parse commands in the console that have been registered with the "registercommand" function
 672
 673 bool CSQC_ConsoleCommand(string command)
 674 {
 675         int argc = tokenize_console(command);
 676         string s = strtolower(argv(0));
 677         // Return value should be true if CSQC handled the command, otherwise return false to have the engine handle it.
 678         return ConsoleCommand_macro_normal(s, argc)
 679                || ConsoleCommand_macro_movement(s, argc)
 680         ;
 681 }