qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 // set modelindex
  18                 self.lodmodelindex0 = self.modelindex;
  19                 self.lodmodelindex1 = self.modelindex;
  20                 self.lodmodelindex2 = self.modelindex;
  21
  22                 // FIXME: this only supports 3-letter extensions
  23                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  24                 if(fexists(s))
  25                 {
  26                         precache_model(s);
  27                         setmodel(self, s);
  28                         if(self.modelindex)
  29                                 self.lodmodelindex1 = self.modelindex;
  30                 }
  31
  32                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  33                 if(fexists(s))
  34                 {
  35                         precache_model(s);
  36                         setmodel(self, s);
  37                         if(self.modelindex)
  38                                 self.lodmodelindex2 = self.modelindex;
  39                 }
  40
  41                 setmodel(self, modelname); // make everything normal again
  42         }
  43
  44         // apply LOD
  45         if(autocvar_cl_playerdetailreduction <= 0)
  46         {
  47                 if(autocvar_cl_playerdetailreduction <= -2)
  48                         self.modelindex = self.lodmodelindex2;
  49                 else if(autocvar_cl_playerdetailreduction <= -1)
  50                         self.modelindex = self.lodmodelindex1;
  51                 else
  52                         self.modelindex = self.lodmodelindex0;
  53         }
  54         else
  55         {
  56                 float distance = vlen(self.origin - other.origin);
  57                 float f = (distance + 100.0) * autocvar_cl_playerdetailreduction;
  58                 f *= 1.0 / bound(0.01, view_quality, 1);
  59                 if(f > autocvar_cl_loddistance2)
  60                         self.modelindex = self.lodmodelindex2;
  61                 else if(f > autocvar_cl_loddistance1)
  62                         self.modelindex = self.lodmodelindex1;
  63                 else
  64                         self.modelindex = self.lodmodelindex0;
  65         }
  66 }
  67
  68 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  69 string forceplayermodels_model;
  70 float forceplayermodels_modelisgoodmodel;
  71 float forceplayermodels_modelindex;
  72 float forceplayermodels_skin;
  73
  74 string forceplayermodels_mymodel;
  75 float forceplayermodels_myisgoodmodel;
  76 float forceplayermodels_mymodelindex;
  77
  78 float forceplayermodels_attempted;
  79
  80 .string forceplayermodels_savemodel;
  81 .float forceplayermodels_savemodelindex;
  82 .float forceplayermodels_saveskin;
  83 .float forceplayermodels_savecolormap;
  84
  85 .string forceplayermodels_isgoodmodel_mdl;
  86 .float forceplayermodels_isgoodmodel;
  87
  88 string forceplayermodels_goodmodel;
  89 float forceplayermodels_goodmodelindex;
  90
  91 void CSQCPlayer_ForceModel_PreUpdate(void)
  92 {
  93         self.model = self.forceplayermodels_savemodel;
  94         self.modelindex = self.forceplayermodels_savemodelindex;
  95         self.skin = self.forceplayermodels_saveskin;
  96         self.colormap = self.forceplayermodels_savecolormap;
  97 }
  98 void CSQCPlayer_ForceModel_PostUpdate(void)
  99 {
 100         self.forceplayermodels_savemodel = self.model;
 101         self.forceplayermodels_savemodelindex = self.modelindex;
 102         self.forceplayermodels_saveskin = self.skin;
 103         self.forceplayermodels_savecolormap = self.colormap;
 104
 105         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 106         {
 107                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 108                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 109                 if(!self.forceplayermodels_isgoodmodel)
 110                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 111         }
 112 }
 113 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 114 {
 115         // which one is ALWAYS good?
 116         if not(forceplayermodels_goodmodel)
 117         {
 118                 entity e;
 119                 e = spawn();
 120                 setmodel(e, cvar_defstring("_cl_playermodel"));
 121                 forceplayermodels_goodmodel = e.model;
 122                 forceplayermodels_goodmodelindex = e.modelindex;
 123                 remove(e);
 124         }
 125
 126         // first, try finding it from the server
 127         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 128         {
 129                 if(islocalplayer)
 130                 {
 131                         // trust server's idea of "own player model"
 132                         forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 133                         forceplayermodels_model = self.forceplayermodels_savemodel;
 134                         forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 135                         forceplayermodels_skin = self.forceplayermodels_saveskin;
 136                         forceplayermodels_attempted = 1;
 137                 }
 138         }
 139
 140         // forcemodel finding
 141         if(!forceplayermodels_attempted)
 142         {
 143                 forceplayermodels_attempted = 1;
 144
 145                 // only if this failed, find it out on our own
 146                 entity e;
 147                 e = spawn();
 148                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 149                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 150                 forceplayermodels_model = e.model;
 151                 forceplayermodels_modelindex = e.modelindex;
 152                 forceplayermodels_skin = autocvar__cl_playerskin;
 153                 remove(e);
 154         }
 155
 156         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 157         {
 158                 entity e;
 159                 e = spawn();
 160                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 161                 forceplayermodels_myisgoodmodel = fexists(e.model);
 162                 forceplayermodels_mymodel = e.model;
 163                 forceplayermodels_mymodelindex = e.modelindex;
 164                 remove(e);
 165         }
 166
 167         // apply it
 168         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && self.entnum == player_localnum + 1)
 169         {
 170                 self.model = forceplayermodels_mymodel;
 171                 self.modelindex = forceplayermodels_mymodelindex;
 172                 self.skin = autocvar_cl_forcemyplayerskin;
 173         }
 174         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 175         {
 176                 self.model = forceplayermodels_model;
 177                 self.modelindex = forceplayermodels_modelindex;
 178                 self.skin = forceplayermodels_skin;
 179         }
 180         else if(self.forceplayermodels_isgoodmodel)
 181         {
 182                 self.model = self.forceplayermodels_savemodel;
 183                 self.modelindex = self.forceplayermodels_savemodelindex;
 184                 self.skin = self.forceplayermodels_saveskin;
 185         }
 186         else
 187         {
 188                 self.model = forceplayermodels_goodmodel;
 189                 self.modelindex = forceplayermodels_goodmodelindex;
 190                 self.skin = self.forceplayermodels_saveskin;
 191         }
 192
 193         // forceplayercolors too
 194         if(!teamplay)
 195         {
 196                 if(autocvar_cl_forcemyplayercolors && self.entnum == player_localnum + 1)
 197                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 198                 else if(autocvar_cl_forceplayercolors)
 199                         self.colormap = player_localnum + 1;
 200         }
 201 }
 202
 203 // FEATURE: fallback frames
 204 .float csqcmodel_saveframe;
 205 .float csqcmodel_saveframe2;
 206 .float csqcmodel_saveframe3;
 207 .float csqcmodel_saveframe4;
 208 .float csqcmodel_framecount;
 209 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 210 {
 211         self.frame = self.csqcmodel_saveframe;
 212         self.frame2 = self.csqcmodel_saveframe2;
 213         self.frame3 = self.csqcmodel_saveframe3;
 214         self.frame4 = self.csqcmodel_saveframe4;
 215 }
 216 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 217 {
 218         self.csqcmodel_saveframe = self.frame;
 219         self.csqcmodel_saveframe2 = self.frame2;
 220         self.csqcmodel_saveframe3 = self.frame3;
 221         self.csqcmodel_saveframe4 = self.frame4;
 222
 223         // hack for death animations: set their frametime to zero in case a
 224         // player "pops in"
 225         if(isnew)
 226         {
 227 #define FIX_FRAMETIME(f,ft) \
 228                 switch(self.f) \
 229                 { \
 230                         case 0: \
 231                         case 1: \
 232                                 self.ft = 0; \
 233                                 break; \
 234                 }
 235                 FIX_FRAMETIME(frame, frame1time)
 236                 FIX_FRAMETIME(frame2, frame2time)
 237                 FIX_FRAMETIME(frame3, frame3time)
 238                 FIX_FRAMETIME(frame4, frame4time)
 239         }
 240 }
 241 float CSQCPlayer_FallbackFrame(float f)
 242 {
 243         if(frameduration(self.modelindex, f) > 0)
 244                 return f; // goooooood
 245         switch(f)
 246         {
 247                 case 23: return 11; // anim_melee -> anim_shoot
 248                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 249                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 250                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 251                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 252                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 253                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 254                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 255         }
 256         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 257         return f;
 258 }
 259 void CSQCPlayer_FallbackFrame_Apply(void)
 260 {
 261         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 262         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 263         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 264         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 265 }
 266
 267 // FEATURE: auto glowmod
 268 .vector glowmod;
 269 void CSQCPlayer_GlowMod_Apply(void)
 270 {
 271         if(self.colormap > 0)
 272                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 273         else
 274                 self.glowmod = '1 1 1';
 275 }
 276
 277 // FEATURE: auto tag_index
 278 .entity tag_entity;
 279 .float tag_entity_lastmodelindex;
 280 .float tag_index;
 281 void CSQCModel_AutoTagIndex_Apply(void)
 282 {
 283         if(self.tag_entity && wasfreed(self.tag_entity))
 284                 self.tag_entity = world;
 285
 286         if(self.tag_networkentity)
 287         {
 288                 // we are ATTACHED!
 289                 float changed = 0;
 290                 if(self.tag_entity.entnum != self.tag_networkentity)
 291                 {
 292                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 293                         changed = 1;
 294                 }
 295
 296                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 297                 {
 298                         entity oldself = self;
 299                         self = self.tag_entity;
 300                         CSQCModel_Hook_PreDraw();
 301                         self = oldself;
 302                 }
 303
 304                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 305                 {
 306                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 307                         changed = 1;
 308                 }
 309                 if(changed)
 310                 {
 311                         if(self.tag_entity)
 312                         {
 313                                 // the best part is: IT EXISTS
 314                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 315                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 316                                         {
 317                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 318                                                 if(!self.tag_index)
 319                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 320                                                 if(!self.tag_index)
 321                                                 {
 322                                                         // we need to prevent this from 'appening
 323                                                         self.tag_entity = world;
 324                                                         self.drawmask = 0;
 325                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 326                                                 }
 327                                         }
 328
 329                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 330                                         if(substring(self.tag_entity.model, 0, 14) == "models/player/")
 331                                         {
 332                                                 self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 333                                                 if(!self.tag_index)
 334                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 335                                         }
 336
 337                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 338                                 {
 339                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 340                                         if(!self.tag_index)
 341                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 342                                 }
 343                         }
 344                         else
 345                         {
 346                                 // damn, see you next frame
 347                                 self.drawmask = 0;
 348                         }
 349                 }
 350         }
 351 }
 352
 353 // FEATURE: EF_NODRAW workalike
 354 float EF_BRIGHTFIELD    = 1;
 355 float EF_BRIGHTLIGHT    = 4;
 356 float EF_DIMLIGHT       = 8;
 357 float EF_DOUBLESIDED = 32768;
 358 float EF_NOSELFSHADOW = 65536;
 359 float EF_DYNAMICMODELLIGHT = 131072;
 360 float MF_ROCKET  =   1; // leave a trail
 361 float MF_GRENADE =   2; // leave a trail
 362 float MF_GIB     =   4; // leave a trail
 363 float MF_ROTATE  =   8; // rotate (bonus items)
 364 float MF_TRACER  =  16; // green split trail
 365 float MF_ZOMGIB  =  32; // small blood trail
 366 float MF_TRACER2 =  64; // orange split trail
 367 float MF_TRACER3 = 128; // purple trail
 368 .float csqcmodel_effects;
 369 .float csqcmodel_modelflags;
 370 void CSQCModel_Effects_PreUpdate(void)
 371 {
 372         self.effects = self.csqcmodel_effects;
 373         self.modelflags = self.csqcmodel_modelflags;
 374 }
 375 void CSQCModel_Effects_PostUpdate(void)
 376 {
 377         self.csqcmodel_effects = self.effects;
 378         self.csqcmodel_modelflags = self.modelflags;
 379         self.effects = 0;
 380         self.modelflags = 0;
 381         if(self.csqcmodel_teleported)
 382                 Projectile_ResetTrail(self.origin);
 383 }
 384 void CSQCModel_Effects_Apply(void)
 385 {
 386         float eff = self.csqcmodel_effects;
 387         eff &~= CSQCMODEL_EF_INVISIBLE;
 388
 389         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 390         self.effects = 0;
 391         self.traileffect = 0;
 392
 393         if(eff & EF_BRIGHTFIELD)
 394                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 395         // ignoring EF_MUZZLEFLASH
 396         if(eff & EF_BRIGHTLIGHT)
 397                 adddynamiclight(self.origin, 400, '3 3 3');
 398         if(eff & EF_DIMLIGHT)
 399                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 400         if((eff & EF_NODRAW) || (self.csqcmodel_effects & CSQCMODEL_EF_INVISIBLE) || (self.alpha < 0))
 401                 self.drawmask = 0;
 402         if(eff & EF_ADDITIVE)
 403                 self.renderflags |= RF_ADDITIVE;
 404         if(eff & EF_BLUE)
 405                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 406         if(eff & EF_RED)
 407                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 408         // ignoring EF_NOGUNBOB
 409         if(eff & EF_FULLBRIGHT)
 410                 self.renderflags |= RF_FULLBRIGHT;
 411         if(eff & EF_FLAME)
 412                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 413         if(eff & EF_STARDUST)
 414                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 415         if(eff & EF_NOSHADOW)
 416                 self.renderflags |= RF_NOSHADOW;
 417         if(eff & EF_NODEPTHTEST)
 418                 self.renderflags |= RF_DEPTHHACK;
 419         // ignoring EF_SELECTABLE
 420         if(eff & EF_DOUBLESIDED)
 421                 self.effects |= EF_DOUBLESIDED;
 422         if(eff & EF_NOSELFSHADOW)
 423                 self.effects |= EF_NOSELFSHADOW;
 424         if(eff & EF_DYNAMICMODELLIGHT)
 425                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 426         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 427         if(self.csqcmodel_modelflags & MF_ROCKET)
 428                 self.traileffect = particleeffectnum("TR_ROCKET");
 429         if(self.csqcmodel_modelflags & MF_GRENADE)
 430                 self.traileffect = particleeffectnum("TR_GRENADE");
 431         if(self.csqcmodel_modelflags & MF_GIB)
 432                 self.traileffect = particleeffectnum("TR_BLOOD");
 433         if(self.csqcmodel_modelflags & MF_ROTATE)
 434         {
 435                 self.renderflags |= RF_USEAXIS;
 436                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 437         }
 438         if(self.csqcmodel_modelflags & MF_TRACER)
 439                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 440         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 441                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 442         if(self.csqcmodel_modelflags & MF_TRACER2)
 443                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 444         if(self.csqcmodel_modelflags & MF_TRACER3)
 445                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 446
 447         if(self.drawmask)
 448                 Projectile_DrawTrail(self.origin);
 449         else
 450                 Projectile_ResetTrail(self.origin);
 451 }
 452
 453 // general functions
 454 .float csqcmodel_predraw_run;
 455 void CSQCModel_Hook_PreDraw()
 456 {
 457         if(self.csqcmodel_predraw_run == framecount)
 458                 return;
 459         self.csqcmodel_predraw_run = framecount;
 460
 461         if(!self.modelindex || self.model == "null")
 462         {
 463                 self.drawmask = 0;
 464                 return;
 465         }
 466         else
 467                 self.drawmask = MASK_NORMAL;
 468
 469         if(self.isplayermodel) // this checks if it's a player MODEL!
 470         {
 471                 CSQCPlayer_GlowMod_Apply();
 472                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 473                 CSQCPlayer_LOD_Apply();
 474                 CSQCPlayer_FallbackFrame_Apply();
 475         }
 476
 477         CSQCModel_AutoTagIndex_Apply();
 478
 479         CSQCModel_Effects_Apply();
 480 }
 481
 482 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 483 {
 484         // revert to values from server
 485         CSQCModel_Effects_PreUpdate();
 486         if(self.isplayermodel)
 487         {
 488                 CSQCPlayer_FallbackFrame_PreUpdate();
 489                 CSQCPlayer_ForceModel_PreUpdate();
 490         }
 491 }
 492
 493 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 494 {
 495         // is it a player model? (shared state)
 496         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
 497
 498         // save values set by server
 499         if(self.isplayermodel)
 500         {
 501                 CSQCPlayer_ForceModel_PostUpdate();
 502                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 503         }
 504         CSQCModel_Effects_PostUpdate();
 505 }