qcsrc/client/hud/panel/pressedkeys.qc

   1 #include "pressedkeys.qh"
   2 /** Draw pressed keys (#11) */
   3 void HUD_PressedKeys()
   4 {
   5         if(!autocvar__hud_configure)
   6         {
   7                 if(!autocvar_hud_panel_pressedkeys) return;
   8                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
   9         }
  10
  11         HUD_Panel_UpdateCvars();
  12         vector pos, mySize;
  13         pos = panel_pos;
  14         mySize = panel_size;
  15
  16         HUD_Scale_Enable();
  17         HUD_Panel_DrawBg(1);
  18         if(panel_bg_padding)
  19         {
  20                 pos += '1 1 0' * panel_bg_padding;
  21                 mySize -= '2 2 0' * panel_bg_padding;
  22         }
  23
  24         // force custom aspect
  25         float aspect = autocvar_hud_panel_pressedkeys_aspect;
  26         if(aspect)
  27         {
  28                 vector newSize = '0 0 0';
  29                 if(mySize.x/mySize.y > aspect)
  30                 {
  31                         newSize.x = aspect * mySize.y;
  32                         newSize.y = mySize.y;
  33
  34                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
  35                 }
  36                 else
  37                 {
  38                         newSize.y = 1/aspect * mySize.x;
  39                         newSize.x = mySize.x;
  40
  41                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
  42                 }
  43                 mySize = newSize;
  44         }
  45
  46         vector keysize;
  47         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
  48         int pressedkeys = STAT(PRESSED_KEYS);
  49
  50         if(autocvar_hud_panel_pressedkeys_attack)
  51         {
  52                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  53                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  54                 pos.y += keysize.y;
  55         }
  56
  57         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  58         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  59         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  60         pos.y += keysize.y;
  61         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  62         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  63         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  64 }