qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2 // QuickMenu (#23)
   3
   4 #include <common/ent_cs.qh>
   5 #include <client/hud/all.qh>
   6 #include <client/mapvoting.qh>
   7
   8 // QUICKMENU_MAXLINES must be <= 10
   9 const int QUICKMENU_MAXLINES = 10;
  10 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  11 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  12 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  14 int QuickMenu_Page_Entries;
  15 int QuickMenu_Page;
  16 int QuickMenu_Page_ActivatedEntry = -1;
  17 bool QuickMenu_Page_ActivatedEntry_Close;
  18 float QuickMenu_Page_ActivatedEntry_Time;
  19 bool QuickMenu_IsLastPage;
  20 // all the entries are loaded into QuickMenu_Buffer
  21 // each entry (submenu or command) is composed of 2 entries
  22 const int QUICKMENU_MAXENTRIES = 256;
  23 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  24 int QuickMenu_Buffer = -1;
  25 int QuickMenu_Buffer_Size;
  26 int QuickMenu_Buffer_Index;
  27 string QuickMenu_CurrentSubMenu;
  28 float QuickMenu_TimeOut;
  29
  30 // QuickMenu_Buffer are labeled with these tags
  31 #define QM_TAG_TITLE "T"
  32 #define QM_TAG_SUBMENU "S"
  33 #define QM_TAG_COMMAND "C"
  34 #define QM_TAG_PLCOMMAND "P"
  35
  36 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  37 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  38
  39 // if s1 is not empty s will be displayed as command otherwise as submenu
  40 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  41 {
  42     TC(int, i);
  43         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  44         if (QuickMenu_Page_Description[i])
  45                 strunzone(QuickMenu_Page_Description[i]);
  46         QuickMenu_Page_Description[i] = strzone(s);
  47         if (QuickMenu_Page_Command[i])
  48                 strunzone(QuickMenu_Page_Command[i]);
  49         QuickMenu_Page_Command[i] = strzone(s1);
  50 }
  51
  52 void QuickMenu_Page_ClearEntry(int i)
  53 {
  54     TC(int, i);
  55         if (QuickMenu_Page_Description[i])
  56                 strunzone(QuickMenu_Page_Description[i]);
  57         QuickMenu_Page_Description[i] = string_null;
  58         if (QuickMenu_Page_Command[i])
  59                 strunzone(QuickMenu_Page_Command[i]);
  60         QuickMenu_Page_Command[i] = string_null;
  61         QuickMenu_Page_Command_Type[i] = 0;
  62 }
  63
  64 float QuickMenu_Page_Load(string target_submenu, float new_page);
  65 void QuickMenu_Default(string submenu);
  66 bool QuickMenu_Open(string mode, string submenu)
  67 {
  68         int fh = -1;
  69         string s;
  70
  71         if(mode == "")
  72         {
  73                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  74                         mode = "default";
  75                 else
  76                         mode = "file";
  77         }
  78
  79         if(mode == "file")
  80         {
  81                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  82                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  83                 else
  84                 {
  85                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  86                         if(fh < 0)
  87                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  88                 }
  89                 if(fh < 0)
  90                         mode = "default";
  91         }
  92
  93         if(mode == "default")
  94         {
  95                 QuickMenu_Buffer = buf_create();
  96                 if(QuickMenu_Buffer < 0)
  97                         return false;
  98
  99                 QuickMenu_Default(submenu);
 100         }
 101         else if(mode == "file")
 102         {
 103                 QuickMenu_Buffer = buf_create();
 104                 if(QuickMenu_Buffer < 0)
 105                 {
 106                         fclose(fh);
 107                         return false;
 108                 }
 109
 110                 QuickMenu_Buffer_Size = 0;
 111                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 112                 {
 113                         // first skip invalid entries, so we don't check them anymore
 114                         float argc;
 115                         argc = tokenize_console(s);
 116                         if(argc == 0 || argv(0) == "")
 117                                 continue;
 118                         if(argc == 1)
 119                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 120                         else if(argc == 2)
 121                         {
 122                                 if(argv(1) == "")
 123                                         continue;
 124                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 125                                 ++QuickMenu_Buffer_Size;
 126                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 127                         }
 128                         else if(argc == 3)
 129                         {
 130                                 // check for special keywords
 131                                 float teamplayers = 0, without_me = 0;
 132                                 switch(argv(2))
 133                                 {
 134                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 135                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 136                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 137                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 138                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 139                                         default: continue;
 140                                 }
 141
 142                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 143                                 {
 144                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 145                                         ++QuickMenu_Buffer_Size;
 146                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 147                                         ++QuickMenu_Buffer_Size;
 148                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 149                                         ++QuickMenu_Buffer_Size;
 150                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 151                                 }
 152                         }
 153                         ++QuickMenu_Buffer_Size;
 154                 }
 155                 fclose(fh);
 156         }
 157         else
 158         {
 159                 LOG_WARNINGF("Unrecognized mode %s\n", mode);
 160                 return false;
 161         }
 162
 163         if (QuickMenu_Buffer_Size <= 0)
 164         {
 165                 buf_del(QuickMenu_Buffer);
 166                 QuickMenu_Buffer = -1;
 167                 return false;
 168         }
 169
 170         if(mode == "file")
 171                 QuickMenu_Page_Load(submenu, 0);
 172         else
 173                 QuickMenu_Page_Load("", 0);
 174
 175         hud_panel_quickmenu = 1;
 176         if(autocvar_hud_cursormode)
 177                 setcursormode(1);
 178         hudShiftState = 0;
 179
 180         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 181         return true;
 182 }
 183
 184 void QuickMenu_Buffer_Close()
 185 {
 186         if (QuickMenu_Buffer >= 0)
 187         {
 188                 buf_del(QuickMenu_Buffer);
 189                 QuickMenu_Buffer = -1;
 190                 QuickMenu_Buffer_Size = 0;
 191         }
 192 }
 193
 194 void QuickMenu_Close()
 195 {
 196         if (QuickMenu_CurrentSubMenu)
 197                 strunzone(QuickMenu_CurrentSubMenu);
 198         QuickMenu_CurrentSubMenu = string_null;
 199         int i;
 200         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 201                 QuickMenu_Page_ClearEntry(i);
 202         QuickMenu_Page_Entries = 0;
 203         hud_panel_quickmenu = 0;
 204         mouseClicked = 0;
 205         prevMouseClicked = 0;
 206         QuickMenu_Buffer_Close();
 207
 208         if(autocvar_hud_cursormode)
 209         if(!mv_active)
 210                 setcursormode(0);
 211 }
 212
 213 // It assumes submenu open tag is already detected
 214 void QuickMenu_skip_submenu(string submenu)
 215 {
 216         string s, z_submenu;
 217         z_submenu = strzone(submenu);
 218         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 219         {
 220                 s = QuickMenu_Buffer_Get();
 221                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 222                         continue;
 223                 if(substring(s, 1, -1) == z_submenu) // submenu end
 224                         break;
 225                 QuickMenu_skip_submenu(substring(s, 1, -1));
 226         }
 227         strunzone(z_submenu);
 228 }
 229
 230 bool QuickMenu_IsOpened()
 231 {
 232         return (QuickMenu_Page_Entries > 0);
 233 }
 234
 235 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 236 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 237 {
 238     TC(int, teamplayers); TC(bool, without_me);
 239         int i;
 240         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 241                 QuickMenu_Page_ClearEntry(i);
 242         QuickMenu_Buffer_Close();
 243
 244         QuickMenu_Buffer = buf_create();
 245         if(QuickMenu_Buffer < 0)
 246                 return false;
 247
 248         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 249
 250         if(QuickMenu_Buffer_Size <= 0)
 251         {
 252                 buf_del(QuickMenu_Buffer);
 253                 QuickMenu_Buffer = -1;
 254                 return false;
 255         }
 256         return true;
 257 }
 258
 259 // new_page 0 means page 0, new_page != 0 means next page
 260 int QuickMenu_Buffer_Index_Prev;
 261 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 262 {
 263     TC(bool, new_page);
 264         string s = string_null, cmd = string_null, z_submenu;
 265
 266         if (new_page == 0)
 267                 QuickMenu_Page = 0;
 268         else
 269                 ++QuickMenu_Page;
 270
 271         z_submenu = strzone(target_submenu);
 272         if (QuickMenu_CurrentSubMenu)
 273                 strunzone(QuickMenu_CurrentSubMenu);
 274         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 275
 276         QuickMenu_IsLastPage = true;
 277         QuickMenu_Page_Entries = 0;
 278
 279         QuickMenu_Buffer_Index = 0;
 280         if (z_submenu != "")
 281         {
 282                 // skip everything until the submenu open tag is found
 283                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 284                 {
 285                         s = QuickMenu_Buffer_Get();
 286                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 287                         {
 288                                 // printf("^3 beginning of %s\n", z_submenu);
 289                                 ++QuickMenu_Buffer_Index;
 290                                 break; // target_submenu found!
 291                         }
 292                         // printf("^1 skipping %s\n", s);
 293                 }
 294                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 295                         LOG_WARNINGF("Couldn't find submenu \"%s\"\n", z_submenu);
 296         }
 297
 298         // only the last page can contain up to QUICKMENU_MAXLINES entries
 299         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 300         // so that the panel can show an empty row and "Continue..."
 301         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 302         int entry_num = 0; // counts entries in target_submenu
 303         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 304         {
 305                 s = QuickMenu_Buffer_Get();
 306
 307                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 308                 {
 309                         // printf("^3 end of %s\n", z_submenu);
 310                         break;
 311                 }
 312
 313                 if(entry_num >= first_entry)
 314                 {
 315                         ++QuickMenu_Page_Entries;
 316                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 317                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 318                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 319                         {
 320                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 321                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 322                                 QuickMenu_IsLastPage = false;
 323                                 break;
 324                         }
 325                 }
 326
 327                 // NOTE: entries are loaded starting from 1, not from 0
 328                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 329                 {
 330                         if(entry_num >= first_entry)
 331                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 332                         QuickMenu_skip_submenu(substring(s, 1, -1));
 333                 }
 334                 else if(entry_num >= first_entry && substring(s, 0, 1) == QM_TAG_TITLE)
 335                 {
 336                         ++QuickMenu_Buffer_Index;
 337                         cmd = QuickMenu_Buffer_Get();
 338                         string command_code = substring(cmd, 0, 1);
 339                         if(command_code == QM_TAG_COMMAND)
 340                                 cmd = substring(cmd, 1, -1);
 341                         else if(command_code == QM_TAG_PLCOMMAND)
 342                         {
 343                                 // throw away the current quickmenu buffer and load a new one
 344                                 cmd = substring(cmd, 1, -1);
 345                                 strunzone(z_submenu);
 346                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 347                                         return QuickMenu_Page_Load("", 0);
 348                                 QuickMenu_Close();
 349                                 return false;
 350                         }
 351
 352                         tokenize_console(cmd);
 353                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 354
 355                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 356                 }
 357
 358                 ++entry_num;
 359         }
 360         strunzone(z_submenu);
 361         if (QuickMenu_Page_Entries == 0)
 362         {
 363                 QuickMenu_Close();
 364                 return false;
 365         }
 366         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 367         return true;
 368 }
 369
 370 bool QuickMenu_ActionForNumber(int num)
 371 {
 372     TC(int, num);
 373         if (!QuickMenu_IsLastPage)
 374         {
 375                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 376                         return false;
 377                 if (num == QUICKMENU_MAXLINES - 1)
 378                         return false;
 379                 if (num == 0)
 380                 {
 381                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 382                         return false;
 383                 }
 384         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 385                 return false;
 386
 387         if (QuickMenu_Page_Command[num] != "")
 388         {
 389                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 390                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 391                 return true;
 392         }
 393         if (QuickMenu_Page_Description[num] != "")
 394                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 395         return false;
 396 }
 397
 398 void QuickMenu_Page_ActiveEntry(int entry_num)
 399 {
 400     TC(int, entry_num);
 401         QuickMenu_Page_ActivatedEntry = entry_num;
 402         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 403         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 404         {
 405                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 406                 // toggle commands don't close the quickmenu
 407                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 408                         QuickMenu_Page_ActivatedEntry_Close = false;
 409                 else
 410                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 411         }
 412         else
 413                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 414 }
 415
 416 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 417 {
 418     TC(int, bInputType);
 419         // we only care for keyboard events
 420         if(bInputType == 2)
 421                 return false;
 422
 423         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 424                 return false;
 425
 426         if(bInputType == 3)
 427         {
 428                 mousepos.x = nPrimary;
 429                 mousepos.y = nSecondary;
 430                 return true;
 431         }
 432
 433         // allow console bind to work
 434         string con_keys;
 435         float keys;
 436         con_keys = findkeysforcommand("toggleconsole", 0);
 437         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 438
 439         bool hit_con_bind = false;
 440         int i;
 441         for (i = 0; i < keys; ++i)
 442         {
 443                 if(nPrimary == stof(argv(i)))
 444                         hit_con_bind = true;
 445         }
 446
 447         if(bInputType == 0) {
 448                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 449                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 450                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 451         }
 452         else if(bInputType == 1) {
 453                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 454                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 455                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 456         }
 457
 458         if(nPrimary == K_ESCAPE)
 459         {
 460                 if (bInputType == 1)
 461                         return true;
 462                 QuickMenu_Close();
 463         }
 464         else if(nPrimary >= '0' && nPrimary <= '9')
 465         {
 466                 if (bInputType == 1)
 467                         return true;
 468                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 469         }
 470         if(nPrimary == K_MOUSE1)
 471         {
 472                 if(bInputType == 0) // key pressed
 473                         mouseClicked |= S_MOUSE1;
 474                 else if(bInputType == 1) // key released
 475                         mouseClicked -= (mouseClicked & S_MOUSE1);
 476         }
 477         else if(nPrimary == K_MOUSE2)
 478         {
 479                 if(bInputType == 0) // key pressed
 480                         mouseClicked |= S_MOUSE2;
 481                 else if(bInputType == 1) // key released
 482                         mouseClicked -= (mouseClicked & S_MOUSE2);
 483         }
 484         else if(hit_con_bind)
 485                 return false;
 486
 487         return true;
 488 }
 489
 490 void QuickMenu_Mouse()
 491 {
 492         if(mv_active) return;
 493
 494         if(!mouseClicked)
 495         if(prevMouseClicked & S_MOUSE2)
 496         {
 497                 QuickMenu_Close();
 498                 return;
 499         }
 500
 501         if(!autocvar_hud_cursormode)
 502         {
 503                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 504
 505                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 506                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 507         }
 508
 509         HUD_Panel_UpdateCvars();
 510
 511         if(panel_bg_padding)
 512         {
 513                 panel_pos += '1 1 0' * panel_bg_padding;
 514                 panel_size -= '2 2 0' * panel_bg_padding;
 515         }
 516
 517         float first_entry_pos, entries_height;
 518         vector fontsize;
 519         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 520         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 521         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 522
 523         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 524         {
 525                 float entry_num;
 526                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 527                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 528                 {
 529                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 530                         vector color;
 531                         if(mouseClicked & S_MOUSE1)
 532                                 color = '0.5 1 0.5';
 533                         else if(hudShiftState & S_CTRL)
 534                                 color = '1 1 0.3';
 535                         else
 536                                 color = '1 1 1';
 537                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 538
 539                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 540                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 541                 }
 542         }
 543
 544         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 545
 546         prevMouseClicked = mouseClicked;
 547 }
 548
 549 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 550 {
 551         string entry;
 552         float offset;
 553         float desc_width = panel_size.x;
 554         if(option)
 555         {
 556                 string pic = strcat(hud_skin_path, "/", option);
 557                 if(precache_pic(pic) == "")
 558                         pic = strcat("gfx/hud/default/", option);
 559                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 560                 desc_width -= option_size.x;
 561                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 562                 desc_width -= fontsize.x / 4;
 563         }
 564         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 565         if (autocvar_hud_panel_quickmenu_align > 0)
 566         {
 567                 float real_desc_width = stringwidth_colors(entry, fontsize);
 568                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 569
 570                 if(option)
 571                 {
 572                         // when there's enough room align description regardless the checkbox
 573                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 574                         if(offset + real_desc_width + extra_offset < desc_width)
 575                                 offset += extra_offset;
 576                         else
 577                                 offset = max(0, desc_width - real_desc_width);
 578                 }
 579                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 580         }
 581         else
 582                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 583 }
 584
 585 void HUD_QuickMenu()
 586 {
 587         if(!autocvar__hud_configure)
 588         {
 589                 if (hud_configure_prev && hud_configure_prev != -1)
 590                         QuickMenu_Close();
 591
 592                 if(!hud_draw_maximized) return;
 593                 if(mv_active) return;
 594                 //if(!autocvar_hud_panel_quickmenu) return;
 595                 if(!hud_panel_quickmenu) return;
 596
 597                 if(QuickMenu_TimeOut)
 598                 if(time > QuickMenu_TimeOut)
 599                 {
 600                         QuickMenu_Close();
 601                         return;
 602                 }
 603         }
 604         else
 605         {
 606                 if(!QuickMenu_IsOpened())
 607                 {
 608                         QuickMenu_Page_Entries = 1;
 609                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 610                         ++QuickMenu_Page_Entries;
 611                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 612                         ++QuickMenu_Page_Entries;
 613                         // although real command doesn't matter here, it must not be empty
 614                         // otherwise the entry is displayed like a submenu
 615                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 616                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 617                         ++QuickMenu_Page_Entries;
 618                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 619                         QuickMenu_IsLastPage = false;
 620                 }
 621         }
 622
 623         HUD_Panel_UpdateCvars();
 624
 625         HUD_Scale_Disable();
 626         HUD_Panel_DrawBg(1);
 627
 628         if(panel_bg_padding)
 629         {
 630                 panel_pos += '1 1 0' * panel_bg_padding;
 631                 panel_size -= '2 2 0' * panel_bg_padding;
 632         }
 633
 634         int i;
 635         vector fontsize;
 636         string color;
 637         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 638
 639         if (!QuickMenu_IsLastPage)
 640         {
 641                 color = "^5";
 642                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 643         }
 644         else
 645                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 646
 647         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 648                 if (QuickMenu_Page_Description[i] == "")
 649                         break;
 650                 string option = string_null;
 651                 if (QuickMenu_Page_Command[i] == "")
 652                         color = "^4";
 653                 else
 654                 {
 655                         color = "^3";
 656                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 657                         {
 658                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 659                                 if(end < 0)
 660                                         tokenize_console(QuickMenu_Page_Command[i]);
 661                                 else
 662                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 663
 664                                 if(argv(1) && argv(0) == "toggle")
 665                                 {
 666                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 667                                         // "disable feature xxx" "toggle xxx 0 1"
 668                                         float ON_value = 1, OFF_value = 0;
 669                                         if(argv(2))
 670                                                 ON_value = stof(argv(2));
 671
 672                                         if(argv(3))
 673                                                 OFF_value = stof(argv(3));
 674                                         else
 675                                                 OFF_value = !ON_value;
 676
 677                                         float value = cvar(argv(1));
 678                                         if(value == ON_value)
 679                                                 option = "checkbox_checked";
 680                                         else if(value == OFF_value)
 681                                                 option = "checkbox_empty";
 682                                         else
 683                                                 option = "checkbox_undefined";
 684                                 }
 685                         }
 686                 }
 687                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 688
 689                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 690                         && QuickMenu_Page_ActivatedEntry == i)
 691                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 692
 693                 panel_pos.y += fontsize.y;
 694         }
 695
 696         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 697         {
 698                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 699                 {
 700                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 701                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 702                                 QuickMenu_Close();
 703                 }
 704                 else if(QuickMenu_Page_ActivatedEntry_Close)
 705                         QuickMenu_Close();
 706                 QuickMenu_Page_ActivatedEntry = -1;
 707                 QuickMenu_Page_ActivatedEntry_Time = 0;
 708         }
 709 }
 710
 711
 712 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 713         if(target_submenu == eng_submenu && target_submenu_found) \
 714                 return; /* target_submenu entries are now loaded, exit */ \
 715         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 716                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 717         ++QuickMenu_Buffer_Size; \
 718         if(target_submenu == eng_submenu && !target_submenu_found) { \
 719                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 720                 target_submenu_found = true; \
 721         } \
 722 }
 723
 724 #define QUICKMENU_ENTRY(title,command) { \
 725         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 726         { \
 727                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 728                 ++QuickMenu_Buffer_Size; \
 729                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 730         } \
 731         ++QuickMenu_Buffer_Size; \
 732 }
 733
 734 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 735         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 736                 QUICKMENU_SMENU(submenu,eng_submenu) \
 737                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 738                 ++QuickMenu_Buffer_Size; \
 739                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 740                 ++QuickMenu_Buffer_Size; \
 741                 QUICKMENU_SMENU(submenu,eng_submenu) \
 742         } \
 743 }
 744
 745
 746
 747 // useful to Translate a string inside the Command
 748 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 749         if(prvm_language == "en") \
 750                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 751         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 752                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 753         else \
 754                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 755 }
 756
 757 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 758 {
 759     TC(int, teamplayers); TC(bool, without_me);
 760         entity pl;
 761         if(teamplayers && !team_count)
 762                 return;
 763
 764         for(pl = players.sort_next; pl; pl = pl.sort_next)
 765         {
 766                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 767                         continue;
 768                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 769                         continue;
 770                 if(without_me && pl.sv_entnum == player_localnum)
 771                         continue;
 772                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 773         }
 774
 775         return;
 776 }
 777
 778
 779 // Specifying target_submenu, this function only loads entries inside target_submenu
 780 // NOTE: alternatively we could have loaded the whole default quickmenu and
 781 // then called QuickMenu_Page_Load(target_submenu, 0);
 782 // but this sytem is more reliable since we can always refer to target_submenu
 783 // with the English title even if a translation is active
 784 void QuickMenu_Default(string target_submenu)
 785 {
 786         bool target_submenu_found = false;
 787         if(target_submenu != "")
 788                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 789
 790         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 791                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 792                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 793                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 794         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 795
 796         if(teamplay)
 797         {
 798         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 813                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 814         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 815         }
 816
 817         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 818
 819         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 820                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 824                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 826                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 827                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 828
 829                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 830                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 831                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 832                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 833
 834                 if(spectatee_status > 0)
 835                 {
 836                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 838                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 839                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 840                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 841                 }
 842
 843                 if(spectatee_status == -1)
 844                 {
 845                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 846                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 847                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 848                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 849                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 850                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 851                 }
 852
 853                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 854                 if(prvm_language != "en")
 855                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 856         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 857
 858         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 859                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 860                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 861                 if(STAT(TIMELIMIT) > 0)
 862                 {
 863                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 864                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 865                 }
 866                 if(teamplay)
 867                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 868         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 869
 870         if(target_submenu != "" && !target_submenu_found)
 871         {
 872                 LOG_WARNINGF("Couldn't find submenu \"%s\"\n", target_submenu);
 873                 if(prvm_language != "en")
 874                         LOG_WARNINGF("^3Warning: submenu must be in English\n", target_submenu);
 875                 QuickMenu_Buffer_Size = 0;
 876         }
 877 }
 878 #undef QUICKMENU_SMENU
 879 #undef QUICKMENU_ENTRY
 880 #undef QUICKMENU_ENTRY_TC