qcsrc/client/hud/panel/radar.qc

   1 #include "radar.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/mapvoting.qh>
   5 #include <client/teamradar.qh>
   6 #include <common/ent_cs.qh>
   7 #include <common/mutators/mutator/waypoints/all.qh>
   8 #include <common/resources/cl_resources.qh>
   9
  10 // Radar (#6)
  11
  12 void HUD_Radar_Export(int fh)
  13 {
  14         // allow saving cvars that aesthetically change the panel into hud skin files
  15         HUD_Write_Cvar("hud_panel_radar_foreground_alpha");
  16         HUD_Write_Cvar("hud_panel_radar_rotation");
  17         HUD_Write_Cvar("hud_panel_radar_zoommode");
  18         HUD_Write_Cvar("hud_panel_radar_scale");
  19         HUD_Write_Cvar("hud_panel_radar_maximized_scale");
  20         HUD_Write_Cvar("hud_panel_radar_maximized_size");
  21         HUD_Write_Cvar("hud_panel_radar_maximized_rotation");
  22         HUD_Write_Cvar("hud_panel_radar_maximized_zoommode");
  23 }
  24
  25 bool HUD_Radar_Clickable()
  26 {
  27         return hud_panel_radar_mouse && !hud_panel_radar_temp_hidden;
  28 }
  29
  30 void HUD_Radar_Show_Maximized(bool doshow, bool clickable)
  31 {
  32         TC(bool, doshow);
  33         hud_panel_radar_maximized = doshow;
  34         hud_panel_radar_temp_hidden = 0;
  35
  36         if ( doshow )
  37         {
  38                 if (clickable)
  39                 {
  40                         hud_panel_radar_mouse = 1;
  41
  42                         // we must unset the player's buttons, as they aren't released elsewhere
  43                         localcmd("-fire\n");
  44                         localcmd("-fire2\n");
  45                         localcmd("-use\n");
  46                         localcmd("-hook\n");
  47                         localcmd("-jump\n");
  48                 }
  49         }
  50         else if ( hud_panel_radar_mouse )
  51         {
  52                 hud_panel_radar_mouse = 0;
  53                 mouseClicked = 0;
  54         }
  55 }
  56 void HUD_Radar_Hide_Maximized()
  57 {
  58         HUD_Radar_Show_Maximized(false,false);
  59 }
  60
  61
  62 float HUD_Radar_InputEvent(int bInputType, float nPrimary, float nSecondary)
  63 {
  64         TC(int, bInputType);
  65         if(!hud_panel_radar_maximized || !hud_panel_radar_mouse || autocvar__hud_configure || mv_active)
  66                 return false;
  67
  68         if(bInputType == 3)
  69         {
  70                 mousepos_x = nPrimary;
  71                 mousepos_y = nSecondary;
  72                 return true;
  73         }
  74
  75         if (bInputType == 2)
  76                 return false;
  77
  78         // at this point bInputType can only be 0 or 1 (key pressed or released)
  79         bool key_pressed = (bInputType == 0);
  80
  81         if(nPrimary == K_MOUSE1)
  82         {
  83                 if(key_pressed)
  84                         mouseClicked |= S_MOUSE1;
  85                 else
  86                         mouseClicked -= (mouseClicked & S_MOUSE1);
  87         }
  88         else if(nPrimary == K_MOUSE2)
  89         {
  90                 if(key_pressed)
  91                         mouseClicked |= S_MOUSE2;
  92                 else
  93                         mouseClicked -= (mouseClicked & S_MOUSE2);
  94         }
  95         else if (nPrimary == K_ESCAPE && key_pressed)
  96         {
  97                 HUD_Radar_Hide_Maximized();
  98         }
  99         else
 100         {
 101                 // allow console/use binds to work without hiding the map
 102                 string con_keys = strcat(findkeysforcommand("toggleconsole", 0), " ", findkeysforcommand("+use", 0)) ;
 103                 int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 104                 int i;
 105                 for (i = 0; i < keys; ++i)
 106                 {
 107                         if(nPrimary == stof(argv(i)))
 108                                 return false;
 109                 }
 110
 111                 if ( STAT(HEALTH) <= 0 )
 112                 {
 113                         // Show scoreboard
 114                         con_keys = findkeysforcommand("+showscores", 0);
 115                         keys = tokenize(con_keys);
 116                         for (i = 0; i < keys; ++i)
 117                         {
 118                                 if ( nPrimary == stof(argv(i)) )
 119                                 {
 120                                         hud_panel_radar_temp_hidden = key_pressed;
 121                                         return false;
 122                                 }
 123                         }
 124                 }
 125                 else if (key_pressed)
 126                         HUD_Radar_Hide_Maximized();
 127
 128                 return false;
 129         }
 130
 131         return true;
 132 }
 133
 134 void HUD_Radar_Mouse()
 135 {
 136         if ( !hud_panel_radar_mouse ) return;
 137         if(mv_active) return;
 138
 139         if (intermission || scoreboard_ui_enabled || (mouseClicked & S_MOUSE2))
 140         {
 141                 HUD_Radar_Hide_Maximized();
 142                 return;
 143         }
 144
 145         panel = HUD_PANEL(RADAR);
 146         HUD_Panel_LoadCvars();
 147
 148
 149         panel_size = autocvar_hud_panel_radar_maximized_size;
 150         panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
 151         panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
 152         panel_pos_x = (vid_conwidth - panel_size_x) / 2;
 153         panel_pos_y = (vid_conheight - panel_size_y) / 2;
 154
 155         if(mouseClicked & S_MOUSE1)
 156         {
 157                 // click outside
 158                 if ( mousepos_x < panel_pos_x || mousepos_x > panel_pos_x + panel_size_x ||
 159                          mousepos_y < panel_pos_y || mousepos_y > panel_pos_y + panel_size_y )
 160                 {
 161                         HUD_Radar_Hide_Maximized();
 162                         return;
 163                 }
 164                 vector pos = teamradar_texcoord_to_3dcoord(teamradar_2dcoord_to_texcoord(mousepos),view_origin_z);
 165                 localcmd(sprintf("cmd ons_spawn %f %f %f",pos_x,pos_y,pos_z));
 166
 167                 HUD_Radar_Hide_Maximized();
 168                 return;
 169         }
 170 }
 171
 172 float HUD_Radar_GetZoomFactor(int zoommode)
 173 {
 174         switch(zoommode)
 175         {
 176                 case 1: return 1 - current_zoomfraction;
 177                 case 2: return 0;
 178                 case 3: return 1;
 179         }
 180         return current_zoomfraction;
 181 }
 182
 183 float HUD_Radar_GetAngle(int rotation)
 184 {
 185         if (rotation)
 186                 return 90 * rotation;
 187         return view_angles.y - 90;
 188 }
 189
 190 void HUD_Radar()
 191 {
 192         if (!autocvar__hud_configure)
 193         {
 194                 if (hud_panel_radar_maximized)
 195                 {
 196                         if (!hud_draw_maximized) return;
 197                 }
 198                 else
 199                 {
 200                         if (autocvar_hud_panel_radar == 0) return;
 201                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
 202                         if(radar_panel_modified)
 203                         {
 204                                 panel.update_time = time; // forces reload of panel attributes
 205                                 radar_panel_modified = false;
 206                         }
 207                 }
 208         }
 209
 210         if ( hud_panel_radar_temp_hidden )
 211                 return;
 212
 213         HUD_Panel_LoadCvars();
 214
 215         float zoom_factor = 0;
 216
 217         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 218         {
 219                 panel_size = autocvar_hud_panel_radar_maximized_size;
 220                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
 221                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
 222                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
 223                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
 224
 225                 string panel_bg;
 226                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
 227                 if(precache_pic(panel_bg) == "")
 228                         panel_bg = "gfx/hud/default/border_default"; // fallback
 229                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
 230                         radar_panel_modified = true;
 231                 strcpy(panel.current_panel_bg, panel_bg);
 232
 233                 zoom_factor = HUD_Radar_GetZoomFactor(hud_panel_radar_maximized_zoommode);
 234                 teamradar_angle = HUD_Radar_GetAngle(hud_panel_radar_maximized_rotation);
 235         }
 236
 237         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
 238         {
 239                 zoom_factor = HUD_Radar_GetZoomFactor(hud_panel_radar_zoommode);
 240                 teamradar_angle = HUD_Radar_GetAngle(hud_panel_radar_rotation);
 241         }
 242
 243         vector pos, mySize;
 244         pos = panel_pos;
 245         mySize = panel_size;
 246
 247         if (autocvar_hud_panel_radar_dynamichud)
 248                 HUD_Scale_Enable();
 249         else
 250                 HUD_Scale_Disable();
 251         HUD_Panel_DrawBg();
 252         if(panel_bg_padding)
 253         {
 254                 pos += '1 1 0' * panel_bg_padding;
 255                 mySize -= '2 2 0' * panel_bg_padding;
 256         }
 257
 258         int color2;
 259         float scale2d, normalsize, bigsize;
 260
 261         teamradar_origin2d = HUD_Shift(pos + 0.5 * mySize);
 262         teamradar_size2d = mySize;
 263
 264         if(minimapname == "")
 265                 return;
 266
 267         teamradar_loadcvars();
 268
 269         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 270         teamradar_size2d = HUD_Scale(mySize);
 271
 272         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
 273
 274         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 275         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
 276         {
 277                 // max-min distance must fit the radar in any rotation
 278                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(vec2(mi_scale)));
 279         }
 280         else
 281         {
 282                 vector c0, c1, c2, c3, span;
 283                 c0 = Rotate(mi_min, teamradar_angle * DEG2RAD);
 284                 c1 = Rotate(mi_max, teamradar_angle * DEG2RAD);
 285                 c2 = Rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
 286                 c3 = Rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
 287                 span = '0 0 0';
 288                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
 289                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
 290
 291                 // max-min distance must fit the radar in x=x, y=y
 292                 bigsize = min(
 293                         teamradar_size2d.x * scale2d / (1.05 * span.x),
 294                         teamradar_size2d.y * scale2d / (1.05 * span.y)
 295                 );
 296         }
 297
 298         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
 299         if(bigsize > normalsize)
 300                 normalsize = bigsize;
 301
 302         teamradar_size = zoom_factor * bigsize + (1 - zoom_factor) * normalsize;
 303         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(zoom_factor * mi_center + (1 - zoom_factor) * view_origin);
 304
 305         drawsetcliparea(pos.x, pos.y, mySize.x, mySize.y);
 306
 307         draw_teamradar_background(hud_panel_radar_foreground_alpha);
 308
 309         IL_EACH(g_radarlinks, true, draw_teamradar_link(it.origin, it.velocity, it.team));
 310
 311         bool mutator_returnvalue = MUTATOR_CALLHOOK(TeamRadar_Draw); // TODO: allow players to show on the radar as well!
 312
 313         IL_EACH(g_radaricons, it.teamradar_icon, {
 314                 if ( hud_panel_radar_mouse )
 315                 if ( GetResource(it, RES_HEALTH) >= 0 )
 316                 if ( it.team == myteam + 1 || mutator_returnvalue || !teamplay )
 317                 {
 318                         vector coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(it.origin));
 319                         if(vdist((mousepos - coord), <, 8))
 320                         {
 321                                 vector brightcolor;
 322                                 brightcolor_x = min(1,it.teamradar_color_x*1.5);
 323                                 brightcolor_y = min(1,it.teamradar_color_y*1.5);
 324                                 brightcolor_z = min(1,it.teamradar_color_z*1.5);
 325                                 drawpic(coord - '8 8 0', "gfx/teamradar_icon_glow", '16 16 0', brightcolor, panel_fg_alpha, 0);
 326                         }
 327                 }
 328                 entity icon = REGISTRY_GET(RadarIcons, it.teamradar_icon);
 329                 draw_teamradar_icon(it.origin, icon, it, spritelookupcolor(it, icon.netname, it.teamradar_color), panel_fg_alpha);
 330         });
 331         AL_EACH(_entcs, e, it != NULL, {
 332                 if (!it.m_entcs_private) continue;
 333                 if (it.sv_entnum == current_player) continue;
 334                 color2 = entcs_GetTeam(it.sv_entnum);
 335                 draw_teamradar_player(it.origin, it.angles, Team_ColorRGB(color2));
 336         });
 337         draw_teamradar_player(entcs_receiver(current_player).origin, view_angles, '1 1 1');
 338
 339         drawresetcliparea();
 340
 341         if ( hud_panel_radar_mouse )
 342         {
 343                 string message = _("Click to select teleport destination");
 344
 345                 if ( STAT(HEALTH) <= 0 )
 346                 {
 347                         message = _("Click to select spawn location");
 348                 }
 349
 350                 drawcolorcodedstring(pos + '0.5 0 0' * (mySize_x - stringwidth(message, true, hud_fontsize)) - '0 1 0' * hud_fontsize_y * 2,
 351                                                          message, hud_fontsize, hud_panel_radar_foreground_alpha, DRAWFLAG_NORMAL);
 352
 353                 hud_panel_radar_bottom = pos_y + mySize_y + hud_fontsize_y;
 354         }
 355 }