qcsrc/client/hud/panel/weapons.qc

   1 // Weapon icons (#0)
   2
   3 entity weaponorder[Weapons_MAX];
   4 void weaponorder_swap(int i, int j, entity pass)
   5 {
   6         entity h = weaponorder[i];
   7         weaponorder[i] = weaponorder[j];
   8         weaponorder[j] = h;
   9 }
  10
  11 string weaponorder_cmp_str;
  12 int weaponorder_cmp(int i, int j, entity pass)
  13 {
  14         int ai, aj;
  15         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
  16         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
  17         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
  18 }
  19
  20 void HUD_Weapons()
  21 {
  22         SELFPARAM();
  23         // declarations
  24         WepSet weapons_stat = WepSet_GetFromStat();
  25         int i;
  26         float f, a;
  27         float screen_ar;
  28         vector center = '0 0 0';
  29         int weapon_count, weapon_id;
  30         int row, column, rows = 0, columns = 0;
  31         bool vertical_order = true;
  32         float aspect = autocvar_hud_panel_weapons_aspect;
  33
  34         float timeout = autocvar_hud_panel_weapons_timeout;
  35         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
  36         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
  37
  38         vector barsize = '0 0 0', baroffset = '0 0 0';
  39         vector ammo_color = '1 0 1';
  40         float ammo_alpha = 1;
  41
  42         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
  43         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
  44
  45         vector weapon_pos, weapon_size = '0 0 0';
  46         vector color;
  47
  48         // check to see if we want to continue
  49         if(hud != HUD_NORMAL) return;
  50
  51         if(!autocvar__hud_configure)
  52         {
  53                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
  54                         return;
  55                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
  56                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
  57                 {
  58                         weaponprevtime = time;
  59                         return;
  60                 }
  61         }
  62
  63         // update generic hud functions
  64         HUD_Panel_UpdateCvars();
  65
  66         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
  67         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
  68         {
  69                 int weapon_cnt;
  70                 if(weaponorder_bypriority)
  71                         strunzone(weaponorder_bypriority);
  72                 if(weaponorder_byimpulse)
  73                         strunzone(weaponorder_byimpulse);
  74
  75                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
  76                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
  77                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
  78
  79                 weapon_cnt = 0;
  80                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  81                 {
  82                         setself(get_weaponinfo(i));
  83                         if(self.impulse >= 0)
  84                         {
  85                                 weaponorder[weapon_cnt] = self;
  86                                 ++weapon_cnt;
  87                         }
  88                 }
  89                 for(i = weapon_cnt; i < Weapons_MAX; ++i)
  90                         weaponorder[i] = world;
  91                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
  92
  93                 weaponorder_cmp_str = string_null;
  94         }
  95
  96         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
  97                 complain_weapon = 0;
  98
  99         if(autocvar__hud_configure)
 100         {
 101                 if(!weapons_stat)
 102                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 103                                 weapons_stat |= WepSet_FromWeapon(i);
 104
 105                 #if 0
 106                 /// debug code
 107                 if(cvar("wep_add"))
 108                 {
 109                         weapons_stat = '0 0 0';
 110                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % (Weapons_COUNT - 1));
 111                         for(i = WEP_FIRST; i <= countw; ++i)
 112                                 weapons_stat |= WepSet_FromWeapon(i);
 113                 }
 114                 #endif
 115         }
 116
 117         // determine which weapons are going to be shown
 118         if (autocvar_hud_panel_weapons_onlyowned)
 119         {
 120                 if(autocvar__hud_configure)
 121                 {
 122                         if(menu_enabled != 2)
 123                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 124                 }
 125
 126                 // do we own this weapon?
 127                 weapon_count = 0;
 128                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 129                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 130                                 ++weapon_count;
 131
 132
 133                 // might as well commit suicide now, no reason to live ;)
 134                 if (weapon_count == 0)
 135                         return;
 136
 137                 vector old_panel_size = panel_size;
 138                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 139
 140                 // get the all-weapons layout
 141                 int nHidden = 0;
 142                 WepSet weapons_stat = WepSet_GetFromStat();
 143                 for (int i = WEP_FIRST; i <= WEP_LAST; ++i) {
 144                         WepSet weapons_wep = WepSet_FromWeapon(i);
 145                         if (weapons_stat & weapons_wep) continue;
 146                         Weapon w = get_weaponinfo(i);
 147                         if (w.spawnflags & WEP_FLAG_MUTATORBLOCKED) nHidden += 1;
 148                 }
 149                 vector table_size = HUD_GetTableSize_BestItemAR((Weapons_COUNT - 1) - nHidden, padded_panel_size, aspect);
 150                 columns = table_size.x;
 151                 rows = table_size.y;
 152                 weapon_size.x = padded_panel_size.x / columns;
 153                 weapon_size.y = padded_panel_size.y / rows;
 154
 155                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 156                 // we enlarge them a bit when possible to better match the desired aspect ratio
 157                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 158                 {
 159                         // maximum number of rows that allows to display items with the desired aspect ratio
 160                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 161                         columns = min(columns, ceil(weapon_count / max_rows));
 162                         rows = ceil(weapon_count / columns);
 163                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 164                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 165                         vertical_order = false;
 166                 }
 167                 else
 168                 {
 169                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 170                         rows = min(rows, ceil(weapon_count / max_columns));
 171                         columns = ceil(weapon_count / rows);
 172                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 173                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 174                         vertical_order = true;
 175                 }
 176
 177                 // reduce size of the panel
 178                 panel_size.x = columns * weapon_size.x;
 179                 panel_size.y = rows * weapon_size.y;
 180                 panel_size += '2 2 0' * panel_bg_padding;
 181
 182                 // center the resized panel, or snap it to the screen edge when close enough
 183                 if(panel_pos.x > vid_conwidth * 0.001)
 184                 {
 185                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 186                                 panel_pos.x += old_panel_size.x - panel_size.x;
 187                         else
 188                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 189                 }
 190                 else if(old_panel_size.x > vid_conwidth * 0.999)
 191                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 192
 193                 if(panel_pos.y > vid_conheight * 0.001)
 194                 {
 195                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 196                                 panel_pos.y += old_panel_size.y - panel_size.y;
 197                         else
 198                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 199                 }
 200                 else if(old_panel_size.y > vid_conheight * 0.999)
 201                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 202         }
 203         else
 204                 weapon_count = (Weapons_COUNT - 1);
 205
 206         // animation for fading in/out the panel respectively when not in use
 207         if(!autocvar__hud_configure)
 208         {
 209                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 210                 {
 211                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 212
 213                         // fade the panel alpha
 214                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 215                         {
 216                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 217                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 218                         }
 219                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 220                         {
 221                                 panel_bg_alpha *= (1 - f);
 222                                 panel_fg_alpha *= (1 - f);
 223                         }
 224
 225                         // move the panel off the screen
 226                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 227                         {
 228                                 f *= f; // for a cooler movement
 229                                 center.x = panel_pos.x + panel_size.x/2;
 230                                 center.y = panel_pos.y + panel_size.y/2;
 231                                 screen_ar = vid_conwidth/vid_conheight;
 232                                 if (center.x/center.y < screen_ar) //bottom left
 233                                 {
 234                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 235                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 236                                         else //left
 237                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 238                                 }
 239                                 else //top right
 240                                 {
 241                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 242                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 243                                         else //top
 244                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 245                                 }
 246                                 if(f == 1)
 247                                         center.x = -1; // mark the panel as off screen
 248                         }
 249                         weaponprevtime = time - (1 - f) * timein_effect_length;
 250                 }
 251                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 252                 {
 253                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 254
 255                         // fade the panel alpha
 256                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 257                         {
 258                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 259                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 260                         }
 261                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 262                         {
 263                                 panel_bg_alpha *= (f);
 264                                 panel_fg_alpha *= (f);
 265                         }
 266
 267                         // move the panel back on screen
 268                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 269                         {
 270                                 f *= f; // for a cooler movement
 271                                 f = 1 - f;
 272                                 center.x = panel_pos.x + panel_size.x/2;
 273                                 center.y = panel_pos.y + panel_size.y/2;
 274                                 screen_ar = vid_conwidth/vid_conheight;
 275                                 if (center.x/center.y < screen_ar) //bottom left
 276                                 {
 277                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 278                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 279                                         else //left
 280                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 281                                 }
 282                                 else //top right
 283                                 {
 284                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 285                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 286                                         else //top
 287                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 288                                 }
 289                         }
 290                 }
 291         }
 292
 293         // draw the background, then change the virtual size of it to better fit other items inside
 294         HUD_Panel_DrawBg(1);
 295
 296         if(center.x == -1)
 297                 return;
 298
 299         if(panel_bg_padding)
 300         {
 301                 panel_pos += '1 1 0' * panel_bg_padding;
 302                 panel_size -= '2 2 0' * panel_bg_padding;
 303         }
 304
 305         // after the sizing and animations are done, update the other values
 306
 307         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 308         {
 309                 vector table_size = HUD_GetTableSize_BestItemAR((Weapons_COUNT - 1), panel_size, aspect);
 310                 columns = table_size.x;
 311                 rows = table_size.y;
 312                 weapon_size.x = panel_size.x / columns;
 313                 weapon_size.y = panel_size.y / rows;
 314                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 315         }
 316
 317         // calculate position/size for visual bar displaying ammount of ammo status
 318         if (autocvar_hud_panel_weapons_ammo)
 319         {
 320                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 321                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 322
 323                 if(weapon_size.x/weapon_size.y > aspect)
 324                 {
 325                         barsize.x = aspect * weapon_size.y;
 326                         barsize.y = weapon_size.y;
 327                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 328                 }
 329                 else
 330                 {
 331                         barsize.y = 1/aspect * weapon_size.x;
 332                         barsize.x = weapon_size.x;
 333                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 334                 }
 335         }
 336         if(autocvar_hud_panel_weapons_accuracy)
 337                 Accuracy_LoadColors();
 338
 339         // draw items
 340         row = column = 0;
 341         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 342         vector noncurrent_pos = '0 0 0';
 343         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 344         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 345         bool isCurrent;
 346
 347         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 348         {
 349                 // retrieve information about the current weapon to be drawn
 350                 setself(weaponorder[i]);
 351                 weapon_id = self.impulse;
 352                 isCurrent = (self.weapon == switchweapon);
 353
 354                 // skip if this weapon doesn't exist
 355                 if(!self || weapon_id < 0) { continue; }
 356
 357                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 358                 if(autocvar_hud_panel_weapons_onlyowned)
 359                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 360                         continue;
 361
 362                 // figure out the drawing position of weapon
 363                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 364                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 365                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 366
 367                 // draw background behind currently selected weapon
 368                 if(isCurrent)
 369                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 370
 371                 // draw the weapon accuracy
 372                 if(autocvar_hud_panel_weapons_accuracy)
 373                 {
 374                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 375                         if(panel_weapon_accuracy >= 0)
 376                         {
 377                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 378                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 379                         }
 380                 }
 381
 382                 // drawing all the weapon items
 383                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 384                 {
 385                         // draw the weapon image
 386                         if(isCurrent)
 387                                 drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 388                         else
 389                                 drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 390
 391                         // draw weapon label string
 392                         switch(autocvar_hud_panel_weapons_label)
 393                         {
 394                                 case 1: // weapon number
 395                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 396                                         break;
 397
 398                                 case 2: // bind
 399                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 400                                         break;
 401
 402                                 case 3: // weapon name
 403                                         drawstring(weapon_pos, strtolower(self.m_name), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 404                                         break;
 405
 406                                 default: // nothing
 407                                         break;
 408                         }
 409
 410                         // draw ammo status bar
 411                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 412                         {
 413                                 float ammo_full;
 414                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 415
 416                                 if(a > 0)
 417                                 {
 418                                         switch(self.ammo_field)
 419                                         {
 420                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 421                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 422                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 423                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 424                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 425                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 426                                                 default: ammo_full = 60;
 427                                         }
 428
 429                                         drawsetcliparea(
 430                                                 weapon_pos.x + baroffset.x,
 431                                                 weapon_pos.y + baroffset.y,
 432                                                 barsize.x * bound(0, a/ammo_full, 1),
 433                                                 barsize.y
 434                                         );
 435
 436                                         drawpic_aspect_skin(
 437                                                 weapon_pos,
 438                                                 "weapon_ammo",
 439                                                 weapon_size,
 440                                                 ammo_color,
 441                                                 ammo_alpha,
 442                                                 DRAWFLAG_NORMAL
 443                                         );
 444
 445                                         drawresetcliparea();
 446                                 }
 447                         }
 448                 }
 449                 else // draw a "ghost weapon icon" if you don't have the weapon
 450                 {
 451                         drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 452                 }
 453
 454                 // draw the complain message
 455                 if(self.weapon == complain_weapon)
 456                 {
 457                         if(fadetime)
 458                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 459                         else
 460                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 461
 462                         string s;
 463                         if(complain_weapon_type == 0) {
 464                                 s = _("Out of ammo");
 465                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 466                         }
 467                         else if(complain_weapon_type == 1) {
 468                                 s = _("Don't have");
 469                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 470                         }
 471                         else {
 472                                 s = _("Unavailable");
 473                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 474                         }
 475                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 476                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 477                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 478                 }
 479
 480                 #if 0
 481                 /// debug code
 482                 if(!autocvar_hud_panel_weapons_onlyowned)
 483                 {
 484                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 485                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 486                 }
 487                 #endif
 488
 489                 // continue with new position for the next weapon
 490                 if(vertical_order)
 491                 {
 492                         ++column;
 493                         if(column >= columns)
 494                         {
 495                                 column = 0;
 496                                 ++row;
 497                         }
 498                 }
 499                 else
 500                 {
 501                         ++row;
 502                         if(row >= rows)
 503                         {
 504                                 row = 0;
 505                                 ++column;
 506                         }
 507                 }
 508         }
 509 }