qcsrc/client/laser.qc

   1 // a laser goes from origin in direction angles
   2 // it has color 'colormod'
   3 // and stops when something is in the way
   4 .float cnt; // end effect
   5 .vector colormod;
   6 .float state; // on-off
   7 .float count; // flags for the laser
   8 .vector velocity;
   9 .float alpha;
  10 .float scale; // scaling factor of the thickness
  11 .float modelscale; // scaling factor of the dlight
  12
  13 // TODO move these into a heade file
  14 float trace_dphitq3surfaceflags;
  15 float Q3SURFACEFLAG_SKY = 4; // sky surface (also has NOIMPACT and NOMARKS set)
  16 float Q3SURFACEFLAG_NOIMPACT = 16; // projectiles should remove themselves on impact (this is set on sky)
  17
  18 void Draw_Laser()
  19 {
  20         if(!self.state)
  21                 return;
  22         InterpolateOrigin_Do();
  23         if(self.count & 0x80)
  24         {
  25                 if(self.count & 0x10)
  26                 {
  27                         trace_endpos = self.velocity,
  28                         trace_dphitq3surfaceflags = 0;
  29                 }
  30                 else
  31                         traceline(self.origin, self.velocity, 0, self);
  32         }
  33         else
  34         {
  35                 if(self.count & 0x10)
  36                 {
  37                         makevectors(self.angles);
  38                         trace_endpos = self.origin + v_forward * 1048576;
  39                         trace_dphitq3surfaceflags = Q3SURFACEFLAG_SKY;
  40                 }
  41                 else
  42                 {
  43                         makevectors(self.angles);
  44                         traceline(self.origin, self.origin + v_forward * 32768, 0, self);
  45                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
  46                                 trace_endpos = self.origin + v_forward * 1048576;
  47                 }
  48         }
  49         if(self.scale != 0)
  50         {
  51                 if(self.alpha)
  52                 {
  53                         Draw_CylindricLine(self.origin, trace_endpos, self.scale, "particles/laserbeam", 0, time * 3, self.colormod, self.alpha, DRAWFLAG_NORMAL, view_origin);
  54                 }
  55                 else
  56                 {
  57                         Draw_CylindricLine(self.origin, trace_endpos, self.scale, "particles/laserbeam", 0, time * 3, self.colormod, 0.5, DRAWFLAG_ADDITIVE, view_origin);
  58                 }
  59         }
  60         if not(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT))
  61         {
  62                 if(self.cnt >= 0)
  63                         pointparticles(self.cnt, trace_endpos, trace_plane_normal, drawframetime * 1000);
  64                 if(self.colormod != '0 0 0' && self.modelscale != 0)
  65                         adddynamiclight(trace_endpos + trace_plane_normal * 1, self.modelscale, self.colormod * 5);
  66         }
  67 }
  68
  69 void Ent_Laser()
  70 {
  71         float f;
  72         InterpolateOrigin_Undo();
  73
  74         // 30 bytes, or 13 bytes for just moving
  75         f = ReadByte();
  76         self.count = (f & 0xF0);
  77
  78         if(self.count & 0x80)
  79                 self.iflags = IFLAG_VELOCITY;
  80         else
  81                 self.iflags = IFLAG_ANGLES;
  82
  83         if(f & 1)
  84         {
  85                 self.origin_x = ReadCoord();
  86                 self.origin_y = ReadCoord();
  87                 self.origin_z = ReadCoord();
  88                 setorigin(self, self.origin);
  89         }
  90         if(f & 8)
  91         {
  92                 self.colormod_x = ReadByte() / 255.0;
  93                 self.colormod_y = ReadByte() / 255.0;
  94                 self.colormod_z = ReadByte() / 255.0;
  95                 if(f & 0x40)
  96                         self.alpha = ReadByte() / 255.0;
  97                 else
  98                         self.alpha = 0;
  99                 self.scale = 2;
 100                 self.modelscale = 50;
 101                 if(f & 0x20)
 102                 {
 103                         self.scale *= ReadByte() / 16.0; // beam radius
 104                         self.modelscale *= ReadByte() / 16.0; // dlight radius
 105                 }
 106                 if((f & 0x80) || !(f & 0x10))
 107                         self.cnt = ReadShort() - 1; // effect number
 108                 else
 109                         self.cnt = 0;
 110         }
 111         if(f & 2)
 112         {
 113                 if(f & 0x80)
 114                 {
 115                         self.velocity_x = ReadCoord();
 116                         self.velocity_y = ReadCoord();
 117                         self.velocity_z = ReadCoord();
 118                 }
 119                 else
 120                 {
 121                         self.angles_x = ReadAngle();
 122                         self.angles_y = ReadAngle();
 123                 }
 124         }
 125         if(f & 4)
 126                 self.state = ReadByte();
 127         InterpolateOrigin_Note();
 128         self.draw = Draw_Laser;
 129 }