qcsrc/client/main.qc

   1 #include "mapvoting.qh"
   2 #include "modeleffects.qh"
   3 #include "particles.qh"
   4 #include "scoreboard.qh"
   5 #include "shownames.qh"
   6 #include "tturrets.qh"
   7 #include "tuba.qh"
   8 #include "wall.qh"
   9 #include "waypointsprites.qh"
  10
  11 #include "vehicles/vehicles.qh"
  12
  13 #include "../server/vehicles/bumblebee.qh"
  14
  15 #include "../common/net_notice.qh"
  16
  17 #include "../common/monsters/monsters.qh"
  18
  19 #include "../common/triggers/include.qh"
  20
  21 #include "../warpzonelib/client.qh"
  22
  23 // --------------------------------------------------------------------------
  24 // BEGIN REQUIRED CSQC FUNCTIONS
  25 //include "main.qh"
  26
  27 entity clearentity_ent;
  28 void clearentity(entity e)
  29 {
  30         if (!clearentity_ent)
  31         {
  32                 clearentity_ent = spawn();
  33                 clearentity_ent.classname = "clearentity";
  34         }
  35         int n = e.entnum;
  36         copyentity(clearentity_ent, e);
  37         e.entnum = n;
  38 }
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41 void menu_show_error()
  42 {
  43         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  44 }
  45
  46 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  47 // Useful for precaching things
  48
  49 void menu_sub_null()
  50 {
  51 }
  52
  53 string forcefog;
  54 void WaypointSprite_Load();
  55 void ConsoleCommand_macro_init();
  56 void CSQC_Init(void)
  57 {
  58         prvm_language = cvar_string("prvm_language");
  59
  60 #ifdef WATERMARK
  61         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  62 #endif
  63
  64         int i;
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = false;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         Cmd_HUD_SetFields(0);
 100
 101         postinit = false;
 102
 103         calledhooks = 0;
 104
 105         teams = Sort_Spawn();
 106         players = Sort_Spawn();
 107
 108         GetTeam(NUM_SPECTATOR, true); // add specs first
 109
 110         // needs to be done so early because of the constants they create
 111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 118
 119         WaypointSprite_Load();
 120
 121         // precaches
 122         precache_model("null");
 123         precache_sound("misc/hit.wav");
 124         precache_sound("misc/typehit.wav");
 125
 126         Projectile_Precache();
 127         Hook_Precache();
 128         GibSplash_Precache();
 129         Casings_Precache();
 130         Vehicles_Precache();
 131         turrets_precache();
 132         Tuba_Precache();
 133         CSQCPlayer_Precache();
 134
 135         if(autocvar_cl_reticle)
 136         {
 137                 precache_pic("gfx/reticle_normal");
 138                 // weapon reticles are precached in weapon files
 139         }
 140
 141         get_mi_min_max_texcoords(1); // try the CLEVER way first
 142         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 143         shortmapname = mi_shortname;
 144
 145         if(precache_pic(minimapname) == "")
 146         {
 147                 // but maybe we have a non-clever minimap
 148                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 149                 if(precache_pic(minimapname) == "")
 150                         minimapname = ""; // FAIL
 151                 else
 152                         get_mi_min_max_texcoords(0); // load new texcoords
 153         }
 154
 155         mi_center = (mi_min + mi_max) * 0.5;
 156         mi_scale = mi_max - mi_min;
 157         minimapname = strzone(minimapname);
 158
 159         WarpZone_Init();
 160
 161         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 162         hud_configure_prev = -1;
 163
 164         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 165 }
 166
 167 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 168 void Shutdown(void)
 169 {
 170         WarpZone_Shutdown();
 171
 172         remove(teams);
 173         remove(players);
 174         db_close(binddb);
 175         db_close(tempdb);
 176         if(autocvar_cl_db_saveasdump)
 177                 db_dump(ClientProgsDB, "client.db");
 178         else
 179                 db_save(ClientProgsDB, "client.db");
 180         db_close(ClientProgsDB);
 181
 182         if(camera_active)
 183                 cvar_set("chase_active",ftos(chase_active_backup));
 184
 185         // unset the event chasecam's chase_active
 186         if(autocvar_chase_active < 0)
 187                 cvar_set("chase_active", "0");
 188
 189         if (!isdemo())
 190         {
 191                 if (!(calledhooks & HOOK_START))
 192                         localcmd("\n_cl_hook_gamestart nop\n");
 193                 if (!(calledhooks & HOOK_END))
 194                         localcmd("\ncl_hook_gameend\n");
 195         }
 196 }
 197
 198 .float has_team;
 199 float SetTeam(entity o, int Team)
 200 {
 201         entity tm;
 202         if(teamplay)
 203         {
 204                 switch(Team)
 205                 {
 206                         case -1:
 207                         case NUM_TEAM_1:
 208                         case NUM_TEAM_2:
 209                         case NUM_TEAM_3:
 210                         case NUM_TEAM_4:
 211                                 break;
 212                         default:
 213                                 if(GetTeam(Team, false) == world)
 214                                 {
 215                                         dprintf("trying to switch to unsupported team %d\n", Team);
 216                                         Team = NUM_SPECTATOR;
 217                                 }
 218                                 break;
 219                 }
 220         }
 221         else
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case 0:
 227                                 break;
 228                         default:
 229                                 if(GetTeam(Team, false) == world)
 230                                 {
 231                                         dprintf("trying to switch to unsupported team %d\n", Team);
 232                                         Team = NUM_SPECTATOR;
 233                                 }
 234                                 break;
 235                 }
 236         }
 237         if(Team == -1) // leave
 238         {
 239                 if(o.has_team)
 240                 {
 241                         tm = GetTeam(o.team, false);
 242                         tm.team_size -= 1;
 243                         o.has_team = 0;
 244                         return true;
 245                 }
 246         }
 247         else
 248         {
 249                 if (!o.has_team)
 250                 {
 251                         o.team = Team;
 252                         tm = GetTeam(Team, true);
 253                         tm.team_size += 1;
 254                         o.has_team = 1;
 255                         return true;
 256                 }
 257                 else if(Team != o.team)
 258                 {
 259                         tm = GetTeam(o.team, false);
 260                         tm.team_size -= 1;
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         return true;
 265                 }
 266         }
 267         return false;
 268 }
 269
 270 void Playerchecker_Think()
 271 {
 272     int i;
 273         entity e;
 274         for(i = 0; i < maxclients; ++i)
 275         {
 276                 e = playerslots[i];
 277                 if(GetPlayerName(i) == "")
 278                 {
 279                         if(e.sort_prev)
 280                         {
 281                                 // player disconnected
 282                                 SetTeam(e, -1);
 283                                 RemovePlayer(e);
 284                                 e.sort_prev = world;
 285                                 //e.gotscores = 0;
 286                         }
 287                 }
 288                 else
 289                 {
 290                         if (!e.sort_prev)
 291                         {
 292                                 // player connected
 293                                 if (!e)
 294                                         playerslots[i] = e = spawn();
 295                                 e.sv_entnum = i;
 296                                 e.ping = 0;
 297                                 e.ping_packetloss = 0;
 298                                 e.ping_movementloss = 0;
 299                                 //e.gotscores = 0; // we might already have the scores...
 300                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 301                                 RegisterPlayer(e);
 302                                 HUD_UpdatePlayerPos(e);
 303                         }
 304                 }
 305         }
 306         self.nextthink = time + 0.2;
 307 }
 308
 309 void Porto_Init();
 310 void TrueAim_Init();
 311 void PostInit(void)
 312 {
 313         entity playerchecker;
 314         playerchecker = spawn();
 315         playerchecker.think = Playerchecker_Think;
 316         playerchecker.nextthink = time + 0.2;
 317
 318         Porto_Init();
 319         TrueAim_Init();
 320
 321         postinit = true;
 322 }
 323
 324 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 325 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 326 // All keys are in ascii.
 327 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 328 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 329 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 330 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 331 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 332 {
 333         float bSkipKey;
 334         bSkipKey = false;
 335
 336         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 337                 return true;
 338
 339         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 340                 return true;
 341
 342         if(menu_visible && menu_action)
 343                 if(menu_action(bInputType, nPrimary, nSecondary))
 344                         return true;
 345
 346         return bSkipKey;
 347 }
 348
 349 // END REQUIRED CSQC FUNCTIONS
 350 // --------------------------------------------------------------------------
 351
 352 // --------------------------------------------------------------------------
 353 // BEGIN OPTIONAL CSQC FUNCTIONS
 354
 355 void Ent_RemoveEntCS()
 356 {
 357         entcs_receiver[self.sv_entnum] = world;
 358 }
 359 void Ent_ReadEntCS()
 360 {
 361     int sf;
 362         InterpolateOrigin_Undo();
 363
 364         self.classname = "entcs_receiver";
 365         sf = ReadByte();
 366
 367         if(sf & 1)
 368                 self.sv_entnum = ReadByte();
 369         if(sf & 2)
 370         {
 371                 self.origin_x = ReadShort();
 372                 self.origin_y = ReadShort();
 373                 self.origin_z = ReadShort();
 374                 setorigin(self, self.origin);
 375         }
 376         if(sf & 4)
 377         {
 378                 self.angles_y = ReadByte() * 360.0 / 256;
 379                 self.angles_x = self.angles_z = 0;
 380         }
 381         if(sf & 8)
 382                 self.healthvalue = ReadByte() * 10;
 383         if(sf & 16)
 384                 self.armorvalue = ReadByte() * 10;
 385
 386         entcs_receiver[self.sv_entnum] = self;
 387         self.entremove = Ent_RemoveEntCS;
 388         self.iflags |= IFLAG_ORIGIN;
 389
 390         InterpolateOrigin_Note();
 391 }
 392
 393 void Ent_Remove();
 394
 395 void Ent_RemovePlayerScore()
 396 {
 397         if(self.owner) {
 398                 SetTeam(self.owner, -1);
 399                 self.owner.gotscores = 0;
 400                 for(int i = 0; i < MAX_SCORE; ++i) {
 401                         self.owner.(scores[i]) = 0; // clear all scores
 402                 }
 403         }
 404 }
 405
 406 void Ent_ReadPlayerScore()
 407 {
 408         int i, n;
 409         bool isNew;
 410         entity o;
 411
 412         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 413         // (no I've never heard of M-x replace-string, sed, or anything like that)
 414         isNew = !self.owner; // workaround for DP bug
 415         n = ReadByte()-1;
 416
 417 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 418         if(!isNew && n != self.sv_entnum)
 419         {
 420                 //print("A CSQC entity changed its owner!\n");
 421                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 422                 isNew = true;
 423                 Ent_Remove();
 424                 self.enttype = ENT_CLIENT_SCORES;
 425         }
 426 #endif
 427
 428         self.sv_entnum = n;
 429
 430         if (!(playerslots[self.sv_entnum]))
 431                 playerslots[self.sv_entnum] = spawn();
 432         o = self.owner = playerslots[self.sv_entnum];
 433         o.sv_entnum = self.sv_entnum;
 434         o.gotscores = 1;
 435
 436         //if (!o.sort_prev)
 437         //      RegisterPlayer(o);
 438         //playerchecker will do this for us later, if it has not already done so
 439
 440     int sf, lf;
 441 #if MAX_SCORE <= 8
 442         sf = ReadByte();
 443         lf = ReadByte();
 444 #else
 445         sf = ReadShort();
 446         lf = ReadShort();
 447 #endif
 448     int p;
 449         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 450                 if(sf & p)
 451                 {
 452                         if(lf & p)
 453                                 o.(scores[i]) = ReadInt24_t();
 454                         else
 455                                 o.(scores[i]) = ReadChar();
 456                 }
 457
 458         if(o.sort_prev)
 459                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 460
 461         self.entremove = Ent_RemovePlayerScore;
 462 }
 463
 464 void Ent_ReadTeamScore()
 465 {
 466         int i;
 467         entity o;
 468
 469         self.team = ReadByte();
 470         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 471
 472     int sf, lf;
 473 #if MAX_TEAMSCORE <= 8
 474         sf = ReadByte();
 475         lf = ReadByte();
 476 #else
 477         sf = ReadShort();
 478         lf = ReadShort();
 479 #endif
 480         int p;
 481         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 482                 if(sf & p)
 483                 {
 484                         if(lf & p)
 485                                 o.(teamscores[i]) = ReadInt24_t();
 486                         else
 487                                 o.(teamscores[i]) = ReadChar();
 488                 }
 489
 490         HUD_UpdateTeamPos(o);
 491 }
 492
 493 void Ent_ClientData()
 494 {
 495         float newspectatee_status;
 496
 497     int f = ReadByte();
 498
 499         scoreboard_showscores_force = (f & 1);
 500
 501         if(f & 2)
 502         {
 503                 newspectatee_status = ReadByte();
 504                 if(newspectatee_status == player_localnum + 1)
 505                         newspectatee_status = -1; // observing
 506         }
 507         else
 508                 newspectatee_status = 0;
 509
 510         spectatorbutton_zoom = (f & 4);
 511
 512         if(f & 8)
 513         {
 514                 angles_held_status = 1;
 515                 angles_held.x = ReadAngle();
 516                 angles_held.y = ReadAngle();
 517                 angles_held.z = 0;
 518         }
 519         else
 520                 angles_held_status = 0;
 521
 522         if(newspectatee_status != spectatee_status)
 523         {
 524                 // clear race stuff
 525                 race_laptime = 0;
 526                 race_checkpointtime = 0;
 527         }
 528         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 529         {
 530                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 531                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 532                 )
 533                         prev_p_health = -1;
 534                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 535                         prev_health = -1;
 536         }
 537         spectatee_status = newspectatee_status;
 538
 539         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 540 }
 541
 542 void Ent_Nagger()
 543 {
 544     int i, j, b, f;
 545
 546     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 547
 548         if(!(nags & 4))
 549         {
 550                 if(vote_called_vote)
 551                         strunzone(vote_called_vote);
 552                 vote_called_vote = string_null;
 553                 vote_active = 0;
 554         }
 555         else
 556         {
 557                 vote_active = 1;
 558         }
 559
 560         if(nags & 64)
 561         {
 562                 vote_yescount = ReadByte();
 563                 vote_nocount = ReadByte();
 564                 vote_needed = ReadByte();
 565                 vote_highlighted = ReadChar();
 566         }
 567
 568         if(nags & 128)
 569         {
 570                 if(vote_called_vote)
 571                         strunzone(vote_called_vote);
 572                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 573         }
 574
 575         if(nags & 1)
 576         {
 577                 for(j = 0; j < maxclients; ++j)
 578                         if(playerslots[j])
 579                                 playerslots[j].ready = 1;
 580                 for(i = 1; i <= maxclients; i += 8)
 581                 {
 582                         f = ReadByte();
 583                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 584                                 if (!(f & b))
 585                                         if(playerslots[j])
 586                                                 playerslots[j].ready = 0;
 587                 }
 588         }
 589
 590         ready_waiting = (nags & 1);
 591         ready_waiting_for_me = (nags & 2);
 592         vote_waiting = (nags & 4);
 593         vote_waiting_for_me = (nags & 8);
 594         warmup_stage = (nags & 16);
 595 }
 596
 597 void Ent_EliminatedPlayers()
 598 {
 599     int i, j, b, f;
 600
 601     int sf = ReadByte();
 602         if(sf & 1)
 603         {
 604                 for(j = 0; j < maxclients; ++j)
 605                         if(playerslots[j])
 606                                 playerslots[j].eliminated = 1;
 607                 for(i = 1; i <= maxclients; i += 8)
 608                 {
 609                         f = ReadByte();
 610                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 611                                 if (!(f & b))
 612                                         if(playerslots[j])
 613                                                 playerslots[j].eliminated = 0;
 614                 }
 615         }
 616 }
 617
 618 void Ent_RandomSeed()
 619 {
 620         float s;
 621         prandom_debug();
 622         s = ReadShort();
 623         psrandom(s);
 624 }
 625
 626 void Ent_ReadAccuracy(void)
 627 {
 628     int f, w;
 629     int sf = ReadInt24_t();
 630         if(sf == 0)
 631         {
 632                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 633                         weapon_accuracy[w] = -1;
 634                 return;
 635         }
 636
 637         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 638         {
 639                 if(sf & f)
 640                 {
 641             int b = ReadByte();
 642                         if(b == 0)
 643                                 weapon_accuracy[w] = -1;
 644                         else if(b == 255)
 645                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 646                         else
 647                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 648                 }
 649                 if(f == 0x800000)
 650                         f = 1;
 651                 else
 652                         f *= 2;
 653         }
 654 }
 655
 656 void Spawn_Draw(void)
 657 {
 658         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 659 }
 660
 661 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 662 {
 663         float teamnum = (ReadByte() - 1);
 664         vector spn_origin;
 665         spn_origin.x = ReadShort();
 666         spn_origin.y = ReadShort();
 667         spn_origin.z = ReadShort();
 668
 669         if(is_new)
 670         {
 671                 self.origin = spn_origin;
 672                 setsize(self, PL_MIN, PL_MAX);
 673                 droptofloor();
 674
 675                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 676                 {
 677                         self.mdl = "models/spawnpoint.md3";
 678                         self.colormod = Team_ColorRGB(teamnum);
 679                         precache_model(self.mdl);
 680                         setmodel(self, self.mdl);
 681                         self.drawmask = MASK_NORMAL;
 682                         //self.movetype = MOVETYPE_NOCLIP;
 683                         //self.draw = Spawn_Draw;
 684                 }*/
 685                 if(autocvar_cl_spawn_point_particles)
 686                 {
 687                         if((serverflags & SERVERFLAG_TEAMPLAY))
 688                         {
 689                                 switch(teamnum)
 690                                 {
 691                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 692                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 693                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 694                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 695                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 696                                 }
 697                         }
 698                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 699
 700                         self.draw = Spawn_Draw;
 701                 }
 702         }
 703
 704         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 705 }
 706
 707 void Ent_ReadSpawnEvent(float is_new)
 708 {
 709         // If entnum is 0, ONLY do the local spawn actions
 710         // this way the server can disable the sending of
 711         // spawn origin or such to clients if wanted.
 712         float entnum = ReadByte();
 713
 714         if(entnum)
 715         {
 716                 self.origin_x = ReadShort();
 717                 self.origin_y = ReadShort();
 718                 self.origin_z = ReadShort();
 719
 720                 if(is_new)
 721                 {
 722                         float teamnum = GetPlayerColor(entnum - 1);
 723
 724                         if(autocvar_cl_spawn_event_particles)
 725                         {
 726                                 switch(teamnum)
 727                                 {
 728                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 729                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 730                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 731                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 732                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 733                                 }
 734                         }
 735                         if(autocvar_cl_spawn_event_sound)
 736                         {
 737                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 738                         }
 739                 }
 740         }
 741
 742         // local spawn actions
 743         if(is_new && (!entnum || (entnum == player_localentnum)))
 744         {
 745                 zoomin_effect = 1;
 746                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 747
 748                 if(autocvar_cl_unpress_zoom_on_spawn)
 749                 {
 750                         localcmd("-zoom\n");
 751                         button_zoom = false;
 752                 }
 753         }
 754
 755         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 756 }
 757
 758 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 759 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 760 void Ent_RadarLink();
 761 void Ent_Init();
 762 void Ent_ScoresInfo();
 763 void CSQC_Ent_Update(float bIsNewEntity)
 764 {
 765         float t;
 766         float savetime;
 767         t = ReadByte();
 768
 769         if(autocvar_developer_csqcentities)
 770                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 771
 772         // set up the "time" global for received entities to be correct for interpolation purposes
 773         savetime = time;
 774         if(servertime)
 775         {
 776                 time = servertime;
 777         }
 778         else
 779         {
 780                 serverprevtime = time;
 781                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 782                 time = serverprevtime + serverdeltatime;
 783         }
 784
 785 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 786         if(self.enttype)
 787         {
 788                 if(t != self.enttype || bIsNewEntity)
 789                 {
 790                         //print("A CSQC entity changed its type!\n");
 791                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 792                         Ent_Remove();
 793                         clearentity(self);
 794                         bIsNewEntity = 1;
 795                 }
 796         }
 797         else
 798         {
 799                 if(!bIsNewEntity)
 800                 {
 801                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 802                         bIsNewEntity = 1;
 803                 }
 804         }
 805 #endif
 806         self.enttype = t;
 807         switch(t)
 808         {
 809                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 810                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 811                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 812                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 813                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 814                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 815                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 816                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 817                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 818                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 819                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 820                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 821                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 822                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 823                 case ENT_CLIENT_INIT: Ent_Init(); break;
 824                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 825                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 826                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 827                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 828                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 829                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 830                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 831                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 832                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 833                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 834                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 835                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 836                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 837                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 838                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 839                 case ENT_CLIENT_TURRET: ent_turret(); break;
 840                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 841                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 842                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 843                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 844                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 845                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 846                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 847                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 848                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 849                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 850                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 851                 case ENT_CLIENT_DOOR: ent_door(); break;
 852                 case ENT_CLIENT_PLAT: ent_plat(); break;
 853                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 854                 case ENT_CLIENT_CORNER: ent_corner(); break;
 855                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 856                 case ENT_CLIENT_TRAIN: ent_train(); break;
 857                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 858
 859                 default:
 860                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 861                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 862                         break;
 863         }
 864
 865         time = savetime;
 866 }
 867 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 868 // used when an entity changes its type. For an entity that someone interacts
 869 // with others, make sure it can no longer do so.
 870 void Ent_Remove()
 871 {
 872         if(self.entremove)
 873                 self.entremove();
 874
 875         if(self.skeletonindex)
 876         {
 877                 skel_delete(self.skeletonindex);
 878                 self.skeletonindex = 0;
 879         }
 880
 881         if(self.snd_looping > 0)
 882         {
 883                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 884                 self.snd_looping = 0;
 885         }
 886
 887         self.enttype = 0;
 888         self.classname = "";
 889         self.draw = menu_sub_null;
 890         self.entremove = menu_sub_null;
 891         // TODO possibly set more stuff to defaults
 892 }
 893 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 894 void CSQC_Ent_Remove()
 895 {
 896         if(autocvar_developer_csqcentities)
 897                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 898
 899         if(wasfreed(self))
 900         {
 901                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 902                 return;
 903         }
 904         if(self.enttype)
 905                 Ent_Remove();
 906         remove(self);
 907 }
 908
 909 void Gamemode_Init()
 910 {
 911         if (!isdemo())
 912         {
 913                 if(!(calledhooks & HOOK_START))
 914                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 915                 calledhooks |= HOOK_START;
 916         }
 917 }
 918 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 919 void CSQC_Parse_StuffCmd(string strMessage)
 920 {
 921         if(autocvar_developer_csqcentities)
 922                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 923
 924         localcmd(strMessage);
 925 }
 926 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 927 void CSQC_Parse_Print(string strMessage)
 928 {
 929         if(autocvar_developer_csqcentities)
 930                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 931
 932         print(ColorTranslateRGB(strMessage));
 933 }
 934
 935 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 936 void CSQC_Parse_CenterPrint(string strMessage)
 937 {
 938         if(autocvar_developer_csqcentities)
 939                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 940
 941         centerprint_hud(strMessage);
 942 }
 943
 944 string notranslate_fogcmd1 = "\nfog ";
 945 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 946 void Fog_Force()
 947 {
 948         // TODO somehow thwart prvm_globalset client ...
 949
 950         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 951                 { localcmd("\nr_drawfog 0\n"); }
 952         else if(forcefog != "")
 953                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 954 }
 955
 956 void Gamemode_Init();
 957 void Ent_ScoresInfo()
 958 {
 959     int i;
 960         self.classname = "ent_client_scores_info";
 961         gametype = ReadInt24_t();
 962         HUD_ModIcons_SetFunc();
 963         for(i = 0; i < MAX_SCORE; ++i)
 964         {
 965                 if(scores_label[i])
 966                         strunzone(scores_label[i]);
 967                 scores_label[i] = strzone(ReadString());
 968                 scores_flags[i] = ReadByte();
 969         }
 970         for(i = 0; i < MAX_TEAMSCORE; ++i)
 971         {
 972                 if(teamscores_label[i])
 973                         strunzone(teamscores_label[i]);
 974                 teamscores_label[i] = strzone(ReadString());
 975                 teamscores_flags[i] = ReadByte();
 976         }
 977         HUD_InitScores();
 978         Gamemode_Init();
 979 }
 980
 981 void Ent_Init()
 982 {
 983         self.classname = "ent_client_init";
 984
 985         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 986
 987         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 989         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 990         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 993         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 994         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 995
 996         if(forcefog)
 997                 strunzone(forcefog);
 998         forcefog = strzone(ReadString());
 999
1000         armorblockpercent = ReadByte() / 255.0;
1001
1002         g_balance_mortar_bouncefactor = ReadCoord();
1003         g_balance_mortar_bouncestop = ReadCoord();
1004         g_balance_electro_secondary_bouncefactor = ReadCoord();
1005         g_balance_electro_secondary_bouncestop = ReadCoord();
1006
1007         vortex_scope = !ReadByte();
1008         rifle_scope = !ReadByte();
1009
1010         serverflags = ReadByte();
1011
1012         minelayer_maxmines = ReadByte();
1013
1014         hagar_maxrockets = ReadByte();
1015
1016         g_trueaim_minrange = ReadCoord();
1017         g_balance_porto_secondary = ReadByte();
1018
1019         if(!postinit)
1020                 PostInit();
1021 }
1022
1023 void Net_ReadRace()
1024 {
1025         float b;
1026
1027         b = ReadByte();
1028
1029         switch(b)
1030         {
1031                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1032                         race_checkpoint = ReadByte();
1033                         race_time = ReadInt24_t();
1034                         race_previousbesttime = ReadInt24_t();
1035                         if(race_previousbestname)
1036                                 strunzone(race_previousbestname);
1037                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1038
1039                         race_checkpointtime = time;
1040
1041                         if(race_checkpoint == 0 || race_checkpoint == 254)
1042                         {
1043                                 race_penaltyaccumulator = 0;
1044                                 race_laptime = time; // valid
1045                         }
1046
1047                         break;
1048
1049                 case RACE_NET_CHECKPOINT_CLEAR:
1050                         race_laptime = 0;
1051                         race_checkpointtime = 0;
1052                         break;
1053
1054                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1055                         race_laptime = ReadCoord();
1056                         race_checkpointtime = -99999;
1057                         // fall through
1058                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1059                         race_nextcheckpoint = ReadByte();
1060
1061                         race_nextbesttime = ReadInt24_t();
1062                         if(race_nextbestname)
1063                                 strunzone(race_nextbestname);
1064                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1065                         break;
1066
1067                 case RACE_NET_CHECKPOINT_HIT_RACE:
1068                         race_mycheckpoint = ReadByte();
1069                         race_mycheckpointtime = time;
1070                         race_mycheckpointdelta = ReadInt24_t();
1071                         race_mycheckpointlapsdelta = ReadByte();
1072                         if(race_mycheckpointlapsdelta >= 128)
1073                                 race_mycheckpointlapsdelta -= 256;
1074                         if(race_mycheckpointenemy)
1075                                 strunzone(race_mycheckpointenemy);
1076                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1077                         break;
1078
1079                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1080                         race_othercheckpoint = ReadByte();
1081                         race_othercheckpointtime = time;
1082                         race_othercheckpointdelta = ReadInt24_t();
1083                         race_othercheckpointlapsdelta = ReadByte();
1084                         if(race_othercheckpointlapsdelta >= 128)
1085                                 race_othercheckpointlapsdelta -= 256;
1086                         if(race_othercheckpointenemy)
1087                                 strunzone(race_othercheckpointenemy);
1088                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1089                         break;
1090
1091                 case RACE_NET_PENALTY_RACE:
1092                         race_penaltyeventtime = time;
1093                         race_penaltytime = ReadShort();
1094                         //race_penaltyaccumulator += race_penaltytime;
1095                         if(race_penaltyreason)
1096                                 strunzone(race_penaltyreason);
1097                         race_penaltyreason = strzone(ReadString());
1098                         break;
1099
1100                 case RACE_NET_PENALTY_QUALIFYING:
1101                         race_penaltyeventtime = time;
1102                         race_penaltytime = ReadShort();
1103                         race_penaltyaccumulator += race_penaltytime;
1104                         if(race_penaltyreason)
1105                                 strunzone(race_penaltyreason);
1106                         race_penaltyreason = strzone(ReadString());
1107                         break;
1108
1109                 case RACE_NET_SERVER_RECORD:
1110                         race_server_record = ReadInt24_t();
1111                         break;
1112                 case RACE_NET_SPEED_AWARD:
1113                         race_speedaward = ReadInt24_t();
1114                         if(race_speedaward_holder)
1115                                 strunzone(race_speedaward_holder);
1116                         race_speedaward_holder = strzone(ReadString());
1117                         break;
1118                 case RACE_NET_SPEED_AWARD_BEST:
1119                         race_speedaward_alltimebest = ReadInt24_t();
1120                         if(race_speedaward_alltimebest_holder)
1121                                 strunzone(race_speedaward_alltimebest_holder);
1122                         race_speedaward_alltimebest_holder = strzone(ReadString());
1123                         break;
1124                 case RACE_NET_SERVER_RANKINGS:
1125                         float prevpos, del;
1126             int pos = ReadShort();
1127                         prevpos = ReadShort();
1128                         del = ReadShort();
1129
1130                         // move other rankings out of the way
1131             int i;
1132                         if (prevpos) {
1133                                 for (i=prevpos-1;i>pos-1;--i) {
1134                                         grecordtime[i] = grecordtime[i-1];
1135                                         if(grecordholder[i])
1136                                                 strunzone(grecordholder[i]);
1137                                         grecordholder[i] = strzone(grecordholder[i-1]);
1138                                 }
1139                         } else if (del) { // a record has been deleted by the admin
1140                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1141                                         if (i == RANKINGS_CNT-1) { // clear out last record
1142                                                 grecordtime[i] = 0;
1143                                                 if (grecordholder[i])
1144                                                         strunzone(grecordholder[i]);
1145                                                 grecordholder[i] = string_null;
1146                                         }
1147                                         else {
1148                                                 grecordtime[i] = grecordtime[i+1];
1149                                                 if (grecordholder[i])
1150                                                         strunzone(grecordholder[i]);
1151                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1152                                         }
1153                                 }
1154                         } else { // player has no ranked record yet
1155                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1156                                         grecordtime[i] = grecordtime[i-1];
1157                                         if(grecordholder[i])
1158                                                 strunzone(grecordholder[i]);
1159                                         grecordholder[i] = strzone(grecordholder[i-1]);
1160                                 }
1161                         }
1162
1163                         // store new ranking
1164                         if(grecordholder[pos-1] != "")
1165                                 strunzone(grecordholder[pos-1]);
1166                         grecordholder[pos-1] = strzone(ReadString());
1167                         grecordtime[pos-1] = ReadInt24_t();
1168                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1169                                 race_myrank = pos;
1170                         break;
1171                 case RACE_NET_SERVER_STATUS:
1172                         race_status = ReadShort();
1173                         if(race_status_name)
1174                                 strunzone(race_status_name);
1175                         race_status_name = strzone(ReadString());
1176         }
1177 }
1178
1179 void Net_TeamNagger()
1180 {
1181         teamnagger = 1;
1182 }
1183
1184 void Net_ReadPingPLReport()
1185 {
1186         int e, pi, pl, ml;
1187         e = ReadByte();
1188         pi = ReadShort();
1189         pl = ReadByte();
1190         ml = ReadByte();
1191         if (!(playerslots[e]))
1192                 return;
1193         playerslots[e].ping = pi;
1194         playerslots[e].ping_packetloss = pl / 255.0;
1195         playerslots[e].ping_movementloss = ml / 255.0;
1196 }
1197
1198 void Net_WeaponComplain()
1199 {
1200         complain_weapon = ReadByte();
1201
1202         if(complain_weapon_name)
1203                 strunzone(complain_weapon_name);
1204         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1205
1206         complain_weapon_type = ReadByte();
1207
1208         complain_weapon_time = time;
1209         weapontime = time; // ping the weapon panel
1210
1211         switch(complain_weapon_type)
1212         {
1213                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1214                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1215                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1216         }
1217 }
1218
1219 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1220 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1221 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1222 float CSQC_Parse_TempEntity()
1223 {
1224         float bHandled;
1225                 bHandled  = true;
1226         // Acquire TE ID
1227         float nTEID;
1228                 nTEID = ReadByte();
1229
1230         if(autocvar_developer_csqcentities)
1231                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1232
1233                 // NOTE: Could just do return instead of break...
1234         switch(nTEID)
1235         {
1236                 case TE_CSQC_TARGET_MUSIC:
1237                         Net_TargetMusic();
1238                         bHandled = true;
1239                         break;
1240                 case TE_CSQC_PICTURE:
1241                         Net_MapVote_Picture();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_RACE:
1245                         Net_ReadRace();
1246                         bHandled = true;
1247                         break;
1248                 case TE_CSQC_VORTEXBEAMPARTICLE:
1249                         Net_ReadVortexBeamParticle();
1250                         bHandled = true;
1251                         break;
1252                 case TE_CSQC_TEAMNAGGER:
1253                         Net_TeamNagger();
1254                         bHandled = true;
1255                         break;
1256                 case TE_CSQC_ARC:
1257                         Net_ReadArc();
1258                         bHandled = true;
1259                         break;
1260                 case TE_CSQC_PINGPLREPORT:
1261                         Net_ReadPingPLReport();
1262                         bHandled = true;
1263                         break;
1264                 case TE_CSQC_WEAPONCOMPLAIN:
1265                         Net_WeaponComplain();
1266                         bHandled = true;
1267                         break;
1268                 case TE_CSQC_VEHICLESETUP:
1269                         Net_VehicleSetup();
1270                         bHandled = true;
1271                         break;
1272                 case TE_CSQC_SVNOTICE:
1273                         cl_notice_read();
1274                         bHandled = true;
1275                         break;
1276                 case TE_CSQC_SHOCKWAVEPARTICLE:
1277                         Net_ReadShockwaveParticle();
1278                         bHandled = true;
1279                         break;
1280                 default:
1281                         // No special logic for this temporary entity; return 0 so the engine can handle it
1282                         bHandled = false;
1283                         break;
1284         }
1285
1286         return bHandled;
1287 }
1288
1289 string getcommandkey(string text, string command)
1290 {
1291         string keys;
1292         float n, j, k, l = 0;
1293
1294         if (!autocvar_hud_showbinds)
1295                 return text;
1296
1297         keys = db_get(binddb, command);
1298         if (keys == "")
1299         {
1300                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1301                 for(j = 0; j < n; ++j)
1302                 {
1303                         k = stof(argv(j));
1304                         if(k != -1)
1305                         {
1306                                 if ("" == keys)
1307                                         keys = keynumtostring(k);
1308                                 else
1309                                         keys = strcat(keys, ", ", keynumtostring(k));
1310
1311                                 ++l;
1312                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1313                                         break;
1314                         }
1315
1316                 }
1317                 if (keys == "")
1318                         keys = "NO_KEY";
1319                 db_put(binddb, command, keys);
1320         }
1321
1322         if (keys == "NO_KEY") {
1323                 if (autocvar_hud_showbinds > 1)
1324                         return sprintf(_("%s (not bound)"), text);
1325                 else
1326                         return text;
1327         }
1328         else if (autocvar_hud_showbinds > 1)
1329                 return sprintf("%s (%s)", text, keys);
1330         else
1331                 return keys;
1332 }