qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 float mv_active;
   4 string mv_maps[MAPVOTE_COUNT];
   5 string mv_pics[MAPVOTE_COUNT];
   6 string mv_pk3[MAPVOTE_COUNT];
   7 float mv_preview[MAPVOTE_COUNT];
   8 float mv_votes[MAPVOTE_COUNT];
   9 entity mv_pk3list;
  10 float mv_abstain;
  11 float mv_ownvote;
  12 float mv_detail;
  13 float mv_timeout;
  14 float mv_maps_mask;
  15 float mv_top2_time;
  16 float mv_top2_alpha;
  17
  18 vector mv_mousepos;
  19 float mv_selection;
  20
  21 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)
  22 {
  23         string pre, post;
  24         pre = sprintf("%d. ", id+1);
  25         if(mv_detail)
  26         {
  27                 if(count == 1)
  28                         post = _(" (1 vote)");
  29                 else if(count >= 0)
  30                         post = sprintf(_(" (%d votes)"), count);
  31         }
  32         else
  33                 post = "";
  34         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);
  35         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  36         return strcat(pre, map, post);
  37 }
  38
  39 vector MapVote_RGB(float id, float count)
  40 {
  41         if(count < 0)
  42                 return '1 1 1';
  43         if(id == mv_ownvote)
  44                 return '0 1 0';
  45         else if (id == mv_selection)
  46                 return '1 1 0';
  47         else
  48                 return '1 1 1';
  49 }
  50
  51 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)
  52 {
  53         vector img_size;
  54         vector rgb;
  55         string label;
  56         float text_size;
  57
  58         isize -= hud_fontsize_y; // respect the text when calculating the image size
  59
  60         rgb = MapVote_RGB(id, count);
  61
  62         img_size_y = isize;
  63         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  64
  65         pos_y = pos_y + img_size_y;
  66
  67         label = MapVote_FormatMapItem(id, map, count, tsize, hud_fontsize);
  68
  69         text_size = stringwidth(label, false, hud_fontsize);
  70
  71         float theAlpha;
  72         if (count < 0 && mv_top2_alpha)
  73                 theAlpha = mv_top2_alpha;
  74         else
  75                 theAlpha = 1;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
  79
  80         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  81         pos_y = pos_y - img_size_y;
  82
  83         pos += autocvar_scoreboard_border_thickness * '1 1 0';
  84         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
  85         if(pic == "")
  86         {
  87                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
  88         }
  89         else
  90         {
  91                 if(drawgetimagesize(pic) == '0 0 0')
  92                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  93                 else
  94                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
  95         }
  96
  97         if(id == mv_ownvote)
  98                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
  99         else
 100                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 101
 102         if(id == mv_selection && count >= 0)
 103                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 104 }
 105
 106 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)
 107 {
 108         vector rgb;
 109         float text_size;
 110         string label;
 111
 112         rgb = MapVote_RGB(id, count);
 113
 114         pos_y = pos_y + hud_fontsize_y;
 115
 116         label = MapVote_FormatMapItem(id, _("Don't care"), count, tsize, hud_fontsize);
 117
 118         text_size = stringwidth(label, false, hud_fontsize);
 119
 120         pos_x -= text_size*0.5;
 121         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 122 }
 123
 124 vector MapVote_GridVec(vector gridspec, float i, float m)
 125 {
 126         float r;
 127         r = mod(i, m);
 128         return
 129                 '1 0 0' * (gridspec_x * r)
 130                 +
 131                 '0 1 0' * (gridspec_y * (i - r) / m);
 132 }
 133
 134 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 135 {
 136         float cell;
 137         float c, r;
 138
 139         cell = -1;
 140
 141         for (r = 0; r < rows; ++r)
 142                 for (c = 0; c < columns; ++c)
 143                 {
 144                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&
 145                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&
 146                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&
 147                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))
 148                         {
 149                                 cell = r * columns + c;
 150                                 break;
 151                         }
 152                 }
 153
 154         if (cell >= mv_num_maps)
 155                 cell = -1;
 156
 157         if (mv_abstain && cell < 0)
 158                 return mv_num_maps;
 159
 160         return cell;
 161 }
 162
 163 void MapVote_Draw()
 164 {
 165         string map;
 166         float i, tmp;
 167         vector pos;
 168         float isize;
 169         float center;
 170         float columns, rows;
 171         float tsize;
 172         vector dist;
 173
 174         if(!mv_active)
 175                 return;
 176
 177         center = (vid_conwidth - 1)/2;
 178         xmin = vid_conwidth*0.05; // 5% border must suffice
 179         xmax = vid_conwidth - xmin;
 180         ymin = 20;
 181         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 182         if(i < 0)
 183                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 184         if(i >= 0 || ymax < (vid_conheight*0.5))
 185                 ymax = vid_conheight - ymin;
 186
 187         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 188
 189         pos_y = ymin;
 190         pos_z = 0;
 191
 192         map = _("Vote for a map");
 193         pos_x = center - stringwidth(map, false, '12 0 0');
 194         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 195         pos_y += 26;
 196
 197         i = ceil(max(0, mv_timeout - time));
 198         map = sprintf(_("%d seconds left"), i);
 199         pos_x = center - stringwidth(map, false, '8 0 0');
 200         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 201         pos_y += 22;
 202         pos_x = xmin;
 203
 204         // base for multi-column stuff...
 205         ymin = pos_y;
 206         if(mv_abstain)
 207                 mv_num_maps -= 1;
 208
 209         if(mv_num_maps > 3)
 210         {
 211                 columns = 3;
 212         } else {
 213                 columns = mv_num_maps;
 214         }
 215         rows = ceil(mv_num_maps / columns);
 216
 217         dist_x = (xmax - xmin) / columns;
 218         dist_y = (ymax - pos_y) / rows;
 219         tsize = dist_x - 10;
 220         isize = min(dist_y - 10, 0.75 * tsize);
 221
 222         mv_selection = MapVote_Selection(pos, dist, rows, columns);
 223
 224         pos_x += (xmax - xmin) / (2 * columns);
 225         pos_y += (dist_y - isize) / 2;
 226         ymax -= isize;
 227
 228         if (mv_top2_time)
 229                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 230
 231         for(i = 0; i < mv_num_maps; ++i)
 232         {
 233                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 234                 map = mv_maps[i];
 235                 if(mv_preview[i])
 236                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);
 237                 else
 238                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);
 239         }
 240
 241         if(mv_abstain)
 242                 ++mv_num_maps;
 243
 244         if(mv_abstain && i < mv_num_maps) {
 245                 tmp = mv_votes[i];
 246                 pos_y = ymax + isize - hud_fontsize_y;
 247                 pos_x = (xmax+xmin)*0.5;
 248                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 249         }
 250
 251         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', autocvar_hud_panel_fg_alpha, DRAWFLAG_NORMAL);
 252 }
 253
 254 void Cmd_MapVote_MapDownload(float argc)
 255 {
 256         float id;
 257         entity pak;
 258
 259         if(argc != 2 || !mv_pk3list)
 260         {
 261                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 262                 return;
 263         }
 264
 265         id = stof(argv(1));
 266         for(pak = mv_pk3list; pak; pak = pak.chain)
 267                 if(pak.sv_entnum == id)
 268                         break;
 269
 270         if(!pak || pak.sv_entnum != id) {
 271                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 272                 return;
 273         }
 274
 275         if(PreviewExists(pak.message))
 276         {
 277                 mv_preview[id] = true;
 278                 return;
 279         } else {
 280                 print(_("Requesting preview...\n"));
 281                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 282         }
 283 }
 284
 285 void MapVote_CheckPK3(string pic, string pk3, float id)
 286 {
 287         entity pak;
 288         pak = spawn();
 289         pak.netname = pk3;
 290         pak.message = pic;
 291         pak.sv_entnum = id;
 292
 293         pak.chain = mv_pk3list;
 294         mv_pk3list = pak;
 295
 296         if(pk3 != "")
 297         {
 298                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 299         }
 300         else
 301         {
 302                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 303         }
 304 }
 305
 306 void MapVote_CheckPic(string pic, string pk3, float id)
 307 {
 308         // never try to retrieve a pic for the "don't care" 'map'
 309         if(mv_abstain && id == mv_num_maps - 1)
 310                 return;
 311
 312         if(PreviewExists(pic))
 313         {
 314                 mv_preview[id] = true;
 315                 return;
 316         }
 317         MapVote_CheckPK3(pic, pk3, id);
 318 }
 319
 320 #define NUM_SSDIRS 4
 321 string ssdirs[NUM_SSDIRS];
 322 float n_ssdirs;
 323 void MapVote_Init()
 324 {
 325         float i, j, power;
 326         string map, pk3, s;
 327
 328         precache_sound ("misc/invshot.wav");
 329
 330         mv_active = 1;
 331         setcursormode(1);
 332         mv_selection = -1;
 333
 334         for(n_ssdirs = 0; ; ++n_ssdirs)
 335         {
 336                 s = ReadString();
 337                 if(s == "")
 338                         break;
 339                 if(n_ssdirs < NUM_SSDIRS)
 340                         ssdirs[n_ssdirs] = s;
 341         }
 342         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 343
 344         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 345         mv_abstain = ReadByte();
 346         if(mv_abstain)
 347                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 348         mv_detail = ReadByte();
 349
 350         mv_ownvote = -1;
 351         mv_timeout = ReadCoord();
 352
 353         if(mv_num_maps <= 8)
 354                 mv_maps_mask = ReadByte();
 355         else
 356                 mv_maps_mask = ReadShort();
 357
 358         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 359         mv_pk3list = world; // I'm still paranoid!
 360
 361         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 362         {
 363                 mv_votes[i] = 0;
 364
 365                 if(mv_maps_mask & power)
 366                 {
 367                         map = strzone(ReadString());
 368                         pk3 = strzone(ReadString());
 369                         j = bound(0, ReadByte(), n_ssdirs - 1);
 370
 371                         mv_maps[i] = map;
 372                         mv_pk3[i] = pk3;
 373                         map = strzone(strcat(ssdirs[j], "/", map));
 374                         mv_pics[i] = map;
 375
 376                         mv_preview[i] = false;
 377
 378                         MapVote_CheckPic(map, pk3, i);
 379                 }
 380                 else
 381                 {
 382                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 383                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 384                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 385                         mv_preview[i] = false;
 386                 }
 387         }
 388
 389         for(i = 0; i < n_ssdirs; ++i)
 390                 ssdirs[n_ssdirs] = string_null;
 391         n_ssdirs = 0;
 392 }
 393
 394 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 395 {
 396         float imp;
 397
 398         if (!mv_active)
 399                 return false;
 400
 401         if(bInputType == 3)
 402         {
 403                 mv_mousepos_x = nPrimary;
 404                 mv_mousepos_y = nSecondary;
 405                 return true;
 406         }
 407
 408         if (bInputType != 0)
 409                 return false;
 410
 411         if ('0' <= nPrimary && nPrimary <= '9')
 412         {
 413                 imp = nPrimary - '0';
 414                 if (imp == 0) imp = 10;
 415                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 416                 return true;
 417         }
 418         switch(nPrimary)
 419         {
 420                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 421                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 422                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 423                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 424                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 425                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 426                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 427                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 428                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 429                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 430         }
 431
 432         if (nPrimary == K_MOUSE1)
 433                 if (mv_selection >= 0)
 434                 {
 435                         imp = min(mv_selection + 1, mv_num_maps);
 436                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 437                         return true;
 438                 }
 439
 440         return false;
 441 }
 442
 443 void MapVote_UpdateMask()
 444 {
 445         float i, power;
 446         float oldmask;
 447
 448         oldmask = mv_maps_mask;
 449         if(mv_num_maps <= 8)
 450                 mv_maps_mask = ReadByte();
 451         else
 452                 mv_maps_mask = ReadShort();
 453
 454         if(oldmask & mv_maps_mask != oldmask)
 455                 if(oldmask & mv_maps_mask == mv_maps_mask)
 456                          sound(world, CH_INFO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);
 457
 458         // remove votes that no longer apply
 459         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 460                 if not(mv_maps_mask & power)
 461                         mv_votes[i] = -1;
 462
 463         mv_top2_time = time;
 464 }
 465
 466 void MapVote_UpdateVotes()
 467 {
 468         float i, power;
 469         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 470         {
 471                 if(mv_maps_mask & power)
 472                 {
 473                         if(mv_detail)
 474                                 mv_votes[i] = ReadByte();
 475                         else
 476                                 mv_votes[i] = 0;
 477                 }
 478                 else
 479                         mv_votes[i] = -1;
 480         }
 481
 482         mv_ownvote = ReadByte()-1;
 483 }
 484
 485 void Ent_MapVote()
 486 {
 487         float sf;
 488
 489         sf = ReadByte();
 490
 491         if(sf & 1)
 492                 MapVote_Init();
 493
 494         if(sf & 2)
 495                 MapVote_UpdateMask();
 496
 497         if(sf & 4)
 498                 MapVote_UpdateVotes();
 499 }
 500
 501 void Net_MapVote_Picture()
 502 {
 503         float type;
 504         type = ReadByte();
 505         mv_preview[type] = true;
 506         mv_pics[type] = strzone(ReadPicture());
 507 }