qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/physics.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_side_speed;
  44 float autocvar_cl_followmodel_side_highpass;
  45 float autocvar_cl_followmodel_side_highpass1;
  46 float autocvar_cl_followmodel_side_limit;
  47 float autocvar_cl_followmodel_side_lowpass;
  48 float autocvar_cl_followmodel_up_speed;
  49 float autocvar_cl_followmodel_up_highpass;
  50 float autocvar_cl_followmodel_up_highpass1;
  51 float autocvar_cl_followmodel_up_limit;
  52 float autocvar_cl_followmodel_up_lowpass;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_side_speed;
  56 float autocvar_cl_leanmodel_side_highpass;
  57 float autocvar_cl_leanmodel_side_highpass1;
  58 float autocvar_cl_leanmodel_side_lowpass;
  59 float autocvar_cl_leanmodel_side_limit;
  60 float autocvar_cl_leanmodel_up_speed;
  61 float autocvar_cl_leanmodel_up_highpass;
  62 float autocvar_cl_leanmodel_up_highpass1;
  63 float autocvar_cl_leanmodel_up_lowpass;
  64 float autocvar_cl_leanmodel_up_limit;
  65
  66 #define lowpass(value, frac, ref_store, ret) do \
  67 { \
  68         float __frac = bound(0, frac, 1); \
  69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  70 } while (0)
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) do \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } while (0)
  77
  78 #define highpass(value, frac, ref_store, ret) do \
  79 { \
  80         float __f; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } while (0)
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) do \
  85 { \
  86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } while (0)
  89
  90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  91 { \
  92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  95 } while (0)
  96
  97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  98 { \
  99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
 100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 102 } while (0)
 103
 104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) do \
 105 { \
 106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 109 } while (0)
 110
 111 void viewmodel_animate(entity this)
 112 {
 113         static float prevtime;
 114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 115         prevtime = time;
 116
 117         if (autocvar_chase_active) return;
 118         if (getstati(STAT_HEALTH) <= 0) return;
 119
 120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 121
 122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 123         static bool oldonground;
 124         static float hitgroundtime;
 125         static float lastongroundtime;
 126         if (clonground)
 127         {
 128                 float f = time; // cl.movecmd[0].time
 129                 if (!oldonground)
 130                         hitgroundtime = f;
 131                 lastongroundtime = f;
 132         }
 133         oldonground = clonground;
 134
 135         vector gunorg = '0 0 0', gunangles = '0 0 0';
 136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 137
 138         bool teleported = view.csqcmodel_teleported;
 139
 140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 141         if (teleported)
 142         {
 143                 // try to fix the first highpass; result is NOT
 144                 // perfect! TODO find a better fix
 145                 gunangles_prev = view_angles;
 146                 gunorg_prev = view_origin;
 147         }
 148
 149         static vector gunorg_highpass = '0 0 0';
 150
 151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 152         gunorg_highpass += gunorg_prev;
 153         highpass3_limited(view_origin,
 154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 157                 gunorg_highpass, gunorg);
 158         gunorg_prev = view_origin;
 159         gunorg_highpass -= gunorg_prev;
 160
 161         static vector gunangles_highpass = '0 0 0';
 162
 163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 164         gunangles_highpass += gunangles_prev;
 165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 168         highpass3_limited(view_angles,
 169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 171                 0, 0,
 172                 gunangles_highpass, gunangles);
 173         gunangles_prev = view_angles;
 174         gunangles_highpass -= gunangles_prev;
 175
 176         // 3. calculate the RAW adjustment vectors
 177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 180
 181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 183         ROLL(gunangles) = 0;
 184
 185         static vector gunorg_adjustment_highpass;
 186         static vector gunorg_adjustment_lowpass;
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 192         highpass3(gunorg,
 193                 frametime * autocvar_cl_followmodel_side_highpass,
 194                 frametime * autocvar_cl_followmodel_side_highpass,
 195                 frametime * autocvar_cl_followmodel_up_highpass,
 196                 gunorg_adjustment_highpass, gunorg);
 197         lowpass3(gunorg,
 198                 frametime * autocvar_cl_followmodel_side_lowpass,
 199                 frametime * autocvar_cl_followmodel_side_lowpass,
 200                 frametime * autocvar_cl_followmodel_up_lowpass,
 201                 gunorg_adjustment_lowpass, gunorg);
 202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 203         highpass3(gunangles,
 204                 frametime * autocvar_cl_leanmodel_up_highpass,
 205                 frametime * autocvar_cl_leanmodel_side_highpass,
 206                 0,
 207                 gunangles_adjustment_highpass, gunangles);
 208         lowpass3(gunangles,
 209                 frametime * autocvar_cl_leanmodel_up_lowpass,
 210                 frametime * autocvar_cl_leanmodel_side_lowpass,
 211                 0,
 212                 gunangles_adjustment_lowpass, gunangles);
 213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 214
 215         // vertical view bobbing code
 216         // TODO: cl_bob
 217
 218         // horizontal view bobbing code
 219         // TODO: cl_bob2
 220
 221         // fall bobbing code
 222         // causes the view to swing down and back up when touching the ground
 223         // TODO: cl_bobfall
 224
 225         // gun model bobbing code
 226         if (autocvar_cl_bobmodel)
 227         {
 228                 // calculate for swinging gun model
 229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 231                 // for the most part, but for some reason when you go through a message trigger or
 232                 // pick up an item or anything like that it will momentarily jolt the gun.
 233                 vector forward, right, up;
 234                 float bspeed;
 235                 float t = 1;
 236                 float s = time * autocvar_cl_bobmodel_speed;
 237                 if (clonground)
 238                 {
 239                         if (time - hitgroundtime < 0.2)
 240                         {
 241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 242                                 t = time - hitgroundtime;
 243                                 t = bound(0, t, 0.2);
 244                                 t *= 5;
 245                         }
 246                 }
 247                 else
 248                 {
 249                         // recently left the ground, slow the bob down over the next 0.2 seconds
 250                         t = time - lastongroundtime;
 251                         t = 0.2 - bound(0, t, 0.2);
 252                         t *= 5;
 253                 }
 254                 bspeed = xyspeed * 0.01;
 255                 MAKEVECTORS(makevectors, gunangles, forward, right, up);
 256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 257                 gunorg += bobr * right;
 258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 259                 gunorg += bobu * up;
 260         }
 261         this.origin += view_forward * gunorg.x + view_right * gunorg.y + view_up * gunorg.z;
 262         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 263         this.angles += gunangles;
 264 }
 265
 266 .vector viewmodel_origin, viewmodel_angles;
 267 .float weapon_nextthink;
 268 .float weapon_eta_last;
 269 .float weapon_switchdelay;
 270
 271 void viewmodel_draw(entity this)
 272 {
 273         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 274         float a = this.alpha;
 275         int c = stof(getplayerkeyvalue(current_player, "colors"));
 276         vector g;
 277         Weapon wep = Weapons_from(switchingweapon);
 278         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 279         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 280         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 281                 | EF_NODEPTHTEST)
 282                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 283         for (entity e = this; e; e = e.weaponchild)
 284         {
 285                 e.drawmask = mask;
 286                 e.alpha = a;
 287                 e.colormap = c;
 288                 e.glowmod = g;
 289                 e.csqcmodel_effects = fx;
 290                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 291         }
 292         {
 293                 static string name_last;
 294                 string name = Weapons_from(activeweapon).mdl;
 295                 if (name != name_last)
 296                 {
 297                         name_last = name;
 298                         CL_WeaponEntity_SetModel(this, name);
 299                         this.viewmodel_origin = this.origin;
 300                         this.viewmodel_angles = this.angles;
 301                 }
 302                 anim_update(this);
 303                 if (!this.animstate_override)
 304                         anim_set(this, this.anim_idle, true, false, false);
 305         }
 306         float f = 0; // 0..1; 0: fully active
 307         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 308         if (eta <= 0) f = this.weapon_eta_last;
 309         else switch (this.state)
 310         {
 311                 case WS_RAISE:
 312                 {
 313                         f = eta / max(eta, this.weapon_switchdelay);
 314                         break;
 315                 }
 316                 case WS_DROP:
 317                 {
 318                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 319                         break;
 320                 }
 321                 case WS_CLEAR:
 322                 {
 323                         f = 1;
 324                         break;
 325                 }
 326         }
 327         this.weapon_eta_last = f;
 328         this.origin = this.viewmodel_origin;
 329         this.angles = this.viewmodel_angles;
 330         this.angles_x = (-90 * f * f);
 331         viewmodel_animate(this);
 332         setorigin(this, this.origin);
 333 }
 334
 335 entity viewmodel;
 336 STATIC_INIT(viewmodel) {
 337     viewmodel = new(viewmodel);
 338         viewmodel.draw = viewmodel_draw;
 339 }
 340
 341 entity porto;
 342 vector polyline[16];
 343 void Porto_Draw(entity this)
 344 {
 345         vector p, dir, ang, q, nextdir;
 346         float portal_number, portal1_idx;
 347
 348         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 349                 return;
 350         if(g_balance_porto_secondary)
 351                 return;
 352         if(intermission == 1)
 353                 return;
 354         if(intermission == 2)
 355                 return;
 356         if (getstati(STAT_HEALTH) <= 0)
 357                 return;
 358
 359         dir = view_forward;
 360
 361         if(angles_held_status)
 362         {
 363                 makevectors(angles_held);
 364                 dir = v_forward;
 365         }
 366
 367         p = view_origin;
 368
 369         polyline[0] = p;
 370         int idx = 1;
 371         portal_number = 0;
 372         nextdir = dir;
 373
 374         for (;;)
 375         {
 376                 dir = nextdir;
 377                 traceline(p, p + 65536 * dir, true, porto);
 378                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 379                         return;
 380                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 381                 p = trace_endpos;
 382                 polyline[idx] = p;
 383                 ++idx;
 384                 if(idx >= 16)
 385                         return;
 386                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 387                         continue;
 388                 ++portal_number;
 389                 ang = vectoangles2(trace_plane_normal, dir);
 390                 ang.x = -ang.x;
 391                 makevectors(ang);
 392                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 393                         return;
 394                 if(portal_number == 1)
 395                 {
 396                         portal1_idx = idx;
 397                         if(portal_number >= 2)
 398                                 break;
 399                 }
 400         }
 401
 402         while(idx >= 2)
 403         {
 404                 p = polyline[idx-2];
 405                 q = polyline[idx-1];
 406                 if(idx == 2)
 407                         p = p - view_up * 16;
 408                 if(idx-1 >= portal1_idx)
 409                 {
 410                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 411                 }
 412                 else
 413                 {
 414                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 415                 }
 416                 --idx;
 417         }
 418 }
 419
 420 void Porto_Init()
 421 {
 422         porto = new(porto);
 423         make_pure(porto);
 424         porto.draw = Porto_Draw;
 425         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 426 }
 427
 428 float drawtime;
 429 float avgspeed;
 430 vector GetCurrentFov(float fov)
 431 {
 432         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 433         float velocityzoom, curspeed;
 434         vector v;
 435
 436         zoomsensitivity = autocvar_cl_zoomsensitivity;
 437         zoomfactor = autocvar_cl_zoomfactor;
 438         if(zoomfactor < 1 || zoomfactor > 30)
 439                 zoomfactor = 2.5;
 440         zoomspeed = autocvar_cl_zoomspeed;
 441         if(zoomspeed >= 0)
 442         if(zoomspeed < 0.5 || zoomspeed > 16)
 443                         zoomspeed = 3.5;
 444
 445         zoomdir = button_zoom;
 446         if(hud == HUD_NORMAL)
 447         if(switchweapon == activeweapon)
 448         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 449                 zoomdir += button_attack2;
 450         if(spectatee_status > 0 || isdemo())
 451         {
 452                 if(spectatorbutton_zoom)
 453                 {
 454                         if(zoomdir)
 455                                 zoomdir = 0;
 456                         else
 457                                 zoomdir = 1;
 458                 }
 459                 // fteqcc failed twice here already, don't optimize this
 460         }
 461
 462         if(zoomdir) { zoomin_effect = 0; }
 463
 464         if(camera_active)
 465         {
 466                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 467         }
 468         else if(autocvar_cl_spawnzoom && zoomin_effect)
 469         {
 470                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 471
 472                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 473                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 474                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 475         }
 476         else
 477         {
 478                 if(zoomspeed < 0) // instant zoom
 479                 {
 480                         if(zoomdir)
 481                                 current_viewzoom = 1 / zoomfactor;
 482                         else
 483                                 current_viewzoom = 1;
 484                 }
 485                 else
 486                 {
 487                         if(zoomdir)
 488                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 489                         else
 490                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 491                 }
 492         }
 493
 494         if(almost_equals(current_viewzoom, 1))
 495                 current_zoomfraction = 0;
 496         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 497                 current_zoomfraction = 1;
 498         else
 499                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 500
 501         if(zoomsensitivity < 1)
 502                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 503         else
 504                 setsensitivityscale(1);
 505
 506         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 507         {
 508                 if(intermission) { curspeed = 0; }
 509                 else
 510                 {
 511
 512                         makevectors(view_angles);
 513                         v = pmove_vel;
 514                         if(csqcplayer)
 515                                 v = csqcplayer.velocity;
 516
 517                         switch(autocvar_cl_velocityzoom_type)
 518                         {
 519                                 case 3: curspeed = max(0, v_forward * v); break;
 520                                 case 2: curspeed = (v_forward * v); break;
 521                                 case 1: default: curspeed = vlen(v); break;
 522                         }
 523                 }
 524
 525                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 526                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 527                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 528
 529                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 530         }
 531         else
 532                 velocityzoom = 1;
 533
 534         float frustumx, frustumy, fovx, fovy;
 535         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 536         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 537         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 538         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 539
 540         return '1 0 0' * fovx + '0 1 0' * fovy;
 541 }
 542
 543 vector GetViewLocationFOV(float fov)
 544 {
 545         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 546         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 547         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 548         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 549         return '1 0 0' * fovx + '0 1 0' * fovy;
 550 }
 551
 552 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 553 {
 554         float fovx, fovy;
 555         float width = (ov_worldmax.x - ov_worldmin.x);
 556         float height = (ov_worldmax.y - ov_worldmin.y);
 557         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 558         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 559         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 560         return '1 0 0' * fovx + '0 1 0' * fovy;
 561 }
 562
 563 // this function must match W_SetupShot!
 564 float zoomscript_caught;
 565
 566 vector wcross_origin;
 567 float wcross_scale_prev, wcross_alpha_prev;
 568 vector wcross_color_prev;
 569 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 570 vector wcross_color_goal_prev;
 571 float wcross_changedonetime;
 572
 573 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 574 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 575 float wcross_name_changestarttime, wcross_name_changedonetime;
 576 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 577
 578 float wcross_ring_prev;
 579
 580 entity trueaim;
 581 entity trueaim_rifle;
 582
 583 const float SHOTTYPE_HITTEAM = 1;
 584 const float SHOTTYPE_HITOBSTRUCTION = 2;
 585 const float SHOTTYPE_HITWORLD = 3;
 586 const float SHOTTYPE_HITENEMY = 4;
 587
 588 void TrueAim_Init()
 589 {
 590         trueaim = new(trueaim);
 591         make_pure(trueaim);
 592         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 593         trueaim_rifle = new(trueaim_rifle);
 594         make_pure(trueaim_rifle);
 595         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 596 }
 597
 598 float EnemyHitCheck()
 599 {
 600         float t, n;
 601         wcross_origin = project_3d_to_2d(trace_endpos);
 602         wcross_origin.z = 0;
 603         if(trace_ent)
 604                 n = trace_ent.entnum;
 605         else
 606                 n = trace_networkentity;
 607         if(n < 1)
 608                 return SHOTTYPE_HITWORLD;
 609         if(n > maxclients)
 610                 return SHOTTYPE_HITWORLD;
 611         t = GetPlayerColor(n - 1);
 612         if(teamplay)
 613                 if(t == myteam)
 614                         return SHOTTYPE_HITTEAM;
 615         if(t == NUM_SPECTATOR)
 616                 return SHOTTYPE_HITWORLD;
 617         return SHOTTYPE_HITENEMY;
 618 }
 619
 620 float TrueAimCheck()
 621 {
 622         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 623         vector vecs, trueaimpoint, w_shotorg;
 624         vector mi, ma, dv;
 625         float shottype;
 626         entity ta;
 627         float mv;
 628
 629         mi = ma = '0 0 0';
 630         ta = trueaim;
 631         mv = MOVE_NOMONSTERS;
 632
 633         switch(activeweapon) // WEAPONTODO
 634         {
 635                 case WEP_TUBA.m_id: // no aim
 636                 case WEP_PORTO.m_id: // shoots from eye
 637                 case WEP_NEXBALL.m_id: // shoots from eye
 638                 case WEP_HOOK.m_id: // no trueaim
 639                 case WEP_MORTAR.m_id: // toss curve
 640                         return SHOTTYPE_HITWORLD;
 641                 case WEP_VORTEX.m_id:
 642                 case WEP_VAPORIZER.m_id:
 643                         mv = MOVE_NORMAL;
 644                         break;
 645                 case WEP_RIFLE.m_id:
 646                         ta = trueaim_rifle;
 647                         mv = MOVE_NORMAL;
 648                         if(zoomscript_caught)
 649                         {
 650                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 651                                 return EnemyHitCheck();
 652                         }
 653                         break;
 654                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 655                         mi = '-3 -3 -3';
 656                         ma = '3 3 3';
 657                         break;
 658                 case WEP_FIREBALL.m_id: // projectile has a size!
 659                         mi = '-16 -16 -16';
 660                         ma = '16 16 16';
 661                         break;
 662                 case WEP_SEEKER.m_id: // projectile has a size!
 663                         mi = '-2 -2 -2';
 664                         ma = '2 2 2';
 665                         break;
 666                 case WEP_ELECTRO.m_id: // projectile has a size!
 667                         mi = '0 0 -3';
 668                         ma = '0 0 -3';
 669                         break;
 670         }
 671
 672         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * getstati(STAT_VIEWHEIGHT));
 673
 674         vecs = decompressShotOrigin(STAT(SHOTORG));
 675
 676         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 677         trueaimpoint = trace_endpos;
 678
 679         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 680                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 681
 682         if(vecs.x > 0)
 683                 vecs.y = -vecs.y;
 684         else
 685                 vecs = '0 0 0';
 686
 687         dv = view_right * vecs.y + view_up * vecs.z;
 688         w_shotorg = traceorigin + dv;
 689
 690         // now move the vecs forward as much as requested if possible
 691         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 692         w_shotorg = trace_endpos - view_forward * nudge;
 693
 694         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 695         shottype = EnemyHitCheck();
 696         if(shottype != SHOTTYPE_HITWORLD)
 697                 return shottype;
 698
 699 #if 0
 700         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 701         // or rather, I know why, but see no fix
 702         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 703                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 704                 return SHOTTYPE_HITOBSTRUCTION;
 705 #endif
 706
 707         return SHOTTYPE_HITWORLD;
 708 }
 709
 710 void PostInit();
 711 void CSQC_Demo_Camera();
 712 float HUD_WouldDrawScoreboard();
 713 float camera_mode;
 714 const float CAMERA_FREE = 1;
 715 const float CAMERA_CHASE = 2;
 716 float reticle_type;
 717 string reticle_image;
 718 string NextFrameCommand;
 719
 720 vector freeze_org, freeze_ang;
 721 entity nightvision_noise, nightvision_noise2;
 722
 723 const float MAX_TIME_DIFF = 5;
 724 float pickup_crosshair_time, pickup_crosshair_size;
 725 float hitindication_crosshair_size;
 726 float use_vortex_chargepool;
 727
 728 float myhealth, myhealth_prev;
 729 float myhealth_flash;
 730
 731 float old_blurradius, old_bluralpha;
 732 float old_sharpen_intensity;
 733
 734 vector myhealth_gentlergb;
 735
 736 float contentavgalpha, liquidalpha_prev;
 737 vector liquidcolor_prev;
 738
 739 float eventchase_current_distance;
 740 float eventchase_running;
 741 bool WantEventchase()
 742 {SELFPARAM();
 743         if(autocvar_cl_orthoview)
 744                 return false;
 745         if(intermission)
 746                 return true;
 747         if(self.viewloc)
 748                 return true;
 749         if(spectatee_status >= 0)
 750         {
 751                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 752                         return true;
 753                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 754                         return true;
 755                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 756                         return true;
 757                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 758                 {
 759                         if(autocvar_cl_eventchase_death == 2)
 760                         {
 761                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 762                                 if(self.velocity == '0 0 0' || eventchase_running)
 763                                         return true;
 764                         }
 765                         else return true;
 766                 }
 767         }
 768         return false;
 769 }
 770
 771 void HUD_Crosshair_Vehicle()
 772 {
 773         if(hud != HUD_BUMBLEBEE_GUN)
 774         {
 775                 Vehicle info = get_vehicleinfo(hud);
 776                 info.vr_crosshair(info);
 777         }
 778 }
 779
 780 vector damage_blurpostprocess, content_blurpostprocess;
 781
 782 float unaccounted_damage = 0;
 783 void UpdateDamage()
 784 {
 785         // accumulate damage with each stat update
 786         static float damage_total_prev = 0;
 787         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 788         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 789         damage_total_prev = damage_total;
 790
 791         static float damage_dealt_time_prev = 0;
 792         float damage_dealt_time = STAT(HIT_TIME);
 793         if (damage_dealt_time != damage_dealt_time_prev)
 794         {
 795                 unaccounted_damage += unaccounted_damage_new;
 796                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 797         }
 798         damage_dealt_time_prev = damage_dealt_time;
 799
 800         // prevent hitsound when switching spectatee
 801         static float spectatee_status_prev = 0;
 802         if (spectatee_status != spectatee_status_prev)
 803                 unaccounted_damage = 0;
 804         spectatee_status_prev = spectatee_status;
 805 }
 806
 807 void HitSound()
 808 {
 809         // varying sound pitch
 810
 811         static float hitsound_time_prev = 0;
 812         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 813         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 814         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 815         {
 816                 if (autocvar_cl_hitsound && unaccounted_damage)
 817                 {
 818                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 819                         float a = autocvar_cl_hitsound_max_pitch;
 820                         float b = autocvar_cl_hitsound_min_pitch;
 821                         float c = autocvar_cl_hitsound_nom_damage;
 822                         float x = unaccounted_damage;
 823                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 824
 825                         // if sound variation is disabled, set pitch_shift to 1
 826                         if (autocvar_cl_hitsound == 1)
 827                                 pitch_shift = 1;
 828
 829                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 830                         if (autocvar_cl_hitsound == 3)
 831                         {
 832                                 float mirror_value = (a-b)/2 + b;
 833                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 834                         }
 835
 836                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 837
 838                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 839                         // todo: normalize sound pressure levels? seems unnecessary
 840
 841                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 842                 }
 843                 unaccounted_damage = 0;
 844                 hitsound_time_prev = time;
 845         }
 846
 847         static float typehit_time_prev = 0;
 848         float typehit_time = STAT(TYPEHIT_TIME);
 849         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 850         {
 851                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 852                 typehit_time_prev = typehit_time;
 853         }
 854 }
 855
 856 void HUD_Crosshair()
 857 {SELFPARAM();
 858         static float rainbow_last_flicker;
 859         static vector rainbow_prev_color;
 860         entity e = self;
 861         float f, i, j;
 862         vector v;
 863         if(!scoreboard_active && !camera_active && intermission != 2 &&
 864                 spectatee_status != -1 && !csqcplayer.viewloc &&
 865                 !HUD_MinigameMenu_IsOpened() )
 866         {
 867                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 868                         return;
 869
 870                 if (hud != HUD_NORMAL)
 871                 {
 872                         HUD_Crosshair_Vehicle();
 873                         return;
 874                 }
 875
 876                 string wcross_style;
 877                 float wcross_alpha, wcross_resolution;
 878                 wcross_style = autocvar_crosshair;
 879                 if (wcross_style == "0")
 880                         return;
 881                 wcross_resolution = autocvar_crosshair_size;
 882                 if (wcross_resolution == 0)
 883                         return;
 884                 wcross_alpha = autocvar_crosshair_alpha;
 885                 if (wcross_alpha == 0)
 886                         return;
 887
 888                 // TrueAim check
 889                 float shottype;
 890
 891                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 892                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 893                 wcross_origin.z = 0;
 894                 if(autocvar_crosshair_hittest)
 895                 {
 896                         vector wcross_oldorigin;
 897                         wcross_oldorigin = wcross_origin;
 898                         shottype = TrueAimCheck();
 899                         if(shottype == SHOTTYPE_HITWORLD)
 900                         {
 901                                 v = wcross_origin - wcross_oldorigin;
 902                                 v.x /= vid_conwidth;
 903                                 v.y /= vid_conheight;
 904                                 if(vlen(v) > 0.01)
 905                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 906                         }
 907                         if(!autocvar_crosshair_hittest_showimpact)
 908                                 wcross_origin = wcross_oldorigin;
 909                 }
 910                 else
 911                         shottype = SHOTTYPE_HITWORLD;
 912
 913                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 914                 string wcross_name = "";
 915                 float wcross_scale, wcross_blur;
 916
 917                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 918                 {
 919                         e = get_weaponinfo(switchingweapon);
 920                         if(e)
 921                         {
 922                                 if(autocvar_crosshair_per_weapon)
 923                                 {
 924                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 925                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 926                                         //if (wcross_resolution == 0)
 927                                                 //return;
 928
 929                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 930                                         wcross_resolution *= e.w_crosshair_size;
 931                                         wcross_name = e.w_crosshair;
 932                                 }
 933                         }
 934                 }
 935
 936                 if(wcross_name == "")
 937                         wcross_name = strcat("gfx/crosshair", wcross_style);
 938
 939                 // MAIN CROSSHAIR COLOR DECISION
 940                 switch(autocvar_crosshair_color_special)
 941                 {
 942                         case 1: // crosshair_color_per_weapon
 943                         {
 944                                 if(e)
 945                                 {
 946                                         wcross_color = e.wpcolor;
 947                                         break;
 948                                 }
 949                                 else { goto normalcolor; }
 950                         }
 951
 952                         case 2: // crosshair_color_by_health
 953                         {
 954                                 float x = getstati(STAT_HEALTH);
 955
 956                                 //x = red
 957                                 //y = green
 958                                 //z = blue
 959
 960                                 wcross_color.z = 0;
 961
 962                                 if(x > 200)
 963                                 {
 964                                         wcross_color.x = 0;
 965                                         wcross_color.y = 1;
 966                                 }
 967                                 else if(x > 150)
 968                                 {
 969                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 970                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 971                                 }
 972                                 else if(x > 100)
 973                                 {
 974                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 975                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 976                                         wcross_color.z = 1 - (x-100)*0.02;
 977                                 }
 978                                 else if(x > 50)
 979                                 {
 980                                         wcross_color.x = 1;
 981                                         wcross_color.y = 1;
 982                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 983                                 }
 984                                 else if(x > 20)
 985                                 {
 986                                         wcross_color.x = 1;
 987                                         wcross_color.y = (x-20)*90/27/100;
 988                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 989                                 }
 990                                 else
 991                                 {
 992                                         wcross_color.x = 1;
 993                                         wcross_color.y = 0;
 994                                 }
 995                                 break;
 996                         }
 997
 998                         case 3: // crosshair_color_rainbow
 999                         {
1000                                 if(time >= rainbow_last_flicker)
1001                                 {
1002                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1003                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1004                                 }
1005                                 wcross_color = rainbow_prev_color;
1006                                 break;
1007                         }
1008                         :normalcolor
1009                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1010                 }
1011
1012                 if(autocvar_crosshair_effect_scalefade)
1013                 {
1014                         wcross_scale = wcross_resolution;
1015                         wcross_resolution = 1;
1016                 }
1017                 else
1018                 {
1019                         wcross_scale = 1;
1020                 }
1021
1022                 if(autocvar_crosshair_pickup)
1023                 {
1024                         float stat_pickup_time = STAT(LAST_PICKUP);
1025
1026                         if(pickup_crosshair_time < stat_pickup_time)
1027                         {
1028                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1029                                         pickup_crosshair_size = 1;
1030
1031                                 pickup_crosshair_time = stat_pickup_time;
1032                         }
1033
1034                         if(pickup_crosshair_size > 0)
1035                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1036                         else
1037                                 pickup_crosshair_size = 0;
1038
1039                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1040                 }
1041
1042                 // todo: make crosshair hit indication dependent on damage dealt
1043                 if(autocvar_crosshair_hitindication)
1044                 {
1045                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1046
1047                         if(unaccounted_damage)
1048                         {
1049                                 hitindication_crosshair_size = 1;
1050                         }
1051
1052                         if(hitindication_crosshair_size > 0)
1053                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1054                         else
1055                                 hitindication_crosshair_size = 0;
1056
1057                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1058                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1059                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1060                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1061                 }
1062
1063                 if(shottype == SHOTTYPE_HITENEMY)
1064                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1065                 if(shottype == SHOTTYPE_HITTEAM)
1066                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1067
1068                 f = fabs(autocvar_crosshair_effect_time);
1069                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1070                 {
1071                         wcross_changedonetime = time + f;
1072                 }
1073                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1074                 {
1075                         wcross_name_changestarttime = time;
1076                         wcross_name_changedonetime = time + f;
1077                         if(wcross_name_goal_prev_prev)
1078                                 strunzone(wcross_name_goal_prev_prev);
1079                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1080                         wcross_name_goal_prev = strzone(wcross_name);
1081                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1082                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1083                         wcross_resolution_goal_prev = wcross_resolution;
1084                 }
1085
1086                 wcross_scale_goal_prev = wcross_scale;
1087                 wcross_alpha_goal_prev = wcross_alpha;
1088                 wcross_color_goal_prev = wcross_color;
1089
1090                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1091                 {
1092                         wcross_blur = 1;
1093                         wcross_alpha *= 0.75;
1094                 }
1095                 else
1096                         wcross_blur = 0;
1097                 // *_prev is at time-frametime
1098                 // * is at wcross_changedonetime+f
1099                 // what do we have at time?
1100                 if(time < wcross_changedonetime)
1101                 {
1102                         f = frametime / (wcross_changedonetime - time + frametime);
1103                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1104                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1105                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1106                 }
1107
1108                 wcross_scale_prev = wcross_scale;
1109                 wcross_alpha_prev = wcross_alpha;
1110                 wcross_color_prev = wcross_color;
1111
1112                 MUTATOR_CALLHOOK(UpdateCrosshair);
1113
1114                 wcross_scale *= 1 - autocvar__menu_alpha;
1115                 wcross_alpha *= 1 - autocvar__menu_alpha;
1116                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1117
1118                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1119                 {
1120                         // crosshair rings for weapon stats
1121                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1122                         {
1123                                 // declarations and stats
1124                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1125                                 string ring_image = string_null, ring_inner_image = string_null;
1126                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1127
1128                                 ring_scale = autocvar_crosshair_ring_size;
1129
1130                                 float weapon_clipload, weapon_clipsize;
1131                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1132                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1133
1134                                 float ok_ammo_charge, ok_ammo_chargepool;
1135                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1136                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1137
1138                                 float vortex_charge, vortex_chargepool;
1139                                 vortex_charge = STAT(VORTEX_CHARGE);
1140                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1141
1142                                 float arc_heat = STAT(ARC_HEAT);
1143
1144                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1145                                         vortex_charge_movingavg = vortex_charge;
1146
1147
1148                                 // handle the values
1149                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1150                                 {
1151                                         if (vortex_chargepool || use_vortex_chargepool) {
1152                                                 use_vortex_chargepool = 1;
1153                                                 ring_inner_value = vortex_chargepool;
1154                                         } else {
1155                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1156                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1157                                         }
1158
1159                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1160                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1161                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1162
1163                                         // draw the outer ring to show the current charge of the weapon
1164                                         ring_value = vortex_charge;
1165                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1166                                         ring_rgb = wcross_color;
1167                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1168                                 }
1169                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1170                                 {
1171                                         ring_value = bound(0, STAT(LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1172                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1173                                         ring_rgb = wcross_color;
1174                                         ring_image = "gfx/crosshair_ring.tga";
1175                                 }
1176                                 else if (activeweapon == WEP_HAGAR.m_id && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1177                                 {
1178                                         ring_value = bound(0, STAT(HAGAR_LOAD) / hagar_maxrockets, 1);
1179                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1180                                         ring_rgb = wcross_color;
1181                                         ring_image = "gfx/crosshair_ring.tga";
1182                                 }
1183                                 else if (ok_ammo_charge)
1184                                 {
1185                                         ring_value = ok_ammo_chargepool;
1186                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1187                                         ring_rgb = wcross_color;
1188                                         ring_image = "gfx/crosshair_ring.tga";
1189                                 }
1190                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1191                                 {
1192                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1193                                         ring_scale = autocvar_crosshair_ring_reload_size;
1194                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1195                                         ring_rgb = wcross_color;
1196
1197                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1198                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1199                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
1200                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1201                                         else
1202                                                 ring_image = "gfx/crosshair_ring.tga";
1203                                 }
1204                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
1205                                 {
1206                                         ring_value = arc_heat;
1207                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1208                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1209                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212
1213                                 // if in weapon switch animation, fade ring out/in
1214                                 if(autocvar_crosshair_effect_time > 0)
1215                                 {
1216                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1217                                         if (f >= 1)
1218                                         {
1219                                                 wcross_ring_prev = ((ring_image) ? true : false);
1220                                         }
1221
1222                                         if(wcross_ring_prev)
1223                                         {
1224                                                 if(f < 1)
1225                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1226                                         }
1227                                         else
1228                                         {
1229                                                 if(f < 1)
1230                                                         ring_alpha *= bound(0, f, 1);
1231                                         }
1232                                 }
1233
1234                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1235                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1236
1237                                 if (ring_value)
1238                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1239                         }
1240
1241 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1242                         do \
1243                         { \
1244                                 if(wcross_blur > 0) \
1245                                 { \
1246                                         for(i = -2; i <= 2; ++i) \
1247                                         for(j = -2; j <= 2; ++j) \
1248                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1249                                 } \
1250                                 else \
1251                                 { \
1252                                         M(0,0,sz,wcross_name,wcross_alpha); \
1253                                 } \
1254                         } \
1255                         while(0)
1256
1257 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1258                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1259
1260 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1261                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1262
1263                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1264                         {
1265                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1266                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1267                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1268                                 f = 1 - f;
1269                         }
1270                         else
1271                         {
1272                                 f = 1;
1273                         }
1274                         wcross_name_alpha_goal_prev = f;
1275
1276                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1277                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1278
1279                         if(autocvar_crosshair_dot)
1280                         {
1281                                 vector wcross_color_old;
1282                                 wcross_color_old = wcross_color;
1283
1284                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1285                                         wcross_color = stov(autocvar_crosshair_dot_color);
1286
1287                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1288                                 // FIXME why don't we use wcross_alpha here?
1289                                 wcross_color = wcross_color_old;
1290                         }
1291                 }
1292         }
1293         else
1294         {
1295                 wcross_scale_prev = 0;
1296                 wcross_alpha_prev = 0;
1297                 wcross_scale_goal_prev = 0;
1298                 wcross_alpha_goal_prev = 0;
1299                 wcross_changedonetime = 0;
1300                 if(wcross_name_goal_prev)
1301                         strunzone(wcross_name_goal_prev);
1302                 wcross_name_goal_prev = string_null;
1303                 if(wcross_name_goal_prev_prev)
1304                         strunzone(wcross_name_goal_prev_prev);
1305                 wcross_name_goal_prev_prev = string_null;
1306                 wcross_name_changestarttime = 0;
1307                 wcross_name_changedonetime = 0;
1308                 wcross_name_alpha_goal_prev = 0;
1309                 wcross_name_alpha_goal_prev_prev = 0;
1310                 wcross_resolution_goal_prev = 0;
1311                 wcross_resolution_goal_prev_prev = 0;
1312         }
1313 }
1314
1315 void HUD_Draw()
1316 {
1317         vector rgb = '0 0 0';
1318         float a = 1;
1319         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1320         {
1321                 rgb = MUTATOR_ARGV(0, vector);
1322                 a = MUTATOR_ARGV(0, float);
1323         }
1324         else if(STAT(FROZEN))
1325         {
1326                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1327         }
1328         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1329         if(!intermission)
1330         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1331         {
1332                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1333                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1334         }
1335         else if(STAT(REVIVE_PROGRESS))
1336         {
1337                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1338                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1339         }
1340
1341         if(autocvar_r_letterbox == 0)
1342                 if(autocvar_viewsize < 120)
1343                 {
1344                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1345                                 Accuracy_LoadLevels();
1346
1347                         HUD_Main();
1348                         HUD_DrawScoreboard();
1349                 }
1350
1351         // crosshair goes VERY LAST
1352         UpdateDamage();
1353         HUD_Crosshair();
1354         HitSound();
1355 }
1356
1357 bool ov_enabled;
1358 float oldr_nearclip;
1359 float oldr_farclip_base;
1360 float oldr_farclip_world;
1361 float oldr_novis;
1362 float oldr_useportalculling;
1363 float oldr_useinfinitefarclip;
1364
1365 void cl_notice_run();
1366 float prev_myteam;
1367 int lasthud;
1368 float vh_notice_time;
1369 void WaypointSprite_Load();
1370 void CSQC_UpdateView(float w, float h)
1371 {SELFPARAM();
1372         entity e;
1373         float fov;
1374         float f;
1375         vector vf_size, vf_min;
1376         float a;
1377
1378         execute_next_frame();
1379
1380         ++framecount;
1381
1382         stats_get();
1383         hud = STAT(HUD);
1384
1385         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1386                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1387
1388         lasthud = hud;
1389
1390         if(autocvar__hud_showbinds_reload) // menu can set this one
1391         {
1392                 db_close(binddb);
1393                 binddb = db_create();
1394                 cvar_set("_hud_showbinds_reload", "0");
1395         }
1396
1397         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1398                 view_quality = getproperty(VF_MINFPS_QUALITY);
1399         else
1400                 view_quality = 1;
1401
1402         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1403         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1404
1405         vf_size = getpropertyvec(VF_SIZE);
1406         vf_min = getpropertyvec(VF_MIN);
1407         vid_width = vf_size.x;
1408         vid_height = vf_size.y;
1409
1410         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1411         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1412
1413         WaypointSprite_Load();
1414
1415         CSQCPlayer_SetCamera();
1416
1417         if(player_localentnum <= maxclients) // is it a client?
1418                 current_player = player_localentnum - 1;
1419         else // then player_localentnum is the vehicle I'm driving
1420                 current_player = player_localnum;
1421         myteam = GetPlayerColor(current_player);
1422
1423         if(myteam != prev_myteam)
1424         {
1425                 myteamcolors = colormapPaletteColor(myteam, 1);
1426                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1427                 prev_myteam = myteam;
1428         }
1429
1430         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1431
1432         float is_dead = (getstati(STAT_HEALTH) <= 0);
1433
1434         // FIXME do we need this hack?
1435         if(isdemo())
1436         {
1437                 // in demos, input_buttons do not work
1438                 button_zoom = (autocvar__togglezoom == "-");
1439         }
1440         else if(button_zoom
1441                 && autocvar_cl_unpress_zoom_on_death
1442                 && (spectatee_status >= 0)
1443                 && (is_dead || intermission))
1444         {
1445                 // no zoom while dead or in intermission please
1446                 localcmd("-zoom\n");
1447                 button_zoom = false;
1448         }
1449
1450         // event chase camera
1451         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1452         {
1453                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1454                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1455                 entity gen = world;
1456
1457                 if(ons_roundlost)
1458                 {
1459                         entity e;
1460                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1461                         {
1462                                 if(e.health <= 0)
1463                                 {
1464                                         gen = e;
1465                                         break;
1466                                 }
1467                         }
1468                         if(!gen)
1469                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1470                 }
1471                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1472                 {
1473                         eventchase_running = true;
1474
1475                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1476                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1477                         if(ons_roundlost) { current_view_origin = gen.origin; }
1478
1479                         // detect maximum viewoffset and use it
1480                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1481                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1482                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1483
1484                         if(view_offset)
1485                         {
1486                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1487                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1488                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1489                         }
1490
1491                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1492                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1493                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1494                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1495
1496                         // make the camera smooth back
1497                         float chase_distance = autocvar_cl_eventchase_distance;
1498                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1499                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1500
1501                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1502                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1503                         else if(eventchase_current_distance != chase_distance)
1504                                 eventchase_current_distance = chase_distance;
1505
1506                         makevectors(view_angles);
1507
1508                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1509                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1510
1511                         // If the boxtrace fails, revert back to line tracing.
1512                         if(!self.viewloc)
1513                         if(trace_startsolid)
1514                         {
1515                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1516                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1517                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1518                         }
1519                         else { setproperty(VF_ORIGIN, trace_endpos); }
1520
1521                         if(!self.viewloc)
1522                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1523                 }
1524                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1525                 {
1526                         eventchase_running = false;
1527                         cvar_set("chase_active", "0");
1528                         eventchase_current_distance = 0; // start from 0 next time
1529                 }
1530         }
1531         // workaround for camera stuck between player's legs when using chase_active 1
1532         // because the engine stops updating the chase_active camera when the game ends
1533         else if(intermission)
1534         {
1535                 cvar_settemp("chase_active", "-1");
1536                 eventchase_current_distance = 0;
1537         }
1538
1539         // do lockview after event chase camera so that it still applies whenever necessary.
1540         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1541         {
1542                 setproperty(VF_ORIGIN, freeze_org);
1543                 setproperty(VF_ANGLES, freeze_ang);
1544         }
1545         else
1546         {
1547                 freeze_org = getpropertyvec(VF_ORIGIN);
1548                 freeze_ang = getpropertyvec(VF_ANGLES);
1549         }
1550
1551         WarpZone_FixView();
1552         //WarpZone_FixPMove();
1553
1554         vector ov_org = '0 0 0';
1555         vector ov_mid = '0 0 0';
1556         vector ov_worldmin = '0 0 0';
1557         vector ov_worldmax = '0 0 0';
1558         if(autocvar_cl_orthoview)
1559         {
1560                 ov_worldmin = mi_picmin;
1561                 ov_worldmax = mi_picmax;
1562
1563                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1564                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1565                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1566
1567                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1568                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1569
1570                 float ov_nearest = vlen(ov_org - vec3(
1571                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1572                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1573                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1574                 ));
1575
1576                 float ov_furthest = 0;
1577                 float dist = 0;
1578
1579                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1580                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1581                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1582                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1583                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1584                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1585                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1586                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1587
1588                 if(!ov_enabled)
1589                 {
1590                         oldr_nearclip = cvar("r_nearclip");
1591                         oldr_farclip_base = cvar("r_farclip_base");
1592                         oldr_farclip_world = cvar("r_farclip_world");
1593                         oldr_novis = cvar("r_novis");
1594                         oldr_useportalculling = cvar("r_useportalculling");
1595                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1596                 }
1597
1598                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1599                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1600                 cvar_settemp("r_farclip_world", "0");
1601                 cvar_settemp("r_novis", "1");
1602                 cvar_settemp("r_useportalculling", "0");
1603                 cvar_settemp("r_useinfinitefarclip", "0");
1604
1605                 setproperty(VF_ORIGIN, ov_org);
1606                 setproperty(VF_ANGLES, '90 0 0');
1607
1608                 ov_enabled = true;
1609
1610                 #if 0
1611                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1612                         vtos(ov_org),
1613                         vtos(getpropertyvec(VF_ANGLES)),
1614                         ov_distance,
1615                         ov_nearest,
1616                         ov_furthest);
1617                 #endif
1618         }
1619         else
1620         {
1621                 if(ov_enabled)
1622                 {
1623                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1624                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1625                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1626                         cvar_set("r_novis", ftos(oldr_novis));
1627                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1628                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1629                 }
1630                 ov_enabled = false;
1631         }
1632
1633         // Render the Scene
1634         view_origin = getpropertyvec(VF_ORIGIN);
1635         view_angles = getpropertyvec(VF_ANGLES);
1636         makevectors(view_angles);
1637         view_forward = v_forward;
1638         view_right = v_right;
1639         view_up = v_up;
1640
1641 #ifdef BLURTEST
1642         if(time > blurtest_time0 && time < blurtest_time1)
1643         {
1644                 float r, t;
1645
1646                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1647                 r = t * blurtest_radius;
1648                 f = 1 / pow(t, blurtest_power) - 1;
1649
1650                 cvar_set("r_glsl_postprocess", "1");
1651                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1652         }
1653         else
1654         {
1655                 cvar_set("r_glsl_postprocess", "0");
1656                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1657         }
1658 #endif
1659
1660         TargetMusic_Advance();
1661         Fog_Force();
1662
1663         if(drawtime == 0)
1664                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1665         else
1666                 drawframetime = bound(0.000001, time - drawtime, 1);
1667         drawtime = time;
1668
1669         // watch for gametype changes here...
1670         // in ParseStuffCMD the cmd isn't executed yet :/
1671         // might even be better to add the gametype to TE_CSQC_INIT...?
1672         if(!postinit)
1673                 PostInit();
1674
1675         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1676         {
1677                 if(calledhooks & HOOK_START)
1678                 {
1679                         localcmd("\ncl_hook_gameend\n");
1680                         calledhooks |= HOOK_END;
1681                 }
1682         }
1683
1684         Announcer();
1685
1686         fov = autocvar_fov;
1687         if(fov <= 59.5)
1688         {
1689                 if(!zoomscript_caught)
1690                 {
1691                         localcmd("+button9\n");
1692                         zoomscript_caught = 1;
1693                 }
1694         }
1695         else
1696         {
1697                 if(zoomscript_caught)
1698                 {
1699                         localcmd("-button9\n");
1700                         zoomscript_caught = 0;
1701                 }
1702         }
1703
1704         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1705
1706         // currently switching-to weapon (for crosshair)
1707         switchingweapon = STAT(SWITCHINGWEAPON);
1708
1709         // actually active weapon (for zoom)
1710         activeweapon = getstati(STAT_ACTIVEWEAPON);
1711
1712         f = (serverflags & SERVERFLAG_TEAMPLAY);
1713         if(f != teamplay)
1714         {
1715                 teamplay = f;
1716                 HUD_InitScores();
1717         }
1718
1719         if(last_switchweapon != switchweapon)
1720         {
1721                 weapontime = time;
1722                 last_switchweapon = switchweapon;
1723                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1724                 {
1725                         localcmd("-zoom\n");
1726                         button_zoom = false;
1727                 }
1728                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1729                 {
1730                         localcmd("-fire\n");
1731                         localcmd("-fire2\n");
1732                         button_attack2 = false;
1733                 }
1734         }
1735         if(last_activeweapon != activeweapon)
1736         {
1737                 last_activeweapon = activeweapon;
1738
1739                 e = get_weaponinfo(activeweapon);
1740                 if(e.netname != "")
1741                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1742                 else
1743                         localcmd("\ncl_hook_activeweapon none\n");
1744         }
1745
1746         // ALWAYS Clear Current Scene First
1747         clearscene();
1748
1749         setproperty(VF_ORIGIN, view_origin);
1750         setproperty(VF_ANGLES, view_angles);
1751
1752         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1753         setproperty(VF_SIZE, vf_size);
1754         setproperty(VF_MIN, vf_min);
1755
1756         // Assign Standard Viewflags
1757         // Draw the World (and sky)
1758         setproperty(VF_DRAWWORLD, 1);
1759
1760         // Set the console size vars
1761         vid_conwidth = autocvar_vid_conwidth;
1762         vid_conheight = autocvar_vid_conheight;
1763         vid_pixelheight = autocvar_vid_pixelheight;
1764
1765         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1766         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1767         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1768
1769         // Camera for demo playback
1770         if(camera_active)
1771         {
1772                 if(autocvar_camera_enable)
1773                         CSQC_Demo_Camera();
1774                 else
1775                 {
1776                         cvar_set("chase_active", ftos(chase_active_backup));
1777                         cvar_set("cl_demo_mousegrab", "0");
1778                         camera_active = false;
1779                 }
1780         }
1781         else
1782         {
1783 #ifdef CAMERATEST
1784                 if(autocvar_camera_enable)
1785 #else
1786                 if(autocvar_camera_enable && isdemo())
1787 #endif
1788                 {
1789                         // Enable required Darkplaces cvars
1790                         chase_active_backup = autocvar_chase_active;
1791                         cvar_set("chase_active", "2");
1792                         cvar_set("cl_demo_mousegrab", "1");
1793                         camera_active = true;
1794                         camera_mode = false;
1795                 }
1796         }
1797
1798         // Draw the Crosshair
1799         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1800
1801         // Draw the Engine Status Bar (the default Quake HUD)
1802         setproperty(VF_DRAWENGINESBAR, 0);
1803
1804         // Update the mouse position
1805         /*
1806            mousepos_x = vid_conwidth;
1807            mousepos_y = vid_conheight;
1808            mousepos = mousepos*0.5 + getmousepos();
1809          */
1810
1811         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1812
1813         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1814         renderscene();
1815
1816         // now switch to 2D drawing mode by calling a 2D drawing function
1817         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1818         // next R_RenderScene call
1819         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1820
1821         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1822         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1823         {
1824                 // apply night vision effect
1825                 vector tc_00, tc_01, tc_10, tc_11;
1826                 vector rgb = '0 0 0';
1827
1828                 if(!nightvision_noise)
1829                 {
1830                         nightvision_noise = new(nightvision_noise);
1831                 }
1832                 if(!nightvision_noise2)
1833                 {
1834                         nightvision_noise2 = new(nightvision_noise2);
1835                 }
1836
1837                 // color tint in yellow
1838                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1839
1840                 // draw BG
1841                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1842                 rgb = '1 1 1';
1843                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1844                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1845                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1846                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1847                 tc_11 = tc_01 + tc_10 - tc_00;
1848                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1849                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1850                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1851                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1852                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1853                 R_EndPolygon();
1854
1855                 // draw FG
1856                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1857                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1858                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1859                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1860                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1861                 tc_11 = tc_01 + tc_10 - tc_00;
1862                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1863                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1866                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1867                 R_EndPolygon();
1868         }
1869
1870         if(autocvar_cl_reticle)
1871         {
1872                 Weapon wep = get_weaponinfo(activeweapon);
1873                 // Draw the aiming reticle for weapons that use it
1874                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1875                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1876                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1877                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1878                 {
1879                         // no zoom reticle while dead
1880                         reticle_type = 0;
1881                 }
1882                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1883                 {
1884                         if(reticle_image != "") { reticle_type = 2; }
1885                         else { reticle_type = 0; }
1886                 }
1887                 else if(button_zoom || zoomscript_caught)
1888                 {
1889                         // normal zoom
1890                         reticle_type = 1;
1891                 }
1892
1893                 if(reticle_type)
1894                 {
1895                         if(autocvar_cl_reticle_stretch)
1896                         {
1897                                 reticle_size.x = vid_conwidth;
1898                                 reticle_size.y = vid_conheight;
1899                                 reticle_pos.x = 0;
1900                                 reticle_pos.y = 0;
1901                         }
1902                         else
1903                         {
1904                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1905                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1906                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1907                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1908                         }
1909
1910                         if(zoomscript_caught)
1911                                 f = 1;
1912                         else
1913                                 f = current_zoomfraction;
1914
1915                         if(f)
1916                         {
1917                                 switch(reticle_type)
1918                                 {
1919                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1920                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1921                                 }
1922                         }
1923                 }
1924         }
1925         else
1926         {
1927                 if(reticle_type != 0) { reticle_type = 0; }
1928         }
1929
1930
1931         // improved polyblend
1932         if(autocvar_hud_contents)
1933         {
1934                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1935                 vector liquidcolor;
1936
1937                 switch(pointcontents(view_origin))
1938                 {
1939                         case CONTENT_WATER:
1940                                 liquidalpha = autocvar_hud_contents_water_alpha;
1941                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1942                                 incontent = 1;
1943                                 break;
1944
1945                         case CONTENT_LAVA:
1946                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1947                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1948                                 incontent = 1;
1949                                 break;
1950
1951                         case CONTENT_SLIME:
1952                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1953                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1954                                 incontent = 1;
1955                                 break;
1956
1957                         default:
1958                                 liquidalpha = 0;
1959                                 liquidcolor = '0 0 0';
1960                                 incontent = 0;
1961                                 break;
1962                 }
1963
1964                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1965                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1966                         contentfadetime = autocvar_hud_contents_fadeintime;
1967                         liquidalpha_prev = liquidalpha;
1968                         liquidcolor_prev = liquidcolor;
1969                 }
1970                 else
1971                         contentfadetime = autocvar_hud_contents_fadeouttime;
1972
1973                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1974                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1975
1976                 if(contentavgalpha)
1977                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1978
1979                 if(autocvar_hud_postprocessing)
1980                 {
1981                         if(autocvar_hud_contents_blur && contentavgalpha)
1982                         {
1983                                 content_blurpostprocess.x = 1;
1984                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1985                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1986                         }
1987                         else
1988                         {
1989                                 content_blurpostprocess.x = 0;
1990                                 content_blurpostprocess.y = 0;
1991                                 content_blurpostprocess.z = 0;
1992                         }
1993                 }
1994         }
1995
1996         if(autocvar_hud_damage && !STAT(FROZEN))
1997         {
1998                 splash_size.x = max(vid_conwidth, vid_conheight);
1999                 splash_size.y = max(vid_conwidth, vid_conheight);
2000                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2001                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2002
2003                 float myhealth_flash_temp;
2004                 myhealth = getstati(STAT_HEALTH);
2005
2006                 // fade out
2007                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2008                 // add new damage
2009                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2010
2011                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2012                 pain_threshold = autocvar_hud_damage_pain_threshold;
2013                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2014                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2015
2016                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2017                 {
2018                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2019                 }
2020
2021                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2022
2023                 if(myhealth_prev < 1)
2024                 {
2025                         if(myhealth >= 1)
2026                         {
2027                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2028                                 myhealth_flash_temp = 0;
2029                         }
2030                         else
2031                         {
2032                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2033                         }
2034                 }
2035
2036                 if(spectatee_status == -1 || intermission)
2037                 {
2038                         myhealth_flash = 0; // observing, or match ended
2039                         myhealth_flash_temp = 0;
2040                 }
2041
2042                 myhealth_prev = myhealth;
2043
2044                 // IDEA: change damage color/picture based on player model for robot/alien species?
2045                 // pro: matches model better
2046                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2047                 // maybe different reddish pics?
2048                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2049                 {
2050                         if(autocvar_cl_gentle_damage == 2)
2051                         {
2052                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2053                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2054                         }
2055                         else
2056                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2057
2058                         if(myhealth_flash_temp > 0)
2059                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2060                 }
2061                 else if(myhealth_flash_temp > 0)
2062                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2063
2064                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2065                 {
2066                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2067                         {
2068                                 damage_blurpostprocess.x = 1;
2069                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2070                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2071                         }
2072                         else
2073                         {
2074                                 damage_blurpostprocess.x = 0;
2075                                 damage_blurpostprocess.y = 0;
2076                                 damage_blurpostprocess.z = 0;
2077                         }
2078                 }
2079         }
2080
2081         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2082         float e2 = (autocvar_hud_powerup != 0);
2083         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2084         {
2085                 // enable or disable rendering types if they are used or not
2086                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2087                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2088
2089                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2090                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2091                 {
2092                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2093                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2094                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2095                         {
2096                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2097                                 old_blurradius = blurradius;
2098                                 old_bluralpha = bluralpha;
2099                         }
2100                 }
2101                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2102                 {
2103                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2104                         old_blurradius = 0;
2105                         old_bluralpha = 0;
2106                 }
2107
2108                 // edge detection postprocess handling done second (used by hud_powerup)
2109                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2110                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2111                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2112
2113                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2114
2115                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2116                 {
2117                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2118                         {
2119                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2120                                 old_sharpen_intensity = sharpen_intensity;
2121                         }
2122                 }
2123                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2124                 {
2125                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2126                         old_sharpen_intensity = 0;
2127                 }
2128
2129                 if(cvar("r_glsl_postprocess") == 0)
2130                         cvar_set("r_glsl_postprocess", "2");
2131         }
2132         else if(cvar("r_glsl_postprocess") == 2)
2133                 cvar_set("r_glsl_postprocess", "0");
2134
2135         /*if(gametype == MAPINFO_TYPE_CTF)
2136           {
2137           ctf_view();
2138           } else */
2139
2140         // draw 2D entities
2141         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2142         Draw_ShowNames_All();
2143         Debug_Draw();
2144
2145         scoreboard_active = HUD_WouldDrawScoreboard();
2146
2147         HUD_Draw();
2148
2149         if(NextFrameCommand)
2150         {
2151                 localcmd("\n", NextFrameCommand, "\n");
2152                 NextFrameCommand = string_null;
2153         }
2154
2155         // we must do this check AFTER a frame was rendered, or it won't work
2156         if(cs_project_is_b0rked == 0)
2157         {
2158                 string w0, h0;
2159                 w0 = ftos(autocvar_vid_conwidth);
2160                 h0 = ftos(autocvar_vid_conheight);
2161                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2162                 //setproperty(VF_FOV, '90 90 0');
2163                 setproperty(VF_ORIGIN, '0 0 0');
2164                 setproperty(VF_ANGLES, '0 0 0');
2165                 setproperty(VF_PERSPECTIVE, 1);
2166                 makevectors('0 0 0');
2167                 vector v1, v2;
2168                 cvar_set("vid_conwidth", "800");
2169                 cvar_set("vid_conheight", "600");
2170                 v1 = cs_project(v_forward);
2171                 cvar_set("vid_conwidth", "640");
2172                 cvar_set("vid_conheight", "480");
2173                 v2 = cs_project(v_forward);
2174                 if(v1 == v2)
2175                         cs_project_is_b0rked = 1;
2176                 else
2177                         cs_project_is_b0rked = -1;
2178                 cvar_set("vid_conwidth", w0);
2179                 cvar_set("vid_conheight", h0);
2180         }
2181
2182         if(autocvar__hud_configure)
2183                 HUD_Panel_Mouse();
2184         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2185                 HUD_Minigame_Mouse();
2186         else if(QuickMenu_IsOpened())
2187                 QuickMenu_Mouse();
2188         else
2189                 HUD_Radar_Mouse();
2190
2191         cl_notice_run();
2192
2193         // let's reset the view back to normal for the end
2194         setproperty(VF_MIN, '0 0 0');
2195         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2196 }
2197
2198
2199 // following vectors must be global to allow seamless switching between camera modes
2200 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2201 void CSQC_Demo_Camera()
2202 {
2203         float speed, attenuation, dimensions;
2204         vector tmp, delta;
2205
2206         if( autocvar_camera_reset || !camera_mode )
2207         {
2208                 camera_offset = '0 0 0';
2209                 current_angles = '0 0 0';
2210                 camera_direction = '0 0 0';
2211                 camera_offset.z += 30;
2212                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2213                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2214                 current_origin = view_origin;
2215                 current_camera_offset  = camera_offset;
2216                 cvar_set("camera_reset", "0");
2217                 camera_mode = CAMERA_CHASE;
2218         }
2219
2220         // Camera angles
2221         if( camera_roll )
2222                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2223
2224         if(autocvar_camera_look_player)
2225         {
2226                 vector dir;
2227                 float n;
2228
2229                 dir = normalize(view_origin - current_position);
2230                 n = mouse_angles.z;
2231                 mouse_angles = vectoangles(dir);
2232                 mouse_angles.x = mouse_angles.x * -1;
2233                 mouse_angles.z = n;
2234         }
2235         else
2236         {
2237                 tmp = getmousepos() * 0.1;
2238                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2239                 {
2240                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2241                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2242                 }
2243         }
2244
2245         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2246         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2247         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2248         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2249
2250         // Fix difference when angles don't have the same sign
2251         delta = '0 0 0';
2252         if(mouse_angles.y < -60 && current_angles.y > 60)
2253                 delta = '0 360 0';
2254         if(mouse_angles.y > 60 && current_angles.y < -60)
2255                 delta = '0 -360 0';
2256
2257         if(autocvar_camera_look_player)
2258                 attenuation = autocvar_camera_look_attenuation;
2259         else
2260                 attenuation = autocvar_camera_speed_attenuation;
2261
2262         attenuation = 1 / max(1, attenuation);
2263         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2264
2265         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2266         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2267         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2268         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2269
2270         // Camera position
2271         tmp = '0 0 0';
2272         dimensions = 0;
2273
2274         if( camera_direction.x )
2275         {
2276                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2277                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2278                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2279                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2280                 ++dimensions;
2281         }
2282
2283         if( camera_direction.y )
2284         {
2285                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2286                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2287                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2288                 ++dimensions;
2289         }
2290
2291         if( camera_direction.z )
2292         {
2293                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2294                 ++dimensions;
2295         }
2296
2297         if(autocvar_camera_free)
2298                 speed = autocvar_camera_speed_free;
2299         else
2300                 speed = autocvar_camera_speed_chase;
2301
2302         if(dimensions)
2303         {
2304                 speed = speed * sqrt(1 / dimensions);
2305                 camera_offset += tmp * speed;
2306         }
2307
2308         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2309
2310         // Camera modes
2311         if( autocvar_camera_free )
2312         {
2313                 if ( camera_mode == CAMERA_CHASE )
2314                 {
2315                         current_camera_offset = current_origin + current_camera_offset;
2316                         camera_offset = current_origin + camera_offset;
2317                 }
2318
2319                 camera_mode = CAMERA_FREE;
2320                 current_position = current_camera_offset;
2321         }
2322         else
2323         {
2324                 if ( camera_mode == CAMERA_FREE )
2325                 {
2326                         current_origin = view_origin;
2327                         camera_offset = camera_offset - current_origin;
2328                         current_camera_offset = current_camera_offset - current_origin;
2329                 }
2330
2331                 camera_mode = CAMERA_CHASE;
2332
2333                 if(autocvar_camera_chase_smoothly)
2334                         current_origin += (view_origin - current_origin) * attenuation;
2335                 else
2336                         current_origin = view_origin;
2337
2338                 current_position = current_origin + current_camera_offset;
2339         }
2340
2341         setproperty(VF_ANGLES, current_angles);
2342         setproperty(VF_ORIGIN, current_position);
2343 }