qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades/all.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw(entity this)
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if(switchweapon == activeweapon)
 135         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 136                 zoomdir += button_attack2;
 137         if(spectatee_status > 0 || isdemo())
 138         {
 139                 if(spectatorbutton_zoom)
 140                 {
 141                         if(zoomdir)
 142                                 zoomdir = 0;
 143                         else
 144                                 zoomdir = 1;
 145                 }
 146                 // fteqcc failed twice here already, don't optimize this
 147         }
 148
 149         if(zoomdir) { zoomin_effect = 0; }
 150
 151         if(camera_active)
 152         {
 153                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 154         }
 155         else if(autocvar_cl_spawnzoom && zoomin_effect)
 156         {
 157                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 158
 159                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 160                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 161                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 162         }
 163         else
 164         {
 165                 if(zoomspeed < 0) // instant zoom
 166                 {
 167                         if(zoomdir)
 168                                 current_viewzoom = 1 / zoomfactor;
 169                         else
 170                                 current_viewzoom = 1;
 171                 }
 172                 else
 173                 {
 174                         if(zoomdir)
 175                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 176                         else
 177                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 178                 }
 179         }
 180
 181         if(almost_equals(current_viewzoom, 1))
 182                 current_zoomfraction = 0;
 183         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 184                 current_zoomfraction = 1;
 185         else
 186                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 187
 188         if(zoomsensitivity < 1)
 189                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 190         else
 191                 setsensitivityscale(1);
 192
 193         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 194         {
 195                 if(intermission) { curspeed = 0; }
 196                 else
 197                 {
 198
 199                         makevectors(view_angles);
 200                         v = pmove_vel;
 201                         if(csqcplayer)
 202                                 v = csqcplayer.velocity;
 203
 204                         switch(autocvar_cl_velocityzoom_type)
 205                         {
 206                                 case 3: curspeed = max(0, v_forward * v); break;
 207                                 case 2: curspeed = (v_forward * v); break;
 208                                 case 1: default: curspeed = vlen(v); break;
 209                         }
 210                 }
 211
 212                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 213                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 214                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 215
 216                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 217         }
 218         else
 219                 velocityzoom = 1;
 220
 221         float frustumx, frustumy, fovx, fovy;
 222         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 223         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 224         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 225         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 226
 227         return '1 0 0' * fovx + '0 1 0' * fovy;
 228 }
 229
 230 vector GetViewLocationFOV(float fov)
 231 {
 232         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 233         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 234         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 235         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 236         return '1 0 0' * fovx + '0 1 0' * fovy;
 237 }
 238
 239 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 240 {
 241         float fovx, fovy;
 242         float width = (ov_worldmax.x - ov_worldmin.x);
 243         float height = (ov_worldmax.y - ov_worldmin.y);
 244         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 245         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 247         return '1 0 0' * fovx + '0 1 0' * fovy;
 248 }
 249
 250 // this function must match W_SetupShot!
 251 float zoomscript_caught;
 252
 253 vector wcross_origin;
 254 float wcross_scale_prev, wcross_alpha_prev;
 255 vector wcross_color_prev;
 256 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 257 vector wcross_color_goal_prev;
 258 float wcross_changedonetime;
 259
 260 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 261 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 262 float wcross_name_changestarttime, wcross_name_changedonetime;
 263 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 264
 265 float wcross_ring_prev;
 266
 267 entity trueaim;
 268 entity trueaim_rifle;
 269
 270 const float SHOTTYPE_HITTEAM = 1;
 271 const float SHOTTYPE_HITOBSTRUCTION = 2;
 272 const float SHOTTYPE_HITWORLD = 3;
 273 const float SHOTTYPE_HITENEMY = 4;
 274
 275 void TrueAim_Init()
 276 {
 277         trueaim = spawn();
 278         trueaim.classname = "trueaim";
 279         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 280         trueaim_rifle = spawn();
 281         trueaim_rifle.classname = "trueaim_rifle";
 282         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 283 }
 284
 285 float EnemyHitCheck()
 286 {
 287         float t, n;
 288         wcross_origin = project_3d_to_2d(trace_endpos);
 289         wcross_origin.z = 0;
 290         if(trace_ent)
 291                 n = trace_ent.entnum;
 292         else
 293                 n = trace_networkentity;
 294         if(n < 1)
 295                 return SHOTTYPE_HITWORLD;
 296         if(n > maxclients)
 297                 return SHOTTYPE_HITWORLD;
 298         t = GetPlayerColor(n - 1);
 299         if(teamplay)
 300                 if(t == myteam)
 301                         return SHOTTYPE_HITTEAM;
 302         if(t == NUM_SPECTATOR)
 303                 return SHOTTYPE_HITWORLD;
 304         return SHOTTYPE_HITENEMY;
 305 }
 306
 307 float TrueAimCheck()
 308 {
 309         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 310         vector vecs, trueaimpoint, w_shotorg;
 311         vector mi, ma, dv;
 312         float shottype;
 313         entity ta;
 314         float mv;
 315
 316         mi = ma = '0 0 0';
 317         ta = trueaim;
 318         mv = MOVE_NOMONSTERS;
 319
 320         switch(activeweapon) // WEAPONTODO
 321         {
 322                 case WEP_TUBA.m_id: // no aim
 323                 case WEP_PORTO.m_id: // shoots from eye
 324                 case WEP_NEXBALL.m_id: // shoots from eye
 325                 case WEP_HOOK.m_id: // no trueaim
 326                 case WEP_MORTAR.m_id: // toss curve
 327                         return SHOTTYPE_HITWORLD;
 328                 case WEP_VORTEX.m_id:
 329                 case WEP_VAPORIZER.m_id:
 330                         mv = MOVE_NORMAL;
 331                         break;
 332                 case WEP_RIFLE.m_id:
 333                         ta = trueaim_rifle;
 334                         mv = MOVE_NORMAL;
 335                         if(zoomscript_caught)
 336                         {
 337                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 338                                 return EnemyHitCheck();
 339                         }
 340                         break;
 341                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 342                         mi = '-3 -3 -3';
 343                         ma = '3 3 3';
 344                         break;
 345                 case WEP_FIREBALL.m_id: // projectile has a size!
 346                         mi = '-16 -16 -16';
 347                         ma = '16 16 16';
 348                         break;
 349                 case WEP_SEEKER.m_id: // projectile has a size!
 350                         mi = '-2 -2 -2';
 351                         ma = '2 2 2';
 352                         break;
 353                 case WEP_ELECTRO.m_id: // projectile has a size!
 354                         mi = '0 0 -3';
 355                         ma = '0 0 -3';
 356                         break;
 357         }
 358
 359         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 360
 361         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 362
 363         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 364         trueaimpoint = trace_endpos;
 365
 366         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 367                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 368
 369         if(vecs.x > 0)
 370                 vecs.y = -vecs.y;
 371         else
 372                 vecs = '0 0 0';
 373
 374         dv = view_right * vecs.y + view_up * vecs.z;
 375         w_shotorg = traceorigin + dv;
 376
 377         // now move the vecs forward as much as requested if possible
 378         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 379         w_shotorg = trace_endpos - view_forward * nudge;
 380
 381         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 382         shottype = EnemyHitCheck();
 383         if(shottype != SHOTTYPE_HITWORLD)
 384                 return shottype;
 385
 386 #if 0
 387         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 388         // or rather, I know why, but see no fix
 389         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 390                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 391                 return SHOTTYPE_HITOBSTRUCTION;
 392 #endif
 393
 394         return SHOTTYPE_HITWORLD;
 395 }
 396
 397 void CSQC_common_hud(void);
 398
 399 void PostInit(void);
 400 void CSQC_Demo_Camera();
 401 float HUD_WouldDrawScoreboard();
 402 float camera_mode;
 403 const float CAMERA_FREE = 1;
 404 const float CAMERA_CHASE = 2;
 405 float reticle_type;
 406 string reticle_image;
 407 string NextFrameCommand;
 408
 409 vector freeze_org, freeze_ang;
 410 entity nightvision_noise, nightvision_noise2;
 411
 412 const float MAX_TIME_DIFF = 5;
 413 float pickup_crosshair_time, pickup_crosshair_size;
 414 float hitindication_crosshair_size;
 415 float use_vortex_chargepool;
 416
 417 float myhealth, myhealth_prev;
 418 float myhealth_flash;
 419
 420 float old_blurradius, old_bluralpha;
 421 float old_sharpen_intensity;
 422
 423 vector myhealth_gentlergb;
 424
 425 float contentavgalpha, liquidalpha_prev;
 426 vector liquidcolor_prev;
 427
 428 float eventchase_current_distance;
 429 float eventchase_running;
 430 bool WantEventchase()
 431 {SELFPARAM();
 432         if(autocvar_cl_orthoview)
 433                 return false;
 434         if(intermission)
 435                 return true;
 436         if(self.viewloc)
 437                 return true;
 438         if(spectatee_status >= 0)
 439         {
 440                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 441                         return true;
 442                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 443                         return true;
 444                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 445                         return true;
 446                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 447                 {
 448                         if(autocvar_cl_eventchase_death == 2)
 449                         {
 450                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 451                                 if(self.velocity == '0 0 0' || eventchase_running)
 452                                         return true;
 453                         }
 454                         else return true;
 455                 }
 456         }
 457         return false;
 458 }
 459
 460 void HUD_Vehicle()
 461 {
 462         if(!hud || intermission)
 463                 return;
 464
 465         if(hud == HUD_BUMBLEBEE_GUN)
 466                 CSQC_BUMBLE_GUN_HUD();
 467         else {
 468                 Vehicle info = get_vehicleinfo(hud);
 469                 info.vr_hud(info);
 470         }
 471 }
 472
 473 void HUD_Crosshair_Vehicle()
 474 {
 475         if(!hud || intermission)
 476                 return;
 477
 478         if(hud != HUD_BUMBLEBEE_GUN)
 479         {
 480                 Vehicle info = get_vehicleinfo(hud);
 481                 info.vr_crosshair(info);
 482         }
 483 }
 484
 485 vector damage_blurpostprocess, content_blurpostprocess;
 486
 487 float unaccounted_damage = 0;
 488 void UpdateDamage()
 489 {
 490         // accumulate damage with each stat update
 491         static float damage_total_prev = 0;
 492         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 493         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 494         damage_total_prev = damage_total;
 495
 496         static float damage_dealt_time_prev = 0;
 497         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 498         if (damage_dealt_time != damage_dealt_time_prev)
 499         {
 500                 unaccounted_damage += unaccounted_damage_new;
 501                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 502         }
 503         damage_dealt_time_prev = damage_dealt_time;
 504
 505         // prevent hitsound when switching spectatee
 506         static float spectatee_status_prev = 0;
 507         if (spectatee_status != spectatee_status_prev)
 508                 unaccounted_damage = 0;
 509         spectatee_status_prev = spectatee_status;
 510 }
 511
 512 void HitSound()
 513 {
 514         // varying sound pitch
 515
 516         static float hitsound_time_prev = 0;
 517         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 518         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 519         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 520         {
 521                 if (autocvar_cl_hitsound && unaccounted_damage)
 522                 {
 523                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 524                         float a = autocvar_cl_hitsound_max_pitch;
 525                         float b = autocvar_cl_hitsound_min_pitch;
 526                         float c = autocvar_cl_hitsound_nom_damage;
 527                         float x = unaccounted_damage;
 528                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 529
 530                         // if sound variation is disabled, set pitch_shift to 1
 531                         if (autocvar_cl_hitsound == 1)
 532                                 pitch_shift = 1;
 533
 534                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 535                         if (autocvar_cl_hitsound == 3)
 536                         {
 537                                 float mirror_value = (a-b)/2 + b;
 538                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 539                         }
 540
 541                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 542
 543                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 544                         // todo: normalize sound pressure levels? seems unnecessary
 545
 546                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 547                 }
 548                 unaccounted_damage = 0;
 549                 hitsound_time_prev = time;
 550         }
 551
 552         static float typehit_time_prev = 0;
 553         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 554         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 555         {
 556                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 557                 typehit_time_prev = typehit_time;
 558         }
 559 }
 560
 561 void HUD_Crosshair()
 562 {SELFPARAM();
 563         static float rainbow_last_flicker;
 564     static vector rainbow_prev_color;
 565         entity e = self;
 566         float f, i, j;
 567         vector v;
 568         if(!scoreboard_active && !camera_active && intermission != 2 &&
 569                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 570                 !HUD_MinigameMenu_IsOpened() )
 571         {
 572                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 573                         return;
 574
 575                 string wcross_style;
 576                 float wcross_alpha, wcross_resolution;
 577                 wcross_style = autocvar_crosshair;
 578                 if (wcross_style == "0")
 579                         return;
 580                 wcross_resolution = autocvar_crosshair_size;
 581                 if (wcross_resolution == 0)
 582                         return;
 583                 wcross_alpha = autocvar_crosshair_alpha;
 584                 if (wcross_alpha == 0)
 585                         return;
 586
 587                 // TrueAim check
 588                 float shottype;
 589
 590                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 591                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 592                 wcross_origin.z = 0;
 593                 if(autocvar_crosshair_hittest)
 594                 {
 595                         vector wcross_oldorigin;
 596                         wcross_oldorigin = wcross_origin;
 597                         shottype = TrueAimCheck();
 598                         if(shottype == SHOTTYPE_HITWORLD)
 599                         {
 600                                 v = wcross_origin - wcross_oldorigin;
 601                                 v.x /= vid_conwidth;
 602                                 v.y /= vid_conheight;
 603                                 if(vlen(v) > 0.01)
 604                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 605                         }
 606                         if(!autocvar_crosshair_hittest_showimpact)
 607                                 wcross_origin = wcross_oldorigin;
 608                 }
 609                 else
 610                         shottype = SHOTTYPE_HITWORLD;
 611
 612                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 613                 string wcross_name = "";
 614                 float wcross_scale, wcross_blur;
 615
 616                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 617                 {
 618                         e = get_weaponinfo(switchingweapon);
 619                         if(e)
 620                         {
 621                                 if(autocvar_crosshair_per_weapon)
 622                                 {
 623                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 624                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 625                                         //if (wcross_resolution == 0)
 626                                                 //return;
 627
 628                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 629                                         wcross_resolution *= e.w_crosshair_size;
 630                                         wcross_name = e.w_crosshair;
 631                                 }
 632                         }
 633                 }
 634
 635                 if(wcross_name == "")
 636                         wcross_name = strcat("gfx/crosshair", wcross_style);
 637
 638                 // MAIN CROSSHAIR COLOR DECISION
 639                 switch(autocvar_crosshair_color_special)
 640                 {
 641                         case 1: // crosshair_color_per_weapon
 642                         {
 643                                 if(e)
 644                                 {
 645                                         wcross_color = e.wpcolor;
 646                                         break;
 647                                 }
 648                                 else { goto normalcolor; }
 649                         }
 650
 651                         case 2: // crosshair_color_by_health
 652                         {
 653                                 float x = getstati(STAT_HEALTH);
 654
 655                                 //x = red
 656                                 //y = green
 657                                 //z = blue
 658
 659                                 wcross_color.z = 0;
 660
 661                                 if(x > 200)
 662                                 {
 663                                         wcross_color.x = 0;
 664                                         wcross_color.y = 1;
 665                                 }
 666                                 else if(x > 150)
 667                                 {
 668                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 669                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 670                                 }
 671                                 else if(x > 100)
 672                                 {
 673                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 674                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 675                                         wcross_color.z = 1 - (x-100)*0.02;
 676                                 }
 677                                 else if(x > 50)
 678                                 {
 679                                         wcross_color.x = 1;
 680                                         wcross_color.y = 1;
 681                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 682                                 }
 683                                 else if(x > 20)
 684                                 {
 685                                         wcross_color.x = 1;
 686                                         wcross_color.y = (x-20)*90/27/100;
 687                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 688                                 }
 689                                 else
 690                                 {
 691                                         wcross_color.x = 1;
 692                                         wcross_color.y = 0;
 693                                 }
 694                                 break;
 695                         }
 696
 697                         case 3: // crosshair_color_rainbow
 698                         {
 699                                 if(time >= rainbow_last_flicker)
 700                                 {
 701                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 702                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 703                                 }
 704                                 wcross_color = rainbow_prev_color;
 705                                 break;
 706                         }
 707                         :normalcolor
 708                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 709                 }
 710
 711                 if(autocvar_crosshair_effect_scalefade)
 712                 {
 713                         wcross_scale = wcross_resolution;
 714                         wcross_resolution = 1;
 715                 }
 716                 else
 717                 {
 718                         wcross_scale = 1;
 719                 }
 720
 721                 if(autocvar_crosshair_pickup)
 722                 {
 723                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 724
 725                         if(pickup_crosshair_time < stat_pickup_time)
 726                         {
 727                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 728                                         pickup_crosshair_size = 1;
 729
 730                                 pickup_crosshair_time = stat_pickup_time;
 731                         }
 732
 733                         if(pickup_crosshair_size > 0)
 734                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 735                         else
 736                                 pickup_crosshair_size = 0;
 737
 738                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 739                 }
 740
 741                 // todo: make crosshair hit indication dependent on damage dealt
 742                 if(autocvar_crosshair_hitindication)
 743                 {
 744                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 745
 746                         if(unaccounted_damage)
 747                         {
 748                                 hitindication_crosshair_size = 1;
 749                         }
 750
 751                         if(hitindication_crosshair_size > 0)
 752                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 753                         else
 754                                 hitindication_crosshair_size = 0;
 755
 756                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 757                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 758                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 759                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 760                 }
 761
 762                 if(shottype == SHOTTYPE_HITENEMY)
 763                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 764                 if(shottype == SHOTTYPE_HITTEAM)
 765                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 766
 767                 f = fabs(autocvar_crosshair_effect_time);
 768                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 769                 {
 770                         wcross_changedonetime = time + f;
 771                 }
 772                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 773                 {
 774                         wcross_name_changestarttime = time;
 775                         wcross_name_changedonetime = time + f;
 776                         if(wcross_name_goal_prev_prev)
 777                                 strunzone(wcross_name_goal_prev_prev);
 778                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 779                         wcross_name_goal_prev = strzone(wcross_name);
 780                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 781                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 782                         wcross_resolution_goal_prev = wcross_resolution;
 783                 }
 784
 785                 wcross_scale_goal_prev = wcross_scale;
 786                 wcross_alpha_goal_prev = wcross_alpha;
 787                 wcross_color_goal_prev = wcross_color;
 788
 789                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 790                 {
 791                         wcross_blur = 1;
 792                         wcross_alpha *= 0.75;
 793                 }
 794                 else
 795                         wcross_blur = 0;
 796                 // *_prev is at time-frametime
 797                 // * is at wcross_changedonetime+f
 798                 // what do we have at time?
 799                 if(time < wcross_changedonetime)
 800                 {
 801                         f = frametime / (wcross_changedonetime - time + frametime);
 802                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 803                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 804                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 805                 }
 806
 807                 wcross_scale_prev = wcross_scale;
 808                 wcross_alpha_prev = wcross_alpha;
 809                 wcross_color_prev = wcross_color;
 810
 811                 MUTATOR_CALLHOOK(UpdateCrosshair);
 812
 813                 wcross_scale *= 1 - autocvar__menu_alpha;
 814                 wcross_alpha *= 1 - autocvar__menu_alpha;
 815                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 816
 817                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 818                 {
 819                         // crosshair rings for weapon stats
 820                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 821                         {
 822                                 // declarations and stats
 823                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 824                                 string ring_image = string_null, ring_inner_image = string_null;
 825                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 826
 827                                 ring_scale = autocvar_crosshair_ring_size;
 828
 829                                 float weapon_clipload, weapon_clipsize;
 830                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 831                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 832
 833                                 float ok_ammo_charge, ok_ammo_chargepool;
 834                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 835                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 836
 837                                 float vortex_charge, vortex_chargepool;
 838                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 839                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 840
 841                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 842
 843                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 844                                         vortex_charge_movingavg = vortex_charge;
 845
 846
 847                                 // handle the values
 848                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 849                                 {
 850                                         if (vortex_chargepool || use_vortex_chargepool) {
 851                                                 use_vortex_chargepool = 1;
 852                                                 ring_inner_value = vortex_chargepool;
 853                                         } else {
 854                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 855                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 856                                         }
 857
 858                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 859                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 860                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 861
 862                                         // draw the outer ring to show the current charge of the weapon
 863                                         ring_value = vortex_charge;
 864                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 865                                         ring_rgb = wcross_color;
 866                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 867                                 }
 868                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 869                                 {
 870                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 871                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 872                                         ring_rgb = wcross_color;
 873                                         ring_image = "gfx/crosshair_ring.tga";
 874                                 }
 875                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 876                                 {
 877                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 878                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 879                                         ring_rgb = wcross_color;
 880                                         ring_image = "gfx/crosshair_ring.tga";
 881                                 }
 882                                 else if (ok_ammo_charge)
 883                                 {
 884                                         ring_value = ok_ammo_chargepool;
 885                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 886                                         ring_rgb = wcross_color;
 887                                         ring_image = "gfx/crosshair_ring.tga";
 888                                 }
 889                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 890                                 {
 891                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 892                                         ring_scale = autocvar_crosshair_ring_reload_size;
 893                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 894                                         ring_rgb = wcross_color;
 895
 896                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 897                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 898                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 899                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 900                                         else
 901                                                 ring_image = "gfx/crosshair_ring.tga";
 902                                 }
 903                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 904                                 {
 905                                         ring_value = arc_heat;
 906                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 907                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 908                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 909                                         ring_image = "gfx/crosshair_ring.tga";
 910                                 }
 911
 912                                 // if in weapon switch animation, fade ring out/in
 913                                 if(autocvar_crosshair_effect_time > 0)
 914                                 {
 915                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 916                                         if (f >= 1)
 917                                         {
 918                                                 wcross_ring_prev = ((ring_image) ? true : false);
 919                                         }
 920
 921                                         if(wcross_ring_prev)
 922                                         {
 923                                                 if(f < 1)
 924                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 925                                         }
 926                                         else
 927                                         {
 928                                                 if(f < 1)
 929                                                         ring_alpha *= bound(0, f, 1);
 930                                         }
 931                                 }
 932
 933                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 934                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 935
 936                                 if (ring_value)
 937                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 938                         }
 939
 940 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 941                         do \
 942                         { \
 943                                 if(wcross_blur > 0) \
 944                                 { \
 945                                         for(i = -2; i <= 2; ++i) \
 946                                         for(j = -2; j <= 2; ++j) \
 947                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 948                                 } \
 949                                 else \
 950                                 { \
 951                                         M(0,0,sz,wcross_name,wcross_alpha); \
 952                                 } \
 953                         } \
 954                         while(0)
 955
 956 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 957                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 958
 959 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 960                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 961
 962                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 963                         {
 964                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 965                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 966                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 967                                 f = 1 - f;
 968                         }
 969                         else
 970                         {
 971                                 f = 1;
 972                         }
 973                         wcross_name_alpha_goal_prev = f;
 974
 975                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 976                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 977
 978                         if(autocvar_crosshair_dot)
 979                         {
 980                                 vector wcross_color_old;
 981                                 wcross_color_old = wcross_color;
 982
 983                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 984                                         wcross_color = stov(autocvar_crosshair_dot_color);
 985
 986                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 987                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 988                                 wcross_color = wcross_color_old;
 989                         }
 990                 }
 991         }
 992         else
 993         {
 994                 wcross_scale_prev = 0;
 995                 wcross_alpha_prev = 0;
 996                 wcross_scale_goal_prev = 0;
 997                 wcross_alpha_goal_prev = 0;
 998                 wcross_changedonetime = 0;
 999                 if(wcross_name_goal_prev)
1000                         strunzone(wcross_name_goal_prev);
1001                 wcross_name_goal_prev = string_null;
1002                 if(wcross_name_goal_prev_prev)
1003                         strunzone(wcross_name_goal_prev_prev);
1004                 wcross_name_goal_prev_prev = string_null;
1005                 wcross_name_changestarttime = 0;
1006                 wcross_name_changedonetime = 0;
1007                 wcross_name_alpha_goal_prev = 0;
1008                 wcross_name_alpha_goal_prev_prev = 0;
1009                 wcross_resolution_goal_prev = 0;
1010                 wcross_resolution_goal_prev_prev = 0;
1011         }
1012 }
1013
1014 void HUD_Draw()
1015 {
1016         if(getstati(STAT_FROZEN))
1017                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1018         else if (getstatf(STAT_HEALING_ORB)>time)
1019                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1020         if(!intermission)
1021         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1022         {
1023                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1024                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1025         }
1026         else if(getstatf(STAT_REVIVE_PROGRESS))
1027         {
1028                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1029                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1030         }
1031
1032         if(autocvar_r_letterbox == 0)
1033                 if(autocvar_viewsize < 120)
1034                         CSQC_common_hud();
1035
1036         // crosshair goes VERY LAST
1037         UpdateDamage();
1038         HUD_Crosshair();
1039         HUD_Crosshair_Vehicle();
1040         HitSound();
1041 }
1042
1043 bool ov_enabled;
1044 float oldr_nearclip;
1045 float oldr_farclip_base;
1046 float oldr_farclip_world;
1047 float oldr_novis;
1048 float oldr_useportalculling;
1049 float oldr_useinfinitefarclip;
1050
1051 const int BUTTON_3 = 4;
1052 const int BUTTON_4 = 8;
1053 float cl_notice_run();
1054 float prev_myteam;
1055 int lasthud;
1056 float vh_notice_time;
1057 void WaypointSprite_Load();
1058 void CSQC_UpdateView(float w, float h)
1059 {SELFPARAM();
1060         entity e;
1061         float fov;
1062         float f;
1063         vector vf_size, vf_min;
1064         float a;
1065
1066         execute_next_frame();
1067
1068         ++framecount;
1069
1070         hud = getstati(STAT_HUD);
1071
1072         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1073                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1074
1075         lasthud = hud;
1076
1077         if(autocvar__hud_showbinds_reload) // menu can set this one
1078         {
1079                 db_close(binddb);
1080                 binddb = db_create();
1081                 cvar_set("_hud_showbinds_reload", "0");
1082         }
1083
1084         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1085                 view_quality = getproperty(VF_MINFPS_QUALITY);
1086         else
1087                 view_quality = 1;
1088
1089         button_attack2 = (input_buttons & BUTTON_3);
1090         button_zoom = (input_buttons & BUTTON_4);
1091
1092         vf_size = getpropertyvec(VF_SIZE);
1093         vf_min = getpropertyvec(VF_MIN);
1094         vid_width = vf_size.x;
1095         vid_height = vf_size.y;
1096
1097         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1098         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1099
1100         WaypointSprite_Load();
1101
1102         CSQCPlayer_SetCamera();
1103
1104         if(player_localentnum <= maxclients) // is it a client?
1105                 current_player = player_localentnum - 1;
1106         else // then player_localentnum is the vehicle I'm driving
1107                 current_player = player_localnum;
1108         myteam = GetPlayerColor(current_player);
1109
1110         if(myteam != prev_myteam)
1111         {
1112                 myteamcolors = colormapPaletteColor(myteam, 1);
1113                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1114                 prev_myteam = myteam;
1115         }
1116
1117         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1118
1119         float is_dead = (getstati(STAT_HEALTH) <= 0);
1120
1121         // FIXME do we need this hack?
1122         if(isdemo())
1123         {
1124                 // in demos, input_buttons do not work
1125                 button_zoom = (autocvar__togglezoom == "-");
1126         }
1127         else if(button_zoom
1128                 && autocvar_cl_unpress_zoom_on_death
1129                 && (spectatee_status >= 0)
1130                 && (is_dead || intermission))
1131         {
1132                 // no zoom while dead or in intermission please
1133                 localcmd("-zoom\n");
1134                 button_zoom = false;
1135         }
1136
1137         // event chase camera
1138         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1139         {
1140                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1141                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1142                 entity gen = world;
1143
1144                 if(ons_roundlost)
1145                 {
1146                         entity e;
1147                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1148                         {
1149                                 if(e.health <= 0)
1150                                 {
1151                                         gen = e;
1152                                         break;
1153                                 }
1154                         }
1155                         if(!gen)
1156                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1157                 }
1158                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1159                 {
1160                         eventchase_running = true;
1161
1162                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1163                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1164                         if(ons_roundlost) { current_view_origin = gen.origin; }
1165
1166                         // detect maximum viewoffset and use it
1167                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1168                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1169                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1170
1171                         if(view_offset)
1172                         {
1173                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1174                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1175                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1176                         }
1177
1178                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1179                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1180                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1181                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1182
1183                         // make the camera smooth back
1184                         float chase_distance = autocvar_cl_eventchase_distance;
1185                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1186                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1187
1188                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1189                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1190                         else if(eventchase_current_distance != chase_distance)
1191                                 eventchase_current_distance = chase_distance;
1192
1193                         makevectors(view_angles);
1194
1195                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1196                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1197
1198                         // If the boxtrace fails, revert back to line tracing.
1199                         if(!self.viewloc)
1200                         if(trace_startsolid)
1201                         {
1202                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1203                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1204                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1205                         }
1206                         else { setproperty(VF_ORIGIN, trace_endpos); }
1207
1208                         if(!self.viewloc)
1209                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1210                 }
1211                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1212                 {
1213                         eventchase_running = false;
1214                         cvar_set("chase_active", "0");
1215                         eventchase_current_distance = 0; // start from 0 next time
1216                 }
1217         }
1218         // workaround for camera stuck between player's legs when using chase_active 1
1219         // because the engine stops updating the chase_active camera when the game ends
1220         else if(intermission)
1221         {
1222                 cvar_settemp("chase_active", "-1");
1223                 eventchase_current_distance = 0;
1224         }
1225
1226         // do lockview after event chase camera so that it still applies whenever necessary.
1227         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1228         {
1229                 setproperty(VF_ORIGIN, freeze_org);
1230                 setproperty(VF_ANGLES, freeze_ang);
1231         }
1232         else
1233         {
1234                 freeze_org = getpropertyvec(VF_ORIGIN);
1235                 freeze_ang = getpropertyvec(VF_ANGLES);
1236         }
1237
1238         WarpZone_FixView();
1239         //WarpZone_FixPMove();
1240
1241         vector ov_org = '0 0 0';
1242         vector ov_mid = '0 0 0';
1243         vector ov_worldmin = '0 0 0';
1244         vector ov_worldmax = '0 0 0';
1245         if(autocvar_cl_orthoview)
1246         {
1247                 ov_worldmin = mi_picmin;
1248                 ov_worldmax = mi_picmax;
1249
1250                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1251                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1252                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1253
1254                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1255                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1256
1257                 float ov_nearest = vlen(ov_org - vec3(
1258                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1259                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1260                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1261                 ));
1262
1263                 float ov_furthest = 0;
1264                 float dist = 0;
1265
1266                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1267                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1268                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1269                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1270                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1271                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1272                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1273                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1274
1275                 if(!ov_enabled)
1276                 {
1277                         oldr_nearclip = cvar("r_nearclip");
1278                         oldr_farclip_base = cvar("r_farclip_base");
1279                         oldr_farclip_world = cvar("r_farclip_world");
1280                         oldr_novis = cvar("r_novis");
1281                         oldr_useportalculling = cvar("r_useportalculling");
1282                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1283                 }
1284
1285                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1286                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1287                 cvar_settemp("r_farclip_world", "0");
1288                 cvar_settemp("r_novis", "1");
1289                 cvar_settemp("r_useportalculling", "0");
1290                 cvar_settemp("r_useinfinitefarclip", "0");
1291
1292                 setproperty(VF_ORIGIN, ov_org);
1293                 setproperty(VF_ANGLES, '90 0 0');
1294
1295                 ov_enabled = true;
1296
1297                 #if 0
1298                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1299                         vtos(ov_org),
1300                         vtos(getpropertyvec(VF_ANGLES)),
1301                         ov_distance,
1302                         ov_nearest,
1303                         ov_furthest);
1304                 #endif
1305         }
1306         else
1307         {
1308                 if(ov_enabled)
1309                 {
1310                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1311                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1312                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1313                         cvar_set("r_novis", ftos(oldr_novis));
1314                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1315                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1316                 }
1317                 ov_enabled = false;
1318         }
1319
1320         // Render the Scene
1321         view_origin = getpropertyvec(VF_ORIGIN);
1322         view_angles = getpropertyvec(VF_ANGLES);
1323         makevectors(view_angles);
1324         view_forward = v_forward;
1325         view_right = v_right;
1326         view_up = v_up;
1327
1328 #ifdef BLURTEST
1329         if(time > blurtest_time0 && time < blurtest_time1)
1330         {
1331                 float r, t;
1332
1333                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1334                 r = t * blurtest_radius;
1335                 f = 1 / pow(t, blurtest_power) - 1;
1336
1337                 cvar_set("r_glsl_postprocess", "1");
1338                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1339         }
1340         else
1341         {
1342                 cvar_set("r_glsl_postprocess", "0");
1343                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1344         }
1345 #endif
1346
1347         TargetMusic_Advance();
1348         Fog_Force();
1349
1350         if(drawtime == 0)
1351                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1352         else
1353                 drawframetime = bound(0.000001, time - drawtime, 1);
1354         drawtime = time;
1355
1356         // watch for gametype changes here...
1357         // in ParseStuffCMD the cmd isn't executed yet :/
1358         // might even be better to add the gametype to TE_CSQC_INIT...?
1359         if(!postinit)
1360                 PostInit();
1361
1362         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1363         {
1364                 if(calledhooks & HOOK_START)
1365                 {
1366                         localcmd("\ncl_hook_gameend\n");
1367                         calledhooks |= HOOK_END;
1368                 }
1369         }
1370
1371         Announcer();
1372
1373         fov = autocvar_fov;
1374         if(fov <= 59.5)
1375         {
1376                 if(!zoomscript_caught)
1377                 {
1378                         localcmd("+button9\n");
1379                         zoomscript_caught = 1;
1380                 }
1381         }
1382         else
1383         {
1384                 if(zoomscript_caught)
1385                 {
1386                         localcmd("-button9\n");
1387                         zoomscript_caught = 0;
1388                 }
1389         }
1390
1391         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1392
1393         // next WANTED weapon (for HUD)
1394         switchweapon = getstati(STAT_SWITCHWEAPON);
1395
1396         // currently switching-to weapon (for crosshair)
1397         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1398
1399         // actually active weapon (for zoom)
1400         activeweapon = getstati(STAT_ACTIVEWEAPON);
1401
1402         f = (serverflags & SERVERFLAG_TEAMPLAY);
1403         if(f != teamplay)
1404         {
1405                 teamplay = f;
1406                 HUD_InitScores();
1407         }
1408
1409         if(last_switchweapon != switchweapon)
1410         {
1411                 weapontime = time;
1412                 last_switchweapon = switchweapon;
1413                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1414                 {
1415                         localcmd("-zoom\n");
1416                         button_zoom = false;
1417                 }
1418                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1419                 {
1420                         localcmd("-fire\n");
1421                         localcmd("-fire2\n");
1422                         button_attack2 = false;
1423                 }
1424         }
1425         if(last_activeweapon != activeweapon)
1426         {
1427                 last_activeweapon = activeweapon;
1428
1429                 e = get_weaponinfo(activeweapon);
1430                 if(e.netname != "")
1431                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1432                 else
1433                         localcmd("\ncl_hook_activeweapon none\n");
1434         }
1435
1436         // ALWAYS Clear Current Scene First
1437         clearscene();
1438
1439         setproperty(VF_ORIGIN, view_origin);
1440         setproperty(VF_ANGLES, view_angles);
1441
1442         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1443         setproperty(VF_SIZE, vf_size);
1444         setproperty(VF_MIN, vf_min);
1445
1446         // Assign Standard Viewflags
1447         // Draw the World (and sky)
1448         setproperty(VF_DRAWWORLD, 1);
1449
1450         // Set the console size vars
1451         vid_conwidth = autocvar_vid_conwidth;
1452         vid_conheight = autocvar_vid_conheight;
1453         vid_pixelheight = autocvar_vid_pixelheight;
1454
1455         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1456         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1457         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1458
1459         // Camera for demo playback
1460         if(camera_active)
1461         {
1462                 if(autocvar_camera_enable)
1463                         CSQC_Demo_Camera();
1464                 else
1465                 {
1466                         cvar_set("chase_active", ftos(chase_active_backup));
1467                         cvar_set("cl_demo_mousegrab", "0");
1468                         camera_active = false;
1469                 }
1470         }
1471         else
1472         {
1473 #ifdef CAMERATEST
1474                 if(autocvar_camera_enable)
1475 #else
1476                 if(autocvar_camera_enable && isdemo())
1477 #endif
1478                 {
1479                         // Enable required Darkplaces cvars
1480                         chase_active_backup = autocvar_chase_active;
1481                         cvar_set("chase_active", "2");
1482                         cvar_set("cl_demo_mousegrab", "1");
1483                         camera_active = true;
1484                         camera_mode = false;
1485                 }
1486         }
1487
1488         // Draw the Crosshair
1489         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1490
1491         // Draw the Engine Status Bar (the default Quake HUD)
1492         setproperty(VF_DRAWENGINESBAR, 0);
1493
1494         // Update the mouse position
1495         /*
1496            mousepos_x = vid_conwidth;
1497            mousepos_y = vid_conheight;
1498            mousepos = mousepos*0.5 + getmousepos();
1499          */
1500
1501         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1502                 WITH(entity, self, e, e.draw(e));
1503         }
1504
1505         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1506         renderscene();
1507
1508         // now switch to 2D drawing mode by calling a 2D drawing function
1509         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1510         // next R_RenderScene call
1511         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1512
1513         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1514         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1515         {
1516                 // apply night vision effect
1517                 vector tc_00, tc_01, tc_10, tc_11;
1518                 vector rgb = '0 0 0';
1519
1520                 if(!nightvision_noise)
1521                 {
1522                         nightvision_noise = spawn();
1523                         nightvision_noise.classname = "nightvision_noise";
1524                 }
1525                 if(!nightvision_noise2)
1526                 {
1527                         nightvision_noise2 = spawn();
1528                         nightvision_noise2.classname = "nightvision_noise2";
1529                 }
1530
1531                 // color tint in yellow
1532                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1533
1534                 // draw BG
1535                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1536                 rgb = '1 1 1';
1537                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1538                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1539                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1540                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1541                 tc_11 = tc_01 + tc_10 - tc_00;
1542                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1543                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1544                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1545                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1546                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1547                 R_EndPolygon();
1548
1549                 // draw FG
1550                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1551                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1552                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1553                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1554                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1555                 tc_11 = tc_01 + tc_10 - tc_00;
1556                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1557                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1558                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1559                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1560                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1561                 R_EndPolygon();
1562         }
1563
1564         if(autocvar_cl_reticle)
1565         {
1566                 Weapon wep = get_weaponinfo(activeweapon);
1567                 // Draw the aiming reticle for weapons that use it
1568                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1569                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1570                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1571                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1572                 {
1573                         // no zoom reticle while dead
1574                         reticle_type = 0;
1575                 }
1576                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1577                 {
1578                         if(reticle_image != "") { reticle_type = 2; }
1579                         else { reticle_type = 0; }
1580                 }
1581                 else if(button_zoom || zoomscript_caught)
1582                 {
1583                         // normal zoom
1584                         reticle_type = 1;
1585                 }
1586
1587                 if(reticle_type)
1588                 {
1589                         if(autocvar_cl_reticle_stretch)
1590                         {
1591                                 reticle_size.x = vid_conwidth;
1592                                 reticle_size.y = vid_conheight;
1593                                 reticle_pos.x = 0;
1594                                 reticle_pos.y = 0;
1595                         }
1596                         else
1597                         {
1598                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1599                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1600                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1601                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1602                         }
1603
1604                         if(zoomscript_caught)
1605                                 f = 1;
1606                         else
1607                                 f = current_zoomfraction;
1608
1609                         if(f)
1610                         {
1611                                 switch(reticle_type)
1612                                 {
1613                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1614                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1615                                 }
1616                         }
1617                 }
1618         }
1619         else
1620         {
1621                 if(reticle_type != 0) { reticle_type = 0; }
1622         }
1623
1624
1625         // improved polyblend
1626         if(autocvar_hud_contents)
1627         {
1628                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1629                 vector liquidcolor;
1630
1631                 switch(pointcontents(view_origin))
1632                 {
1633                         case CONTENT_WATER:
1634                                 liquidalpha = autocvar_hud_contents_water_alpha;
1635                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1636                                 incontent = 1;
1637                                 break;
1638
1639                         case CONTENT_LAVA:
1640                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1641                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1642                                 incontent = 1;
1643                                 break;
1644
1645                         case CONTENT_SLIME:
1646                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1647                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1648                                 incontent = 1;
1649                                 break;
1650
1651                         default:
1652                                 liquidalpha = 0;
1653                                 liquidcolor = '0 0 0';
1654                                 incontent = 0;
1655                                 break;
1656                 }
1657
1658                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1659                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1660                         contentfadetime = autocvar_hud_contents_fadeintime;
1661                         liquidalpha_prev = liquidalpha;
1662                         liquidcolor_prev = liquidcolor;
1663                 }
1664                 else
1665                         contentfadetime = autocvar_hud_contents_fadeouttime;
1666
1667                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1668                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1669
1670                 if(contentavgalpha)
1671                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1672
1673                 if(autocvar_hud_postprocessing)
1674                 {
1675                         if(autocvar_hud_contents_blur && contentavgalpha)
1676                         {
1677                                 content_blurpostprocess.x = 1;
1678                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1679                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1680                         }
1681                         else
1682                         {
1683                                 content_blurpostprocess.x = 0;
1684                                 content_blurpostprocess.y = 0;
1685                                 content_blurpostprocess.z = 0;
1686                         }
1687                 }
1688         }
1689
1690         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1691         {
1692                 splash_size.x = max(vid_conwidth, vid_conheight);
1693                 splash_size.y = max(vid_conwidth, vid_conheight);
1694                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1695                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1696
1697                 float myhealth_flash_temp;
1698                 myhealth = getstati(STAT_HEALTH);
1699
1700                 // fade out
1701                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1702                 // add new damage
1703                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1704
1705                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1706                 pain_threshold = autocvar_hud_damage_pain_threshold;
1707                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1708                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1709
1710                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1711                 {
1712                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1713                 }
1714
1715                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1716
1717                 if(myhealth_prev < 1)
1718                 {
1719                         if(myhealth >= 1)
1720                         {
1721                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1722                                 myhealth_flash_temp = 0;
1723                         }
1724                         else
1725                         {
1726                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1727                         }
1728                 }
1729
1730                 if(spectatee_status == -1 || intermission)
1731                 {
1732                         myhealth_flash = 0; // observing, or match ended
1733                         myhealth_flash_temp = 0;
1734                 }
1735
1736                 myhealth_prev = myhealth;
1737
1738                 // IDEA: change damage color/picture based on player model for robot/alien species?
1739                 // pro: matches model better
1740                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1741                 // maybe different reddish pics?
1742                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1743                 {
1744                         if(autocvar_cl_gentle_damage == 2)
1745                         {
1746                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1747                                 {
1748                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1749                                 }
1750                         }
1751                         else
1752                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1753
1754                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1755                 }
1756                 else
1757                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1758
1759                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1760                 {
1761                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1762                         {
1763                                 damage_blurpostprocess.x = 1;
1764                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1765                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1766                         }
1767                         else
1768                         {
1769                                 damage_blurpostprocess.x = 0;
1770                                 damage_blurpostprocess.y = 0;
1771                                 damage_blurpostprocess.z = 0;
1772                         }
1773                 }
1774         }
1775
1776         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1777         float e2 = (autocvar_hud_powerup != 0);
1778         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1779         {
1780                 // enable or disable rendering types if they are used or not
1781                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1782                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1783
1784                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1785                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1786                 {
1787                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1788                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1789                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1790                         {
1791                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1792                                 old_blurradius = blurradius;
1793                                 old_bluralpha = bluralpha;
1794                         }
1795                 }
1796                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1797                 {
1798                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1799                         old_blurradius = 0;
1800                         old_bluralpha = 0;
1801                 }
1802
1803                 // edge detection postprocess handling done second (used by hud_powerup)
1804                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1805                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1806                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1807
1808                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1809
1810                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1811                 {
1812                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1813                         {
1814                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1815                                 old_sharpen_intensity = sharpen_intensity;
1816                         }
1817                 }
1818                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1819                 {
1820                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1821                         old_sharpen_intensity = 0;
1822                 }
1823
1824                 if(cvar("r_glsl_postprocess") == 0)
1825                         cvar_set("r_glsl_postprocess", "2");
1826         }
1827         else if(cvar("r_glsl_postprocess") == 2)
1828                 cvar_set("r_glsl_postprocess", "0");
1829
1830         if(menu_visible)
1831                 menu_show();
1832
1833         /*if(gametype == MAPINFO_TYPE_CTF)
1834           {
1835           ctf_view();
1836           } else */
1837
1838         // draw 2D entities
1839         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1840                 WITH(entity, self, e, e.draw2d(e));
1841         }
1842         Draw_ShowNames_All();
1843
1844         scoreboard_active = HUD_WouldDrawScoreboard();
1845
1846         HUD_Draw();
1847
1848         if(NextFrameCommand)
1849         {
1850                 localcmd("\n", NextFrameCommand, "\n");
1851                 NextFrameCommand = string_null;
1852         }
1853
1854         // we must do this check AFTER a frame was rendered, or it won't work
1855         if(cs_project_is_b0rked == 0)
1856         {
1857                 string w0, h0;
1858                 w0 = ftos(autocvar_vid_conwidth);
1859                 h0 = ftos(autocvar_vid_conheight);
1860                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1861                 //setproperty(VF_FOV, '90 90 0');
1862                 setproperty(VF_ORIGIN, '0 0 0');
1863                 setproperty(VF_ANGLES, '0 0 0');
1864                 setproperty(VF_PERSPECTIVE, 1);
1865                 makevectors('0 0 0');
1866                 vector v1, v2;
1867                 cvar_set("vid_conwidth", "800");
1868                 cvar_set("vid_conheight", "600");
1869                 v1 = cs_project(v_forward);
1870                 cvar_set("vid_conwidth", "640");
1871                 cvar_set("vid_conheight", "480");
1872                 v2 = cs_project(v_forward);
1873                 if(v1 == v2)
1874                         cs_project_is_b0rked = 1;
1875                 else
1876                         cs_project_is_b0rked = -1;
1877                 cvar_set("vid_conwidth", w0);
1878                 cvar_set("vid_conheight", h0);
1879         }
1880
1881         if(autocvar__hud_configure)
1882                 HUD_Panel_Mouse();
1883         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1884                 HUD_Minigame_Mouse();
1885         else if(QuickMenu_IsOpened())
1886                 QuickMenu_Mouse();
1887         else
1888                 HUD_Radar_Mouse();
1889
1890         cl_notice_run();
1891
1892         // let's reset the view back to normal for the end
1893         setproperty(VF_MIN, '0 0 0');
1894         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1895 }
1896
1897 void CSQC_common_hud(void)
1898 {
1899         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1900                 Accuracy_LoadLevels();
1901
1902         HUD_Main(); // always run these functions for alpha checks
1903         HUD_Vehicle();
1904         HUD_DrawScoreboard();
1905
1906         // scoreboard/accuracy, map/gametype voting screen
1907         if (scoreboard_active || intermission == 2)
1908                 HUD_Reset();
1909 }
1910
1911
1912 // following vectors must be global to allow seamless switching between camera modes
1913 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1914 void CSQC_Demo_Camera()
1915 {
1916         float speed, attenuation, dimensions;
1917         vector tmp, delta;
1918
1919         if( autocvar_camera_reset || !camera_mode )
1920         {
1921                 camera_offset = '0 0 0';
1922                 current_angles = '0 0 0';
1923                 camera_direction = '0 0 0';
1924                 camera_offset.z += 30;
1925                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1926                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1927                 current_origin = view_origin;
1928                 current_camera_offset  = camera_offset;
1929                 cvar_set("camera_reset", "0");
1930                 camera_mode = CAMERA_CHASE;
1931         }
1932
1933         // Camera angles
1934         if( camera_roll )
1935                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1936
1937         if(autocvar_camera_look_player)
1938         {
1939                 vector dir;
1940                 float n;
1941
1942                 dir = normalize(view_origin - current_position);
1943                 n = mouse_angles.z;
1944                 mouse_angles = vectoangles(dir);
1945                 mouse_angles.x = mouse_angles.x * -1;
1946                 mouse_angles.z = n;
1947         }
1948         else
1949         {
1950                 tmp = getmousepos() * 0.1;
1951                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1952                 {
1953                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1954                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1955                 }
1956         }
1957
1958         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1959         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1960         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1961         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1962
1963         // Fix difference when angles don't have the same sign
1964         delta = '0 0 0';
1965         if(mouse_angles.y < -60 && current_angles.y > 60)
1966                 delta = '0 360 0';
1967         if(mouse_angles.y > 60 && current_angles.y < -60)
1968                 delta = '0 -360 0';
1969
1970         if(autocvar_camera_look_player)
1971                 attenuation = autocvar_camera_look_attenuation;
1972         else
1973                 attenuation = autocvar_camera_speed_attenuation;
1974
1975         attenuation = 1 / max(1, attenuation);
1976         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1977
1978         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1979         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1980         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1981         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1982
1983         // Camera position
1984         tmp = '0 0 0';
1985         dimensions = 0;
1986
1987         if( camera_direction.x )
1988         {
1989                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1990                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1991                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1992                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1993                 ++dimensions;
1994         }
1995
1996         if( camera_direction.y )
1997         {
1998                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1999                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2000                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2001                 ++dimensions;
2002         }
2003
2004         if( camera_direction.z )
2005         {
2006                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2007                 ++dimensions;
2008         }
2009
2010         if(autocvar_camera_free)
2011                 speed = autocvar_camera_speed_free;
2012         else
2013                 speed = autocvar_camera_speed_chase;
2014
2015         if(dimensions)
2016         {
2017                 speed = speed * sqrt(1 / dimensions);
2018                 camera_offset += tmp * speed;
2019         }
2020
2021         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2022
2023         // Camera modes
2024         if( autocvar_camera_free )
2025         {
2026                 if ( camera_mode == CAMERA_CHASE )
2027                 {
2028                         current_camera_offset = current_origin + current_camera_offset;
2029                         camera_offset = current_origin + camera_offset;
2030                 }
2031
2032                 camera_mode = CAMERA_FREE;
2033                 current_position = current_camera_offset;
2034         }
2035         else
2036         {
2037                 if ( camera_mode == CAMERA_FREE )
2038                 {
2039                         current_origin = view_origin;
2040                         camera_offset = camera_offset - current_origin;
2041                         current_camera_offset = current_camera_offset - current_origin;
2042                 }
2043
2044                 camera_mode = CAMERA_CHASE;
2045
2046                 if(autocvar_camera_chase_smoothly)
2047                         current_origin += (view_origin - current_origin) * attenuation;
2048                 else
2049                         current_origin = view_origin;
2050
2051                 current_position = current_origin + current_camera_offset;
2052         }
2053
2054         setproperty(VF_ANGLES, current_angles);
2055         setproperty(VF_ORIGIN, current_position);
2056 }