qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/minigames/cl_minigames.qh>
  35 #include <common/minigames/cl_minigames_hud.qh>
  36
  37 #include <lib/csqcmodel/cl_player.qh>
  38 #include <lib/csqcmodel/cl_model.qh>
  39 #include "csqcmodel_hooks.qh"
  40
  41 #include <lib/warpzone/client.qh>
  42 #include <lib/warpzone/common.qh>
  43
  44 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  45
  46 float autocvar_cl_viewmodel_scale;
  47
  48 bool autocvar_cl_bobmodel;
  49 float autocvar_cl_bobmodel_speed;
  50 float autocvar_cl_bobmodel_side;
  51 float autocvar_cl_bobmodel_up;
  52
  53 float autocvar_cl_followmodel;
  54 float autocvar_cl_followmodel_speed = 0.3;
  55 float autocvar_cl_followmodel_limit = 135;
  56 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  57 float autocvar_cl_followmodel_highpass = 0.05;
  58 float autocvar_cl_followmodel_lowpass = 0.03;
  59 bool autocvar_cl_followmodel_velocity_absolute;
  60
  61 float autocvar_cl_leanmodel;
  62 float autocvar_cl_leanmodel_speed = 0.3;
  63 float autocvar_cl_leanmodel_limit = 30;
  64 float autocvar_cl_leanmodel_highpass1 = 0.2;
  65 float autocvar_cl_leanmodel_highpass = 0.2;
  66 float autocvar_cl_leanmodel_lowpass = 0.05;
  67
  68 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  69
  70 #define lowpass(value, frac, ref_store, ret) \
  71         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  72
  73 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  76         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  77 } MACRO_END
  78
  79 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass(value, frac, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  86 { \
  87         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  88         ret = (value) - __f; \
  89 } MACRO_END
  90
  91 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  94         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 106         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 107 } MACRO_END
 108
 109 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 110 { \
 111         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 112         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 113         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 114 } MACRO_END
 115
 116 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 117 { \
 118         highpass(value.x, frac, ref_store.x, ref_out.x); \
 119         highpass(value.y, frac, ref_store.y, ref_out.y); \
 120         highpass(value.z, frac, ref_store.z, ref_out.z); \
 121 } MACRO_END
 122
 123 void calc_followmodel_ofs(entity view)
 124 {
 125         if(cl_followmodel_time == time)
 126                 return; // cl_followmodel_ofs already calculated for this frame
 127
 128         float frac;
 129         vector gunorg = '0 0 0';
 130         static vector vel_average;
 131         static vector gunorg_adjustment_highpass;
 132         static vector gunorg_adjustment_lowpass;
 133
 134         vector vel;
 135         if (autocvar_cl_followmodel_velocity_absolute)
 136                 vel = view.velocity;
 137         else
 138         {
 139                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 140                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 141                 vel.x = view.velocity * forward;
 142                 vel.y = view.velocity * right * -1;
 143                 vel.z = view.velocity * up;
 144         }
 145
 146         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 147         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 148         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 149
 150         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 151         lowpass3(vel, frac, vel_average, gunorg);
 152
 153         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 154
 155         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 156         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 157         frac = avg_factor(autocvar_cl_followmodel_highpass);
 158         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 159         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 160         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 161
 162         if (autocvar_cl_followmodel_velocity_absolute)
 163         {
 164                 vector fixed_gunorg;
 165                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 166                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 167                 fixed_gunorg.x = gunorg * forward;
 168                 fixed_gunorg.y = gunorg * right * -1;
 169                 fixed_gunorg.z = gunorg * up;
 170                 gunorg = fixed_gunorg;
 171         }
 172
 173         cl_followmodel_ofs = gunorg;
 174         cl_followmodel_time = time;
 175 }
 176
 177 vector leanmodel_ofs(entity view)
 178 {
 179         float frac;
 180         vector gunangles = '0 0 0';
 181         static vector gunangles_prev = '0 0 0';
 182         static vector gunangles_highpass = '0 0 0';
 183         static vector gunangles_adjustment_highpass;
 184         static vector gunangles_adjustment_lowpass;
 185
 186         if (view.csqcmodel_teleported)
 187                 gunangles_prev = view_angles;
 188
 189         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 190         gunangles_highpass += gunangles_prev;
 191         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 192         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 193         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 194         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 195         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 196         gunangles_prev = view_angles;
 197         gunangles_highpass -= gunangles_prev;
 198
 199         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 200         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 201
 202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 203         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 204         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 205         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 206         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 207
 208         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 209
 210         return gunangles;
 211 }
 212
 213 vector bobmodel_ofs(entity view)
 214 {
 215         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 216         static bool oldonground;
 217         static float hitgroundtime;
 218         if (clonground)
 219         {
 220                 float f = time; // cl.movecmd[0].time
 221                 if (!oldonground)
 222                         hitgroundtime = f;
 223         }
 224         oldonground = clonground;
 225
 226         // calculate for swinging gun model
 227         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 228         vector gunorg = '0 0 0';
 229         static float bobmodel_scale = 0;
 230         static float time_ofs = 0; // makes the effect always restart in the same way
 231         if (clonground)
 232         {
 233                 if (time - hitgroundtime > 0.05)
 234                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 235         }
 236         else
 237                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 238
 239         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 240         if (bobmodel_scale && xyspeed)
 241         {
 242                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 243                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 244                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 245                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 246         }
 247         else
 248                 time_ofs = time;
 249
 250         return gunorg;
 251 }
 252
 253 void viewmodel_animate(entity this)
 254 {
 255         if (autocvar_chase_active) return;
 256         if (STAT(HEALTH) <= 0) return;
 257
 258         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 259
 260         if (autocvar_cl_followmodel)
 261         {
 262                 calc_followmodel_ofs(view);
 263                 this.origin += cl_followmodel_ofs;
 264         }
 265
 266         if (autocvar_cl_leanmodel)
 267                 this.angles += leanmodel_ofs(view);
 268
 269         // vertical view bobbing code
 270         // TODO: cl_bob
 271
 272         // horizontal view bobbing code
 273         // TODO: cl_bob2
 274
 275         // fall bobbing code
 276         // causes the view to swing down and back up when touching the ground
 277         // TODO: cl_bobfall
 278
 279         // gun model bobbing code
 280         if (autocvar_cl_bobmodel)
 281                 this.origin += bobmodel_ofs(view);
 282 }
 283
 284 .vector viewmodel_origin, viewmodel_angles;
 285 .float weapon_nextthink;
 286 .float weapon_eta_last;
 287 .float weapon_switchdelay;
 288
 289 .string name_last;
 290
 291 void viewmodel_draw(entity this)
 292 {
 293         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 294                 return;
 295         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 296         float a = this.alpha;
 297         static bool wasinvehicle;
 298         bool invehicle = player_localentnum > maxclients;
 299         if (invehicle) a = -1;
 300         else if (wasinvehicle) a = 1;
 301         wasinvehicle = invehicle;
 302         Weapon wep = this.activeweapon;
 303         int c = entcs_GetClientColors(current_player);
 304         vector g = weaponentity_glowmod(wep, NULL, c, this);
 305         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 306         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 307                 | EF_NODEPTHTEST)
 308                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 309         for (entity e = this; e; e = e.weaponchild)
 310         {
 311                 e.drawmask = mask;
 312                 e.alpha = a;
 313                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 314                 e.glowmod = g;
 315                 e.csqcmodel_effects = fx;
 316                 CSQCModel_Effects_Apply(e);
 317         }
 318         if(a >= 0)
 319         {
 320                 string name = wep.mdl;
 321                 string newname = wep.wr_viewmodel(wep, this);
 322                 if(newname)
 323                         name = newname;
 324                 bool swap = name != this.name_last;
 325                 // if (swap)
 326                 {
 327                         this.name_last = name;
 328                         CL_WeaponEntity_SetModel(this, name, swap);
 329                         this.viewmodel_origin = this.origin;
 330                         this.viewmodel_angles = this.angles;
 331                 }
 332                 anim_update(this);
 333                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 334                         anim_set(this, this.anim_idle, true, false, false);
 335         }
 336         float f = 0; // 0..1; 0: fully active
 337         float rate = STAT(WEAPONRATEFACTOR);
 338         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 339         if (eta <= 0) f = this.weapon_eta_last;
 340         else switch (this.state)
 341         {
 342                 case WS_RAISE:
 343                 {
 344                         f = eta / max(eta, this.weapon_switchdelay);
 345                         break;
 346                 }
 347                 case WS_DROP:
 348                 {
 349                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 350                         break;
 351                 }
 352                 case WS_CLEAR:
 353                 {
 354                         f = 1;
 355                         break;
 356                 }
 357         }
 358         this.weapon_eta_last = f;
 359         this.origin = this.viewmodel_origin;
 360         this.angles = this.viewmodel_angles;
 361         this.angles_x = (-90 * f * f);
 362         viewmodel_animate(this);
 363         MUTATOR_CALLHOOK(DrawViewModel, this);
 364         setorigin(this, this.origin);
 365 }
 366
 367 STATIC_INIT(viewmodel) {
 368     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 369         viewmodels[slot] = new(viewmodel);
 370 }
 371
 372 void Porto_Draw(entity this);
 373 STATIC_INIT(Porto)
 374 {
 375         entity e = new_pure(porto);
 376         e.draw = Porto_Draw;
 377         IL_PUSH(g_drawables, e);
 378         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 379 }
 380
 381 const int polyline_length = 16;
 382 .vector polyline[polyline_length];
 383 void Porto_Draw(entity this)
 384 {
 385         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 386         {
 387                 entity wepent = viewmodels[slot];
 388
 389                 if (wepent.activeweapon != WEP_PORTO) continue;
 390                 if (spectatee_status) continue;
 391                 if (WEP_CVAR(porto, secondary)) continue;
 392                 if (intermission == 1) continue;
 393                 if (intermission == 2) continue;
 394                 if (STAT(HEALTH) <= 0) continue;
 395
 396                 vector pos = view_origin;
 397                 vector dir = view_forward;
 398                 if (wepent.angles_held_status)
 399                 {
 400                         makevectors(wepent.angles_held);
 401                         dir = v_forward;
 402                 }
 403
 404                 wepent.polyline[0] = pos;
 405
 406                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 407                 int n = 1 + 2;  // 2 lines == 3 points
 408                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 409                 {
 410                         traceline(pos, pos + 65536 * dir, true, this);
 411                         dir = reflect(dir, trace_plane_normal);
 412                         pos = trace_endpos;
 413                         wepent.polyline[++idx] = pos;
 414                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 415                         {
 416                                 n += 1;
 417                                 continue;
 418                         }
 419                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 420                         {
 421                                 n = max(2, idx);
 422                                 break;
 423                         }
 424                         // check size
 425                         {
 426                                 vector ang = vectoangles2(trace_plane_normal, dir);
 427                                 ang.x = -ang.x;
 428                                 makevectors(ang);
 429                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 430                                 {
 431                                         n = max(2, idx);
 432                                         break;
 433                                 }
 434                         }
 435                         portal_number += 1;
 436                         if (portal_number >= portal_max) break;
 437                         if (portal_number == 1) portal1_idx = idx;
 438                 }
 439                 for (int idx = 0; idx < n - 1; ++idx)
 440                 {
 441                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 442                         if (idx == 0) p -= view_up * 16;  // line from player
 443                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 444                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 445                 }
 446         }
 447 }
 448
 449 float drawtime;
 450 float avgspeed;
 451 vector GetCurrentFov(float fov)
 452 {
 453         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 454         float velocityzoom, curspeed;
 455         vector v;
 456
 457         zoomsensitivity = autocvar_cl_zoomsensitivity;
 458         zoomfactor = autocvar_cl_zoomfactor;
 459         if(zoomfactor < 1 || zoomfactor > 30)
 460                 zoomfactor = 2.5;
 461         zoomspeed = autocvar_cl_zoomspeed;
 462         if(zoomspeed >= 0)
 463         if(zoomspeed < 0.5 || zoomspeed > 16)
 464                         zoomspeed = 3.5;
 465
 466         zoomdir = button_zoom;
 467
 468         if(hud == HUD_NORMAL && !spectatee_status)
 469         {
 470                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 471                 {
 472                         entity wepent = viewmodels[slot];
 473                         if(wepent.switchweapon == wepent.activeweapon)
 474                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 475                                 zoomdir += button_attack2;
 476                 }
 477         }
 478         if(spectatee_status > 0 || isdemo())
 479         {
 480                 if(spectatorbutton_zoom)
 481                 {
 482                         if(zoomdir)
 483                                 zoomdir = 0;
 484                         else
 485                                 zoomdir = 1;
 486                 }
 487                 // fteqcc failed twice here already, don't optimize this
 488         }
 489
 490         if(zoomdir) { zoomin_effect = 0; }
 491
 492         if(camera_active)
 493         {
 494                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 495         }
 496         else if(autocvar_cl_spawnzoom && zoomin_effect)
 497         {
 498                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 499
 500                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 501                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 502                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 503         }
 504         else
 505         {
 506                 if(zoomspeed < 0) // instant zoom
 507                 {
 508                         if(zoomdir)
 509                                 current_viewzoom = 1 / zoomfactor;
 510                         else
 511                                 current_viewzoom = 1;
 512                 }
 513                 else
 514                 {
 515                         if(zoomdir)
 516                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 517                         else
 518                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 519                 }
 520         }
 521
 522         if(almost_equals(current_viewzoom, 1))
 523                 current_zoomfraction = 0;
 524         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 525                 current_zoomfraction = 1;
 526         else
 527                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 528
 529         if(zoomsensitivity < 1)
 530                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 531         else
 532                 setsensitivityscale(1);
 533
 534         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 535         {
 536                 if(intermission) { curspeed = 0; }
 537                 else
 538                 {
 539
 540                         makevectors(view_angles);
 541                         v = pmove_vel;
 542                         if(csqcplayer)
 543                                 v = csqcplayer.velocity;
 544
 545                         switch(autocvar_cl_velocityzoom_type)
 546                         {
 547                                 case 3: curspeed = max(0, v_forward * v); break;
 548                                 case 2: curspeed = (v_forward * v); break;
 549                                 case 1: default: curspeed = vlen(v); break;
 550                         }
 551                 }
 552
 553                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 554                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 555                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 556
 557                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 558         }
 559         else
 560                 velocityzoom = 1;
 561
 562         float frustumx, frustumy, fovx, fovy;
 563         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 564         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 565         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 566         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 567
 568         return '1 0 0' * fovx + '0 1 0' * fovy;
 569 }
 570
 571 vector GetViewLocationFOV(float fov)
 572 {
 573         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 574         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 575         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 576         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 577         return '1 0 0' * fovx + '0 1 0' * fovy;
 578 }
 579
 580 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 581 {
 582         float fovx, fovy;
 583         float width = (ov_worldmax.x - ov_worldmin.x);
 584         float height = (ov_worldmax.y - ov_worldmin.y);
 585         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 586         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 587         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 588         return '1 0 0' * fovx + '0 1 0' * fovy;
 589 }
 590
 591 // this function must match W_SetupShot!
 592 float zoomscript_caught;
 593
 594 vector wcross_origin;
 595 float wcross_scale_prev, wcross_alpha_prev;
 596 vector wcross_color_prev;
 597 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 598 vector wcross_color_goal_prev;
 599 float wcross_changedonetime;
 600
 601 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 602 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 603 float wcross_name_changestarttime, wcross_name_changedonetime;
 604 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 605
 606 float wcross_ring_prev;
 607
 608 entity trueaim;
 609 entity trueaim_rifle;
 610
 611 const float SHOTTYPE_HITTEAM = 1;
 612 const float SHOTTYPE_HITOBSTRUCTION = 2;
 613 const float SHOTTYPE_HITWORLD = 3;
 614 const float SHOTTYPE_HITENEMY = 4;
 615
 616 void TrueAim_Init()
 617 {
 618         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 619         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 620 }
 621
 622 float EnemyHitCheck()
 623 {
 624         float t, n;
 625         wcross_origin = project_3d_to_2d(trace_endpos);
 626         wcross_origin.z = 0;
 627         if(trace_ent)
 628                 n = trace_ent.entnum;
 629         else
 630                 n = trace_networkentity;
 631         if(n < 1)
 632                 return SHOTTYPE_HITWORLD;
 633         if(n > maxclients)
 634                 return SHOTTYPE_HITWORLD;
 635         t = entcs_GetTeam(n - 1);
 636         if(teamplay)
 637                 if(t == myteam)
 638                         return SHOTTYPE_HITTEAM;
 639         if(t == NUM_SPECTATOR)
 640                 return SHOTTYPE_HITWORLD;
 641         return SHOTTYPE_HITENEMY;
 642 }
 643
 644 float TrueAimCheck(entity wepent)
 645 {
 646         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 647         vector vecs, trueaimpoint, w_shotorg;
 648         vector mi, ma, dv;
 649         float shottype;
 650         entity ta;
 651         float mv;
 652
 653         mi = ma = '0 0 0';
 654         ta = trueaim;
 655         mv = MOVE_NOMONSTERS;
 656
 657         switch(wepent.activeweapon) // WEAPONTODO
 658         {
 659                 case WEP_TUBA: // no aim
 660                 case WEP_PORTO: // shoots from eye
 661                 case WEP_NEXBALL: // shoots from eye
 662                 case WEP_HOOK: // no trueaim
 663                 case WEP_MORTAR: // toss curve
 664                         return SHOTTYPE_HITWORLD;
 665                 case WEP_VORTEX:
 666                 case WEP_VAPORIZER:
 667                         mv = MOVE_NORMAL;
 668                         break;
 669                 case WEP_RIFLE:
 670                         ta = trueaim_rifle;
 671                         mv = MOVE_NORMAL;
 672                         if(zoomscript_caught)
 673                         {
 674                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 675                                 return EnemyHitCheck();
 676                         }
 677                         break;
 678                 case WEP_DEVASTATOR: // projectile has a size!
 679                         mi = '-3 -3 -3';
 680                         ma = '3 3 3';
 681                         break;
 682                 case WEP_FIREBALL: // projectile has a size!
 683                         mi = '-16 -16 -16';
 684                         ma = '16 16 16';
 685                         break;
 686                 case WEP_SEEKER: // projectile has a size!
 687                         mi = '-2 -2 -2';
 688                         ma = '2 2 2';
 689                         break;
 690                 case WEP_ELECTRO: // projectile has a size!
 691                         mi = '0 0 -3';
 692                         ma = '0 0 -3';
 693                         break;
 694         }
 695
 696         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 697
 698         vecs = decompressShotOrigin(STAT(SHOTORG));
 699
 700         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 701         trueaimpoint = trace_endpos;
 702
 703         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 704                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 705
 706         if(vecs.x > 0)
 707                 vecs.y = -vecs.y;
 708         else
 709                 vecs = '0 0 0';
 710
 711         dv = view_right * vecs.y + view_up * vecs.z;
 712         w_shotorg = traceorigin + dv;
 713
 714         // now move the vecs forward as much as requested if possible
 715         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 716         w_shotorg = trace_endpos - view_forward * nudge;
 717
 718         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 719         shottype = EnemyHitCheck();
 720         if(shottype != SHOTTYPE_HITWORLD)
 721                 return shottype;
 722
 723 #if 0
 724         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 725         // or rather, I know why, but see no fix
 726         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 727                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 728                 return SHOTTYPE_HITOBSTRUCTION;
 729 #endif
 730
 731         return SHOTTYPE_HITWORLD;
 732 }
 733
 734 void PostInit();
 735 void CSQC_Demo_Camera();
 736 float camera_mode;
 737 const float CAMERA_FREE = 1;
 738 const float CAMERA_CHASE = 2;
 739 float reticle_type;
 740 string NextFrameCommand;
 741
 742 vector freeze_org, freeze_ang;
 743 entity nightvision_noise, nightvision_noise2;
 744
 745 const float MAX_TIME_DIFF = 5;
 746 float pickup_crosshair_time, pickup_crosshair_size;
 747 float hitindication_crosshair_size;
 748 float use_vortex_chargepool;
 749
 750 float myhealth, myhealth_prev;
 751 float myhealth_flash;
 752
 753 float old_blurradius, old_bluralpha;
 754 float old_sharpen_intensity;
 755
 756 vector myhealth_gentlergb;
 757
 758 float contentavgalpha, liquidalpha_prev;
 759 vector liquidcolor_prev;
 760
 761 float eventchase_current_distance;
 762 float eventchase_running;
 763 bool WantEventchase(entity this)
 764 {
 765         if(autocvar_cl_orthoview)
 766                 return false;
 767         if(STAT(GAME_STOPPED) || intermission)
 768                 return true;
 769         if(this.viewloc)
 770                 return true;
 771         if(spectatee_status >= 0)
 772         {
 773                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 774                         return true;
 775                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 776                         return true;
 777                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 778                         return true;
 779                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 780                 {
 781                         if(autocvar_cl_eventchase_death == 2)
 782                         {
 783                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 784                                 if(this.velocity == '0 0 0' || eventchase_running)
 785                                         return true;
 786                         }
 787                         else return true;
 788                 }
 789         }
 790         return false;
 791 }
 792
 793 void HUD_Crosshair_Vehicle(entity this)
 794 {
 795         if(hud != HUD_BUMBLEBEE_GUN)
 796         {
 797                 Vehicle info = Vehicles_from(hud);
 798                 info.vr_crosshair(info, this);
 799         }
 800 }
 801
 802 vector damage_blurpostprocess, content_blurpostprocess;
 803
 804 float unaccounted_damage = 0;
 805 void UpdateDamage()
 806 {
 807         // accumulate damage with each stat update
 808         static float damage_total_prev = 0;
 809         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 810         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 811         damage_total_prev = damage_total;
 812
 813         static float damage_dealt_time_prev = 0;
 814         float damage_dealt_time = STAT(HIT_TIME);
 815         if (damage_dealt_time != damage_dealt_time_prev)
 816         {
 817                 unaccounted_damage += unaccounted_damage_new;
 818                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 819         }
 820         damage_dealt_time_prev = damage_dealt_time;
 821
 822         // prevent hitsound when switching spectatee
 823         static float spectatee_status_prev = 0;
 824         if (spectatee_status != spectatee_status_prev)
 825                 unaccounted_damage = 0;
 826         spectatee_status_prev = spectatee_status;
 827 }
 828
 829 void HitSound()
 830 {
 831         // varying sound pitch
 832
 833         bool have_arc = false;
 834         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 835         {
 836                 entity wepent = viewmodels[slot];
 837
 838                 if(wepent.activeweapon == WEP_ARC)
 839                         have_arc = true;
 840         }
 841
 842         static float hitsound_time_prev = 0;
 843         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 844         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 845         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 846         {
 847                 if (autocvar_cl_hitsound && unaccounted_damage)
 848                 {
 849                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 850                         float a = autocvar_cl_hitsound_max_pitch;
 851                         float b = autocvar_cl_hitsound_min_pitch;
 852                         float c = autocvar_cl_hitsound_nom_damage;
 853                         float d = unaccounted_damage;
 854                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 855
 856                         // if sound variation is disabled, set pitch_shift to 1
 857                         if (autocvar_cl_hitsound == 1)
 858                                 pitch_shift = 1;
 859
 860                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 861                         if (autocvar_cl_hitsound == 3)
 862                         {
 863                                 float mirror_value = (a-b)/2 + b;
 864                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 865                         }
 866
 867                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 868
 869                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 870                         // todo: normalize sound pressure levels? seems unnecessary
 871
 872                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 873                 }
 874                 unaccounted_damage = 0;
 875                 hitsound_time_prev = time;
 876         }
 877
 878         static float typehit_time_prev = 0;
 879         float typehit_time = STAT(TYPEHIT_TIME);
 880         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 881         {
 882                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 883                 typehit_time_prev = typehit_time;
 884         }
 885
 886         static float kill_time_prev = 0;
 887         float kill_time = STAT(KILL_TIME);
 888         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 889         {
 890                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 891                 kill_time_prev = kill_time;
 892         }
 893 }
 894
 895 vector crosshair_getcolor(entity this, float health_stat)
 896 {
 897         static float rainbow_last_flicker;
 898         static vector rainbow_prev_color;
 899         vector wcross_color = '0 0 0';
 900         switch(autocvar_crosshair_color_special)
 901         {
 902                 case 1: // crosshair_color_per_weapon
 903                 {
 904                         if(this != WEP_Null && hud == HUD_NORMAL)
 905                         {
 906                                 wcross_color = this.wpcolor;
 907                                 break;
 908                         }
 909                         else { goto normalcolor; }
 910                 }
 911
 912                 case 2: // crosshair_color_by_health
 913                 {
 914                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 915                         float hp = floor(v.x + 1);
 916
 917                         //x = red
 918                         //y = green
 919                         //z = blue
 920
 921                         wcross_color.z = 0;
 922
 923                         if(hp > 200)
 924                         {
 925                                 wcross_color.x = 0;
 926                                 wcross_color.y = 1;
 927                         }
 928                         else if(hp > 150)
 929                         {
 930                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 931                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 932                         }
 933                         else if(hp > 100)
 934                         {
 935                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 936                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 937                                 wcross_color.z = 1 - (hp-100)*0.02;
 938                         }
 939                         else if(hp > 50)
 940                         {
 941                                 wcross_color.x = 1;
 942                                 wcross_color.y = 1;
 943                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 944                         }
 945                         else if(hp > 20)
 946                         {
 947                                 wcross_color.x = 1;
 948                                 wcross_color.y = (hp-20)*90/27/100;
 949                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 950                         }
 951                         else
 952                         {
 953                                 wcross_color.x = 1;
 954                                 wcross_color.y = 0;
 955                         }
 956                         break;
 957                 }
 958
 959                 case 3: // crosshair_color_rainbow
 960                 {
 961                         if(time >= rainbow_last_flicker)
 962                         {
 963                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 964                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 965                         }
 966                         wcross_color = rainbow_prev_color;
 967                         break;
 968                 }
 969 LABEL(normalcolor)
 970                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 971         }
 972
 973         return wcross_color;
 974 }
 975
 976 void HUD_Crosshair(entity this)
 977 {
 978         float f, i, j;
 979         vector v;
 980         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 981                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 982                 !HUD_MinigameMenu_IsOpened() )
 983         {
 984                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 985                         return;
 986
 987                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 988                         return;
 989
 990                 if (hud != HUD_NORMAL)
 991                 {
 992                         HUD_Crosshair_Vehicle(this);
 993                         return;
 994                 }
 995
 996                 string wcross_style;
 997                 float wcross_alpha, wcross_resolution;
 998                 wcross_style = autocvar_crosshair;
 999                 if (wcross_style == "0")
1000                         return;
1001                 wcross_resolution = autocvar_crosshair_size;
1002                 if (wcross_resolution == 0)
1003                         return;
1004                 wcross_alpha = autocvar_crosshair_alpha;
1005                 if (wcross_alpha == 0)
1006                         return;
1007
1008                 // TrueAim check
1009                 float shottype;
1010
1011                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1012                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1013                 wcross_origin.z = 0;
1014                 if(autocvar_crosshair_hittest)
1015                 {
1016                         vector wcross_oldorigin;
1017                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1018                         wcross_oldorigin = wcross_origin;
1019                         shottype = TrueAimCheck(thiswep);
1020                         if(shottype == SHOTTYPE_HITWORLD)
1021                         {
1022                                 v = wcross_origin - wcross_oldorigin;
1023                                 v.x /= vid_conwidth;
1024                                 v.y /= vid_conheight;
1025                                 if(vdist(v, >, 0.01))
1026                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1027                         }
1028                         if(!autocvar_crosshair_hittest_showimpact)
1029                                 wcross_origin = wcross_oldorigin;
1030                 }
1031                 else
1032                         shottype = SHOTTYPE_HITWORLD;
1033
1034                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1035                 string wcross_name = "";
1036                 float wcross_scale, wcross_blur;
1037
1038         entity e = WEP_Null;
1039                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1040                 {
1041                         entity wepent = viewmodels[0]; // TODO: unhardcode
1042                         e = wepent.switchingweapon;
1043                         if(e)
1044                         {
1045                                 if(autocvar_crosshair_per_weapon)
1046                                 {
1047                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1048                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1049                                         //if (wcross_resolution == 0)
1050                                                 //return;
1051
1052                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1053                                         wcross_resolution *= e.w_crosshair_size;
1054                                         wcross_name = e.w_crosshair;
1055                                 }
1056                         }
1057                 }
1058
1059                 if(wcross_name == "")
1060                         wcross_name = strcat("gfx/crosshair", wcross_style);
1061
1062                 // MAIN CROSSHAIR COLOR DECISION
1063                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1064
1065                 if(autocvar_crosshair_effect_scalefade)
1066                 {
1067                         wcross_scale = wcross_resolution;
1068                         wcross_resolution = 1;
1069                 }
1070                 else
1071                 {
1072                         wcross_scale = 1;
1073                 }
1074
1075                 if(autocvar_crosshair_pickup)
1076                 {
1077                         float stat_pickup_time = STAT(LAST_PICKUP);
1078
1079                         if(pickup_crosshair_time < stat_pickup_time)
1080                         {
1081                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1082                                         pickup_crosshair_size = 1;
1083
1084                                 pickup_crosshair_time = stat_pickup_time;
1085                         }
1086
1087                         if(pickup_crosshair_size > 0)
1088                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1089                         else
1090                                 pickup_crosshair_size = 0;
1091
1092                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1093                 }
1094
1095                 // todo: make crosshair hit indication dependent on damage dealt
1096                 if(autocvar_crosshair_hitindication)
1097                 {
1098                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1099
1100                         if(unaccounted_damage)
1101                         {
1102                                 hitindication_crosshair_size = 1;
1103                         }
1104
1105                         if(hitindication_crosshair_size > 0)
1106                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1107                         else
1108                                 hitindication_crosshair_size = 0;
1109
1110                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1111                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1112                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1113                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1114                 }
1115
1116                 if(shottype == SHOTTYPE_HITENEMY)
1117                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1118                 if(shottype == SHOTTYPE_HITTEAM)
1119                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1120
1121                 f = fabs(autocvar_crosshair_effect_time);
1122                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1123                 {
1124                         wcross_changedonetime = time + f;
1125                 }
1126                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1127                 {
1128                         wcross_name_changestarttime = time;
1129                         wcross_name_changedonetime = time + f;
1130                         if(wcross_name_goal_prev_prev)
1131                                 strunzone(wcross_name_goal_prev_prev);
1132                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1133                         wcross_name_goal_prev = strzone(wcross_name);
1134                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1135                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1136                         wcross_resolution_goal_prev = wcross_resolution;
1137                 }
1138
1139                 wcross_scale_goal_prev = wcross_scale;
1140                 wcross_alpha_goal_prev = wcross_alpha;
1141                 wcross_color_goal_prev = wcross_color;
1142
1143                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1144                 {
1145                         wcross_blur = 1;
1146                         wcross_alpha *= 0.75;
1147                 }
1148                 else
1149                         wcross_blur = 0;
1150                 // *_prev is at time-frametime
1151                 // * is at wcross_changedonetime+f
1152                 // what do we have at time?
1153                 if(time < wcross_changedonetime)
1154                 {
1155                         f = frametime / (wcross_changedonetime - time + frametime);
1156                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1157                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1158                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1159                 }
1160
1161                 wcross_scale_prev = wcross_scale;
1162                 wcross_alpha_prev = wcross_alpha;
1163                 wcross_color_prev = wcross_color;
1164
1165                 MUTATOR_CALLHOOK(UpdateCrosshair);
1166
1167                 wcross_scale *= 1 - autocvar__menu_alpha;
1168                 wcross_alpha *= 1 - autocvar__menu_alpha;
1169                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1170
1171                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1172                 {
1173                         // crosshair rings for weapon stats
1174                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1175                         {
1176                                 // declarations and stats
1177                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1178                                 string ring_image = string_null, ring_inner_image = string_null;
1179                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1180
1181                                 ring_scale = autocvar_crosshair_ring_size;
1182
1183                                 float weapon_clipload, weapon_clipsize;
1184                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1185                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1186
1187                                 float vortex_charge, vortex_chargepool;
1188                                 vortex_charge = STAT(VORTEX_CHARGE);
1189                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1190
1191                                 float arc_heat = STAT(ARC_HEAT);
1192
1193                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1194                                         vortex_charge_movingavg = vortex_charge;
1195
1196                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1197
1198                                 // handle the values
1199                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1200                                 {
1201                                         if (vortex_chargepool || use_vortex_chargepool) {
1202                                                 use_vortex_chargepool = 1;
1203                                                 ring_inner_value = vortex_chargepool;
1204                                         } else {
1205                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1206                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1207                                         }
1208
1209                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1210                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1211                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1212
1213                                         // draw the outer ring to show the current charge of the weapon
1214                                         ring_value = vortex_charge;
1215                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1218                                 }
1219                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1220                                 {
1221                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1222                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1223                                         ring_rgb = wcross_color;
1224                                         ring_image = "gfx/crosshair_ring.tga";
1225                                 }
1226                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1227                                 {
1228                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1229                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1230                                         ring_rgb = wcross_color;
1231                                         ring_image = "gfx/crosshair_ring.tga";
1232                                 }
1233                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1234                                 {
1235                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1236                                         ring_scale = autocvar_crosshair_ring_reload_size;
1237                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1238                                         ring_rgb = wcross_color;
1239
1240                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1241                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1242                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1243                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1244                                         else
1245                                                 ring_image = "gfx/crosshair_ring.tga";
1246                                 }
1247                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1248                                 {
1249                                         ring_value = arc_heat;
1250                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1251                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1252                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1253                                         ring_image = "gfx/crosshair_ring.tga";
1254                                 }
1255
1256                                 // if in weapon switch animation, fade ring out/in
1257                                 if(autocvar_crosshair_effect_time > 0)
1258                                 {
1259                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1260                                         if (f >= 1)
1261                                         {
1262                                                 wcross_ring_prev = ((ring_image) ? true : false);
1263                                         }
1264
1265                                         if(wcross_ring_prev)
1266                                         {
1267                                                 if(f < 1)
1268                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1269                                         }
1270                                         else
1271                                         {
1272                                                 if(f < 1)
1273                                                         ring_alpha *= bound(0, f, 1);
1274                                         }
1275                                 }
1276
1277                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1278                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1279
1280                                 if (ring_value)
1281                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1282                         }
1283
1284 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1285                         MACRO_BEGIN { \
1286                                 if(wcross_blur > 0) \
1287                                 { \
1288                                         for(i = -2; i <= 2; ++i) \
1289                                         for(j = -2; j <= 2; ++j) \
1290                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1291                                 } \
1292                                 else \
1293                                 { \
1294                                         M(0,0,sz,wcross_name,wcross_alpha); \
1295                                 } \
1296                         } MACRO_END
1297
1298 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1299                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1300
1301 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1302                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1303
1304                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1305                         {
1306                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1307                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1308                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1309                                 f = 1 - f;
1310                         }
1311                         else
1312                         {
1313                                 f = 1;
1314                         }
1315                         wcross_name_alpha_goal_prev = f;
1316
1317                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1318                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1319
1320                         if(autocvar_crosshair_dot)
1321                         {
1322                                 vector wcross_color_old;
1323                                 wcross_color_old = wcross_color;
1324
1325                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1326                                         wcross_color = stov(autocvar_crosshair_dot_color);
1327
1328                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1329                                 // FIXME why don't we use wcross_alpha here?
1330                                 wcross_color = wcross_color_old;
1331                         }
1332                 }
1333         }
1334         else
1335         {
1336                 wcross_scale_prev = 0;
1337                 wcross_alpha_prev = 0;
1338                 wcross_scale_goal_prev = 0;
1339                 wcross_alpha_goal_prev = 0;
1340                 wcross_changedonetime = 0;
1341                 if(wcross_name_goal_prev)
1342                         strunzone(wcross_name_goal_prev);
1343                 wcross_name_goal_prev = string_null;
1344                 if(wcross_name_goal_prev_prev)
1345                         strunzone(wcross_name_goal_prev_prev);
1346                 wcross_name_goal_prev_prev = string_null;
1347                 wcross_name_changestarttime = 0;
1348                 wcross_name_changedonetime = 0;
1349                 wcross_name_alpha_goal_prev = 0;
1350                 wcross_name_alpha_goal_prev_prev = 0;
1351                 wcross_resolution_goal_prev = 0;
1352                 wcross_resolution_goal_prev_prev = 0;
1353         }
1354 }
1355
1356 const int MAX_SPECIALCOMMAND = 15;
1357 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1358 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1359 const float SPECIALCOMMAND_SPEED = 150;
1360 const float SPECIALCOMMAND_TURNSPEED = 2;
1361 const float SPECIALCOMMAND_SIZE = 0.025;
1362 const float SPECIALCOMMAND_CHANCE = 0.35;
1363 float sc_spawntime, sc_changetime;
1364 vector sc_color = '1 1 1';
1365 void SpecialCommand()
1366 {
1367         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1368                 return;
1369
1370         if(time >= sc_changetime)
1371         {
1372                 sc_changetime = time + 1;
1373                 sc_color = randomvec() * 1.5;
1374                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1375                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1376                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1377         }
1378         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1379
1380         if(!precache_pic("gfx/smile"))
1381                 return; // damn party poopers
1382
1383         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1384         {
1385                 vector slot = specialcommand_slots[j];
1386                 if(slot.y)
1387                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1388                 if(slot.z)
1389                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1390                 if(slot.y >= vid_conheight)
1391                         slot = '0 0 0';
1392
1393                 if(slot == '0 0 0')
1394                 {
1395                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1396                         {
1397                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1398                                 slot.y = 1; // start it off 0 so we can use it
1399                                 slot.z = random();
1400                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1401                                 vector newcolor = randomvec() * 2;
1402                                 newcolor.x = bound(0.4, newcolor.x, 1);
1403                                 newcolor.y = bound(0.4, newcolor.y, 1);
1404                                 newcolor.z = bound(0.4, newcolor.z, 1);
1405                                 specialcommand_colors[j] = newcolor;
1406                         }
1407                 }
1408                 else
1409                 {
1410                         vector splash_size = '0 0 0';
1411                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1412                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1413                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1414                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1415                 }
1416
1417                 specialcommand_slots[j] = slot;
1418         }
1419 }
1420
1421 void HUD_Draw(entity this)
1422 {
1423         // if we don't know gametype and scores yet avoid drawing the scoreboard
1424         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1425         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1426         // cl_deathscoreboard would show the scoreboard and so on
1427         if(!gametype)
1428                 return;
1429
1430         Hud_Dynamic_Frame();
1431
1432         if(!intermission)
1433         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1434         {
1435                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1436         }
1437         else if(STAT(FROZEN))
1438         {
1439                 vector col = '0.25 0.90 1';
1440                 if(STAT(REVIVE_PROGRESS))
1441                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1442                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1443         }
1444
1445         HUD_Scale_Enable();
1446         if(!intermission)
1447         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1448         {
1449                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1450                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1451                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1452         }
1453         else if(STAT(CAPTURE_PROGRESS))
1454         {
1455                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1456                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1457         }
1458         else if(STAT(REVIVE_PROGRESS))
1459         {
1460                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1461                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1462         }
1463         HUD_Scale_Disable();
1464
1465         if(autocvar_r_letterbox == 0)
1466                 if(autocvar_viewsize < 120)
1467                 {
1468                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1469                                 Accuracy_LoadLevels();
1470
1471                         HUD_Main();
1472                         HUD_Scale_Disable();
1473                 }
1474
1475         // crosshair goes VERY LAST
1476         SpecialCommand();
1477         UpdateDamage();
1478         HUD_Crosshair(this);
1479         HitSound();
1480 }
1481
1482 void ViewLocation_Mouse()
1483 {
1484         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1485         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1486         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1487
1488         float cursor_alpha = 1 - autocvar__menu_alpha;
1489         draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1490 }
1491
1492 bool ov_enabled;
1493 float oldr_nearclip;
1494 float oldr_farclip_base;
1495 float oldr_farclip_world;
1496 float oldr_novis;
1497 float oldr_useportalculling;
1498 float oldr_useinfinitefarclip;
1499
1500 void cl_notice_run();
1501
1502 float prev_myteam;
1503 int lasthud;
1504 float vh_notice_time;
1505 void WaypointSprite_Load();
1506 void CSQC_UpdateView(entity this, float w, float h)
1507 {
1508     TC(int, w); TC(int, h);
1509         entity e;
1510         float fov;
1511         float f;
1512         vector vf_size, vf_min;
1513         float a;
1514
1515         execute_next_frame();
1516
1517         ++framecount;
1518
1519         stats_get();
1520         hud = STAT(HUD);
1521
1522         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1523                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1524
1525         lasthud = hud;
1526
1527         HUD_Scale_Disable();
1528
1529         if(autocvar__hud_showbinds_reload) // menu can set this one
1530         {
1531                 db_close(binddb);
1532                 binddb = db_create();
1533                 cvar_set("_hud_showbinds_reload", "0");
1534         }
1535
1536         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1537                 view_quality = getproperty(VF_MINFPS_QUALITY);
1538         else
1539                 view_quality = 1;
1540
1541         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1542         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1543
1544         vf_size = getpropertyvec(VF_SIZE);
1545         vf_min = getpropertyvec(VF_MIN);
1546         vid_width = vf_size.x;
1547         vid_height = vf_size.y;
1548
1549         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1550         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1551
1552         WaypointSprite_Load();
1553
1554         CSQCPlayer_SetCamera();
1555
1556         if(player_localentnum <= maxclients) // is it a client?
1557                 current_player = player_localentnum - 1;
1558         else // then player_localentnum is the vehicle I'm driving
1559                 current_player = player_localnum;
1560         myteam = entcs_GetTeam(current_player);
1561
1562         if(myteam != prev_myteam)
1563         {
1564                 myteamcolors = colormapPaletteColor(myteam, 1);
1565                 FOREACH(hud_panels, true, it.update_time = time);
1566                 prev_myteam = myteam;
1567         }
1568
1569         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1570
1571         float is_dead = (STAT(HEALTH) <= 0);
1572
1573         // FIXME do we need this hack?
1574         if(isdemo())
1575         {
1576                 // in demos, input_buttons do not work
1577                 button_zoom = (autocvar__togglezoom == "-");
1578         }
1579         else if(button_zoom
1580                 && autocvar_cl_unpress_zoom_on_death
1581                 && (spectatee_status >= 0)
1582                 && (is_dead || intermission))
1583         {
1584                 // no zoom while dead or in intermission please
1585                 localcmd("-zoom\n");
1586                 button_zoom = false;
1587         }
1588
1589         // abused multiple places below
1590         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1591         if(!local_player)
1592                 local_player = this; // fall back!
1593
1594         // event chase camera
1595         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1596         {
1597                 if(STAT(CAMERA_SPECTATOR))
1598                 {
1599                         if(spectatee_status > 0)
1600                         {
1601                                 if(!autocvar_chase_active)
1602                                 {
1603                                         cvar_set("chase_active", "-2");
1604                                         goto skip_eventchase_death;
1605                                 }
1606                         }
1607                         else if(autocvar_chase_active == -2)
1608                                 cvar_set("chase_active", "0");
1609
1610                         if(autocvar_chase_active == -2)
1611                                 goto skip_eventchase_death;
1612                 }
1613                 else if(autocvar_chase_active == -2)
1614                         cvar_set("chase_active", "0");
1615
1616                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1617
1618                 float vehicle_viewdist = 0;
1619                 vector vehicle_viewofs = '0 0 0';
1620
1621                 if(vehicle_chase)
1622                 {
1623                         if(hud != HUD_BUMBLEBEE_GUN)
1624                         {
1625                                 Vehicle info = Vehicles_from(hud);
1626                                 vehicle_viewdist = info.height;
1627                                 vehicle_viewofs = info.view_ofs;
1628                         }
1629                 }
1630
1631                 if(WantEventchase(this))
1632                 {
1633                         vector current_view_origin_override = '0 0 0';
1634                         vector view_offset_override = '0 0 0';
1635                         float chase_distance_override = 0;
1636                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1637                         if(custom_eventchase)
1638                         {
1639                                 current_view_origin_override = M_ARGV(0, vector);
1640                                 view_offset_override = M_ARGV(1, vector);
1641                                 chase_distance_override = M_ARGV(0, float);
1642                         }
1643                         eventchase_running = true;
1644
1645                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1646                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1647                         if (custom_eventchase)
1648                                 current_view_origin = current_view_origin_override;
1649
1650                         // detect maximum viewoffset and use it
1651                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1652                         if(vehicle_chase)
1653                         {
1654                                 if(vehicle_viewofs)
1655                                         view_offset = vehicle_viewofs;
1656                                 else
1657                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1658                         }
1659                         if (custom_eventchase)
1660                                 view_offset = view_offset_override;
1661
1662                         if(view_offset)
1663                         {
1664                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1665                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1666                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1667                         }
1668
1669                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1670                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1671                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1672                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1673
1674                         // make the camera smooth back
1675                         float chase_distance = autocvar_cl_eventchase_distance;
1676                         if(vehicle_chase)
1677                         {
1678                                 if(vehicle_viewofs)
1679                                         chase_distance = vehicle_viewdist;
1680                                 else
1681                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1682                         }
1683                         if (custom_eventchase)
1684                                 chase_distance = chase_distance_override;
1685
1686                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1687                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1688                         else if(eventchase_current_distance != chase_distance)
1689                                 eventchase_current_distance = chase_distance;
1690
1691                         makevectors(view_angles);
1692
1693                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1694                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1695
1696                         // If the boxtrace fails, revert back to line tracing.
1697                         if(!local_player.viewloc)
1698                         if(trace_startsolid)
1699                         {
1700                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1701                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1702                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1703                         }
1704                         else { setproperty(VF_ORIGIN, trace_endpos); }
1705
1706                         if(!local_player.viewloc)
1707                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1708                 }
1709                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1710                 {
1711                         eventchase_running = false;
1712                         cvar_set("chase_active", "0");
1713                         eventchase_current_distance = 0; // start from 0 next time
1714                 }
1715         }
1716         // workaround for camera stuck between player's legs when using chase_active 1
1717         // because the engine stops updating the chase_active camera when the game ends
1718         else if(intermission)
1719         {
1720                 cvar_settemp("chase_active", "-1");
1721                 eventchase_current_distance = 0;
1722         }
1723
1724         LABEL(skip_eventchase_death);
1725
1726         // do lockview after event chase camera so that it still applies whenever necessary.
1727         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1728         {
1729                 setproperty(VF_ORIGIN, freeze_org);
1730                 setproperty(VF_ANGLES, freeze_ang);
1731         }
1732         else
1733         {
1734                 freeze_org = getpropertyvec(VF_ORIGIN);
1735                 freeze_ang = getpropertyvec(VF_ANGLES);
1736         }
1737
1738         WarpZone_FixView();
1739         //WarpZone_FixPMove();
1740
1741         vector ov_org = '0 0 0';
1742         vector ov_mid = '0 0 0';
1743         vector ov_worldmin = '0 0 0';
1744         vector ov_worldmax = '0 0 0';
1745         if(autocvar_cl_orthoview)
1746         {
1747                 ov_worldmin = mi_picmin;
1748                 ov_worldmax = mi_picmax;
1749
1750                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1751                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1752                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1753
1754                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1755                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1756
1757                 float ov_nearest = vlen(ov_org - vec3(
1758                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1759                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1760                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1761                 ));
1762
1763                 float ov_furthest = 0;
1764                 float dist = 0;
1765
1766                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1767                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1768                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1769                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1770                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1771                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1772                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1773                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1774
1775                 if(!ov_enabled)
1776                 {
1777                         oldr_nearclip = cvar("r_nearclip");
1778                         oldr_farclip_base = cvar("r_farclip_base");
1779                         oldr_farclip_world = cvar("r_farclip_world");
1780                         oldr_novis = cvar("r_novis");
1781                         oldr_useportalculling = cvar("r_useportalculling");
1782                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1783                 }
1784
1785                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1786                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1787                 cvar_settemp("r_farclip_world", "0");
1788                 cvar_settemp("r_novis", "1");
1789                 cvar_settemp("r_useportalculling", "0");
1790                 cvar_settemp("r_useinfinitefarclip", "0");
1791
1792                 setproperty(VF_ORIGIN, ov_org);
1793                 setproperty(VF_ANGLES, '90 0 0');
1794
1795                 ov_enabled = true;
1796
1797                 #if 0
1798                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1799                         vtos(ov_org),
1800                         vtos(getpropertyvec(VF_ANGLES)),
1801                         ov_distance,
1802                         ov_nearest,
1803                         ov_furthest);
1804                 #endif
1805         }
1806         else
1807         {
1808                 if(ov_enabled)
1809                 {
1810                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1811                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1812                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1813                         cvar_set("r_novis", ftos(oldr_novis));
1814                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1815                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1816                 }
1817                 ov_enabled = false;
1818         }
1819
1820         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1821         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1822         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1823                 viewmodel_draw(viewmodels[slot]);
1824
1825         // Render the Scene
1826         view_origin = getpropertyvec(VF_ORIGIN);
1827         view_angles = getpropertyvec(VF_ANGLES);
1828         makevectors(view_angles);
1829         view_forward = v_forward;
1830         view_right = v_right;
1831         view_up = v_up;
1832
1833 #ifdef BLURTEST
1834         if(time > blurtest_time0 && time < blurtest_time1)
1835         {
1836                 float r, t;
1837
1838                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1839                 r = t * blurtest_radius;
1840                 f = 1 / (t ** blurtest_power) - 1;
1841
1842                 cvar_set("r_glsl_postprocess", "1");
1843                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1844         }
1845         else
1846         {
1847                 cvar_set("r_glsl_postprocess", "0");
1848                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1849         }
1850 #endif
1851
1852         TargetMusic_Advance();
1853         Fog_Force();
1854
1855         if(drawtime == 0)
1856                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1857         else
1858                 drawframetime = bound(0.000001, time - drawtime, 1);
1859         drawtime = time;
1860
1861         // watch for gametype changes here...
1862         // in ParseStuffCMD the cmd isn't executed yet :/
1863         // might even be better to add the gametype to TE_CSQC_INIT...?
1864         if(!postinit)
1865                 PostInit();
1866
1867         if(intermission && !intermission_time)
1868                 intermission_time = time;
1869
1870         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1871         {
1872                 if(calledhooks & HOOK_START)
1873                 {
1874                         localcmd("\ncl_hook_gameend\n");
1875                         calledhooks |= HOOK_END;
1876                 }
1877         }
1878
1879         Announcer();
1880
1881         fov = autocvar_fov;
1882         if(fov <= 59.5)
1883         {
1884                 if(!zoomscript_caught)
1885                 {
1886                         localcmd("+button9\n");
1887                         zoomscript_caught = 1;
1888                 }
1889         }
1890         else
1891         {
1892                 if(zoomscript_caught)
1893                 {
1894                         localcmd("-button9\n");
1895                         zoomscript_caught = 0;
1896                 }
1897         }
1898
1899         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1900
1901         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1902         {
1903                 entity wepent = viewmodels[slot];
1904
1905                 if(wepent.last_switchweapon != wepent.switchweapon)
1906                 {
1907                         weapontime = time;
1908                         wepent.last_switchweapon = wepent.switchweapon;
1909                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1910                         {
1911                                 localcmd("-zoom\n");
1912                                 button_zoom = false;
1913                         }
1914                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1915                         {
1916                                 localcmd("-fire\n");
1917                                 localcmd("-fire2\n");
1918                                 button_attack2 = false;
1919                         }
1920                 }
1921                 if(wepent.last_activeweapon != wepent.activeweapon)
1922                 {
1923                         wepent.last_activeweapon = wepent.activeweapon;
1924
1925                         e = wepent.activeweapon;
1926                         if(e.netname != "")
1927                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1928                         else if(slot == 0)
1929                                 localcmd("\ncl_hook_activeweapon none\n");
1930                 }
1931         }
1932
1933         // ALWAYS Clear Current Scene First
1934         clearscene();
1935
1936         setproperty(VF_ORIGIN, view_origin);
1937         setproperty(VF_ANGLES, view_angles);
1938
1939         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1940         setproperty(VF_SIZE, vf_size);
1941         setproperty(VF_MIN, vf_min);
1942
1943         // Assign Standard Viewflags
1944         // Draw the World (and sky)
1945         setproperty(VF_DRAWWORLD, 1);
1946
1947         // Set the console size vars
1948         vid_conwidth = autocvar_vid_conwidth;
1949         vid_conheight = autocvar_vid_conheight;
1950         vid_pixelheight = autocvar_vid_pixelheight;
1951
1952         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1953         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1954         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1955
1956         if(camera_active) // Camera for demo playback
1957         {
1958                 if(autocvar_camera_enable)
1959                         CSQC_Demo_Camera();
1960                 else
1961                 {
1962                         cvar_set("chase_active", ftos(chase_active_backup));
1963                         cvar_set("cl_demo_mousegrab", "0");
1964                         camera_active = false;
1965                 }
1966         }
1967         else
1968         {
1969 #ifdef CAMERATEST
1970                 if(autocvar_camera_enable)
1971 #else
1972                 if(autocvar_camera_enable && isdemo())
1973 #endif
1974                 {
1975                         // Enable required Darkplaces cvars
1976                         chase_active_backup = autocvar_chase_active;
1977                         cvar_set("chase_active", "2");
1978                         cvar_set("cl_demo_mousegrab", "1");
1979                         camera_active = true;
1980                         camera_mode = false;
1981                 }
1982         }
1983
1984         // Draw the Crosshair
1985         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1986
1987         // Draw the Engine Status Bar (the default Quake HUD)
1988         setproperty(VF_DRAWENGINESBAR, 0);
1989
1990         // Update the mouse position
1991         /*
1992            mousepos_x = vid_conwidth;
1993            mousepos_y = vid_conheight;
1994            mousepos = mousepos*0.5 + getmousepos();
1995          */
1996
1997         IL_EACH(g_drawables, it.draw, it.draw(it));
1998
1999         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2000         renderscene();
2001
2002         // now switch to 2D drawing mode by calling a 2D drawing function
2003         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2004         // next R_RenderScene call
2005         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2006
2007         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2008         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2009         {
2010                 // apply night vision effect
2011                 vector tc_00, tc_01, tc_10, tc_11;
2012                 vector rgb = '0 0 0';
2013
2014                 if(!nightvision_noise)
2015                 {
2016                         nightvision_noise = new(nightvision_noise);
2017                 }
2018                 if(!nightvision_noise2)
2019                 {
2020                         nightvision_noise2 = new(nightvision_noise2);
2021                 }
2022
2023                 // color tint in yellow
2024                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2025
2026                 // draw BG
2027                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2028                 rgb = '1 1 1';
2029                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2030                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2031                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2032                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2033                 tc_11 = tc_01 + tc_10 - tc_00;
2034                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2035                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2036                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2037                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2038                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2039                 R_EndPolygon();
2040
2041                 // draw FG
2042                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2043                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2044                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2045                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2046                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2047                 tc_11 = tc_01 + tc_10 - tc_00;
2048                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2049                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2050                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2051                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2052                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2053                 R_EndPolygon();
2054         }
2055
2056         if(autocvar_cl_reticle)
2057         {
2058                 string reticle_image = string_null;
2059                 bool wep_zoomed = false;
2060                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2061                 {
2062                         entity wepe = viewmodels[slot];
2063                         Weapon wep = wepe.activeweapon;
2064                         if(wep != WEP_Null && wep.wr_zoom)
2065                         {
2066                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2067                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2068                                         reticle_image = wep.w_reticle;
2069                                 wep_zoomed += do_zoom;
2070                         }
2071                 }
2072                 // Draw the aiming reticle for weapons that use it
2073                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2074                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2075                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2076                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2077                 {
2078                         // no zoom reticle while dead
2079                         reticle_type = 0;
2080                 }
2081                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2082                 {
2083                         if(reticle_image) { reticle_type = 2; }
2084                         else { reticle_type = 0; }
2085                 }
2086                 else if(button_zoom || zoomscript_caught)
2087                 {
2088                         // normal zoom
2089                         reticle_type = 1;
2090                 }
2091
2092                 if(reticle_type)
2093                 {
2094                         if(autocvar_cl_reticle_stretch)
2095                         {
2096                                 reticle_size.x = vid_conwidth;
2097                                 reticle_size.y = vid_conheight;
2098                                 reticle_pos.x = 0;
2099                                 reticle_pos.y = 0;
2100                         }
2101                         else
2102                         {
2103                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2104                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2105                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2106                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2107                         }
2108
2109                         if(zoomscript_caught)
2110                                 f = 1;
2111                         else
2112                                 f = current_zoomfraction;
2113
2114                         if(f)
2115                         {
2116                                 switch(reticle_type)
2117                                 {
2118                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2119                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2120                                 }
2121                         }
2122                 }
2123         }
2124         else
2125         {
2126                 if(reticle_type != 0) { reticle_type = 0; }
2127         }
2128
2129
2130         // improved polyblend
2131         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2132         {
2133                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2134                 vector liquidcolor;
2135
2136                 switch(pointcontents(view_origin))
2137                 {
2138                         case CONTENT_WATER:
2139                                 liquidalpha = autocvar_hud_contents_water_alpha;
2140                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2141                                 incontent = 1;
2142                                 break;
2143
2144                         case CONTENT_LAVA:
2145                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2146                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2147                                 incontent = 1;
2148                                 break;
2149
2150                         case CONTENT_SLIME:
2151                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2152                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2153                                 incontent = 1;
2154                                 break;
2155
2156                         default:
2157                                 liquidalpha = 0;
2158                                 liquidcolor = '0 0 0';
2159                                 incontent = 0;
2160                                 break;
2161                 }
2162
2163                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2164                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2165                         contentfadetime = autocvar_hud_contents_fadeintime;
2166                         liquidalpha_prev = liquidalpha;
2167                         liquidcolor_prev = liquidcolor;
2168                 }
2169                 else
2170                         contentfadetime = autocvar_hud_contents_fadeouttime;
2171
2172                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2173                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2174
2175                 if(contentavgalpha)
2176                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2177
2178                 if(autocvar_hud_postprocessing)
2179                 {
2180                         if(autocvar_hud_contents_blur && contentavgalpha)
2181                         {
2182                                 content_blurpostprocess.x = 1;
2183                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2184                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2185                         }
2186                         else
2187                         {
2188                                 content_blurpostprocess.x = 0;
2189                                 content_blurpostprocess.y = 0;
2190                                 content_blurpostprocess.z = 0;
2191                         }
2192                 }
2193         }
2194
2195         if(autocvar_hud_damage && !STAT(FROZEN))
2196         {
2197                 splash_size.x = max(vid_conwidth, vid_conheight);
2198                 splash_size.y = max(vid_conwidth, vid_conheight);
2199                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2200                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2201
2202                 float myhealth_flash_temp;
2203                 myhealth = STAT(HEALTH);
2204
2205                 // fade out
2206                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2207                 // add new damage
2208                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2209
2210                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2211                 pain_threshold = autocvar_hud_damage_pain_threshold;
2212                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2213                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2214
2215                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2216                 {
2217                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2218                 }
2219
2220                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2221
2222                 if(myhealth_prev < 1)
2223                 {
2224                         if(myhealth >= 1)
2225                         {
2226                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2227                                 myhealth_flash_temp = 0;
2228                         }
2229                         else
2230                         {
2231                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2232                         }
2233                 }
2234
2235                 if(spectatee_status == -1 || intermission)
2236                 {
2237                         myhealth_flash = 0; // observing, or match ended
2238                         myhealth_flash_temp = 0;
2239                 }
2240
2241                 myhealth_prev = myhealth;
2242
2243                 // IDEA: change damage color/picture based on player model for robot/alien species?
2244                 // pro: matches model better
2245                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2246                 // maybe different reddish pics?
2247                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2248                 {
2249                         if(autocvar_cl_gentle_damage == 2)
2250                         {
2251                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2252                                         myhealth_gentlergb = randomvec();
2253                         }
2254                         else
2255                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2256
2257                         if(myhealth_flash_temp > 0)
2258                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2259                 }
2260                 else if(myhealth_flash_temp > 0)
2261                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2262
2263                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2264                 {
2265                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2266                         {
2267                                 damage_blurpostprocess.x = 1;
2268                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2269                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2270                         }
2271                         else
2272                         {
2273                                 damage_blurpostprocess.x = 0;
2274                                 damage_blurpostprocess.y = 0;
2275                                 damage_blurpostprocess.z = 0;
2276                         }
2277                 }
2278         }
2279
2280         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2281         float e2 = (autocvar_hud_powerup != 0);
2282         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2283         {
2284                 // enable or disable rendering types if they are used or not
2285                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2286                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2287
2288                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2289                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2290                 {
2291                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2292                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2293                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2294                         {
2295                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2296                                 old_blurradius = blurradius;
2297                                 old_bluralpha = bluralpha;
2298                         }
2299                 }
2300                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2301                 {
2302                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2303                         old_blurradius = 0;
2304                         old_bluralpha = 0;
2305                 }
2306
2307                 // edge detection postprocess handling done second (used by hud_powerup)
2308                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2309                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2310                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2311
2312                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2313
2314                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2315                 {
2316                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2317                         {
2318                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2319                                 old_sharpen_intensity = sharpen_intensity;
2320                         }
2321                 }
2322                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2323                 {
2324                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2325                         old_sharpen_intensity = 0;
2326                 }
2327
2328                 if(cvar("r_glsl_postprocess") == 0)
2329                         cvar_set("r_glsl_postprocess", "2");
2330         }
2331         else if(cvar("r_glsl_postprocess") == 2)
2332                 cvar_set("r_glsl_postprocess", "0");
2333
2334         /*if(gametype == MAPINFO_TYPE_CTF)
2335           {
2336           ctf_view();
2337           } else */
2338
2339         // draw 2D entities
2340         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2341         Draw_ShowNames_All();
2342 #if ENABLE_DEBUGDRAW
2343         Debug_Draw();
2344 #endif
2345
2346         scoreboard_active = Scoreboard_WouldDraw();
2347
2348         HUD_Draw(this); // this parameter for deep vehicle function
2349
2350         if(NextFrameCommand)
2351         {
2352                 localcmd("\n", NextFrameCommand, "\n");
2353                 NextFrameCommand = string_null;
2354         }
2355
2356         // we must do this check AFTER a frame was rendered, or it won't work
2357         if(cs_project_is_b0rked == 0)
2358         {
2359                 string w0, h0;
2360                 w0 = ftos(autocvar_vid_conwidth);
2361                 h0 = ftos(autocvar_vid_conheight);
2362                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2363                 //setproperty(VF_FOV, '90 90 0');
2364                 setproperty(VF_ORIGIN, '0 0 0');
2365                 setproperty(VF_ANGLES, '0 0 0');
2366                 setproperty(VF_PERSPECTIVE, 1);
2367                 makevectors('0 0 0');
2368                 vector v1, v2;
2369                 cvar_set("vid_conwidth", "800");
2370                 cvar_set("vid_conheight", "600");
2371                 v1 = cs_project(v_forward);
2372                 cvar_set("vid_conwidth", "640");
2373                 cvar_set("vid_conheight", "480");
2374                 v2 = cs_project(v_forward);
2375                 if(v1 == v2)
2376                         cs_project_is_b0rked = 1;
2377                 else
2378                         cs_project_is_b0rked = -1;
2379                 cvar_set("vid_conwidth", w0);
2380                 cvar_set("vid_conheight", h0);
2381         }
2382
2383         if(autocvar__hud_configure)
2384                 HUD_Panel_Mouse();
2385         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2386                 HUD_Minigame_Mouse();
2387         else if(QuickMenu_IsOpened())
2388                 QuickMenu_Mouse();
2389         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2390                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2391         else
2392                 HUD_Radar_Mouse();
2393
2394         cl_notice_run();
2395         unpause_update();
2396         Net_Flush();
2397
2398         // let's reset the view back to normal for the end
2399         setproperty(VF_MIN, '0 0 0');
2400         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2401
2402         IL_ENDFRAME();
2403 }
2404
2405
2406 // following vectors must be global to allow seamless switching between camera modes
2407 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2408 void CSQC_Demo_Camera()
2409 {
2410         float speed, attenuation, dimensions;
2411         vector tmp, delta;
2412
2413         if( autocvar_camera_reset || !camera_mode )
2414         {
2415                 camera_offset = '0 0 0';
2416                 current_angles = '0 0 0';
2417                 camera_direction = '0 0 0';
2418                 camera_offset.z += 30;
2419                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2420                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2421                 current_origin = view_origin;
2422                 current_camera_offset  = camera_offset;
2423                 cvar_set("camera_reset", "0");
2424                 camera_mode = CAMERA_CHASE;
2425         }
2426
2427         // Camera angles
2428         if( camera_roll )
2429                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2430
2431         if(autocvar_camera_look_player)
2432         {
2433                 vector dir;
2434                 float n;
2435
2436                 dir = normalize(view_origin - current_position);
2437                 n = mouse_angles.z;
2438                 mouse_angles = vectoangles(dir);
2439                 mouse_angles.x = mouse_angles.x * -1;
2440                 mouse_angles.z = n;
2441         }
2442         else
2443         {
2444                 tmp = getmousepos() * 0.1;
2445                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2446                 {
2447                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2448                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2449                 }
2450         }
2451
2452         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2453         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2454         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2455         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2456
2457         // Fix difference when angles don't have the same sign
2458         delta = '0 0 0';
2459         if(mouse_angles.y < -60 && current_angles.y > 60)
2460                 delta = '0 360 0';
2461         if(mouse_angles.y > 60 && current_angles.y < -60)
2462                 delta = '0 -360 0';
2463
2464         if(autocvar_camera_look_player)
2465                 attenuation = autocvar_camera_look_attenuation;
2466         else
2467                 attenuation = autocvar_camera_speed_attenuation;
2468
2469         attenuation = 1 / max(1, attenuation);
2470         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2471
2472         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2473         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2474         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2475         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2476
2477         // Camera position
2478         tmp = '0 0 0';
2479         dimensions = 0;
2480
2481         if( camera_direction.x )
2482         {
2483                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2484                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2485                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2486                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2487                 ++dimensions;
2488         }
2489
2490         if( camera_direction.y )
2491         {
2492                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2493                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2494                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2495                 ++dimensions;
2496         }
2497
2498         if( camera_direction.z )
2499         {
2500                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2501                 ++dimensions;
2502         }
2503
2504         if(autocvar_camera_free)
2505                 speed = autocvar_camera_speed_free;
2506         else
2507                 speed = autocvar_camera_speed_chase;
2508
2509         if(dimensions)
2510         {
2511                 speed = speed * sqrt(1 / dimensions);
2512                 camera_offset += tmp * speed;
2513         }
2514
2515         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2516
2517         // Camera modes
2518         if( autocvar_camera_free )
2519         {
2520                 if ( camera_mode == CAMERA_CHASE )
2521                 {
2522                         current_camera_offset = current_origin + current_camera_offset;
2523                         camera_offset = current_origin + camera_offset;
2524                 }
2525
2526                 camera_mode = CAMERA_FREE;
2527                 current_position = current_camera_offset;
2528         }
2529         else
2530         {
2531                 if ( camera_mode == CAMERA_FREE )
2532                 {
2533                         current_origin = view_origin;
2534                         camera_offset = camera_offset - current_origin;
2535                         current_camera_offset = current_camera_offset - current_origin;
2536                 }
2537
2538                 camera_mode = CAMERA_CHASE;
2539
2540                 if(autocvar_camera_chase_smoothly)
2541                         current_origin += (view_origin - current_origin) * attenuation;
2542                 else
2543                         current_origin = view_origin;
2544
2545                 current_position = current_origin + current_camera_offset;
2546         }
2547
2548         setproperty(VF_ANGLES, current_angles);
2549         setproperty(VF_ORIGIN, current_position);
2550 }