qcsrc/common/animdecide.qc

   1 // player animation data for this model
   2 // each vector is as follows:
   3 // _x = startframe
   4 // _y = numframes
   5 // _z = framerate
   6 .vector anim_die1; // player dies
   7 .vector anim_die2; // player dies differently
   8 .vector anim_draw; // player pulls out a weapon
   9 .vector anim_duckwalk; // player walking while crouching
  10 .vector anim_duckjump; // player jumping from a crouch
  11 .vector anim_duckidle; // player idling while crouching
  12 .vector anim_idle; // player standing
  13 .vector anim_jump; // player jump
  14 .vector anim_pain1; // player flinches from pain
  15 .vector anim_pain2; // player flinches from pain, differently
  16 .vector anim_shoot; // player shoots
  17 .vector anim_taunt; // player taunts others (FIXME: no code references this)
  18 .vector anim_run; // player running forward
  19 .vector anim_runbackwards; // player running backward
  20 .vector anim_strafeleft; // player shuffling left quickly
  21 .vector anim_straferight; // player shuffling right quickly
  22 .vector anim_forwardright; // player running forward and right
  23 .vector anim_forwardleft; // player running forward and left
  24 .vector anim_backright; // player running backward and right
  25 .vector anim_backleft; // player running back and left
  26 .vector anim_melee; // player doing the melee action
  27 .vector anim_duck; // player doing the melee action
  28 .vector anim_duckwalkbackwards;
  29 .vector anim_duckwalkstrafeleft;
  30 .vector anim_duckwalkstraferight;
  31 .vector anim_duckwalkforwardright;
  32 .vector anim_duckwalkforwardleft;
  33 .vector anim_duckwalkbackright;
  34 .vector anim_duckwalkbackleft;
  35
  36 void animdecide_init(entity e)
  37 {
  38         vector none = '0 0 0';
  39         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  40         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  41         e.anim_draw = animfixfps(e, '2 1 3', none);
  42         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  43         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  44         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  45         e.anim_idle = animfixfps(e, '7 1 1', none);
  46         e.anim_jump = animfixfps(e, '8 1 10', none);
  47         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  48         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  49         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  50         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  51         e.anim_run = animfixfps(e, '13 1 1', none);
  52         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  53         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  54         e.anim_straferight = animfixfps(e, '16 1 1', none);
  55         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  56         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  57         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  58         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  59         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  60         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  61         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  62         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  63         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  64         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  65         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  66         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  67
  68         // these anims ought to stay until stopped explicitly by weaponsystem
  69         e.aim_shoot_z = 0.001;
  70         e.aim_melee_z = 0.001;
  71 }
  72
  73 #define ANIMPRIO_IDLE 0
  74 #define ANIMPRIO_STATIC 1
  75 #define ANIMPRIO_ACTIVE 2
  76 #define ANIMPRIO_DEAD 3
  77
  78 vector animdecide_getupperanim(entity e)
  79 {
  80         // is there an action?
  81         vector outframe = '-1 0 0';
  82         float t, a;
  83         if(e.anim_upper_time >= e.anim_upper_implicit_time)
  84         {
  85                 a = e.anim_upper_action;
  86                 t = e.anim_upper_time;
  87         }
  88         else
  89         {
  90                 a = e.anim_upper_implicit_action;
  91                 t = e.anim_upper_implicit_time;
  92         }
  93         switch(a)
  94         {
  95                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
  96                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
  97                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
  98                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
  99                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
 100                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
 101         }
 102         if(outframe_x >= 0)
 103         {
 104                 if(time <= t + outframe_y / outframe_z)
 105                 {
 106                         // animation is running!
 107                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 108                 }
 109         }
 110         // or, decide the anim by state
 111         t = max(e.anim_time, e.anim_implicit_time);
 112         // but all states are for lower body!
 113         return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 114 }
 115
 116 vector animdecide_getloweranim(entity e)
 117 {
 118         // death etc.
 119         if(e.anim_state & ANIMSTATE_FROZEN)
 120                 return vec3(e.anim_idle_x, e.anim_time, ANIMPRIO_DEAD);
 121         if(e.anim_state & ANIMSTATE_DEAD1)
 122                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 123         if(e.anim_state & ANIMSTATE_DEAD2)
 124                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 125
 126         // is there an action?
 127         vector outframe = '-1 0 0';
 128         float t, a;
 129         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 130         {
 131                 a = e.anim_lower_action;
 132                 t = e.anim_lower_time;
 133         }
 134         else
 135         {
 136                 a = e.anim_lower_implicit_action;
 137                 t = e.anim_lower_implicit_time;
 138         }
 139         switch(a)
 140         {
 141                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 142         }
 143         if(outframe_x >= 0)
 144         {
 145                 if(time <= t + outframe_y / outframe_z)
 146                 {
 147                         // animation is running!
 148                         return vec3(outframe_x, t, ANIMPRIO_ACTIVE);
 149                 }
 150         }
 151         // or, decide the anim by state
 152         t = max(e.anim_time, e.anim_implicit_time);
 153         if(e.anim_state & ANIMSTATE_DUCK)
 154         {
 155                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 156                         return vec3(e.anim_duckjump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 157                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 158                 {
 159                         case ANIMIMPLICITSTATE_FORWARD:
 160                                 return vec3(e.anim_duckwalk_x, t, ANIMPRIO_ACTIVE);
 161                         case ANIMIMPLICITSTATE_BACKWARDS:
 162                                 return vec3(e.anim_duckwalkbackwards_x, t, ANIMPRIO_ACTIVE);
 163                         case ANIMIMPLICITSTATE_RIGHT:
 164                                 return vec3(e.anim_duckwalkstraferight_x, t, ANIMPRIO_ACTIVE);
 165                         case ANIMIMPLICITSTATE_LEFT:
 166                                 return vec3(e.anim_duckwalkstrafeleft_x, t, ANIMPRIO_ACTIVE);
 167                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 168                                 return vec3(e.anim_duckwalkforwardright_x, t, ANIMPRIO_ACTIVE);
 169                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 170                                 return vec3(e.anim_duckwalkforwardleft_x, t, ANIMPRIO_ACTIVE);
 171                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 172                                 return vec3(e.anim_duckwalkbackright_x, t, ANIMPRIO_ACTIVE);
 173                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 174                                 return vec3(e.anim_duckwalkbackleft_x, t, ANIMPRIO_ACTIVE);
 175                         default:
 176                                 return vec3(e.anim_duckidle_x, t, ANIMPRIO_STATIC);
 177                 }
 178         }
 179         else
 180         {
 181                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 182                         return vec3(e.anim_jump_x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 183                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 184                 {
 185                         case ANIMIMPLICITSTATE_FORWARD:
 186                                 return vec3(e.anim_run_x, t, ANIMPRIO_ACTIVE);
 187                         case ANIMIMPLICITSTATE_BACKWARDS:
 188                                 return vec3(e.anim_runbackwards_x, t, ANIMPRIO_ACTIVE);
 189                         case ANIMIMPLICITSTATE_RIGHT:
 190                                 return vec3(e.anim_straferight_x, t, ANIMPRIO_ACTIVE);
 191                         case ANIMIMPLICITSTATE_LEFT:
 192                                 return vec3(e.anim_strafeleft_x, t, ANIMPRIO_ACTIVE);
 193                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 194                                 return vec3(e.anim_forwardright_x, t, ANIMPRIO_ACTIVE);
 195                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 196                                 return vec3(e.anim_forwardleft_x, t, ANIMPRIO_ACTIVE);
 197                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 198                                 return vec3(e.anim_backright_x, t, ANIMPRIO_ACTIVE);
 199                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 200                                 return vec3(e.anim_backleft_x, t, ANIMPRIO_ACTIVE);
 201                         default:
 202                                 return vec3(e.anim_idle_x, t, ANIMPRIO_IDLE);
 203                 }
 204         }
 205         // can't get here
 206 }
 207
 208 void animdecide_setimplicitstate(entity e, float onground)
 209 {
 210         float s;
 211         s = 0;
 212
 213         makevectors(e.angles);
 214         vector v;
 215         v_x = e.velocity * v_forward;
 216         v_y = e.velocity * v_right;
 217
 218         // we want to match like this:
 219         // the 8 directions shall be "evenly spaced"
 220         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 221         // which then means x > |y| * cot(3pi/8)
 222         //
 223         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 224         // which would be an angle range from -63.43 to +63.43 degrees, making
 225         // it slightly less likely to "hit two keys at once", so let's do this
 226         // here too
 227
 228         if(vlen(v) > 10)
 229         {
 230                 if(v_x >  fabs(v_y) * 0.5)
 231                         s |= ANIMIMPLICITSTATE_FORWARD;
 232                 if(v_x < -fabs(v_y) * 0.5)
 233                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 234                 if(v_y >  fabs(v_x) * 0.5)
 235                         s |= ANIMIMPLICITSTATE_RIGHT;
 236                 if(v_y < -fabs(v_x) * 0.5)
 237                         s |= ANIMIMPLICITSTATE_LEFT;
 238         }
 239         if(!onground)
 240                 s |= ANIMIMPLICITSTATE_INAIR;
 241
 242         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 243         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 244         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 245         {
 246                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 247                 e.anim_lower_implicit_time = time;
 248         }
 249
 250         if(s != e.anim_implicit_state)
 251         {
 252                 e.anim_implicit_state = s;
 253                 e.anim_implicit_time = time;
 254         }
 255 }
 256 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 257 {
 258         // _x: frame
 259         // _y: start time
 260         // _z: priority
 261         vector upper = animdecide_getupperanim(e);
 262         vector lower = animdecide_getloweranim(e);
 263         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 264         if(upper_z > lower_z)
 265                 lower = upper;
 266         else if(lower_z > upper_z)
 267                 upper = lower;
 268         if(support_blending)
 269         {
 270                 if(e.frame1time != upper_y || e.frame2time != lower_y)
 271                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 272                 e.fld_frame = upper_x;
 273                 e.fld_frame1time = upper_y;
 274                 e.fld_frame2 = lower_x;
 275                 e.fld_frame2time = lower_y;
 276         }
 277         else
 278         {
 279                 if(e.frame1time != upper_y)
 280                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 281                 e.fld_frame = upper_x;
 282                 e.fld_frame1time = upper_y;
 283         }
 284 }
 285
 286 void animdecide_setstate(entity e, float newstate, float restart)
 287 {
 288         if(!restart)
 289                 if(newstate == e.anim_state)
 290                         return;
 291         e.anim_state = newstate;
 292         e.anim_time = time;
 293 }
 294 void animdecide_setaction(entity e, float action, float restart)
 295 {
 296         if(action < 0)
 297         {
 298                 if(!restart)
 299                         if(action == e.anim_lower_action)
 300                                 return;
 301                 e.anim_lower_action = action;
 302                 e.anim_lower_time = time;
 303         }
 304         else
 305         {
 306                 if(!restart)
 307                         if(action == e.anim_upper_action)
 308                                 return;
 309                 e.anim_upper_action = action;
 310                 e.anim_upper_time = time;
 311         }
 312 }