qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 #if defined(CSQC)
   4         #include <common/gamemodes/_mod.qh>
   5         #include <common/resources/resources.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8         #include <common/gamemodes/_mod.qh>
   9         #include <common/resources/resources.qh>
  10         #include <common/resources/sv_resources.qh>
  11 #endif
  12
  13 REGISTRY(EntCSProps, BITS(16) - 1)
  14 REGISTER_REGISTRY(EntCSProps)
  15 REGISTRY_SORT(EntCSProps)
  16 REGISTRY_CHECK(EntCSProps)
  17
  18 REGISTRY_DEFINE_GET(EntCSProps, NULL)
  19 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
  20
  21 // these entcs_props ids need to be referenced directly
  22 int ENTCS_PROP_ENTNUM_id = 0;
  23 int ENTCS_PROP_ORIGIN_id = 0;
  24 int ENTCS_PROP_HEALTH_id = 0;
  25 STATIC_INIT(EntCSProps_setglobalids)
  26 {
  27         FOREACH(EntCSProps, true, {
  28                 if (it.registered_id == "ENTCS_PROP_ENTNUM") ENTCS_PROP_ENTNUM_id = it.m_id;
  29                 if (it.registered_id == "ENTCS_PROP_ORIGIN") ENTCS_PROP_ORIGIN_id = it.m_id;
  30                 if (it.registered_id == "ENTCS_PROP_HEALTH") ENTCS_PROP_HEALTH_id = it.m_id;
  31         });
  32 }
  33
  34 #ifdef SVQC
  35 // Force an origin update, for player sounds
  36 void entcs_force_origin(entity player)
  37 {
  38         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
  39 }
  40 #endif
  41
  42 .bool m_public;
  43 .bool(entity ent, entity player) m_check;
  44 .void(entity ent, entity player) m_set;
  45 .void(int chan, entity ent) m_send;
  46 .void(entity ent) m_receive;
  47
  48 #ifdef SVQC
  49 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  50         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
  51         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  52         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  53                 this.m_public = ispublic; \
  54                 this.m_check = id##_check; \
  55                 this.m_set = id##_set; \
  56                 this.m_send = id##_send; \
  57         }
  58
  59 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  60         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
  61         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  62
  63 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  64         bool id##_check(entity ent, entity player) { \
  65                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
  66         } \
  67         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  68
  69 #elif defined(CSQC)
  70 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
  71         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  72         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  73                 this.m_public = ispublic; \
  74                 this.m_receive = id##_receive; \
  75         }
  76
  77 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
  78         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
  79 #endif
  80
  81 #ifdef SVQC
  82 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  83         bool id##_check(entity ent, entity player) { \
  84                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
  85         } \
  86         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
  87         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  88         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  89                 this.m_public = ispublic; \
  90                 this.m_check = id##_check; \
  91                 this.m_set = id##_set; \
  92                 this.m_send = id##_send; \
  93         }
  94 #elif defined(CSQC)
  95 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
  96         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  97         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  98                 this.m_public = ispublic; \
  99                 this.m_receive = id##_receive; \
 100         }
 101 #endif
 102
 103 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
 104         var = x; \
 105 MACRO_END
 106
 107 /** the engine player name strings are mutable! */
 108 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
 109         strcpy(var, x); \
 110 MACRO_END
 111
 112 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
 113
 114 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
 115         { WriteVector(chan, ent.origin); },
 116         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
 117
 118 #define DEC_FACTOR (360 / 64)
 119 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
 120         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
 121         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
 122 #undef DEC_FACTOR
 123
 124 // FIXME: use a better scale?
 125 #define DEC_FACTOR 10
 126 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
 127         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
 128         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
 129
 130 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
 131         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
 132         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
 133 #undef DEC_FACTOR
 134
 135 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
 136         { WriteString(chan, ent.netname); },
 137         { strcpy(ent.netname, ReadString()); })
 138
 139 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
 140         { WriteString(chan, ent.model); },
 141         { strcpy(ent.model, ReadString()); })
 142
 143 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
 144         { WriteByte(chan, ent.skin); },
 145         { ent.skin = ReadByte(); })
 146
 147 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
 148         { WriteByte(chan, ent.clientcolors); },
 149         { ent.colormap = ReadByte(); })
 150
 151 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
 152         { WriteShort(chan, ent.frags); },
 153         { ent.frags = ReadShort(); })
 154
 155 ENTCS_PROP(WANTSJOIN, true, wants_join, wants_join, ENTCS_SET_NORMAL,
 156         { WriteByte(chan, ent.wants_join); },
 157         { ent.wants_join = ReadByte(); })
 158
 159 // use sv_solid to avoid changing solidity state of entcs entities
 160 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
 161         { WriteByte(chan, ent.sv_solid); },
 162         { ent.sv_solid = ReadByte(); })
 163
 164 #ifdef SVQC
 165
 166         int ENTCS_PUBLICMASK = 0, ENTCS_PRIVATEMASK = 0;
 167         STATIC_INIT(ENTCS_PUBLICMASK)
 168         {
 169                 FOREACH(EntCSProps, true,
 170                 {
 171                         if (it.m_public)
 172                                 ENTCS_PUBLICMASK |= BIT(it.m_id);
 173                         else
 174                                 ENTCS_PRIVATEMASK |= BIT(it.m_id);
 175                 });
 176         }
 177
 178         void entcs_update_players(entity player)
 179         {
 180                 FOREACH_CLIENT(it != player && IS_PLAYER(it),
 181                 {
 182                         CS(it).entcs.SendFlags |= ENTCS_PRIVATEMASK;
 183                 });
 184         }
 185
 186         bool _entcs_send(entity this, entity to, int sf, int chan)
 187         {
 188                 entity player = this.owner;
 189                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
 190                 do {
 191                         if (IS_PLAYER(player))
 192                         {
 193                                 if (radar_showenemies) break;
 194                                 if (SAME_TEAM(to, player)) break;
 195                                 if (!(IS_PLAYER(to) || INGAME(to))) break;
 196                         }
 197                         sf &= ENTCS_PUBLICMASK; // no private updates
 198                 } while (0);
 199
 200                 sf |= this.m_forceupdate;
 201                 this.m_forceupdate = 0;
 202                 if (chan == MSG_ENTITY)
 203                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 204                 else
 205                         WriteHeader(chan, CLIENT_ENTCS);
 206                 WriteByte(chan, etof(player) - 1);
 207                 WriteShort(chan, sf);
 208                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 209                 {
 210                         it.m_send(chan, this);
 211                 });
 212                 return true;
 213         }
 214
 215         bool entcs_send(entity this, entity to, int sf)
 216         {
 217                 return _entcs_send(this, to, sf, MSG_ENTITY);
 218         }
 219
 220         void entcs_think(entity this)
 221         {
 222                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 223                 entity player = this.owner;
 224                 FOREACH(EntCSProps, it.m_check(this, player),
 225                 {
 226                         it.m_set(this, player);
 227                         this.SendFlags |= BIT(it.m_id);
 228                 });
 229
 230                 if (intermission_running)
 231                 {
 232                         // health is set to special values after the game ends, ignore any change
 233                         this.SendFlags &= ~BIT(ENTCS_PROP_HEALTH_id);
 234                 }
 235
 236                 // always send origin of players even if they stand still otherwise
 237                 // if a teammate isn't in my pvs and their health (or view angle or name
 238                 // etc...) changes then their tag disappears
 239                 if (IS_PLAYER(this.owner))
 240                         this.SendFlags |= BIT(ENTCS_PROP_ORIGIN_id);
 241
 242                 // not needed, origin is just data to be sent
 243                 //setorigin(this, this.origin); // relink
 244         }
 245
 246         void entcs_attach(entity player)
 247         {
 248                 entity e = CS(player).entcs = new_pure(entcs_sender);
 249                 e.owner = player;
 250                 setthink(e, entcs_think);
 251                 e.nextthink = time;
 252                 Net_LinkEntity(e, false, 0, entcs_send);
 253                 // NOTE: the following code block has been disabled as a workaround for https://gitlab.com/xonotic/xonotic-data.pk3dir/-/issues/1824
 254 #if 0
 255                 if (!IS_REAL_CLIENT(player)) return;
 256                 FOREACH_CLIENT(true, {
 257                         assert(CS(it).entcs);
 258                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
 259                 });
 260 #endif
 261         }
 262
 263         void entcs_detach(entity player)
 264         {
 265                 if (!CS(player).entcs) return;
 266                 delete(CS(player).entcs);
 267                 CS(player).entcs = NULL;
 268         }
 269
 270 #endif
 271
 272 #ifdef CSQC
 273
 274         void Ent_RemoveEntCS(entity this)
 275         {
 276                 int n = this.sv_entnum;
 277                 entity e = entcs_receiver(n);
 278                 entcs_receiver(n, NULL);
 279                 strfree(e.netname);
 280                 strfree(e.model);
 281                 if (e != this) delete(e);
 282         }
 283
 284         void entcs_think(entity this)
 285         {
 286                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 287                 if (e == NULL)
 288                 {
 289                         // player model is NOT in client's PVS
 290                         InterpolateOrigin_Do(this);
 291                         this.has_origin = this.has_sv_origin;
 292                         return;
 293                 }
 294                 this.has_origin = true;
 295                 // when a player model is in client's PVS we use its origin directly
 296                 // (entcs networked origin is overriden)
 297                 this.origin = e.origin;
 298                 InterpolateOrigin_Reset(this);
 299                 setorigin(this, this.origin);
 300                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 301                 if (this.model != e.model)
 302                 {
 303                         strcpy(this.model, e.model);
 304                 }
 305         }
 306
 307         bool ReadEntcs(entity this)
 308         {
 309                 int n = ReadByte();
 310                 entity e = entcs_receiver(n);
 311                 if (e == NULL)
 312                 {
 313                         if (!this)
 314                                 // initial = temp
 315                                 e = new_pure(ENT_CLIENT_ENTCS);
 316                         else
 317                                 // initial = linked
 318                                 e = this;
 319                         setthink(e, entcs_think);
 320                         entcs_receiver(n, e);
 321                 }
 322                 else if (e != this && this)
 323                 {
 324                         // upgrade to linked
 325                         delete(e);
 326                         e = this;
 327                         setthink(e, entcs_think);
 328                         entcs_receiver(n, e);
 329                 }
 330
 331                 InterpolateOrigin_Undo(e);
 332                 e.sv_entnum = n;
 333                 int sf = ReadShort();
 334                 e.has_sv_origin = false;
 335                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
 336                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 337                 {
 338                         it.m_receive(e);
 339                 });
 340                 e.iflags |= IFLAG_ORIGIN;
 341                 InterpolateOrigin_Note(e);
 342                 getthink(e)(e);
 343                 return true;
 344         }
 345
 346         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 347         {
 348                 if (isnew)
 349                 {
 350                         make_pure(this);
 351                         this.entremove = Ent_RemoveEntCS;
 352                 }
 353                 return ReadEntcs(this);
 354         }
 355
 356         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 357         {
 358                 return ReadEntcs(NULL);
 359         }
 360
 361 #endif