qcsrc/common/items/inventory.qh

   1 #ifndef INVENTORY_H
   2 #define INVENTORY_H
   3
   4 #include "all.qh"
   5 #include "item/pickup.qh"
   6
   7 CLASS(Inventory, Object)
   8     /** Stores counts of items, the id being the index */
   9     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX)
  10     /** Previous state */
  11     ATTRIB(Inventory, inventory, Inventory, NULL)
  12 ENDCLASS(Inventory)
  13
  14 /** Player inventory */
  15 .Inventory inventory;
  16
  17 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  18
  19 #ifdef CSQC
  20 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  21 {
  22     make_pure(this);
  23     const int bits = ReadInt24_t();
  24     FOREACH(Items, bits & BIT(it.m_id), {
  25         .int fld = inv_items[it.m_id];
  26         int prev = this.(fld);
  27         int next = this.(fld) = ReadByte();
  28         LOG_TRACEF("%s: %.0f -> %.0f\n", it.m_name, prev, next);
  29     });
  30     return true;
  31 }
  32 #endif
  33
  34 #ifdef SVQC
  35 void Inventory_Write(Inventory data)
  36 {
  37     TC(Inventory, data);
  38     int bits = 0;
  39     FOREACH(Items, true, {
  40         .int fld = inv_items[it.m_id];
  41         bits = BITSET(bits, BIT(it.m_id), data.inventory.(fld) != (data.inventory.(fld) = data.(fld)));
  42     });
  43     WriteInt24_t(MSG_ENTITY, bits);
  44     FOREACH(Items, bits & BIT(it.m_id), {
  45         WriteByte(MSG_ENTITY, data.inv_items[it.m_id]);
  46     });
  47 }
  48 #endif
  49
  50 #ifdef SVQC
  51 bool Inventory_Send(Inventory this, Client to, int sf)
  52 {
  53     TC(Inventory, this);
  54     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
  55     entity e = this.owner;
  56     if (IS_SPEC(e)) e = e.enemy;
  57     TC(Player, e);
  58     Inventory data = e.inventory;
  59     Inventory_Write(data);
  60     return true;
  61 }
  62
  63 void Inventory_new(entity e)
  64 {
  65     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
  66     inv.inventory = bak;
  67     inv.drawonlytoclient = e;
  68     Net_LinkEntity((inv.owner = e).inventory = inv, false, 0, Inventory_Send);
  69 }
  70 void Inventory_delete(entity e) { remove(e.inventory.inventory); remove(e.inventory); }
  71 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
  72 #endif
  73
  74 #endif