qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //      SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float Monster_SkillModifier()
  45 {
  46         float t = 0.5+self.monster_skill*((1.2-0.3)/10);
  47
  48         return t;
  49 }
  50
  51 float monster_isvalidtarget (entity targ, entity ent)
  52 {
  53         if(!targ || !ent)
  54                 return FALSE; // someone doesn't exist
  55
  56         if(targ == ent)
  57                 return FALSE; // don't attack ourselves
  58
  59         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  60
  61         if(trace_ent != targ)
  62                 return FALSE;
  63
  64         if(targ.vehicle_flags & VHF_ISVEHICLE)
  65         if(!((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED))
  66                 return FALSE; // melee attacks are useless against vehicles
  67
  68         if(time < game_starttime)
  69                 return FALSE; // monsters do nothing before the match has started
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(targ.takedamage == DAMAGE_NO)
  75                 return FALSE; // enemy can't be damaged
  76
  77         if(targ.items & IT_INVISIBILITY)
  78                 return FALSE; // enemy is invisible
  79
  80         if(substring(targ.classname, 0, 10) == "onslaught_")
  81                 return FALSE; // don't attack onslaught targets
  82
  83         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  84                 return FALSE; // enemy is a spectator
  85
  86         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  87         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  88                 return FALSE; // enemy/self is dead
  89
  90         if(ent.monster_owner == targ)
  91                 return FALSE; // don't attack our master
  92
  93         if(targ.monster_owner == ent)
  94                 return FALSE; // don't attack our pet
  95
  96         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  97         if(targ.flags & FL_NOTARGET)
  98                 return FALSE; // enemy can't be targeted
  99
 100         if(!autocvar_g_monsters_typefrag)
 101         if(targ.BUTTON_CHAT)
 102                 return FALSE; // no typefragging!
 103
 104         if(SAME_TEAM(targ, ent))
 105                 return FALSE; // enemy is on our team
 106
 107         if (targ.frozen)
 108                 return FALSE; // ignore frozen
 109
 110         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 111         if(ent.enemy != targ)
 112         {
 113                 float dot;
 114
 115                 makevectors (ent.angles);
 116                 dot = normalize (targ.origin - ent.origin) * v_forward;
 117
 118                 if(dot <= 0.3)
 119                         return FALSE;
 120         }
 121
 122         return TRUE;
 123 }
 124
 125 entity FindTarget (entity ent)
 126 {
 127         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 128
 129         entity head, closest_target = world;
 130         head = findradius(ent.origin, ent.target_range);
 131
 132         while(head) // find the closest acceptable target to pass to
 133         {
 134                 if(head.monster_attack)
 135                 if(monster_isvalidtarget(head, ent))
 136                 {
 137                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 138                         vector head_center = CENTER_OR_VIEWOFS(head);
 139                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 140
 141                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 142                         if(closest_target)
 143                         {
 144                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 145                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 146                                         { closest_target = head; }
 147                         }
 148                         else { closest_target = head; }
 149                 }
 150
 151                 head = head.chain;
 152         }
 153
 154         return closest_target;
 155 }
 156
 157 void MonsterTouch ()
 158 {
 159         if(other == world)
 160                 return;
 161
 162         if(self.enemy != other)
 163         if(!(other.flags & FL_MONSTER))
 164         if(monster_isvalidtarget(other, self))
 165                 self.enemy = other;
 166 }
 167
 168 string get_monster_model_datafilename(string m, float sk, string fil)
 169 {
 170         if(m)
 171                 m = strcat(m, "_");
 172         else
 173                 m = "models/monsters/*_";
 174         if(sk >= 0)
 175                 m = strcat(m, ftos(sk));
 176         else
 177                 m = strcat(m, "*");
 178         return strcat(m, ".", fil);
 179 }
 180
 181 void PrecacheMonsterSounds(string f)
 182 {
 183         float fh;
 184         string s;
 185         fh = fopen(f, FILE_READ);
 186         if(fh < 0)
 187                 return;
 188         while((s = fgets(fh)))
 189         {
 190                 if(tokenize_console(s) != 3)
 191                 {
 192                         dprint("Invalid sound info line: ", s, "\n");
 193                         continue;
 194                 }
 195                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 196         }
 197         fclose(fh);
 198 }
 199
 200 void precache_monstersounds()
 201 {
 202         string m = (get_monsterinfo(self.monsterid)).model;
 203         float globhandle, n, i;
 204         string f;
 205
 206         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 207         if (globhandle < 0)
 208                 return;
 209         n = search_getsize(globhandle);
 210         for (i = 0; i < n; ++i)
 211         {
 212                 //print(search_getfilename(globhandle, i), "\n");
 213                 f = search_getfilename(globhandle, i);
 214                 PrecacheMonsterSounds(f);
 215         }
 216         search_end(globhandle);
 217 }
 218
 219 void ClearMonsterSounds()
 220 {
 221 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 222         ALLMONSTERSOUNDS
 223 #undef _MSOUND
 224 }
 225
 226 .string GetMonsterSoundSampleField(string type)
 227 {
 228         GetMonsterSoundSampleField_notFound = 0;
 229         switch(type)
 230         {
 231 #define _MSOUND(m) case #m: return monstersound_##m;
 232                 ALLMONSTERSOUNDS
 233 #undef _MSOUND
 234         }
 235         GetMonsterSoundSampleField_notFound = 1;
 236         return string_null;
 237 }
 238
 239 float LoadMonsterSounds(string f, float first)
 240 {
 241         float fh;
 242         string s;
 243         var .string field;
 244         fh = fopen(f, FILE_READ);
 245         if(fh < 0)
 246         {
 247                 dprint("Monster sound file not found: ", f, "\n");
 248                 return 0;
 249         }
 250         while((s = fgets(fh)))
 251         {
 252                 if(tokenize_console(s) != 3)
 253                         continue;
 254                 field = GetMonsterSoundSampleField(argv(0));
 255                 if(GetMonsterSoundSampleField_notFound)
 256                         continue;
 257                 if(self.field)
 258                         strunzone(self.field);
 259                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 260         }
 261         fclose(fh);
 262         return 1;
 263 }
 264
 265 .float skin_for_monstersound;
 266 void UpdateMonsterSounds()
 267 {
 268         entity mon = get_monsterinfo(self.monsterid);
 269
 270         if(self.skin == self.skin_for_monstersound)
 271                 return;
 272         self.skin_for_monstersound = self.skin;
 273         ClearMonsterSounds();
 274         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 275         if(!autocvar_g_debug_defaultsounds)
 276         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 277                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 278 }
 279
 280 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 281 {
 282         if(delaytoo && time < self.msound_delay)
 283                 return; // too early
 284         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 285
 286         self.msound_delay = time + sound_delay;
 287 }
 288
 289 void monster_makevectors(entity e)
 290 {
 291         vector v;
 292
 293         v = e.origin + (e.mins + e.maxs) * 0.5;
 294         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 295         self.v_angle_x = -self.v_angle_x;
 296
 297         makevectors(self.v_angle);
 298 }
 299
 300 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 301 {
 302         if (self.health <= 0)
 303                 return FALSE; // attacking while dead?!
 304
 305         if(dostop)
 306         {
 307                 self.velocity_x = 0;
 308                 self.velocity_y = 0;
 309                 self.state = MONSTER_STATE_ATTACK_MELEE;
 310         }
 311
 312         self.frame = anim;
 313
 314         if(anim_finished != 0)
 315                 self.attack_finished_single = time + anim_finished;
 316
 317         monster_makevectors(targ);
 318
 319         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 320
 321         if(trace_ent.takedamage)
 322                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 323
 324         return TRUE;
 325 }
 326
 327 void Monster_CheckMinibossFlag ()
 328 {
 329         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 330                 return;
 331
 332         float chance = random() * 100;
 333
 334         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 335         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 336         {
 337                 self.health += autocvar_g_monsters_miniboss_healthboost;
 338                 self.effects |= EF_RED;
 339                 if(!self.weapon)
 340                         self.weapon = WEP_NEX;
 341         }
 342 }
 343
 344 float Monster_CanRespawn(entity ent)
 345 {
 346         other = ent;
 347         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 348         if(MUTATOR_CALLHOOK(MonsterRespawn))
 349                 return TRUE; // enabled by a mutator
 350
 351         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 352                 return FALSE;
 353
 354         if(!autocvar_g_monsters_respawn)
 355                 return FALSE;
 356
 357         return TRUE;
 358 }
 359
 360 void Monster_Fade ()
 361 {
 362         if(Monster_CanRespawn(self))
 363         {
 364                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 365                 self.think = self.monster_spawnfunc;
 366                 self.nextthink = time + self.respawntime;
 367                 self.ltime = 0;
 368                 self.deadflag = DEAD_RESPAWNING;
 369                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 370                 {
 371                         self.pos1 = self.origin;
 372                         self.pos2 = self.angles;
 373                 }
 374                 self.event_damage = func_null;
 375                 self.takedamage = DAMAGE_NO;
 376                 setorigin(self, self.pos1);
 377                 self.angles = self.pos2;
 378                 self.health = self.max_health;
 379                 setmodel(self, "null");
 380         }
 381         else
 382         {
 383                 // number of monsters spawned with mobspawn command
 384                 totalspawned -= 1;
 385
 386                 if(IS_CLIENT(self.realowner))
 387                         self.realowner.monstercount -= 1;
 388
 389                 SUB_SetFade(self, time + 3, 1);
 390         }
 391 }
 392
 393 float Monster_CanJump (vector vel)
 394 {
 395         if(self.state)
 396                 return FALSE; // already attacking
 397         if(!(self.flags & FL_ONGROUND))
 398                 return FALSE; // not on the ground
 399         if(self.health <= 0)
 400                 return FALSE; // called when dead?
 401         if(time < self.attack_finished_single)
 402                 return FALSE; // still attacking
 403
 404         vector old = self.velocity;
 405
 406         self.velocity = vel;
 407         tracetoss(self, self);
 408         self.velocity = old;
 409         if (trace_ent != self.enemy)
 410                 return FALSE;
 411
 412         return TRUE;
 413 }
 414
 415 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 416 {
 417         if(!Monster_CanJump(vel))
 418                 return FALSE;
 419
 420         self.frame = anm;
 421         self.state = MONSTER_STATE_ATTACK_LEAP;
 422         self.touch = touchfunc;
 423         self.origin_z += 1;
 424         self.velocity = vel;
 425         self.flags &= ~FL_ONGROUND;
 426
 427         self.attack_finished_single = time + anim_finished;
 428
 429         return TRUE;
 430 }
 431
 432 void monster_checkattack(entity e, entity targ)
 433 {
 434         if(e == world)
 435                 return;
 436         if(targ == world)
 437                 return;
 438
 439         if(!e.monster_attackfunc)
 440                 return;
 441
 442         if(time < e.attack_finished_single)
 443                 return;
 444
 445         if(vlen(targ.origin - e.origin) <= e.attack_range)
 446         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 447         {
 448                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 449                 return;
 450         }
 451
 452         if(vlen(targ.origin - e.origin) > e.attack_range)
 453         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 454         {
 455                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 456                 return;
 457         }
 458 }
 459
 460 void monster_use ()
 461 {
 462         if(!self.enemy)
 463         if(self.health > 0)
 464         if(monster_isvalidtarget(activator, self))
 465                 self.enemy = activator;
 466 }
 467
 468 .float last_trace;
 469 .float last_enemycheck; // for checking enemy
 470 vector monster_pickmovetarget(entity targ)
 471 {
 472         // enemy is always preferred target
 473         if(self.enemy)
 474         {
 475                 makevectors(self.angles);
 476                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 477                 self.last_trace = time + 1.2;
 478                 return self.enemy.origin;
 479         }
 480
 481         switch(self.monster_moveflags)
 482         {
 483                 case MONSTER_MOVE_OWNER:
 484                 {
 485                         self.monster_movestate = MONSTER_MOVE_OWNER;
 486                         self.last_trace = time + 0.3;
 487                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 488                 }
 489                 case MONSTER_MOVE_SPAWNLOC:
 490                 {
 491                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 492                         self.last_trace = time + 2;
 493                         return self.pos1;
 494                 }
 495                 case MONSTER_MOVE_NOMOVE:
 496                 {
 497                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 498                         self.last_trace = time + 2;
 499                         return self.origin;
 500                 }
 501                 default:
 502                 case MONSTER_MOVE_WANDER:
 503                 {
 504                         vector pos;
 505                         self.monster_movestate = MONSTER_MOVE_WANDER;
 506                         self.last_trace = time + 2;
 507
 508                         self.angles_y = rint(random() * 500);
 509                         makevectors(self.angles);
 510                         pos = self.origin + v_forward * 600;
 511
 512                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 513                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 514                         {
 515                                 pos_z = random() * 200;
 516                                 if(random() >= 0.5)
 517                                         pos_z *= -1;
 518                         }
 519
 520                         if(targ)
 521                         {
 522                                 self.last_trace = time + 0.5;
 523                                 pos = targ.origin;
 524                         }
 525
 526                         return pos;
 527                 }
 528         }
 529 }
 530
 531 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 532 {
 533         fixedmakevectors(self.angles);
 534
 535         if(self.target2)
 536                 self.goalentity = find(world, targetname, self.target2);
 537
 538         entity targ;
 539
 540         if(self.frozen == 2)
 541         {
 542                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 543                 self.health = max(1, self.revive_progress * self.max_health);
 544                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
 545
 546                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 547
 548                 movelib_beak_simple(stopspeed);
 549                 self.frame = manim_idle;
 550
 551                 self.enemy = world;
 552                 self.nextthink = time + self.ticrate;
 553
 554                 if(self.revive_progress >= 1)
 555                         Unfreeze(self);
 556
 557                 return;
 558         }
 559         else if(self.frozen == 3)
 560         {
 561                 self.revive_progress = bound(0, self.revive_progress - self.ticrate * self.revive_speed, 1);
 562                 self.health = max(0, autocvar_g_nades_ice_health + (self.max_health-autocvar_g_nades_ice_health) * self.revive_progress );
 563
 564                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 565
 566                 movelib_beak_simple(stopspeed);
 567                 self.frame = manim_idle;
 568
 569                 self.enemy = world;
 570                 self.nextthink = time + self.ticrate;
 571
 572                 if(self.health < 1)
 573                 {
 574                         Unfreeze(self);
 575                         self.health = 0;
 576                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
 577                 }
 578
 579                 else if ( self.revive_progress <= 0 )
 580                         Unfreeze(self);
 581
 582                 return;
 583         }
 584
 585         if(self.flags & FL_SWIM)
 586         {
 587                 if(self.waterlevel < WATERLEVEL_WETFEET)
 588                 {
 589                         if(time >= self.last_trace)
 590                         {
 591                                 self.fish_wasdrowning = TRUE;
 592                                 self.last_trace = time + 0.4;
 593
 594                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 595                                 self.angles = '90 90 0';
 596                                 if(random() < 0.5)
 597                                 {
 598                                         self.velocity_y += random() * 50;
 599                                         self.velocity_x -= random() * 50;
 600                                 }
 601                                 else
 602                                 {
 603                                         self.velocity_y -= random() * 50;
 604                                         self.velocity_x += random() * 50;
 605                                 }
 606                                 self.velocity_z += random() * 150;
 607                         }
 608
 609
 610                         self.movetype = MOVETYPE_BOUNCE;
 611                         //self.velocity_z = -200;
 612
 613                         return;
 614                 }
 615                 else if(self.fish_wasdrowning)
 616                 {
 617                         self.fish_wasdrowning = FALSE;
 618                         self.angles_x = 0;
 619                         self.movetype = MOVETYPE_WALK;
 620                 }
 621         }
 622
 623         targ = self.goalentity;
 624
 625         monster_target = targ;
 626         monster_speed_run = runspeed;
 627         monster_speed_walk = walkspeed;
 628
 629         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 630         {
 631                 runspeed = walkspeed = 0;
 632                 if(time >= self.spawn_time)
 633                         self.frame = manim_idle;
 634                 movelib_beak_simple(stopspeed);
 635                 return;
 636         }
 637
 638         targ = monster_target;
 639         runspeed = bound(0, monster_speed_run * Monster_SkillModifier(), runspeed * 2); // limit maxspeed to prevent craziness
 640         walkspeed = bound(0, monster_speed_walk * Monster_SkillModifier(), walkspeed * 2); // limit maxspeed to prevent craziness
 641
 642         if(time < self.spider_slowness)
 643         {
 644                 runspeed *= 0.5;
 645                 walkspeed *= 0.5;
 646         }
 647
 648         if(teamplay)
 649         if(autocvar_g_monsters_teams)
 650         if(DIFF_TEAM(self.monster_owner, self))
 651                 self.monster_owner = world;
 652
 653         if(self.enemy && self.enemy.health < 1)
 654                 self.enemy = world; // enough!
 655
 656         if(time >= self.last_enemycheck)
 657         {
 658                 if(!monster_isvalidtarget(self.enemy, self))
 659                         self.enemy = world;
 660
 661                 if(!self.enemy)
 662                 {
 663                         self.enemy = FindTarget(self);
 664                         if(self.enemy)
 665                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 666                 }
 667
 668                 self.last_enemycheck = time + 0.5;
 669         }
 670
 671         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 672                 self.state = 0;
 673
 674         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 675         if(time >= self.last_trace || self.enemy) // update enemy instantly
 676                 self.moveto = monster_pickmovetarget(targ);
 677
 678         if(!self.enemy)
 679                 MonsterSound(monstersound_idle, 7, TRUE, CH_VOICE);
 680
 681         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 682                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 683
 684         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 685         {
 686                 self.state = 0;
 687                 self.touch = MonsterTouch;
 688         }
 689
 690         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 691
 692         float turny = 0;
 693         vector real_angle = vectoangles(self.steerto) - self.angles;
 694
 695         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 696                 turny = 20;
 697
 698         if(self.flags & FL_SWIM)
 699                 turny = vlen(self.angles - self.moveto);
 700
 701         if(turny)
 702         {
 703                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 704                 self.angles_y += turny;
 705         }
 706
 707         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 708                 self.moveto = self.origin;
 709
 710         if(self.enemy && self.enemy.vehicle)
 711                 runspeed = 0;
 712
 713         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 714                 v_forward = normalize(self.moveto - self.origin);
 715         else
 716                 self.moveto_z = self.origin_z;
 717
 718         if(vlen(self.origin - self.moveto) > 64)
 719         {
 720                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 721                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 722                 else
 723                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 724
 725                 if(time > self.pain_finished)
 726                 if(time > self.attack_finished_single)
 727                 if(vlen(self.velocity) > 10)
 728                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 729                 else
 730                         self.frame = manim_idle;
 731         }
 732         else
 733         {
 734                 entity e = find(world, targetname, self.target2);
 735                 if(e.target2)
 736                         self.target2 = e.target2;
 737                 else if(e.target)
 738                         self.target2 = e.target;
 739
 740                 movelib_beak_simple(stopspeed);
 741                 if(time > self.attack_finished_single)
 742                 if(time > self.pain_finished)
 743                 if (vlen(self.velocity) <= 30)
 744                         self.frame = manim_idle;
 745         }
 746
 747         monster_checkattack(self, self.enemy);
 748 }
 749
 750 void monster_remove(entity mon)
 751 {
 752         if(!mon)
 753                 return; // nothing to remove
 754
 755         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 756
 757         if(mon.weaponentity)
 758                 remove(mon.weaponentity);
 759
 760         if(mon.iceblock)
 761                 remove(mon.iceblock);
 762
 763         WaypointSprite_Kill(mon.sprite);
 764
 765         remove(mon);
 766 }
 767
 768 void monster_dead_think()
 769 {
 770         self.nextthink = time + self.ticrate;
 771
 772         CSQCMODEL_AUTOUPDATE();
 773
 774         if(self.ltime != 0)
 775         if(time >= self.ltime)
 776         {
 777                 Monster_Fade();
 778                 return;
 779         }
 780 }
 781
 782 void monsters_setstatus()
 783 {
 784         self.stat_monsters_total = monsters_total;
 785         self.stat_monsters_killed = monsters_killed;
 786 }
 787
 788 void Monster_Appear()
 789 {
 790         self.enemy = activator;
 791         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 792         self.monster_spawnfunc();
 793 }
 794
 795 float Monster_CheckAppearFlags(entity ent)
 796 {
 797         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 798                 return FALSE;
 799
 800         ent.think = func_null;
 801         ent.nextthink = 0;
 802         ent.use = Monster_Appear;
 803         ent.flags = FL_MONSTER; // set so this monster can get butchered
 804
 805         return TRUE;
 806 }
 807
 808 void monsters_reset()
 809 {
 810         setorigin(self, self.pos1);
 811         self.angles = self.pos2;
 812
 813         Unfreeze(self); // remove any icy remains
 814
 815         self.health = self.max_health;
 816         self.velocity = '0 0 0';
 817         self.enemy = world;
 818         self.goalentity = world;
 819         self.attack_finished_single = 0;
 820         self.moveto = self.origin;
 821 }
 822
 823 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 824 {
 825         self.health -= damage;
 826
 827         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 828
 829         if(self.health <= -100) // 100 health until gone?
 830         {
 831                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 832
 833                 // number of monsters spawned with mobspawn command
 834                 totalspawned -= 1;
 835
 836                 if(IS_CLIENT(self.realowner))
 837                         self.realowner.monstercount -= 1;
 838
 839                 self.think = SUB_Remove;
 840                 self.nextthink = time + 0.1;
 841         }
 842 }
 843
 844 void monster_die(entity attacker, float gibbed)
 845 {
 846         self.think = monster_dead_think;
 847         self.nextthink = time;
 848         self.ltime = time + 5;
 849
 850         if(self.frozen)
 851         {
 852                 Unfreeze(self); // remove any icy remains
 853                 self.health = 0; // reset by Unfreeze
 854         }
 855
 856         monster_dropitem();
 857
 858         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 859
 860         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
 861                 monsters_killed += 1;
 862
 863         if(IS_PLAYER(attacker))
 864         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
 865                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 866
 867         if(gibbed)
 868         {
 869                 // number of monsters spawned with mobspawn command
 870                 totalspawned -= 1;
 871
 872                 if(IS_CLIENT(self.realowner))
 873                         self.realowner.monstercount -= 1;
 874         }
 875
 876         if(self.candrop && self.weapon)
 877                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 878
 879         self.event_damage       = monsters_corpse_damage;
 880         self.solid                      = SOLID_CORPSE;
 881         self.takedamage         = DAMAGE_AIM;
 882         self.deadflag           = DEAD_DEAD;
 883         self.enemy                      = world;
 884         self.movetype           = MOVETYPE_TOSS;
 885         self.moveto                     = self.origin;
 886         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 887         self.reset                      = func_null;
 888         self.state                      = 0;
 889         self.attack_finished_single = 0;
 890
 891         if(!(self.flags & FL_FLY))
 892                 self.velocity = '0 0 0';
 893
 894         MON_ACTION(self.monsterid, MR_DEATH);
 895 }
 896
 897 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 898 {
 899         if(self.frozen && deathtype != DEATH_KILL && deathtype != DEATH_NADE_ICE_FREEZE)
 900                 return;
 901
 902         if(time < self.pain_finished && deathtype != DEATH_KILL)
 903                 return;
 904
 905         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 906                 return;
 907
 908         vector v;
 909         float take, save;
 910
 911         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 912         take = v_x;
 913         save = v_y;
 914
 915         self.health -= take;
 916
 917         WaypointSprite_UpdateHealth(self.sprite, self.health);
 918
 919         self.dmg_time = time;
 920
 921         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 922                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 923
 924         self.velocity += force * self.damageforcescale;
 925
 926         if(deathtype != DEATH_DROWN)
 927         {
 928                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 929                 if (take > 50)
 930                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 931                 if (take > 100)
 932                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 933         }
 934
 935         if(self.health <= 0)
 936         {
 937                 if(deathtype == DEATH_KILL)
 938                         self.candrop = FALSE; // killed by mobkill command
 939
 940                 // TODO: fix this?
 941                 activator = attacker;
 942                 other = self.enemy;
 943                 SUB_UseTargets();
 944                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 945
 946                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 947
 948                 WaypointSprite_Kill(self.sprite);
 949
 950                 frag_attacker = attacker;
 951                 frag_target = self;
 952                 MUTATOR_CALLHOOK(MonsterDies);
 953
 954                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 955                 {
 956                         Violence_GibSplash(self, 1, 0.5, attacker);
 957
 958                         self.think = SUB_Remove;
 959                         self.nextthink = time + 0.1;
 960                 }
 961         }
 962 }
 963
 964 void monster_setupcolors()
 965 {
 966         if(IS_PLAYER(self.monster_owner))
 967                 self.colormap = self.monster_owner.colormap;
 968         else if(teamplay && self.team)
 969                 self.colormap = 1024 + (self.team - 1) * 17;
 970         else
 971         {
 972                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 973                         self.colormap = 1029;
 974                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 975                         self.colormap = 1027;
 976                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 977                         self.colormap = 1038;
 978                 else if(self.monster_skill <= MONSTER_SKILL_INSANE)
 979                         self.colormap = 1028;
 980                 else if(self.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 981                         self.colormap = 1032;
 982                 else
 983                         self.colormap = 1024;
 984         }
 985 }
 986
 987 void monster_think()
 988 {
 989         self.think = monster_think;
 990         self.nextthink = self.ticrate;
 991
 992         if(self.ltime)
 993         if(time >= self.ltime)
 994         {
 995                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 996                 return;
 997         }
 998
 999         MON_ACTION(self.monsterid, MR_THINK);
1000
1001         CSQCMODEL_AUTOUPDATE();
1002 }
1003
1004 float monster_spawn()
1005 {
1006         MON_ACTION(self.monsterid, MR_SETUP);
1007
1008         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1009         {
1010                 Monster_CheckMinibossFlag();
1011                 self.health *= Monster_SkillModifier();
1012         }
1013
1014         self.max_health = self.health;
1015         self.pain_finished = self.nextthink;
1016
1017         if(IS_PLAYER(self.monster_owner))
1018                 self.effects |= EF_DIMLIGHT;
1019
1020         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1021         if(!self.skin)
1022                 self.skin = rint(random() * 4);
1023
1024         if(!self.attack_range)
1025                 self.attack_range = autocvar_g_monsters_attack_range;
1026
1027         precache_monstersounds();
1028         UpdateMonsterSounds();
1029
1030         if(teamplay)
1031                 self.monster_attack = TRUE; // we can have monster enemies in team games
1032
1033         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1034
1035         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
1036         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
1037         WaypointSprite_UpdateHealth(self.sprite, self.health);
1038
1039         self.think = monster_think;
1040         self.nextthink = time + self.ticrate;
1041
1042         if(MUTATOR_CALLHOOK(MonsterSpawn))
1043                 return FALSE;
1044
1045         return TRUE;
1046 }
1047
1048 float monster_initialize(float mon_id, float nodrop)
1049 {
1050         if(!autocvar_g_monsters)
1051                 return FALSE;
1052
1053         entity mon = get_monsterinfo(mon_id);
1054
1055         if(!self.monster_skill)
1056                 self.monster_skill = cvar("g_monsters_skill");
1057
1058         // support for quake style removing monsters based on skill
1059         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1060         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1061         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1062
1063         if(self.team && !teamplay)
1064                 self.team = 0;
1065
1066         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1067         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1068                 monsters_total += 1;
1069
1070         setmodel(self, mon.model);
1071         setsize(self, mon.mins, mon.maxs);
1072         self.flags                              = FL_MONSTER;
1073         self.takedamage                 = DAMAGE_AIM;
1074         self.bot_attack                 = TRUE;
1075         self.iscreature                 = TRUE;
1076         self.teleportable               = TRUE;
1077         self.damagedbycontents  = TRUE;
1078         self.monsterid                  = mon_id;
1079         self.damageforcescale   = 0;
1080         self.event_damage               = monsters_damage;
1081         self.touch                              = MonsterTouch;
1082         self.use                                = monster_use;
1083         self.solid                              = SOLID_BBOX;
1084         self.movetype                   = MOVETYPE_WALK;
1085         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1086         self.enemy                              = world;
1087         self.velocity                   = '0 0 0';
1088         self.moveto                             = self.origin;
1089         self.pos1                               = self.origin;
1090         self.pos2                               = self.angles;
1091         self.reset                              = monsters_reset;
1092         self.netname                    = mon.netname;
1093         self.monster_name               = M_NAME(mon_id);
1094         self.candrop                    = TRUE;
1095         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1096         self.oldtarget2                 = self.target2;
1097         self.deadflag                   = DEAD_NO;
1098         self.scale                              = 1;
1099         self.noalign                    = nodrop;
1100         self.spawn_time                 = time;
1101         self.spider_slowness    = 0;
1102         self.gravity                    = 1;
1103         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1104
1105         if(autocvar_g_fullbrightplayers)
1106                 self.effects |= EF_FULLBRIGHT;
1107
1108         if(autocvar_g_nodepthtestplayers)
1109                 self.effects |= EF_NODEPTHTEST;
1110
1111         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1112                 self.flags |= FL_SWIM;
1113
1114         if(mon.spawnflags & MONSTER_TYPE_FLY)
1115         {
1116                 self.flags |= FL_FLY;
1117                 self.movetype = MOVETYPE_FLY;
1118         }
1119
1120         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1121                 self.scale = 1.3;
1122
1123         if(!self.ticrate)
1124                 self.ticrate = autocvar_g_monsters_think_delay;
1125
1126         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1127
1128         if(!self.m_armor_blockpercent)
1129                 self.m_armor_blockpercent = 0.5;
1130
1131         if(!self.target_range)
1132                 self.target_range = autocvar_g_monsters_target_range;
1133
1134         if(!self.respawntime)
1135                 self.respawntime = autocvar_g_monsters_respawn_delay;
1136
1137         if(!self.monster_moveflags)
1138                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1139
1140         if(!self.noalign)
1141         {
1142                 setorigin(self, self.origin + '0 0 20');
1143                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1144                 setorigin(self, trace_endpos);
1145         }
1146
1147         if(!monster_spawn())
1148                 return FALSE;
1149
1150         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1151                 monster_setupcolors();
1152
1153         CSQCMODEL_AUTOINIT();
1154
1155         return TRUE;
1156 }