qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //      SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float Monster_SkillModifier()
  45 {
  46         float t = 0.5+self.monster_skill*((1.2-0.3)/10);
  47
  48         return t;
  49 }
  50
  51 float monster_isvalidtarget (entity targ, entity ent)
  52 {
  53         if(!targ || !ent)
  54                 return FALSE; // someone doesn't exist
  55
  56         if(targ == ent)
  57                 return FALSE; // don't attack ourselves
  58
  59         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  60
  61         if(trace_ent != targ)
  62                 return FALSE;
  63
  64         if(targ.vehicle_flags & VHF_ISVEHICLE)
  65         if(!((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED))
  66                 return FALSE; // melee attacks are useless against vehicles
  67
  68         if(time < game_starttime)
  69                 return FALSE; // monsters do nothing before the match has started
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(targ.takedamage == DAMAGE_NO)
  75                 return FALSE; // enemy can't be damaged
  76
  77         if(targ.items & IT_INVISIBILITY)
  78                 return FALSE; // enemy is invisible
  79
  80         if(substring(targ.classname, 0, 10) == "onslaught_")
  81                 return FALSE; // don't attack onslaught targets
  82
  83         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  84                 return FALSE; // enemy is a spectator
  85
  86         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  87         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  88                 return FALSE; // enemy/self is dead
  89
  90         if(ent.monster_owner == targ)
  91                 return FALSE; // don't attack our master
  92
  93         if(targ.monster_owner == ent)
  94                 return FALSE; // don't attack our pet
  95
  96         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  97         if(targ.flags & FL_NOTARGET)
  98                 return FALSE; // enemy can't be targeted
  99
 100         if(!autocvar_g_monsters_typefrag)
 101         if(targ.BUTTON_CHAT)
 102                 return FALSE; // no typefragging!
 103
 104         if(SAME_TEAM(targ, ent))
 105                 return FALSE; // enemy is on our team
 106
 107         if (targ.frozen)
 108                 return FALSE; // ignore frozen
 109
 110         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 111         if(ent.enemy != targ)
 112         {
 113                 float dot;
 114
 115                 makevectors (ent.angles);
 116                 dot = normalize (targ.origin - ent.origin) * v_forward;
 117
 118                 if(dot <= 0.3)
 119                         return FALSE;
 120         }
 121
 122         return TRUE;
 123 }
 124
 125 entity FindTarget (entity ent)
 126 {
 127         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 128
 129         entity head, closest_target = world;
 130         head = findradius(ent.origin, ent.target_range);
 131
 132         while(head) // find the closest acceptable target to pass to
 133         {
 134                 if(head.monster_attack)
 135                 if(monster_isvalidtarget(head, ent))
 136                 {
 137                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 138                         vector head_center = CENTER_OR_VIEWOFS(head);
 139                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 140
 141                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 142                         if(closest_target)
 143                         {
 144                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 145                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 146                                         { closest_target = head; }
 147                         }
 148                         else { closest_target = head; }
 149                 }
 150
 151                 head = head.chain;
 152         }
 153
 154         return closest_target;
 155 }
 156
 157 void MonsterTouch ()
 158 {
 159         if(other == world)
 160                 return;
 161
 162         if(self.enemy != other)
 163         if(!(other.flags & FL_MONSTER))
 164         if(monster_isvalidtarget(other, self))
 165                 self.enemy = other;
 166 }
 167
 168 string get_monster_model_datafilename(string m, float sk, string fil)
 169 {
 170         if(m)
 171                 m = strcat(m, "_");
 172         else
 173                 m = "models/monsters/*_";
 174         if(sk >= 0)
 175                 m = strcat(m, ftos(sk));
 176         else
 177                 m = strcat(m, "*");
 178         return strcat(m, ".", fil);
 179 }
 180
 181 void PrecacheMonsterSounds(string f)
 182 {
 183         float fh;
 184         string s;
 185         fh = fopen(f, FILE_READ);
 186         if(fh < 0)
 187                 return;
 188         while((s = fgets(fh)))
 189         {
 190                 if(tokenize_console(s) != 3)
 191                 {
 192                         dprint("Invalid sound info line: ", s, "\n");
 193                         continue;
 194                 }
 195                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 196         }
 197         fclose(fh);
 198 }
 199
 200 void precache_monstersounds()
 201 {
 202         string m = (get_monsterinfo(self.monsterid)).model;
 203         float globhandle, n, i;
 204         string f;
 205
 206         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 207         if (globhandle < 0)
 208                 return;
 209         n = search_getsize(globhandle);
 210         for (i = 0; i < n; ++i)
 211         {
 212                 //print(search_getfilename(globhandle, i), "\n");
 213                 f = search_getfilename(globhandle, i);
 214                 PrecacheMonsterSounds(f);
 215         }
 216         search_end(globhandle);
 217 }
 218
 219 void ClearMonsterSounds()
 220 {
 221 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 222         ALLMONSTERSOUNDS
 223 #undef _MSOUND
 224 }
 225
 226 .string GetMonsterSoundSampleField(string type)
 227 {
 228         GetMonsterSoundSampleField_notFound = 0;
 229         switch(type)
 230         {
 231 #define _MSOUND(m) case #m: return monstersound_##m;
 232                 ALLMONSTERSOUNDS
 233 #undef _MSOUND
 234         }
 235         GetMonsterSoundSampleField_notFound = 1;
 236         return string_null;
 237 }
 238
 239 float LoadMonsterSounds(string f, float first)
 240 {
 241         float fh;
 242         string s;
 243         var .string field;
 244         fh = fopen(f, FILE_READ);
 245         if(fh < 0)
 246         {
 247                 dprint("Monster sound file not found: ", f, "\n");
 248                 return 0;
 249         }
 250         while((s = fgets(fh)))
 251         {
 252                 if(tokenize_console(s) != 3)
 253                         continue;
 254                 field = GetMonsterSoundSampleField(argv(0));
 255                 if(GetMonsterSoundSampleField_notFound)
 256                         continue;
 257                 if(self.field)
 258                         strunzone(self.field);
 259                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 260         }
 261         fclose(fh);
 262         return 1;
 263 }
 264
 265 .float skin_for_monstersound;
 266 void UpdateMonsterSounds()
 267 {
 268         entity mon = get_monsterinfo(self.monsterid);
 269
 270         if(self.skin == self.skin_for_monstersound)
 271                 return;
 272         self.skin_for_monstersound = self.skin;
 273         ClearMonsterSounds();
 274         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 275         if(!autocvar_g_debug_defaultsounds)
 276         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 277                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 278 }
 279
 280 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 281 {
 282         if(delaytoo && time < self.msound_delay)
 283                 return; // too early
 284         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 285
 286         self.msound_delay = time + sound_delay;
 287 }
 288
 289 void monster_makevectors(entity e)
 290 {
 291         vector v;
 292
 293         v = e.origin + (e.mins + e.maxs) * 0.5;
 294         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 295         self.v_angle_x = -self.v_angle_x;
 296
 297         makevectors(self.v_angle);
 298 }
 299
 300 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 301 {
 302         if (self.health <= 0)
 303                 return FALSE; // attacking while dead?!
 304
 305         if(dostop)
 306         {
 307                 self.velocity_x = 0;
 308                 self.velocity_y = 0;
 309                 self.state = MONSTER_STATE_ATTACK_MELEE;
 310         }
 311
 312         self.frame = anim;
 313
 314         if(anim_finished != 0)
 315                 self.attack_finished_single = time + anim_finished;
 316
 317         monster_makevectors(targ);
 318
 319         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 320
 321         if(trace_ent.takedamage)
 322                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 323
 324         return TRUE;
 325 }
 326
 327 void Monster_CheckMinibossFlag ()
 328 {
 329         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 330                 return;
 331
 332         float chance = random() * 100;
 333
 334         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 335         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 336         {
 337                 self.health += autocvar_g_monsters_miniboss_healthboost;
 338                 self.effects |= EF_RED;
 339                 if(!self.weapon)
 340                         self.weapon = WEP_NEX;
 341         }
 342 }
 343
 344 float Monster_CanRespawn(entity ent)
 345 {
 346         other = ent;
 347         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 348         if(MUTATOR_CALLHOOK(MonsterRespawn))
 349                 return TRUE; // enabled by a mutator
 350
 351         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 352                 return FALSE;
 353
 354         if(!autocvar_g_monsters_respawn)
 355                 return FALSE;
 356
 357         return TRUE;
 358 }
 359
 360 void Monster_Fade ()
 361 {
 362         if(Monster_CanRespawn(self))
 363         {
 364                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 365                 self.think = self.monster_spawnfunc;
 366                 self.nextthink = time + self.respawntime;
 367                 self.ltime = 0;
 368                 self.deadflag = DEAD_RESPAWNING;
 369                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 370                 {
 371                         self.pos1 = self.origin;
 372                         self.pos2 = self.angles;
 373                 }
 374                 self.event_damage = func_null;
 375                 self.takedamage = DAMAGE_NO;
 376                 setorigin(self, self.pos1);
 377                 self.angles = self.pos2;
 378                 self.health = self.max_health;
 379                 setmodel(self, "null");
 380         }
 381         else
 382         {
 383                 // number of monsters spawned with mobspawn command
 384                 totalspawned -= 1;
 385
 386                 if(IS_CLIENT(self.realowner))
 387                 if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 388                                 self.realowner.monstercount -= 1;
 389
 390                 SUB_SetFade(self, time + 3, 1);
 391         }
 392 }
 393
 394 float Monster_CanJump (vector vel)
 395 {
 396         if(self.state)
 397                 return FALSE; // already attacking
 398         if(!(self.flags & FL_ONGROUND))
 399                 return FALSE; // not on the ground
 400         if(self.health <= 0)
 401                 return FALSE; // called when dead?
 402         if(time < self.attack_finished_single)
 403                 return FALSE; // still attacking
 404
 405         vector old = self.velocity;
 406
 407         self.velocity = vel;
 408         tracetoss(self, self);
 409         self.velocity = old;
 410         if (trace_ent != self.enemy)
 411                 return FALSE;
 412
 413         return TRUE;
 414 }
 415
 416 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 417 {
 418         if(!Monster_CanJump(vel))
 419                 return FALSE;
 420
 421         self.frame = anm;
 422         self.state = MONSTER_STATE_ATTACK_LEAP;
 423         self.touch = touchfunc;
 424         self.origin_z += 1;
 425         self.velocity = vel;
 426         self.flags &= ~FL_ONGROUND;
 427
 428         self.attack_finished_single = time + anim_finished;
 429
 430         return TRUE;
 431 }
 432
 433 void monster_checkattack(entity e, entity targ)
 434 {
 435         if(e == world)
 436                 return;
 437         if(targ == world)
 438                 return;
 439
 440         if(!e.monster_attackfunc)
 441                 return;
 442
 443         if(time < e.attack_finished_single)
 444                 return;
 445
 446         if(vlen(targ.origin - e.origin) <= e.attack_range)
 447         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 448         {
 449                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 450                 return;
 451         }
 452
 453         if(vlen(targ.origin - e.origin) > e.attack_range)
 454         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 455         {
 456                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 457                 return;
 458         }
 459 }
 460
 461 void monster_use ()
 462 {
 463         if(!self.enemy)
 464         if(self.health > 0)
 465         if(monster_isvalidtarget(activator, self))
 466                 self.enemy = activator;
 467 }
 468
 469 .float last_trace;
 470 .float last_enemycheck; // for checking enemy
 471 vector monster_pickmovetarget(entity targ)
 472 {
 473         // enemy is always preferred target
 474         if(self.enemy)
 475         {
 476                 makevectors(self.angles);
 477                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 478                 self.last_trace = time + 1.2;
 479                 return self.enemy.origin;
 480         }
 481
 482         switch(self.monster_moveflags)
 483         {
 484                 case MONSTER_MOVE_OWNER:
 485                 {
 486                         self.monster_movestate = MONSTER_MOVE_OWNER;
 487                         self.last_trace = time + 0.3;
 488                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 489                 }
 490                 case MONSTER_MOVE_SPAWNLOC:
 491                 {
 492                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 493                         self.last_trace = time + 2;
 494                         return self.pos1;
 495                 }
 496                 case MONSTER_MOVE_NOMOVE:
 497                 {
 498                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 499                         self.last_trace = time + 2;
 500                         return self.origin;
 501                 }
 502                 default:
 503                 case MONSTER_MOVE_WANDER:
 504                 {
 505                         vector pos;
 506                         self.monster_movestate = MONSTER_MOVE_WANDER;
 507                         self.last_trace = time + 2;
 508
 509                         self.angles_y = rint(random() * 500);
 510                         makevectors(self.angles);
 511                         pos = self.origin + v_forward * 600;
 512
 513                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 514                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 515                         {
 516                                 pos_z = random() * 200;
 517                                 if(random() >= 0.5)
 518                                         pos_z *= -1;
 519                         }
 520
 521                         if(targ)
 522                         {
 523                                 self.last_trace = time + 0.5;
 524                                 pos = targ.origin;
 525                         }
 526
 527                         return pos;
 528                 }
 529         }
 530 }
 531
 532 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 533 {
 534         fixedmakevectors(self.angles);
 535
 536         if(self.target2)
 537                 self.goalentity = find(world, targetname, self.target2);
 538
 539         entity targ;
 540
 541         if(self.frozen)
 542         {
 543                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 544                 self.health = max(1, self.max_health * self.revive_progress);
 545
 546                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 547
 548                 movelib_beak_simple(stopspeed);
 549
 550                 self.frame = manim_idle;
 551
 552                 self.enemy = world;
 553                 self.nextthink = time + self.ticrate;
 554
 555                 if(self.revive_progress >= 1)
 556                         Unfreeze(self); // wait for next think before attacking
 557
 558                 return; // no moving while frozen
 559         }
 560
 561         if(self.flags & FL_SWIM)
 562         {
 563                 if(self.waterlevel < WATERLEVEL_WETFEET)
 564                 {
 565                         if(time >= self.last_trace)
 566                         {
 567                                 self.fish_wasdrowning = TRUE;
 568                                 self.last_trace = time + 0.4;
 569
 570                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 571                                 self.angles = '90 90 0';
 572                                 if(random() < 0.5)
 573                                 {
 574                                         self.velocity_y += random() * 50;
 575                                         self.velocity_x -= random() * 50;
 576                                 }
 577                                 else
 578                                 {
 579                                         self.velocity_y -= random() * 50;
 580                                         self.velocity_x += random() * 50;
 581                                 }
 582                                 self.velocity_z += random() * 150;
 583                         }
 584
 585
 586                         self.movetype = MOVETYPE_BOUNCE;
 587                         //self.velocity_z = -200;
 588
 589                         return;
 590                 }
 591                 else if(self.fish_wasdrowning)
 592                 {
 593                         self.fish_wasdrowning = FALSE;
 594                         self.angles_x = 0;
 595                         self.movetype = MOVETYPE_WALK;
 596                 }
 597         }
 598
 599         targ = self.goalentity;
 600
 601         monster_target = targ;
 602         monster_speed_run = runspeed;
 603         monster_speed_walk = walkspeed;
 604
 605         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 606         {
 607                 runspeed = walkspeed = 0;
 608                 if(time >= self.spawn_time)
 609                         self.frame = manim_idle;
 610                 movelib_beak_simple(stopspeed);
 611                 return;
 612         }
 613
 614         targ = monster_target;
 615         runspeed = bound(0, monster_speed_run * Monster_SkillModifier(), runspeed * 2); // limit maxspeed to prevent craziness
 616         walkspeed = bound(0, monster_speed_walk * Monster_SkillModifier(), walkspeed * 2); // limit maxspeed to prevent craziness
 617
 618         if(time < self.spider_slowness)
 619         {
 620                 runspeed *= 0.5;
 621                 walkspeed *= 0.5;
 622         }
 623
 624         if(teamplay)
 625         if(autocvar_g_monsters_teams)
 626         if(DIFF_TEAM(self.monster_owner, self))
 627                 self.monster_owner = world;
 628
 629         if(self.enemy && self.enemy.health < 1)
 630                 self.enemy = world; // enough!
 631
 632         if(time >= self.last_enemycheck)
 633         {
 634                 if(!monster_isvalidtarget(self.enemy, self))
 635                         self.enemy = world;
 636
 637                 if(!self.enemy)
 638                 {
 639                         self.enemy = FindTarget(self);
 640                         if(self.enemy)
 641                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 642                 }
 643
 644                 self.last_enemycheck = time + 0.5;
 645         }
 646
 647         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 648                 self.state = 0;
 649
 650         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 651         if(time >= self.last_trace || self.enemy) // update enemy instantly
 652                 self.moveto = monster_pickmovetarget(targ);
 653
 654         if(!self.enemy)
 655                 MonsterSound(monstersound_idle, 7, TRUE, CH_VOICE);
 656
 657         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 658                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 659
 660         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 661         {
 662                 self.state = 0;
 663                 self.touch = MonsterTouch;
 664         }
 665
 666         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 667
 668         float turny = 0;
 669         vector real_angle = vectoangles(self.steerto) - self.angles;
 670
 671         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 672                 turny = 20;
 673
 674         if(self.flags & FL_SWIM)
 675                 turny = vlen(self.angles - self.moveto);
 676
 677         if(turny)
 678         {
 679                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 680                 self.angles_y += turny;
 681         }
 682
 683         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 684                 self.moveto = self.origin;
 685
 686         if(self.enemy && self.enemy.vehicle)
 687                 runspeed = 0;
 688
 689         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 690                 v_forward = normalize(self.moveto - self.origin);
 691         else
 692                 self.moveto_z = self.origin_z;
 693
 694         if(vlen(self.origin - self.moveto) > 64)
 695         {
 696                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 697                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 698                 else
 699                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 700
 701                 if(time > self.pain_finished)
 702                 if(time > self.attack_finished_single)
 703                 if(vlen(self.velocity) > 10)
 704                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 705                 else
 706                         self.frame = manim_idle;
 707         }
 708         else
 709         {
 710                 entity e = find(world, targetname, self.target2);
 711                 if(e.target2)
 712                         self.target2 = e.target2;
 713                 else if(e.target)
 714                         self.target2 = e.target;
 715
 716                 movelib_beak_simple(stopspeed);
 717                 if(time > self.attack_finished_single)
 718                 if(time > self.pain_finished)
 719                 if (vlen(self.velocity) <= 30)
 720                         self.frame = manim_idle;
 721         }
 722
 723         monster_checkattack(self, self.enemy);
 724 }
 725
 726 void monster_remove(entity mon)
 727 {
 728         if(!mon)
 729                 return; // nothing to remove
 730
 731         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 732
 733         if(mon.weaponentity)
 734                 remove(mon.weaponentity);
 735
 736         if(mon.iceblock)
 737                 remove(mon.iceblock);
 738
 739         WaypointSprite_Kill(mon.sprite);
 740
 741         remove(mon);
 742 }
 743
 744 void monster_dead_think()
 745 {
 746         self.nextthink = time + self.ticrate;
 747
 748         CSQCMODEL_AUTOUPDATE();
 749
 750         if(self.ltime != 0)
 751         if(time >= self.ltime)
 752         {
 753                 Monster_Fade();
 754                 return;
 755         }
 756 }
 757
 758 void monsters_setstatus()
 759 {
 760         self.stat_monsters_total = monsters_total;
 761         self.stat_monsters_killed = monsters_killed;
 762 }
 763
 764 void Monster_Appear()
 765 {
 766         self.enemy = activator;
 767         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 768         self.monster_spawnfunc();
 769 }
 770
 771 float Monster_CheckAppearFlags(entity ent)
 772 {
 773         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 774                 return FALSE;
 775
 776         ent.think = func_null;
 777         ent.nextthink = 0;
 778         ent.use = Monster_Appear;
 779         ent.flags = FL_MONSTER; // set so this monster can get butchered
 780
 781         return TRUE;
 782 }
 783
 784 void monsters_reset()
 785 {
 786         setorigin(self, self.pos1);
 787         self.angles = self.pos2;
 788
 789         Unfreeze(self); // remove any icy remains
 790
 791         self.health = self.max_health;
 792         self.velocity = '0 0 0';
 793         self.enemy = world;
 794         self.goalentity = world;
 795         self.attack_finished_single = 0;
 796         self.moveto = self.origin;
 797 }
 798
 799 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 800 {
 801         self.health -= damage;
 802
 803         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 804
 805         if(self.health <= -100) // 100 health until gone?
 806         {
 807                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 808
 809                 if(IS_CLIENT(self.realowner))
 810                 if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 811                         self.realowner.monstercount -= 1;
 812
 813                 self.think = SUB_Remove;
 814                 self.nextthink = time + 0.1;
 815         }
 816 }
 817
 818 void monster_die(entity attacker, float gibbed)
 819 {
 820         self.think = monster_dead_think;
 821         self.nextthink = time;
 822         self.ltime = time + 5;
 823
 824         if ( self.frozen )
 825         {
 826                 Unfreeze(self); // remove any icy remains
 827                 self.health = 0; // reset by Unfreeze
 828         }
 829
 830         monster_dropitem();
 831
 832         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 833
 834         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
 835                 monsters_killed += 1;
 836
 837         if(IS_PLAYER(attacker))
 838         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
 839                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 840
 841         if(!Monster_CanRespawn(self) && gibbed)
 842         {
 843                 // number of monsters spawned with mobspawn command
 844                 totalspawned -= 1;
 845
 846                 if(IS_CLIENT(self.realowner))
 847                 if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 848                         self.realowner.monstercount -= 1;
 849         }
 850
 851         if(self.candrop && self.weapon)
 852                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 853
 854         self.event_damage       = monsters_corpse_damage;
 855         self.solid                      = SOLID_CORPSE;
 856         self.takedamage         = DAMAGE_AIM;
 857         self.deadflag           = DEAD_DEAD;
 858         self.enemy                      = world;
 859         self.movetype           = MOVETYPE_TOSS;
 860         self.moveto                     = self.origin;
 861         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 862         self.reset                      = func_null;
 863         self.state                      = 0;
 864         self.attack_finished_single = 0;
 865
 866         if(!(self.flags & FL_FLY))
 867                 self.velocity = '0 0 0';
 868
 869         MON_ACTION(self.monsterid, MR_DEATH);
 870 }
 871
 872 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 873 {
 874
 875         if(self.frozen && deathtype != DEATH_KILL)
 876                 return;
 877
 878         if(time < self.pain_finished && deathtype != DEATH_KILL)
 879                 return;
 880
 881         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 882                 return;
 883
 884         vector v;
 885         float take, save;
 886
 887         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 888         take = v_x;
 889         save = v_y;
 890
 891         self.health -= take;
 892
 893         WaypointSprite_UpdateHealth(self.sprite, self.health);
 894
 895         self.dmg_time = time;
 896
 897         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 898                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 899
 900         self.velocity += force * self.damageforcescale;
 901
 902         if(deathtype != DEATH_DROWN)
 903         {
 904                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 905                 if (take > 50)
 906                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 907                 if (take > 100)
 908                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 909         }
 910
 911         if(self.health <= 0)
 912         {
 913                 if(deathtype == DEATH_KILL)
 914                         self.candrop = FALSE; // killed by mobkill command
 915
 916                 // TODO: fix this?
 917                 activator = attacker;
 918                 other = self.enemy;
 919                 SUB_UseTargets();
 920                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 921
 922                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 923
 924                 WaypointSprite_Kill(self.sprite);
 925
 926                 frag_attacker = attacker;
 927                 frag_target = self;
 928                 MUTATOR_CALLHOOK(MonsterDies);
 929
 930                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 931                 {
 932                         Violence_GibSplash(self, 1, 0.5, attacker);
 933
 934                         self.think = SUB_Remove;
 935                         self.nextthink = time + 0.1;
 936                 }
 937         }
 938 }
 939
 940 void monster_setupcolors()
 941 {
 942         if(IS_PLAYER(self.monster_owner))
 943                 self.colormap = self.monster_owner.colormap;
 944         else if(teamplay && self.team)
 945                 self.colormap = 1024 + (self.team - 1) * 17;
 946         else
 947         {
 948                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 949                         self.colormap = 1029;
 950                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 951                         self.colormap = 1027;
 952                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 953                         self.colormap = 1038;
 954                 else if(self.monster_skill <= MONSTER_SKILL_INSANE)
 955                         self.colormap = 1028;
 956                 else if(self.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 957                         self.colormap = 1032;
 958                 else
 959                         self.colormap = 1024;
 960         }
 961 }
 962
 963 void monster_think()
 964 {
 965         self.think = monster_think;
 966         self.nextthink = self.ticrate;
 967
 968         if(self.ltime)
 969         if(time >= self.ltime)
 970         {
 971                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 972                 return;
 973         }
 974
 975         MON_ACTION(self.monsterid, MR_THINK);
 976
 977         CSQCMODEL_AUTOUPDATE();
 978 }
 979
 980 float monster_spawn()
 981 {
 982         MON_ACTION(self.monsterid, MR_SETUP);
 983
 984         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 985         {
 986                 Monster_CheckMinibossFlag();
 987                 self.health *= Monster_SkillModifier();
 988         }
 989
 990         self.max_health = self.health;
 991         self.pain_finished = self.nextthink;
 992
 993         if(IS_PLAYER(self.monster_owner))
 994                 self.effects |= EF_DIMLIGHT;
 995
 996         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 997         if(!self.skin)
 998                 self.skin = rint(random() * 4);
 999
1000         if(!self.attack_range)
1001                 self.attack_range = autocvar_g_monsters_attack_range;
1002
1003         precache_monstersounds();
1004         UpdateMonsterSounds();
1005
1006         if(teamplay)
1007                 self.monster_attack = TRUE; // we can have monster enemies in team games
1008
1009         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1010
1011         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
1012         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
1013         WaypointSprite_UpdateHealth(self.sprite, self.health);
1014
1015         self.think = monster_think;
1016         self.nextthink = time + self.ticrate;
1017
1018         if(MUTATOR_CALLHOOK(MonsterSpawn))
1019                 return FALSE;
1020
1021         return TRUE;
1022 }
1023
1024 float monster_initialize(float mon_id, float nodrop)
1025 {
1026         if(!autocvar_g_monsters)
1027                 return FALSE;
1028
1029         entity mon = get_monsterinfo(mon_id);
1030
1031         if(!self.monster_skill)
1032                 self.monster_skill = cvar("g_monsters_skill");
1033
1034         // support for quake style removing monsters based on skill
1035         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1036         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1037         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1038
1039         if(self.team && !teamplay)
1040                 self.team = 0;
1041
1042         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1043         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1044                 monsters_total += 1;
1045
1046         setmodel(self, mon.model);
1047         setsize(self, mon.mins, mon.maxs);
1048         self.flags                              = FL_MONSTER;
1049         self.takedamage                 = DAMAGE_AIM;
1050         self.bot_attack                 = TRUE;
1051         self.iscreature                 = TRUE;
1052         self.teleportable               = TRUE;
1053         self.damagedbycontents  = TRUE;
1054         self.monsterid                  = mon_id;
1055         self.damageforcescale   = 0;
1056         self.event_damage               = monsters_damage;
1057         self.touch                              = MonsterTouch;
1058         self.use                                = monster_use;
1059         self.solid                              = SOLID_BBOX;
1060         self.movetype                   = MOVETYPE_WALK;
1061         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1062         self.enemy                              = world;
1063         self.velocity                   = '0 0 0';
1064         self.moveto                             = self.origin;
1065         self.pos1                               = self.origin;
1066         self.pos2                               = self.angles;
1067         self.reset                              = monsters_reset;
1068         self.netname                    = mon.netname;
1069         self.monster_name               = M_NAME(mon_id);
1070         self.candrop                    = TRUE;
1071         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1072         self.oldtarget2                 = self.target2;
1073         self.deadflag                   = DEAD_NO;
1074         self.scale                              = 1;
1075         self.noalign                    = nodrop;
1076         self.spawn_time                 = time;
1077         self.spider_slowness    = 0;
1078         self.gravity                    = 1;
1079         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1080
1081         if(autocvar_g_fullbrightplayers)
1082                 self.effects |= EF_FULLBRIGHT;
1083
1084         if(autocvar_g_nodepthtestplayers)
1085                 self.effects |= EF_NODEPTHTEST;
1086
1087         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1088                 self.flags |= FL_SWIM;
1089
1090         if(mon.spawnflags & MONSTER_TYPE_FLY)
1091         {
1092                 self.flags |= FL_FLY;
1093                 self.movetype = MOVETYPE_FLY;
1094         }
1095
1096         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1097                 self.scale = 1.3;
1098
1099         if(!self.ticrate)
1100                 self.ticrate = autocvar_g_monsters_think_delay;
1101
1102         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1103
1104         if(!self.m_armor_blockpercent)
1105                 self.m_armor_blockpercent = 0.5;
1106
1107         if(!self.target_range)
1108                 self.target_range = autocvar_g_monsters_target_range;
1109
1110         if(!self.respawntime)
1111                 self.respawntime = autocvar_g_monsters_respawn_delay;
1112
1113         if(!self.monster_moveflags)
1114                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1115
1116         if(!self.noalign)
1117         {
1118                 setorigin(self, self.origin + '0 0 20');
1119                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1120                 setorigin(self, trace_endpos);
1121         }
1122
1123         if(!monster_spawn())
1124                 return FALSE;
1125
1126         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1127                 monster_setupcolors();
1128
1129         CSQCMODEL_AUTOINIT();
1130
1131         return TRUE;
1132 }