qcsrc/common/mutators/mutator/nades/nades.qc

   1 #include "nades.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6 bool autocvar_g_nades_nade_small;
   7 float autocvar_g_nades_spread = 0.04;
   8 #endif
   9
  10 REGISTER_STAT(NADES_SMALL, int, autocvar_g_nades_nade_small)
  11
  12 #ifndef MENUQC
  13 entity Nade_TrailEffect(int proj, int nade_team)
  14 {
  15     switch (proj)
  16     {
  17         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
  18         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
  19     }
  20
  21     FOREACH(Nades, true, LAMBDA(
  22         for (int j = 0; j < 2; j++)
  23         {
  24             if (it.m_projectile[j] == proj)
  25             {
  26                 string trail = it.m_trail[j].eent_eff_name;
  27                 if (trail) return it.m_trail[j];
  28                 break;
  29             }
  30         }
  31     ));
  32
  33     return EFFECT_Null;
  34 }
  35 #endif
  36
  37 #ifdef CSQC
  38 REGISTER_MUTATOR(cl_nades, true);
  39 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
  40 {
  41         if (STAT(HEALING_ORB) > time)
  42         {
  43                 M_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
  44                 M_ARGV(1, float) = STAT(HEALING_ORB_ALPHA);
  45                 return true;
  46         }
  47         if (STAT(ENTRAP_ORB) > time)
  48         {
  49                 M_ARGV(0, vector) = NADE_TYPE_ENTRAP.m_color;
  50                 M_ARGV(1, float) = STAT(ENTRAP_ORB_ALPHA);
  51                 return true;
  52         }
  53         return false;
  54 }
  55 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
  56 {
  57         entity proj = M_ARGV(0, entity);
  58
  59         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  60         {
  61                 proj.modelindex = 0;
  62                 proj.traileffect = EFFECT_FIREBALL.m_id;
  63                 return true;
  64         }
  65         if (Nade_FromProjectile(proj.cnt) != NADE_TYPE_Null)
  66         {
  67                 setmodel(proj, MDL_PROJECTILE_NADE);
  68                 entity trail = Nade_TrailEffect(proj.cnt, proj.team);
  69                 if (trail.eent_eff_name) proj.traileffect = trail.m_id;
  70                 return true;
  71         }
  72 }
  73 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
  74 {
  75         entity proj = M_ARGV(0, entity);
  76
  77         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  78         {
  79                 loopsound(proj, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
  80                 proj.mins = '-16 -16 -16';
  81                 proj.maxs = '16 16 16';
  82         }
  83
  84         entity nade_type = Nade_FromProjectile(proj.cnt);
  85         if (nade_type == NADE_TYPE_Null) return;
  86         if(STAT(NADES_SMALL, NULL))
  87         {
  88                 proj.mins = '-8 -8 -8';
  89                 proj.maxs = '8 8 8';
  90         }
  91         else
  92         {
  93                 proj.mins = '-16 -16 -16';
  94                 proj.maxs = '16 16 16';
  95         }
  96         proj.colormod = nade_type.m_color;
  97         set_movetype(proj, MOVETYPE_BOUNCE);
  98         settouch(proj, func_null);
  99         proj.scale = 1.5;
 100         proj.avelocity = randomvec() * 720;
 101
 102         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 103                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 104         else
 105                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 106 }
 107 bool Projectile_isnade(int p)
 108 {
 109         return Nade_FromProjectile(p) != NADE_TYPE_Null;
 110 }
 111 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 112 {
 113         float bonusNades    = STAT(NADE_BONUS);
 114         float bonusProgress = STAT(NADE_BONUS_SCORE);
 115         float bonusType     = STAT(NADE_BONUS_TYPE);
 116         Nade def = Nades_from(bonusType);
 117         vector nadeColor    = def.m_color;
 118         string nadeIcon     = def.m_icon;
 119
 120         vector iconPos, textPos;
 121
 122         if(autocvar_hud_panel_ammo_iconalign)
 123         {
 124                 iconPos = myPos + eX * 2 * mySize.y;
 125                 textPos = myPos;
 126         }
 127         else
 128         {
 129                 iconPos = myPos;
 130                 textPos = myPos + eX * mySize.y;
 131         }
 132
 133         if(bonusNades > 0 || bonusProgress > 0)
 134         {
 135                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 136
 137                 if(autocvar_hud_panel_ammo_text)
 138                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 139
 140                 if(draw_expanding)
 141                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 142
 143                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 144         }
 145 }
 146 #endif
 147
 148 #ifdef SVQC
 149
 150 #include <common/gamemodes/all.qh>
 151 #include <common/monsters/spawn.qh>
 152 #include <common/monsters/sv_monsters.qh>
 153 #include <server/g_subs.qh>
 154
 155 REGISTER_MUTATOR(nades, cvar("g_nades"));
 156
 157 .float nade_time_primed;
 158
 159 .entity nade_spawnloc;
 160
 161 void nade_timer_think(entity this)
 162 {
 163         this.skin = 8 - (this.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
 164         this.nextthink = time;
 165         if(!this.owner || wasfreed(this.owner))
 166                 remove(this);
 167 }
 168
 169 void nade_burn_spawn(entity _nade)
 170 {
 171         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[true], true);
 172 }
 173
 174 void nade_spawn(entity _nade)
 175 {
 176         entity timer = new(nade_timer);
 177         setmodel(timer, MDL_NADE_TIMER);
 178         setattachment(timer, _nade, "");
 179         timer.colormap = _nade.colormap;
 180         timer.glowmod = _nade.glowmod;
 181         setthink(timer, nade_timer_think);
 182         timer.nextthink = time;
 183         timer.wait = _nade.wait;
 184         timer.owner = _nade;
 185         timer.skin = 10;
 186
 187         _nade.effects |= EF_LOWPRECISION;
 188
 189         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[false], true);
 190 }
 191
 192 void napalm_damage(entity this, float dist, float damage, float edgedamage, float burntime)
 193 {
 194         entity e;
 195         float d;
 196         vector p;
 197
 198         if ( damage < 0 )
 199                 return;
 200
 201         RandomSelection_Init();
 202         for(e = WarpZone_FindRadius(this.origin, dist, true); e; e = e.chain)
 203                 if(e.takedamage == DAMAGE_AIM)
 204                 if(this.realowner != e || autocvar_g_nades_napalm_selfdamage)
 205                 if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
 206                 if(!STAT(FROZEN, e))
 207                 {
 208                         p = e.origin;
 209                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 210                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 211                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 212                         d = vlen(WarpZone_UnTransformOrigin(e, this.origin) - p);
 213                         if(d < dist)
 214                         {
 215                                 e.fireball_impactvec = p;
 216                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
 217                         }
 218                 }
 219         if(RandomSelection_chosen_ent)
 220         {
 221                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, this.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 222                 d = damage + (edgedamage - damage) * (d / dist);
 223                 Fire_AddDamage(RandomSelection_chosen_ent, this.realowner, d * burntime, burntime, this.projectiledeathtype | HITTYPE_BOUNCE);
 224                 //trailparticles(this, particleeffectnum(EFFECT_FIREBALL_LASER), this.origin, RandomSelection_chosen_ent.fireball_impactvec);
 225                 Send_Effect(EFFECT_FIREBALL_LASER, this.origin, RandomSelection_chosen_ent.fireball_impactvec - this.origin, 1);
 226         }
 227 }
 228
 229
 230 void napalm_ball_think(entity this)
 231 {
 232         if(round_handler_IsActive())
 233         if(!round_handler_IsRoundStarted())
 234         {
 235                 remove(this);
 236                 return;
 237         }
 238
 239         if(time > this.pushltime)
 240         {
 241                 remove(this);
 242                 return;
 243         }
 244
 245         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 246         if(pointcontents(midpoint) == CONTENT_WATER)
 247         {
 248                 this.velocity = this.velocity * 0.5;
 249
 250                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 251                         { this.velocity_z = 200; }
 252         }
 253
 254         this.angles = vectoangles(this.velocity);
 255
 256         napalm_damage(this, autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 257                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 258
 259         this.nextthink = time + 0.1;
 260 }
 261
 262
 263 void nade_napalm_ball(entity this)
 264 {
 265         entity proj;
 266         vector kick;
 267
 268         spamsound(this, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
 269
 270         proj = new(grenade);
 271         proj.owner = this.owner;
 272         proj.realowner = this.realowner;
 273         proj.team = this.owner.team;
 274         proj.bot_dodge = true;
 275         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 276         set_movetype(proj, MOVETYPE_BOUNCE);
 277         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 278         PROJECTILE_MAKETRIGGER(proj);
 279         setmodel(proj, MDL_Null);
 280         proj.scale = 1;//0.5;
 281         setsize(proj, '-4 -4 -4', '4 4 4');
 282         setorigin(proj, this.origin);
 283         setthink(proj, napalm_ball_think);
 284         proj.nextthink = time;
 285         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 286         proj.effects = EF_LOWPRECISION | EF_FLAME;
 287
 288         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 289         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 290         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 291         proj.velocity = kick;
 292
 293         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 294
 295         proj.angles = vectoangles(proj.velocity);
 296         proj.flags = FL_PROJECTILE;
 297         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 298
 299         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 300 }
 301
 302
 303 void napalm_fountain_think(entity this)
 304 {
 305
 306         if(round_handler_IsActive())
 307         if(!round_handler_IsRoundStarted())
 308         {
 309                 remove(this);
 310                 return;
 311         }
 312
 313         if(time >= this.ltime)
 314         {
 315                 remove(this);
 316                 return;
 317         }
 318
 319         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 320         if(pointcontents(midpoint) == CONTENT_WATER)
 321         {
 322                 this.velocity = this.velocity * 0.5;
 323
 324                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 325                         { this.velocity_z = 200; }
 326
 327                 UpdateCSQCProjectile(this);
 328         }
 329
 330         napalm_damage(this, autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 331                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 332
 333         this.nextthink = time + 0.1;
 334         if(time >= this.nade_special_time)
 335         {
 336                 this.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 337                 nade_napalm_ball(this);
 338         }
 339 }
 340
 341 void nade_napalm_boom(entity this)
 342 {
 343         entity fountain;
 344         int c;
 345         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 346                 nade_napalm_ball(this);
 347
 348
 349         fountain = spawn();
 350         fountain.owner = this.owner;
 351         fountain.realowner = this.realowner;
 352         fountain.origin = this.origin;
 353         setorigin(fountain, fountain.origin);
 354         setthink(fountain, napalm_fountain_think);
 355         fountain.nextthink = time;
 356         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 357         fountain.pushltime = fountain.ltime;
 358         fountain.team = this.team;
 359         set_movetype(fountain, MOVETYPE_TOSS);
 360         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 361         fountain.bot_dodge = true;
 362         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 363         fountain.nade_special_time = time;
 364         setsize(fountain, '-16 -16 -16', '16 16 16');
 365         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 366 }
 367
 368 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 369 {
 370         frost_target.frozen_by = freezefield.realowner;
 371         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 372         Freeze(frost_target, 1/freeze_time, 3, false);
 373
 374         Drop_Special_Items(frost_target);
 375 }
 376
 377 void nade_ice_think(entity this)
 378 {
 379         if(round_handler_IsActive())
 380         if(!round_handler_IsRoundStarted())
 381         {
 382                 remove(this);
 383                 return;
 384         }
 385
 386         if(time >= this.ltime)
 387         {
 388                 if ( autocvar_g_nades_ice_explode )
 389                 {
 390                         entity expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 391                         Send_Effect(expef, this.origin + '0 0 1', '0 0 0', 1);
 392                         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 393
 394                         RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 395                                 autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 396                         Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 397                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 398                 }
 399                 remove(this);
 400                 return;
 401         }
 402
 403
 404         this.nextthink = time+0.1;
 405
 406         // gaussian
 407         float randomr;
 408         randomr = random();
 409         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 410         float randomw;
 411         randomw = random()*M_PI*2;
 412         vector randomp;
 413         randomp.x = randomr*cos(randomw);
 414         randomp.y = randomr*sin(randomw);
 415         randomp.z = 1;
 416         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, this.origin + randomp, '0 0 0', 1);
 417
 418         if(time >= this.nade_special_time)
 419         {
 420                 this.nade_special_time = time+0.7;
 421
 422                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 423                 Send_Effect(EFFECT_ICEFIELD, this.origin, '0 0 0', 1);
 424         }
 425
 426
 427         float current_freeze_time = this.ltime - time - 0.1;
 428
 429         FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_nades_nade_radius, it != this && it.takedamage && !IS_DEAD(it) && it.health > 0 && current_freeze_time > 0,
 430         {
 431                 if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(it, this.realowner) || it == this.realowner))
 432                 if(!it.revival_time || ((time - it.revival_time) >= 1.5))
 433                 if(!STAT(FROZEN, it))
 434                         nade_ice_freeze(this, it, current_freeze_time);
 435         });
 436 }
 437
 438 void nade_ice_boom(entity this)
 439 {
 440         entity fountain;
 441         fountain = spawn();
 442         fountain.owner = this.owner;
 443         fountain.realowner = this.realowner;
 444         fountain.origin = this.origin;
 445         setorigin(fountain, fountain.origin);
 446         setthink(fountain, nade_ice_think);
 447         fountain.nextthink = time;
 448         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 449         fountain.pushltime = fountain.wait = fountain.ltime;
 450         fountain.team = this.team;
 451         set_movetype(fountain, MOVETYPE_TOSS);
 452         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
 453         fountain.bot_dodge = false;
 454         setsize(fountain, '-16 -16 -16', '16 16 16');
 455         fountain.nade_special_time = time+0.3;
 456         fountain.angles = this.angles;
 457
 458         if ( autocvar_g_nades_ice_explode )
 459         {
 460                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 461                 entity timer = new(nade_timer);
 462                 setmodel(timer, MDL_NADE_TIMER);
 463                 setattachment(timer, fountain, "");
 464                 timer.colormap = this.colormap;
 465                 timer.glowmod = this.glowmod;
 466                 setthink(timer, nade_timer_think);
 467                 timer.nextthink = time;
 468                 timer.wait = fountain.ltime;
 469                 timer.owner = fountain;
 470                 timer.skin = 10;
 471         }
 472         else
 473                 setmodel(fountain, MDL_Null);
 474 }
 475
 476 void nade_translocate_boom(entity this)
 477 {
 478         if(this.realowner.vehicle)
 479                 return;
 480
 481         vector locout = this.origin + '0 0 1' * (1 - this.realowner.mins.z - 24);
 482         tracebox(locout, this.realowner.mins, this.realowner.maxs, locout, MOVE_NOMONSTERS, this.realowner);
 483         locout = trace_endpos;
 484
 485         makevectors(this.realowner.angles);
 486
 487         MUTATOR_CALLHOOK(PortalTeleport, this.realowner);
 488
 489         TeleportPlayer(this, this.realowner, locout, this.realowner.angles, v_forward * vlen(this.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 490 }
 491
 492 void nade_spawn_boom(entity this)
 493 {
 494         entity spawnloc = spawn();
 495         setorigin(spawnloc, this.origin);
 496         setsize(spawnloc, this.realowner.mins, this.realowner.maxs);
 497         set_movetype(spawnloc, MOVETYPE_NONE);
 498         spawnloc.solid = SOLID_NOT;
 499         spawnloc.drawonlytoclient = this.realowner;
 500         spawnloc.effects = EF_STARDUST;
 501         spawnloc.cnt = autocvar_g_nades_spawn_count;
 502
 503         if(this.realowner.nade_spawnloc)
 504         {
 505                 remove(this.realowner.nade_spawnloc);
 506                 this.realowner.nade_spawnloc = NULL;
 507         }
 508
 509         this.realowner.nade_spawnloc = spawnloc;
 510 }
 511
 512 void nades_orb_think(entity this)
 513 {
 514         if(time >= this.ltime)
 515         {
 516                 remove(this);
 517                 return;
 518         }
 519
 520         this.nextthink = time;
 521
 522         if(time >= this.nade_special_time)
 523         {
 524                 this.nade_special_time = time+0.25;
 525                 this.nade_show_particles = 1;
 526         }
 527         else
 528                 this.nade_show_particles = 0;
 529 }
 530
 531 entity nades_spawn_orb(entity own, entity realown, vector org, float orb_ltime, float orb_rad)
 532 {
 533         // NOTE: this function merely places an orb
 534         // you must add a custom touch function to the returned entity if desired
 535         // also set .colormod if you wish to have it colorized
 536         entity orb = spawn(); // Net_LinkEntity sets the classname (TODO)
 537         orb.owner = own;
 538         orb.realowner = realown;
 539         setorigin(orb, org);
 540
 541         orb.orb_lifetime = orb_ltime; // required for timers
 542         orb.ltime = time + orb.orb_lifetime;
 543         orb.bot_dodge = false;
 544         orb.team = realown.team;
 545         orb.solid = SOLID_TRIGGER;
 546
 547         setmodel(orb, MDL_NADE_ORB);
 548         orb.skin = 1;
 549         orb.orb_radius = orb_rad; // required for fading
 550         vector size = '1 1 1' * orb.orb_radius / 2;
 551         setsize(orb, -size, size);
 552
 553         Net_LinkEntity(orb, true, 0, orb_send);
 554         orb.SendFlags |= 1;
 555
 556         setthink(orb, nades_orb_think);
 557         orb.nextthink = time;
 558
 559         return orb;
 560 }
 561
 562 void nade_entrap_touch(entity this, entity toucher)
 563 {
 564         if(DIFF_TEAM(toucher, this.realowner)) // TODO: what if realowner changes team or disconnects?
 565         {
 566                 if (!isPushable(toucher))
 567                         return;
 568
 569                 float pushdeltatime = time - toucher.lastpushtime;
 570                 if (pushdeltatime > 0.15) pushdeltatime = 0;
 571                 toucher.lastpushtime = time;
 572                 if(!pushdeltatime) return;
 573
 574                 // div0: ticrate independent, 1 = identity (not 20)
 575                 toucher.velocity = toucher.velocity * pow(autocvar_g_nades_entrap_strength, pushdeltatime);
 576
 577         #ifdef SVQC
 578                 UpdateCSQCProjectile(toucher);
 579         #endif
 580         }
 581
 582         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) || IS_MONSTER(toucher) )
 583         {
 584                 entity show_tint = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 585                 STAT(ENTRAP_ORB, show_tint) = time + 0.1;
 586
 587                 float tint_alpha = 0.75;
 588                 if(SAME_TEAM(toucher, this.realowner))
 589                         tint_alpha = 0.45;
 590                 STAT(ENTRAP_ORB_ALPHA, show_tint) = tint_alpha * (this.ltime - time) / this.orb_lifetime;
 591         }
 592 }
 593
 594 void nade_entrap_boom(entity this)
 595 {
 596         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_entrap_time, autocvar_g_nades_entrap_radius);
 597
 598         settouch(orb, nade_entrap_touch);
 599         orb.colormod = NADE_TYPE_ENTRAP.m_color;
 600 }
 601
 602 void nade_heal_touch(entity this, entity toucher)
 603 {
 604         float maxhealth;
 605         float health_factor;
 606         if(IS_PLAYER(toucher) || IS_MONSTER(toucher))
 607         if(!IS_DEAD(toucher))
 608         if(!STAT(FROZEN, toucher))
 609         {
 610                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 611                 if ( toucher != this.realowner )
 612                 {
 613                         if ( SAME_TEAM(toucher,this) )
 614                                 health_factor *= autocvar_g_nades_heal_friend;
 615                         else
 616                                 health_factor *= autocvar_g_nades_heal_foe;
 617                 }
 618                 if ( health_factor > 0 )
 619                 {
 620                         maxhealth = (IS_MONSTER(toucher)) ? toucher.max_health : g_pickup_healthmega_max;
 621                         if ( toucher.health < maxhealth )
 622                         {
 623                                 if ( this.nade_show_particles )
 624                                         Send_Effect(EFFECT_HEALING, toucher.origin, '0 0 0', 1);
 625                                 toucher.health = min(toucher.health+health_factor, maxhealth);
 626                         }
 627                         toucher.pauserothealth_finished = max(toucher.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 628                 }
 629                 else if ( health_factor < 0 )
 630                 {
 631                         Damage(toucher,this,this.realowner,-health_factor,DEATH_NADE_HEAL.m_id,toucher.origin,'0 0 0');
 632                 }
 633
 634         }
 635
 636         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) )
 637         {
 638                 entity show_red = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 639                 show_red.stat_healing_orb = time+0.1;
 640                 show_red.stat_healing_orb_alpha = 0.75 * (this.ltime - time) / this.orb_lifetime;
 641         }
 642 }
 643
 644 void nade_heal_boom(entity this)
 645 {
 646         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_heal_time, autocvar_g_nades_nade_radius);
 647
 648         settouch(orb, nade_heal_touch);
 649         orb.colormod = '1 0 0';
 650 }
 651
 652 void nade_monster_boom(entity this)
 653 {
 654         entity e = spawnmonster(this.pokenade_type, 0, this.realowner, this.realowner, this.origin, false, false, 1);
 655
 656         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 657                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 658         e.monster_skill = MONSTER_SKILL_INSANE;
 659 }
 660
 661 void nade_boom(entity this)
 662 {
 663         entity expef = NULL;
 664         bool nade_blast = true;
 665
 666         switch ( Nades_from(this.nade_type) )
 667         {
 668                 case NADE_TYPE_NAPALM:
 669                         nade_blast = autocvar_g_nades_napalm_blast;
 670                         expef = EFFECT_EXPLOSION_MEDIUM;
 671                         break;
 672                 case NADE_TYPE_ICE:
 673                         nade_blast = false;
 674                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 675                         break;
 676                 case NADE_TYPE_TRANSLOCATE:
 677                         nade_blast = false;
 678                         break;
 679                 case NADE_TYPE_MONSTER:
 680                 case NADE_TYPE_SPAWN:
 681                         nade_blast = false;
 682                         switch(this.realowner.team)
 683                         {
 684                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 685                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 686                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 687                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 688                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 689                         }
 690                         break;
 691                 case NADE_TYPE_HEAL:
 692                         nade_blast = false;
 693                         expef = EFFECT_SPAWN_RED;
 694                         break;
 695
 696                 case NADE_TYPE_ENTRAP:
 697                         nade_blast = false;
 698                         expef = EFFECT_SPAWN_YELLOW;
 699                         break;
 700
 701                 default:
 702                 case NADE_TYPE_NORMAL:
 703                         expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 704                         break;
 705         }
 706
 707         if(expef)
 708                 Send_Effect(expef, findbetterlocation(this.origin, 8), '0 0 0', 1);
 709
 710         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 711         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 712
 713         this.event_damage = func_null; // prevent somehow calling damage in the next call
 714
 715         if(nade_blast)
 716         {
 717                 RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 718                                  autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 719                 Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 720         }
 721
 722         if(this.takedamage)
 723         switch ( Nades_from(this.nade_type) )
 724         {
 725                 case NADE_TYPE_NAPALM: nade_napalm_boom(this); break;
 726                 case NADE_TYPE_ICE: nade_ice_boom(this); break;
 727                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(this); break;
 728                 case NADE_TYPE_SPAWN: nade_spawn_boom(this); break;
 729                 case NADE_TYPE_HEAL: nade_heal_boom(this); break;
 730                 case NADE_TYPE_MONSTER: nade_monster_boom(this); break;
 731                 case NADE_TYPE_ENTRAP: nade_entrap_boom(this); break;
 732         }
 733
 734         FOREACH_ENTITY_ENT(aiment, this,
 735         {
 736                 if(it.classname == "grapplinghook")
 737                         RemoveGrapplingHook(it.realowner);
 738         });
 739
 740         remove(this);
 741 }
 742
 743 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype);
 744 void nade_pickup(entity this, entity thenade)
 745 {
 746         spawn_held_nade(this, thenade.realowner, autocvar_g_nades_pickup_time, thenade.nade_type, thenade.pokenade_type);
 747
 748         // set refire so player can't even
 749         this.nade_refire = time + autocvar_g_nades_nade_refire;
 750         this.nade_timer = 0;
 751
 752         if(this.nade)
 753                 this.nade.nade_time_primed = thenade.nade_time_primed;
 754 }
 755
 756 bool CanThrowNade(entity this);
 757 void nade_touch(entity this, entity toucher)
 758 {
 759         if(toucher)
 760                 UpdateCSQCProjectile(this);
 761
 762         if(toucher == this.realowner)
 763                 return; // no this impacts
 764
 765         if(autocvar_g_nades_pickup)
 766         if(time >= this.spawnshieldtime)
 767         if(!toucher.nade && this.health == this.max_health) // no boosted shot pickups, thank you very much
 768         if(!STAT(FROZEN, toucher))
 769         if(CanThrowNade(toucher)) // prevent some obvious things, like dead players
 770         if(IS_REAL_CLIENT(toucher)) // above checks for IS_PLAYER, don't need to do it here
 771         {
 772                 nade_pickup(toucher, this);
 773                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 774                 remove(this);
 775                 return;
 776         }
 777         /*float is_weapclip = 0;
 778         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 779         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 780         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 781                 is_weapclip = 1;*/
 782         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 783         {
 784                 FOREACH_ENTITY_ENT(aiment, this,
 785                 {
 786                         if(it.classname == "grapplinghook")
 787                                 RemoveGrapplingHook(it.realowner);
 788                 });
 789                 remove(this);
 790                 return;
 791         }
 792
 793         PROJECTILE_TOUCH(this, toucher);
 794
 795         //setsize(this, '-2 -2 -2', '2 2 2');
 796         //UpdateCSQCProjectile(this);
 797         if(this.health == this.max_health)
 798         {
 799                 spamsound(this, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
 800                 return;
 801         }
 802
 803         this.enemy = toucher;
 804         nade_boom(this);
 805 }
 806
 807 void nade_beep(entity this)
 808 {
 809         sound(this, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 810         setthink(this, nade_boom);
 811         this.nextthink = max(this.wait, time);
 812 }
 813
 814 void nade_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 815 {
 816         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 817         {
 818                 this.takedamage = DAMAGE_NO;
 819                 nade_boom(this);
 820                 return;
 821         }
 822
 823         if(this.nade_type == NADE_TYPE_TRANSLOCATE.m_id || this.nade_type == NADE_TYPE_SPAWN.m_id)
 824                 return;
 825
 826         if (MUTATOR_CALLHOOK(Nade_Damage, this, DEATH_WEAPONOF(deathtype), force, damage)) {}
 827         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 828         {
 829                 force *= 1.5;
 830                 damage = 0;
 831         }
 832         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 833         {
 834                 force *= 0.5; // too much
 835                 damage = 0;
 836         }
 837         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 838         {
 839                 force *= 6;
 840                 damage = this.max_health * 0.55;
 841         }
 842         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 843                 damage = this.max_health * 0.1;
 844         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 845         {
 846                 if(deathtype & HITTYPE_SECONDARY)
 847                 {
 848                         damage = this.max_health * 0.1;
 849                         force *= 10;
 850                 }
 851                 else
 852                         damage = this.max_health * 1.15;
 853         }
 854
 855         this.velocity += force;
 856         UpdateCSQCProjectile(this);
 857
 858         if(damage <= 0 || ((IS_ONGROUND(this)) && IS_PLAYER(attacker)))
 859                 return;
 860
 861         if(this.health == this.max_health)
 862         {
 863                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 864                 this.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 865                 setthink(this, nade_beep);
 866         }
 867
 868         this.health -= damage;
 869
 870         if ( this.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 871                 this.realowner = attacker;
 872
 873         if(this.health <= 0)
 874                 W_PrepareExplosionByDamage(this, attacker, nade_boom);
 875         else
 876                 nade_burn_spawn(this);
 877 }
 878
 879 void toss_nade(entity e, bool set_owner, vector _velocity, float _time)
 880 {
 881         if(e.nade == NULL)
 882                 return;
 883
 884         entity _nade = e.nade;
 885         e.nade = NULL;
 886
 887         remove(e.fake_nade);
 888         e.fake_nade = NULL;
 889
 890         makevectors(e.v_angle);
 891
 892         W_SetupShot(e, false, false, SND_Null, CH_WEAPON_A, 0);
 893
 894         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_NADES);
 895
 896         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 897                                   + (v_right * autocvar_g_nades_throw_offset.y)
 898                                   + (v_up * autocvar_g_nades_throw_offset.z);
 899         if(autocvar_g_nades_throw_offset == '0 0 0')
 900                 offset = '0 0 0';
 901
 902         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 903         //setmodel(_nade, MDL_PROJECTILE_NADE);
 904         //setattachment(_nade, NULL, "");
 905         PROJECTILE_MAKETRIGGER(_nade);
 906         if(STAT(NADES_SMALL, e))
 907                 setsize(_nade, '-8 -8 -8', '8 8 8');
 908         else
 909                 setsize(_nade, '-16 -16 -16', '16 16 16');
 910         set_movetype(_nade, MOVETYPE_BOUNCE);
 911
 912         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 913         if (trace_startsolid)
 914                 setorigin(_nade, e.origin);
 915
 916         if(e.v_angle.x >= 70 && e.v_angle.x <= 110 && PHYS_INPUT_BUTTON_CROUCH(e))
 917                 _nade.velocity = '0 0 100';
 918         else if(autocvar_g_nades_nade_newton_style == 1)
 919                 _nade.velocity = e.velocity + _velocity;
 920         else if(autocvar_g_nades_nade_newton_style == 2)
 921                 _nade.velocity = _velocity;
 922         else
 923                 _nade.velocity = W_CalculateProjectileVelocity(e, e.velocity, _velocity, true);
 924
 925         if(set_owner)
 926                 _nade.realowner = e;
 927
 928         settouch(_nade, nade_touch);
 929         _nade.spawnshieldtime = time + 0.1; // prevent instantly picking up again
 930         _nade.health = autocvar_g_nades_nade_health;
 931         _nade.max_health = _nade.health;
 932         _nade.takedamage = DAMAGE_AIM;
 933         _nade.event_damage = nade_damage;
 934         setcefc(_nade, func_null);
 935         _nade.exteriormodeltoclient = NULL;
 936         _nade.traileffectnum = 0;
 937         _nade.teleportable = true;
 938         _nade.pushable = true;
 939         _nade.gravity = 1;
 940         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 941         _nade.damagedbycontents = true;
 942         _nade.angles = vectoangles(_nade.velocity);
 943         _nade.flags = FL_PROJECTILE;
 944         _nade.projectiledeathtype = DEATH_NADE.m_id;
 945         _nade.toss_time = time;
 946         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 947
 948         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 949                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 950         else
 951                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 952
 953         nade_spawn(_nade);
 954
 955         if(_time)
 956         {
 957                 setthink(_nade, nade_boom);
 958                 _nade.nextthink = _time;
 959         }
 960
 961         e.nade_refire = time + autocvar_g_nades_nade_refire;
 962         e.nade_timer = 0;
 963 }
 964
 965 void nades_GiveBonus(entity player, float score)
 966 {
 967         if (autocvar_g_nades)
 968         if (autocvar_g_nades_bonus)
 969         if (IS_REAL_CLIENT(player))
 970         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 971         if (STAT(FROZEN, player) == 0)
 972         if (!IS_DEAD(player))
 973         {
 974                 if ( player.bonus_nade_score < 1 )
 975                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 976
 977                 if ( player.bonus_nade_score >= 1 )
 978                 {
 979                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 980                         play2(player, SND(KH_ALARM));
 981                         player.bonus_nades++;
 982                         player.bonus_nade_score -= 1;
 983                 }
 984         }
 985 }
 986
 987 /** Remove all bonus nades from a player */
 988 void nades_RemoveBonus(entity player)
 989 {
 990         player.bonus_nades = player.bonus_nade_score = 0;
 991 }
 992
 993 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
 994 {
 995     entity player = M_ARGV(0, entity);
 996
 997         nades_RemoveBonus(player);
 998 }
 999
1000 bool nade_customize(entity this, entity client)
1001 {
1002         //if(IS_SPEC(client)) { return false; }
1003         if(client == this.exteriormodeltoclient || (IS_SPEC(client) && client.enemy == this.exteriormodeltoclient))
1004         {
1005                 // somewhat hide the model, but keep the glow
1006                 //this.effects = 0;
1007                 if(this.traileffectnum)
1008                         this.traileffectnum = 0;
1009                 this.alpha = -1;
1010         }
1011         else
1012         {
1013                 //this.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
1014                 if(!this.traileffectnum)
1015                         this.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(this.nade_type).m_projectile[false], this.team).eent_eff_name);
1016                 this.alpha = 1;
1017         }
1018
1019         return true;
1020 }
1021
1022 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype)
1023 {
1024         entity n = new(nade), fn = new(fake_nade);
1025
1026         n.nade_type = max(1, ntype);
1027         n.pokenade_type = pntype;
1028
1029         if(Nades_from(n.nade_type) == NADE_TYPE_Null)
1030                 n.nade_type = NADE_TYPE_NORMAL.m_id;
1031
1032         setmodel(n, MDL_PROJECTILE_NADE);
1033         //setattachment(n, player, "bip01 l hand");
1034         n.exteriormodeltoclient = player;
1035         setcefc(n, nade_customize);
1036         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(n.nade_type).m_projectile[false], player.team).eent_eff_name);
1037         n.colormod = Nades_from(n.nade_type).m_color;
1038         n.realowner = nowner;
1039         n.colormap = player.colormap;
1040         n.glowmod = player.glowmod;
1041         n.wait = time + max(0, ntime);
1042         n.nade_time_primed = time;
1043         setthink(n, nade_beep);
1044         n.nextthink = max(n.wait - 3, time);
1045         n.projectiledeathtype = DEATH_NADE.m_id;
1046
1047         setmodel(fn, MDL_NADE_VIEW);
1048         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1049         setattachment(fn, player.(weaponentity), "");
1050         fn.realowner = fn.owner = player;
1051         fn.colormod = Nades_from(n.nade_type).m_color;
1052         fn.colormap = player.colormap;
1053         fn.glowmod = player.glowmod;
1054         setthink(fn, SUB_Remove);
1055         fn.nextthink = n.wait;
1056
1057         player.nade = n;
1058         player.fake_nade = fn;
1059 }
1060
1061 void nade_prime(entity this)
1062 {
1063         if(autocvar_g_nades_bonus_only)
1064         if(!this.bonus_nades)
1065                 return; // only allow bonus nades
1066
1067         if(this.nade)
1068                 remove(this.nade);
1069
1070         if(this.fake_nade)
1071                 remove(this.fake_nade);
1072
1073         int ntype;
1074         string pntype = this.pokenade_type;
1075
1076         if(this.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
1077                 ntype = this.nade_type;
1078         else if (this.bonus_nades >= 1)
1079         {
1080                 ntype = this.nade_type;
1081                 pntype = this.pokenade_type;
1082                 this.bonus_nades -= 1;
1083         }
1084         else
1085         {
1086                 ntype = ((autocvar_g_nades_client_select) ? this.cvar_cl_nade_type : autocvar_g_nades_nade_type);
1087                 pntype = ((autocvar_g_nades_client_select) ? this.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
1088         }
1089
1090         spawn_held_nade(this, this, autocvar_g_nades_nade_lifetime, ntype, pntype);
1091 }
1092
1093 bool CanThrowNade(entity this)
1094 {
1095         if(this.vehicle)
1096                 return false;
1097
1098         if(gameover)
1099                 return false;
1100
1101         if(IS_DEAD(this))
1102                 return false;
1103
1104         if (!autocvar_g_nades)
1105                 return false; // allow turning them off mid match
1106
1107         if(forbidWeaponUse(this))
1108                 return false;
1109
1110         if (!IS_PLAYER(this))
1111                 return false;
1112
1113         return true;
1114 }
1115
1116 .bool nade_altbutton;
1117
1118 void nades_CheckThrow(entity this)
1119 {
1120         if(!CanThrowNade(this))
1121                 return;
1122
1123         entity held_nade = this.nade;
1124         if (!held_nade)
1125         {
1126                 this.nade_altbutton = true;
1127                 if(time > this.nade_refire)
1128                 {
1129                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_NADE_THROW);
1130                         nade_prime(this);
1131                         this.nade_refire = time + autocvar_g_nades_nade_refire;
1132                 }
1133         }
1134         else
1135         {
1136                 this.nade_altbutton = false;
1137                 if (time >= held_nade.nade_time_primed + 1) {
1138                         makevectors(this.v_angle);
1139                         float _force = time - held_nade.nade_time_primed;
1140                         _force /= autocvar_g_nades_nade_lifetime;
1141                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1142                         vector dir = (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05);
1143                         dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1144                         toss_nade(this, true, dir * _force, 0);
1145                 }
1146         }
1147 }
1148
1149 void nades_Clear(entity player)
1150 {
1151         if(player.nade)
1152                 remove(player.nade);
1153         if(player.fake_nade)
1154                 remove(player.fake_nade);
1155
1156         player.nade = player.fake_nade = NULL;
1157         player.nade_timer = 0;
1158 }
1159
1160 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1161 {
1162         entity player = M_ARGV(0, entity);
1163
1164         if(player.nade)
1165                 toss_nade(player, true, '0 0 100', max(player.nade.wait, time + 0.05));
1166 }
1167
1168 CLASS(NadeOffhand, OffhandWeapon)
1169     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1170     {
1171         entity held_nade = player.nade;
1172                 if (held_nade)
1173                 {
1174                         player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / autocvar_g_nades_nade_lifetime, 1);
1175                         // LOG_TRACEF("%d %d\n", player.nade_timer, time - held_nade.nade_time_primed);
1176                         makevectors(player.angles);
1177                         held_nade.velocity = player.velocity;
1178                         setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1179                         held_nade.angles_y = player.angles.y;
1180
1181                         if (time + 0.1 >= held_nade.wait)
1182                                 toss_nade(player, false, '0 0 0', time + 0.05);
1183                 }
1184
1185         if (!CanThrowNade(player)) return;
1186         if (!(time > player.nade_refire)) return;
1187                 if (key_pressed) {
1188                         if (!held_nade) {
1189                                 nade_prime(player);
1190                                 held_nade = player.nade;
1191                         }
1192                 } else if (time >= held_nade.nade_time_primed + 1) {
1193                         if (held_nade) {
1194                                 makevectors(player.v_angle);
1195                                 float _force = time - held_nade.nade_time_primed;
1196                                 _force /= autocvar_g_nades_nade_lifetime;
1197                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1198                                 vector dir = (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1);
1199                                 dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1200                                 toss_nade(player, false, dir * _force, 0);
1201                         }
1202                 }
1203     }
1204 ENDCLASS(NadeOffhand)
1205 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1206
1207 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1208 {
1209     entity player = M_ARGV(0, entity);
1210
1211         if (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1212                 nades_CheckThrow(player);
1213                 return true;
1214         }
1215 }
1216
1217 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1218 {
1219         entity player = M_ARGV(0, entity);
1220
1221         if (!IS_PLAYER(player)) { return; }
1222
1223         if (player.nade && (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, player, player.nade_altbutton);
1224
1225         if(IS_PLAYER(player))
1226         {
1227                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1228                 {
1229                         entity key;
1230                         float key_count = 0;
1231                         FOR_EACH_KH_KEY(key) if(key.owner == player) { ++key_count; }
1232
1233                         float time_score;
1234                         if(player.flagcarried || player.ballcarried) // this player is important
1235                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1236                         else
1237                                 time_score = autocvar_g_nades_bonus_score_time;
1238
1239                         if(key_count)
1240                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1241
1242                         if(autocvar_g_nades_bonus_client_select)
1243                         {
1244                                 player.nade_type = player.cvar_cl_nade_type;
1245                                 player.pokenade_type = player.cvar_cl_pokenade_type;
1246                         }
1247                         else
1248                         {
1249                                 player.nade_type = autocvar_g_nades_bonus_type;
1250                                 player.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1251                         }
1252
1253                         player.nade_type = bound(1, player.nade_type, Nades_COUNT);
1254
1255                         if(player.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1256                                 nades_GiveBonus(player, time_score / autocvar_g_nades_bonus_score_max);
1257                 }
1258                 else
1259                 {
1260                         player.bonus_nades = player.bonus_nade_score = 0;
1261                 }
1262         }
1263
1264         float n = 0;
1265         entity o = NULL;
1266         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
1267                 n = -1;
1268         else
1269         {
1270                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1271                 n = 0;
1272                 FOREACH_CLIENT(IS_PLAYER(it) && it != player, LAMBDA(
1273                         if(!IS_DEAD(it))
1274                         if(STAT(FROZEN, it) == 0)
1275                         if(SAME_TEAM(it, player))
1276                         if(boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
1277                         {
1278                                 if(!o)
1279                                         o = it;
1280                                 if(STAT(FROZEN, player) == 1)
1281                                         it.reviving = true;
1282                                 ++n;
1283                         }
1284                 ));
1285         }
1286
1287         if(n && STAT(FROZEN, player) == 3) // OK, there is at least one teammate reviving us
1288         {
1289                 player.revive_progress = bound(0, player.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1290                 player.health = max(1, player.revive_progress * start_health);
1291
1292                 if(player.revive_progress >= 1)
1293                 {
1294                         Unfreeze(player);
1295
1296                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1297                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
1298                 }
1299
1300                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
1301                         it.revive_progress = player.revive_progress;
1302                         it.reviving = false;
1303                 ));
1304         }
1305 }
1306
1307 MUTATOR_HOOKFUNCTION(nades, PlayerPhysics)
1308 {
1309         entity player = M_ARGV(0, entity);
1310
1311         if (STAT(ENTRAP_ORB, player) > time)
1312         {
1313                 player.stat_sv_maxspeed *= autocvar_g_nades_entrap_speed;
1314                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_nades_entrap_speed;
1315         }
1316 }
1317
1318 MUTATOR_HOOKFUNCTION(nades, MonsterMove)
1319 {
1320     entity mon = M_ARGV(0, entity);
1321
1322         if (STAT(ENTRAP_ORB, mon) > time)
1323         {
1324                 M_ARGV(1, float) *= autocvar_g_nades_entrap_speed; // run speed
1325                 M_ARGV(2, float) *= autocvar_g_nades_entrap_speed; // walk speed
1326         }
1327 }
1328
1329 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1330 {
1331         entity player = M_ARGV(0, entity);
1332
1333         if(autocvar_g_nades_spawn)
1334                 player.nade_refire = time + autocvar_g_spawnshieldtime;
1335         else
1336                 player.nade_refire  = time + autocvar_g_nades_nade_refire;
1337
1338         if(autocvar_g_nades_bonus_client_select)
1339                 player.nade_type = player.cvar_cl_nade_type;
1340
1341         player.nade_timer = 0;
1342
1343         if (!player.offhand) player.offhand = OFFHAND_NADE;
1344
1345         if(player.nade_spawnloc)
1346         {
1347                 setorigin(player, player.nade_spawnloc.origin);
1348                 player.nade_spawnloc.cnt -= 1;
1349
1350                 if(player.nade_spawnloc.cnt <= 0)
1351                 {
1352                         remove(player.nade_spawnloc);
1353                         player.nade_spawnloc = NULL;
1354                 }
1355         }
1356 }
1357
1358 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1359 {
1360         entity frag_attacker = M_ARGV(1, entity);
1361         entity frag_target = M_ARGV(2, entity);
1362
1363         if(frag_target.nade)
1364         if(!STAT(FROZEN, frag_target) || !autocvar_g_freezetag_revive_nade)
1365                 toss_nade(frag_target, true, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1366
1367         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1368
1369         if(IS_PLAYER(frag_attacker))
1370         {
1371                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1372                         nades_RemoveBonus(frag_attacker);
1373                 else if(frag_target.flagcarried)
1374                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1375                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1376                 {
1377                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1378                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1379                         switch(frag_attacker.killcount)
1380                         {
1381                                 KILL_SPREE_LIST
1382                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1383                         }
1384                         #undef SPREE_ITEM
1385                 }
1386                 else
1387                         nades_GiveBonus(frag_attacker, killcount_bonus);
1388         }
1389
1390         nades_RemoveBonus(frag_target);
1391 }
1392
1393 MUTATOR_HOOKFUNCTION(nades, PlayerDamage_Calculate)
1394 {
1395         entity frag_inflictor = M_ARGV(0, entity);
1396         entity frag_attacker = M_ARGV(1, entity);
1397         entity frag_target = M_ARGV(2, entity);
1398         float frag_deathtype = M_ARGV(3, float);
1399
1400         if(STAT(FROZEN, frag_target))
1401         if(autocvar_g_freezetag_revive_nade)
1402         if(frag_attacker == frag_target)
1403         if(frag_deathtype == DEATH_NADE.m_id)
1404         if(time - frag_inflictor.toss_time <= 0.1)
1405         {
1406                 Unfreeze(frag_target);
1407                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1408                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1409                 M_ARGV(4, float) = 0;
1410                 M_ARGV(6, vector) = '0 0 0';
1411                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1412                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1413         }
1414 }
1415
1416 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1417 {
1418         entity frag_target = M_ARGV(0, entity);
1419         entity frag_attacker = M_ARGV(1, entity);
1420
1421         if(IS_PLAYER(frag_attacker))
1422         if(DIFF_TEAM(frag_attacker, frag_target))
1423         if(!(frag_target.spawnflags & MONSTERFLAG_SPAWNED))
1424                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1425 }
1426
1427 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1428 {
1429         entity frag_target = M_ARGV(0, entity);
1430
1431         if(frag_target.nade)
1432                 toss_nade(frag_target, true, '0 0 0', time + 0.05);
1433 }
1434
1435 void nades_RemovePlayer(entity this)
1436 {
1437         nades_Clear(this);
1438         nades_RemoveBonus(this);
1439 }
1440
1441 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1442 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1443 MUTATOR_HOOKFUNCTION(nades, reset_map_global)
1444 {
1445         FOREACH_CLIENT(IS_PLAYER(it),
1446         {
1447                 nades_RemovePlayer(it);
1448         });
1449 }
1450
1451 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1452 {
1453         entity spectatee = M_ARGV(0, entity);
1454         entity client = M_ARGV(1, entity);
1455
1456         client.nade_timer = spectatee.nade_timer;
1457         client.nade_type = spectatee.nade_type;
1458         client.pokenade_type = spectatee.pokenade_type;
1459         client.bonus_nades = spectatee.bonus_nades;
1460         client.bonus_nade_score = spectatee.bonus_nade_score;
1461         client.stat_healing_orb = spectatee.stat_healing_orb;
1462         client.stat_healing_orb_alpha = spectatee.stat_healing_orb_alpha;
1463         STAT(ENTRAP_ORB, client) = STAT(ENTRAP_ORB, spectatee);
1464         STAT(ENTRAP_ORB_ALPHA, client) = STAT(ENTRAP_ORB_ALPHA, spectatee);
1465 }
1466
1467 REPLICATE(cvar_cl_nade_type, int, "cl_nade_type");
1468 REPLICATE(cvar_cl_pokenade_type, string, "cl_pokenade_type");
1469
1470 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1471 {
1472         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Nades");
1473 }
1474
1475 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsPrettyString)
1476 {
1477         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Nades");
1478 }
1479
1480 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1481 {
1482         M_ARGV(0, string) = strcat(M_ARGV(0, string), "\n\n^3nades^8 are enabled, press 'g' to use them\n");
1483 }
1484
1485 #endif
1486 #endif