qcsrc/common/mutators/mutator/new_toys/new_toys.qc

   1 #ifdef IMPLEMENTATION
   2 /*
   3
   4 CORE    laser   vortex     lg      rl      cry     gl      elec    hagar   fireb   hook
   5                                                                         vaporizer  porto
   6                                                                         tuba
   7
   8 NEW             rifle   hlac    minel                           seeker
   9 IDEAS                                   OPEN    flak    OPEN            FUN FUN FUN FUN
  10
  11
  12
  13 How this mutator works:
  14  =======================
  15
  16 When a gun tries to spawn, this mutator is called. It will provide alternate
  17 weaponreplace lists.
  18
  19 Entity:
  20
  21 {
  22 "classname" "weapon_vortex"
  23 "new_toys" "rifle"
  24 }
  25 -> This will spawn as Rifle in this mutator ONLY, and as Vortex otherwise.
  26
  27 {
  28 "classname" "weapon_vortext"
  29 "new_toys" "vortex rifle"
  30 }
  31 -> This will spawn as either Vortex or Rifle in this mutator ONLY, and as Vortex otherwise.
  32
  33 {
  34 "classname" "weapon_vortex"
  35 "new_toys" "vortex"
  36 }
  37 -> This is always a Vortex.
  38
  39 If the map specifies no "new_toys" argument
  40
  41 There will be two default replacements selectable: "replace all" and "replace random".
  42 In "replace all" mode, e.g. Vortex will have the default replacement "rifle".
  43 In "replace random" mode, Vortex will have the default replacement "vortex rifle".
  44
  45 This mutator's replacements run BEFORE regular weaponreplace!
  46
  47 The New Toys guns do NOT get a spawn function, so they can only ever be spawned
  48 when this mutator is active.
  49
  50 Likewise, warmup, give all, give ALL and impulse 99 will not give them unless
  51 this mutator is active.
  52
  53 Outside this mutator, they still can be spawned by:
  54 - setting their start weapon cvar to 1
  55 - give weaponname
  56 - weaponreplace
  57 - weaponarena (but all and most weapons arena again won't include them)
  58
  59 This mutator performs the default replacements on the DEFAULTS of the
  60 start weapon selection.
  61
  62 These weapons appear in the menu's priority list, BUT get a suffix
  63 "(Mutator weapon)".
  64
  65 Picking up a "new toys" weapon will not play standard weapon pickup sound, but
  66 roflsound "New toys, new toys!" sound.
  67
  68 */
  69
  70 bool nt_IsNewToy(int w);
  71
  72 REGISTER_MUTATOR(nt, cvar("g_new_toys") && !cvar("g_instagib") && !cvar("g_overkill"))
  73 {
  74         MUTATOR_ONADD
  75         {
  76                 if(time > 1) // game loads at time 1
  77                         error("This cannot be added at runtime\n");
  78
  79                 // mark the guns as ok to use by e.g. impulse 99
  80                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
  81                         if(nt_IsNewToy(it.m_id))
  82                                 it.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
  83                 ));
  84         }
  85
  86         MUTATOR_ONROLLBACK_OR_REMOVE
  87         {
  88                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
  89                         if(nt_IsNewToy(it.m_id))
  90                                 it.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  91                 ));
  92         }
  93
  94         MUTATOR_ONREMOVE
  95         {
  96                 LOG_INFO("This cannot be removed at runtime\n");
  97                 return -1;
  98         }
  99
 100         return 0;
 101 }
 102
 103 .string new_toys;
 104
 105 float autocvar_g_new_toys_autoreplace;
 106 bool autocvar_g_new_toys_use_pickupsound = true;
 107 const float NT_AUTOREPLACE_NEVER = 0;
 108 const float NT_AUTOREPLACE_ALWAYS = 1;
 109 const float NT_AUTOREPLACE_RANDOM = 2;
 110
 111 MUTATOR_HOOKFUNCTION(nt, SetModname)
 112 {
 113         modname = "NewToys";
 114         return 0;
 115 }
 116
 117 bool nt_IsNewToy(int w)
 118 {
 119         switch(w)
 120         {
 121                 case WEP_SEEKER.m_id:
 122                 case WEP_MINE_LAYER.m_id:
 123                 case WEP_HLAC.m_id:
 124                 case WEP_RIFLE.m_id:
 125                 case WEP_SHOCKWAVE.m_id:
 126                         return true;
 127                 default:
 128                         return false;
 129         }
 130 }
 131
 132 string nt_GetFullReplacement(string w)
 133 {
 134         switch(w)
 135         {
 136                 case "hagar": return "seeker";
 137                 case "devastator": return "minelayer";
 138                 case "machinegun": return "hlac";
 139                 case "vortex": return "rifle";
 140                 //case "shotgun": return "shockwave";
 141                 default: return string_null;
 142         }
 143 }
 144
 145 string nt_GetReplacement(string w, float m)
 146 {
 147         if(m == NT_AUTOREPLACE_NEVER)
 148                 return w;
 149         string s = nt_GetFullReplacement(w);
 150         if (!s)
 151                 return w;
 152         if(m == NT_AUTOREPLACE_RANDOM)
 153                 s = strcat(w, " ", s);
 154         return s;
 155 }
 156
 157 MUTATOR_HOOKFUNCTION(nt, SetStartItems)
 158 {
 159         // rearrange start_weapon_default
 160         // apply those bits that are set by start_weapon_defaultmask
 161         // same for warmup
 162
 163         float i, j, k, n;
 164
 165         WepSet newdefault;
 166         WepSet warmup_newdefault;
 167
 168         newdefault = '0 0 0';
 169         warmup_newdefault = '0 0 0';
 170
 171         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 172         {
 173                 entity e = Weapons_from(i);
 174                 if(e == WEP_Null) continue;
 175
 176                 n = tokenize_console(nt_GetReplacement(e.netname, autocvar_g_new_toys_autoreplace));
 177
 178                 for (j = 0; j < n; ++j)
 179                         for (k = WEP_FIRST; k <= WEP_LAST; ++k)
 180                         {
 181                                 Weapon w = Weapons_from(k);
 182                                 if (w.netname == argv(j))
 183                                 {
 184                                         WepSet seti = e.m_wepset;
 185                                         WepSet setk = w.m_wepset;
 186                                         if (start_weapons & seti) newdefault |= setk;
 187                                         if (warmup_start_weapons & seti) warmup_newdefault |= setk;
 188                                 }
 189                         }
 190         }
 191
 192         newdefault &= start_weapons_defaultmask;
 193         start_weapons &= ~start_weapons_defaultmask;
 194         start_weapons |= newdefault;
 195
 196         warmup_newdefault &= warmup_start_weapons_defaultmask;
 197         warmup_start_weapons &= ~warmup_start_weapons_defaultmask;
 198         warmup_start_weapons |= warmup_newdefault;
 199
 200         return 0;
 201 }
 202
 203 MUTATOR_HOOKFUNCTION(nt, SetWeaponreplace)
 204 {SELFPARAM();
 205         // otherwise, we do replace
 206         if(self.new_toys)
 207         {
 208                 // map defined replacement:
 209                 ret_string = self.new_toys;
 210         }
 211         else
 212         {
 213                 // auto replacement:
 214                 ret_string = nt_GetReplacement(other.netname, autocvar_g_new_toys_autoreplace);
 215         }
 216
 217         // apply regular weaponreplace
 218         ret_string = W_Apply_Weaponreplace(ret_string);
 219
 220         return 0;
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(nt, FilterItem)
 224 {SELFPARAM();
 225         if(nt_IsNewToy(self.weapon) && autocvar_g_new_toys_use_pickupsound) {
 226                 self.item_pickupsound = string_null;
 227                 self.item_pickupsound_ent = SND_WEAPONPICKUP_NEW_TOYS;
 228         }
 229         return 0;
 230 }
 231 #endif