qcsrc/common/mutators/mutator/spawn_near_teammate/spawn_near_teammate.qc

   1 #ifdef IMPLEMENTATION
   2
   3 float autocvar_g_spawn_near_teammate_distance;
   4 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
   5 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
   6 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
   7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
   8 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
   9
  10 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate"));
  11
  12 .entity msnt_lookat;
  13
  14 .float msnt_timer;
  15 .vector msnt_deathloc;
  16
  17 .float cvar_cl_spawn_near_teammate;
  18
  19 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  20 {SELFPARAM();
  21         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  22                 return 0;
  23
  24         spawn_spot.msnt_lookat = world;
  25
  26         if(!teamplay)
  27                 return 0;
  28
  29         RandomSelection_Init();
  30         FOREACH_CLIENT(IS_PLAYER(it) && it != self && SAME_TEAM(it, self) && !IS_DEAD(it), LAMBDA(
  31                 if(vdist(spawn_spot.origin - it.origin, >, autocvar_g_spawn_near_teammate_distance))
  32                         continue;
  33                 if(vdist(spawn_spot.origin - it.origin, <, 48))
  34                         continue;
  35                 if(!checkpvs(spawn_spot.origin, it))
  36                         continue;
  37                 RandomSelection_Add(it, 0, string_null, 1, 1);
  38         ));
  39
  40         if(RandomSelection_chosen_ent)
  41         {
  42                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  43                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  44         }
  45         else if(self.team == spawn_spot.team)
  46                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  47
  48         return 0;
  49 }
  50
  51 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  52 {SELFPARAM();
  53         if(!teamplay) { return false; }
  54         // Note: when entering this, fixangle is already set.
  55         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  56         {
  57                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  58                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  59
  60                 entity best_mate = world;
  61                 vector best_spot = '0 0 0';
  62                 float pc = 0, best_dist = 0, dist = 0;
  63                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  64                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && it.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  65                         if(!IS_DEAD(it))
  66                         if(it.msnt_timer < time)
  67                         if(SAME_TEAM(self, it))
  68                         if(time > it.spawnshieldtime) // spawn shielding
  69                         if(STAT(FROZEN, it) == 0)
  70                         if(it != self)
  71                         {
  72                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - '0 0 100', MOVE_NOMONSTERS, it);
  73                                 if(trace_fraction != 1.0)
  74                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  75                                 {
  76                                         pc = pointcontents(trace_endpos + '0 0 1');
  77                                         if(pc == CONTENT_EMPTY)
  78                                         {
  79                                                 if(vdist(it.velocity, >, 5))
  80                                                         fixedmakevectors(vectoangles(it.velocity));
  81                                                 else
  82                                                         fixedmakevectors(it.angles);
  83
  84                                                 for(pc = 0; pc < 4; ++pc) // test 4 diffrent spots close to mate
  85                                                 {
  86                                                         switch(pc)
  87                                                         {
  88                                                                 case 0:
  89                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 128, MOVE_NOMONSTERS, it);
  90                                                                         break;
  91                                                                 case 1:
  92                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 128 , MOVE_NOMONSTERS, it);
  93                                                                         break;
  94                                                                 case 2:
  95                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 64 - v_forward * 64, MOVE_NOMONSTERS, it);
  96                                                                         break;
  97                                                                 case 3:
  98                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 64 - v_forward * 64, MOVE_NOMONSTERS, it);
  99                                                                         break;
 100                                                                 //case 4:
 101                                                                         //tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128, MOVE_NOMONSTERS, it);
 102                                                                         //break;
 103                                                         }
 104
 105                                                         if(trace_fraction == 1.0)
 106                                                         {
 107                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NOMONSTERS, it);
 108                                                                 if(trace_fraction != 1.0)
 109                                                                 {
 110                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 111                                                                         {
 112                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 113                                                                                 if(dist < best_dist || best_dist == 0)
 114                                                                                 {
 115                                                                                         best_dist = dist;
 116                                                                                         best_spot = trace_endpos;
 117                                                                                         best_mate = it;
 118                                                                                 }
 119                                                                         }
 120                                                                         else
 121                                                                         {
 122                                                                                 setorigin(self, trace_endpos);
 123                                                                                 self.angles = it.angles;
 124                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 125                                                                                 it.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 126                                                                                 return 0;
 127                                                                         }
 128                                                                 }
 129                                                         }
 130                                                 }
 131                                         }
 132                                 }
 133                         }
 134                 ));
 135
 136                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 137                 if(best_dist)
 138                 {
 139                         setorigin(self, best_spot);
 140                         self.angles = best_mate.angles;
 141                         self.angles_z = 0; // never spawn tilted even if the spot says to
 142                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 143                 }
 144         }
 145         else if(spawn_spot.msnt_lookat)
 146         {
 147                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 148                 self.angles_x = -self.angles.x;
 149                 self.angles_z = 0; // never spawn tilted even if the spot says to
 150                 /*
 151                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 152                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 153                 sprint(self, "angles: ", vtos(self.angles), "\n");
 154                 */
 155         }
 156
 157         return 0;
 158 }
 159
 160 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
 161 {
 162         frag_target.msnt_deathloc = frag_target.origin;
 163         return 0;
 164 }
 165
 166 REPLICATE(cvar_cl_spawn_near_teammate, bool, "cl_spawn_near_teammate");
 167
 168 #endif