qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: December, 2012
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 // get the actual name of a notification and return it as a string
   8 string Get_Field_Value(float field, float net_type, float net_name)
   9 {
  10         string output = "";
  11
  12         #define GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) \
  13                 switch(field) { \
  14                         case F_NAME: { output = VAR_TO_TEXT(name); break; } \
  15                         case F_STRNUM: { output = ftos(strnum); break; } \
  16                         case F_FLNUM: { output = ftos(flnum); break; } }
  17
  18         switch(net_type)
  19         {
  20                 case MSG_INFO:
  21                 {
  22                         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
  23                                 case name: { { GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) } break; }
  24
  25                         switch(net_name)
  26                         {
  27                                 MSG_INFO_NOTIFICATIONS
  28                                 default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_INFO, net_name = ", ftos(net_name), ".\n")); break; }
  29                         }
  30
  31                         #undef MSG_INFO_NOTIF
  32                         break;
  33                 }
  34                 case MSG_CENTER:
  35                 {
  36                         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
  37                                 case name: { { GET_FIELD_VALUE_OUTPUT(field,name,strnum,flnum) } break; }
  38
  39                         switch(net_name)
  40                         {
  41                                 MSG_CENTER_NOTIFICATIONS
  42                                 default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_CENTER, net_name = ", ftos(net_name), ".\n")); break; }
  43                         }
  44
  45                         #undef MSG_CENTER_NOTIF
  46                         break;
  47                 }
  48                 case MSG_WEAPON:
  49                 {
  50                         #define MSG_WEAPON_NOTIF(name,infoname,centername) \
  51                                 case name: { { GET_FIELD_VALUE_OUTPUT(field,name, \
  52                                 max(stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername))), \
  53                                 max(stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)))) } break; }
  54
  55                         switch(net_name)
  56                         {
  57                                 MSG_WEAPON_NOTIFICATIONS
  58                                 default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_WEAPON, net_name = ", ftos(net_name), ".\n")); break; }
  59                         }
  60
  61                         #undef MSG_WEAPON_NOTIF
  62                         break;
  63                 }
  64                 case MSG_DEATH:
  65                 {
  66                         #define MSG_DEATH_NOTIF(name,infoname,centername) \
  67                                 case name: { { GET_FIELD_VALUE_OUTPUT(field,name, \
  68                                 max(stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername))), \
  69                                 max(stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)))) } break; }
  70
  71                         switch(net_name)
  72                         {
  73                                 MSG_DEATH_NOTIFICATIONS
  74                                 default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_DEATH, net_name = ", ftos(net_name), ".\n")); break; }
  75                         }
  76
  77                         #undef MSG_DEATH_NOTIF
  78                         break;
  79                 }
  80         }
  81
  82         #undef GET_FIELD_VALUE_OUTPUT
  83         return output;
  84 }
  85 #endif // ifndef MENUQC
  86
  87
  88 // ===============================
  89 //  Frontend Notification Pushing
  90 // ===============================
  91
  92 void Dump_Notifications(float fh, float alsoprint)
  93 {
  94         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
  95         string notif_msg;
  96
  97         #define NOTIF_WRITE(type,name,text) notif_msg = sprintf("seta %s 1 // %s - %s\n", name, type, strreplace("\n", "\\n", text)); fputs(fh, notif_msg); if(alsoprint) { print(strreplace("^", "^^", notif_msg)); }
  98         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) { ++MSG_INFO_NOTIFS; NOTIF_WRITE("MSG_INFO", VAR_TO_TEXT(name), normal) }
  99         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) { ++MSG_CENTER_NOTIFS; NOTIF_WRITE("MSG_CENTER", VAR_TO_TEXT(name), normal) }
 100         #define MSG_WEAPON_NOTIF(name,infoname,centername) { ++MSG_WEAPON_NOTIFS; NOTIF_WRITE("MSG_WEAPON", VAR_TO_TEXT(name),sprintf("infoname: %s, centername: %s", VAR_TO_TEXT(infoname), VAR_TO_TEXT(centername))) }
 101         #define MSG_DEATH_NOTIF(name,infoname,centername) { ++MSG_DEATH_NOTIFS; NOTIF_WRITE("MSG_DEATH", VAR_TO_TEXT(name), sprintf("infoname: %s, centername: %s", VAR_TO_TEXT(infoname), VAR_TO_TEXT(centername))) }
 102         MSG_INFO_NOTIFICATIONS
 103         MSG_CENTER_NOTIFICATIONS
 104         MSG_WEAPON_NOTIFICATIONS
 105         MSG_DEATH_NOTIFICATIONS
 106         #undef NOTIF_WRITE
 107         #undef MSG_INFO_NOTIF
 108         #undef MSG_CENTER_NOTIF
 109         #undef MSG_WEAPON_NOTIF
 110         #undef MSG_DEATH_NOTIF
 111
 112         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n", MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 113         return;
 114 }
 115
 116 #ifndef MENUQC
 117 #ifdef CSQC
 118 void HUD_Notify_Push(string icon, string attacker, string victim)
 119 {
 120         if(icon != "")
 121         {
 122                 --kn_index;
 123                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
 124                 killnotify_times[kn_index] = time;
 125
 126                 // icon
 127                 if(killnotify_icon[kn_index]) { strunzone(killnotify_icon[kn_index]); }
 128                 killnotify_icon[kn_index] = strzone(icon);
 129
 130                 // attacker
 131                 if(killnotify_attackers[kn_index]) { strunzone(killnotify_attackers[kn_index]); }
 132                 killnotify_attackers[kn_index] = strzone(attacker);
 133
 134                 // victim
 135                 if(killnotify_victims[kn_index]) { strunzone(killnotify_victims[kn_index]); }
 136                 killnotify_victims[kn_index] = strzone(victim);
 137         }
 138 }
 139 #endif // ifdef CSQC
 140
 141 void Local_Notification(float net_type, float net_name, ...count)
 142 {
 143         if(net_type && net_name)
 144         {
 145                 float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 146                 float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 147
 148                 string s1 = ((0 < stringcount) ? ...(0, string) : NO_STR_ARG);
 149                 string s2 = ((1 < stringcount) ? ...(1, string) : NO_STR_ARG);
 150                 string s3 = ((2 < stringcount) ? ...(2, string) : NO_STR_ARG);
 151                 string s4 = ((3 < stringcount) ? ...(3, string) : NO_STR_ARG);
 152                 float f1 = ((stringcount < count) ? ...(stringcount, float) : NO_FL_ARG);
 153                 float f2 = (((stringcount + 1) < count) ? ...((stringcount + 1), float) : NO_FL_ARG);
 154                 float f3 = (((stringcount + 2) < count) ? ...((stringcount + 2), float) : NO_FL_ARG);
 155                 float f4 = (((stringcount + 3) < count) ? ...((stringcount + 3), float) : NO_FL_ARG);
 156
 157                 string tmp_s;
 158
 159                 dprint("Local_Notification(", ftos(net_type), ", ", Get_Field_Value(F_NAME, net_type, net_name), strcat(", ", s1, ", ", s2, ", ", s3, ", ", s4, ", "), strcat(ftos(f1), strcat(", ", ftos(f2), ", ", ftos(f3), ", ", ftos(f4), ");\n")));
 160                 dprint("  ^--: stringcount: ", ftos(stringcount), ", floatcount: ", ftos(floatcount), ".\n");
 161
 162                 if((stringcount + floatcount) > count) { backtrace(strcat("Not enough arguments for Local_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), ")"), " > count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 163                 else if((stringcount + floatcount) < count) { backtrace(strcat("Too many arguments for Local_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), ")"), " < count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 164
 165                 switch(net_type)
 166                 {
 167                         case MSG_INFO:
 168                         {
 169                                 #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
 170                                         case name: { CHECK_AUTOCVAR(name) \
 171                                         { \
 172                                                 tmp_s = normal_or_gentle(normal, gentle); if(tmp_s != "") \
 173                                                 { \
 174                                                         if(substring(tmp_s, (strlen(tmp_s) - 1), 1) == "\n") { print(sprintf(CCR(tmp_s), args)); } \
 175                                                         else { backtrace(strcat("^1MISSING/BROKEN NEW LINE AT END OF NOTIFICATION: ^7net_type = MSG_INFO, net_name = ", Get_Field_Value(F_NAME, net_type, net_name), (GENTLE ? ", GENTLE string" : ", NORMAL string"), ".\n")); } \
 176                                                         #ifdef CSQC \
 177                                                                 tmp_s = icon; if(tmp_s != "") { HUD_Notify_Push(icon, hudargs); } \
 178                                                         #endif \
 179                                                 } \
 180                                                 else { backtrace(strcat("^1EMPTY NOTIFICATION: ^7net_type = MSG_INFO, net_name = ", Get_Field_Value(F_NAME, net_type, net_name), ".\n")); } \
 181                                         } } break;
 182
 183                                 switch(net_name)
 184                                 {
 185                                         MSG_INFO_NOTIFICATIONS
 186                                         default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_INFO, net_name = ", ftos(net_name), ".\n")); break; }
 187                                 }
 188
 189                                 #undef MSG_INFO_NOTIF
 190                                 break;
 191                         }
 192                         #ifdef CSQC
 193                         case MSG_CENTER:
 194                         {
 195                                 #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
 196                                         case name: { CHECK_AUTOCVAR(name) \
 197                                         { \
 198                                                 tmp_s = normal_or_gentle(normal, gentle); if(tmp_s != "") { centerprint_generic(HANDLE_CPID(cpid), sprintf(CCR(tmp_s), args), durcnt); } \
 199                                                 else { backtrace(strcat("^1EMPTY NOTIFICATION: ^7net_type = MSG_CENTER, net_name = ", Get_Field_Value(F_NAME, net_type, net_name), ".\n")); } \
 200                                         } } break;
 201
 202                                 switch(net_name)
 203                                 {
 204                                         MSG_CENTER_NOTIFICATIONS
 205                                         default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_CENTER, net_name = ", ftos(net_name), ".\n")); break; }
 206                                 }
 207
 208                                 #undef MSG_CENTER_NOTIF
 209                                 break;
 210                         }
 211                         #endif
 212                         case MSG_WEAPON:
 213                         {
 214                                 #define MSG_WEAPON_NOTIF(name,infoname,centername) \
 215                                         case name: { CHECK_AUTOCVAR(name) \
 216                                         { \
 217                                                 #if infoname != NO_MSG \
 218                                                         Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 219                                                                 stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), \
 220                                                                 stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), \
 221                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 222                                                 #endif \
 223                                                 #ifdef CSQC \
 224                                                         #if centername != NO_MSG \
 225                                                                 Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 226                                                                         stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername)), \
 227                                                                         stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)), \
 228                                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 229                                                         #endif \
 230                                                 #endif \
 231                                         } } break;
 232
 233                                 switch(net_name)
 234                                 {
 235                                         MSG_WEAPON_NOTIFICATIONS
 236                                         default: { backtrace(strcat("^1NOTIFICATION HAD NO MATCH: ^7net_type = MSG_WEAPON, net_name = ", ftos(net_name), ".\n")); break; }
 237                                 }
 238
 239                                 #undef MSG_WEAPON_NOTIF
 240                                 break;
 241                         }
 242                         case MSG_DEATH:
 243                         {
 244                                 #define MSG_DEATH_NOTIF(name,infoname,centername) \
 245                                         { if(min(name,10000) == net_name) CHECK_AUTOCVAR(name) \
 246                                         { \
 247                                                 #if infoname != NO_MSG \
 248                                                         Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 249                                                                 stof(Get_Field_Value(F_STRNUM, MSG_INFO, infoname)), \
 250                                                                 stof(Get_Field_Value(F_FLNUM, MSG_INFO, infoname)), \
 251                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 252                                                 #endif \
 253                                                 #ifdef CSQC \
 254                                                         #if centername != NO_MSG \
 255                                                                 Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 256                                                                         stof(Get_Field_Value(F_STRNUM, MSG_CENTER, centername)), \
 257                                                                         stof(Get_Field_Value(F_FLNUM, MSG_CENTER, centername)), \
 258                                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 259                                                         #endif \
 260                                                 #endif \
 261                                         } }
 262
 263                                 MSG_DEATH_NOTIFICATIONS
 264
 265
 266                                 #undef MSG_DEATH_NOTIF
 267                                 break;
 268                         }
 269                 }
 270         }
 271         else { backtrace("Incorrect usage of Local_Notification!\n"); }
 272 }
 273
 274 void Local_Notification_Without_VarArgs(float net_type, float net_name, float stringcount, float floatcount, string s1, string s2, string s3, string s4, float f1, float f2, float f3, float f4)
 275 {
 276         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 277         EIGHT_VARS_TO_VARARGS_VARLIST
 278         #undef VARITEM
 279
 280         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 281 }
 282
 283
 284 // =========================
 285 //  Notification Networking
 286 // =========================
 287
 288 #ifdef CSQC
 289 void Read_Notification(float is_new)
 290 {
 291         float net_type = ReadByte();
 292         float net_name = ReadShort();
 293
 294         float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 295         float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 296
 297         string s1 = ((stringcount >= 1) ? ReadString() : NO_STR_ARG);
 298         string s2 = ((stringcount >= 2) ? ReadString() : NO_STR_ARG);
 299         string s3 = ((stringcount >= 3) ? ReadString() : NO_STR_ARG);
 300         string s4 = ((stringcount == 4) ? ReadString() : NO_STR_ARG);
 301         float f1 = ((floatcount >= 1) ? ReadLong() : NO_FL_ARG);
 302         float f2 = ((floatcount >= 2) ? ReadLong() : NO_FL_ARG);
 303         float f3 = ((floatcount >= 3) ? ReadLong() : NO_FL_ARG);
 304         float f4 = ((floatcount == 4) ? ReadLong() : NO_FL_ARG);
 305
 306         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 307         else { print("received old notification? net_name = ", Get_Field_Value(F_NAME, net_type, net_name), ".\n"); }
 308 }
 309 #endif
 310
 311 #ifdef SVQC
 312 void Notification_Remove()
 313 {
 314         float i;
 315         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 316         remove(self);
 317 }
 318
 319 float Write_Notification(entity client, float sf)
 320 {
 321         float i, send = FALSE;
 322
 323         switch(self.nent_broadcast)
 324         {
 325                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 326                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 327                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 328                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 329                 case NOTIF_ANY: { send = TRUE; break; }
 330                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 331                 default: { send = FALSE; break; }
 332         }
 333
 334         if(send)
 335         {
 336                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 337                 WriteByte(MSG_ENTITY, self.nent_net_type);
 338                 WriteShort(MSG_ENTITY, self.nent_net_name);
 339                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 340                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 341         }
 342
 343         return send;
 344 }
 345
 346 void Send_Notification(float broadcast, entity client, float net_type, float net_name, ...count)
 347 {
 348         if(broadcast && net_type && net_name)
 349         {
 350                 float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 351                 float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 352                 float i;
 353
 354                 dprint("Send_Notification(", ftos(broadcast), ", ", ftos(net_type), ", ", Get_Field_Value(F_NAME, net_type, net_name), strcat(", ", ftos(count), ");\n"));
 355                 dprint("  ^--: stringcount: ", ftos(stringcount), ", floatcount: ", ftos(floatcount), ".\n");
 356
 357                 if((stringcount + floatcount) > count) { backtrace(strcat("Not enough arguments for Send_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), "),"), " > count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 358                 else if((stringcount + floatcount) < count) { backtrace(strcat("Too many arguments for Send_Notification! ", strcat("stringcount(", ftos(stringcount), ") + floatcount(", ftos(floatcount), "),"), " < count(", ftos(count), ").\nCheck the notification definition and the function call for accuracy...?\n")); return; }
 359
 360                 entity notif = spawn();
 361                 notif.nent_broadcast = broadcast;
 362                 notif.nent_client = client;
 363                 notif.nent_net_type = net_type;
 364                 notif.nent_net_name = net_name;
 365                 notif.nent_stringcount = stringcount;
 366                 notif.nent_floatcount = floatcount;
 367                 for(i = 0; i < stringcount; ++i) { notif.nent_strings[i] = strzone(...(i, string)); }
 368                 for(i = 0; i < floatcount; ++i) { notif.nent_floats[i] = ...((stringcount + i), float); }
 369
 370                 notif.think = Notification_Remove;
 371                 notif.nextthink = (time + 0.5);
 372
 373                 Net_LinkEntity(notif, FALSE, 0, Write_Notification);
 374
 375                 if(!server_is_local)
 376                 {
 377                         Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3));
 378                 }
 379         }
 380         else { backtrace("Incorrect usage of Send_Notification!\n"); }
 381 }
 382
 383 void Send_Notification_Without_VarArgs(float broadcast, entity client, float net_type, float net_name, float stringcount, float floatcount, string s1, string s2, string s3, string s4, float f1, float f2, float f3, float f4)
 384 {
 385         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 386         EIGHT_VARS_TO_VARARGS_VARLIST
 387         #undef VARITEM
 388
 389         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 390 }
 391
 392 void Send_Notification_Legacy_Wrapper(float broadcast, entity client, float net_type, float net_name, string s1, string s2, float f1, float f2, float f3)
 393 {
 394         float stringcount = stof(Get_Field_Value(F_STRNUM, net_type, net_name));
 395         float floatcount = stof(Get_Field_Value(F_FLNUM, net_type, net_name));
 396         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, NO_STR_ARG, NO_STR_ARG, f1, f2, f3, NO_FL_ARG);
 397 }
 398
 399
 400 // =============================
 401 //  LEGACY NOTIFICATION SYSTEMS
 402 // =============================
 403
 404 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 405 {
 406         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 407         {
 408                 msg_entity = e;
 409                 WRITESPECTATABLE_MSG_ONE({
 410                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 411                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 412                         WriteByte(MSG_ONE, id);
 413                         WriteString(MSG_ONE, s);
 414                         if (id != 0 && s != "")
 415                         {
 416                                 WriteByte(MSG_ONE, duration);
 417                                 WriteByte(MSG_ONE, countdown_num);
 418                         }
 419                 });
 420         }
 421 }
 422 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 423 {
 424         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 425 }
 426 #endif // ifdef SVQC
 427 #endif // ifndef MENUQC