qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../triggers/include.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/miscfunctions.qh>
   8 #include "../triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option, float defaultval)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return defaultval;
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw", autocvar_sv_airaccel_qw), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw", autocvar_sv_airspeedlimit_nonqw) * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed", autocvar_sv_maxspeed) * maxspd_mod; // also slow walking
  41
  42         // old stats
  43         // fix some new settings
  44         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor", autocvar_sv_airaccel_qw_stretchfactor);
  45         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed", autocvar_sv_maxairstrafespeed);
  46         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed", autocvar_sv_maxairspeed);
  47         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate", autocvar_sv_airstrafeaccelerate);
  48         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel", autocvar_sv_warsowbunny_turnaccel);
  49         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction", autocvar_sv_airaccel_sideways_friction);
  50         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol", autocvar_sv_aircontrol);
  51         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power", autocvar_sv_aircontrol_power);
  52         STAT(MOVEVARS_AIRCONTROL_BACKWARDS, this) = Physics_ClientOption(this, "aircontrol_backwards", autocvar_sv_aircontrol_backwards);
  53         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty", autocvar_sv_aircontrol_penalty);
  54         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel", autocvar_sv_warsowbunny_airforwardaccel);
  55         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed", autocvar_sv_warsowbunny_topspeed);
  56         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel", autocvar_sv_warsowbunny_accel);
  57         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio", autocvar_sv_warsowbunny_backtosideratio);
  58         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction", autocvar_sv_friction);
  59         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate", autocvar_sv_accelerate);
  60         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed", autocvar_sv_stopspeed);
  61         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate", autocvar_sv_airaccelerate);
  62         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate", autocvar_sv_airstopaccelerate);
  63         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity", autocvar_sv_jumpvelocity);
  64         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump", autocvar_sv_track_canjump);
  65 }
  66 #endif
  67
  68 float IsMoveInDirection(vector mv, float ang) // key mix factor
  69 {
  70         if (mv_x == 0 && mv_y == 0)
  71                 return 0; // avoid division by zero
  72         ang -= RAD2DEG * atan2(mv_y, mv_x);
  73         ang = remainder(ang, 360) / 45;
  74         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  75 }
  76
  77 float GeomLerp(float a, float _lerp, float b)
  78 {
  79         return a == 0 ? (_lerp < 1 ? 0 : b)
  80                 : b == 0 ? (_lerp > 0 ? 0 : a)
  81                 : a * pow(fabs(b / a), _lerp);
  82 }
  83
  84 void PM_ClientMovement_UpdateStatus(entity this)
  85 {
  86 #ifdef CSQC
  87         if(!IS_PLAYER(this))
  88                 return;
  89
  90         // set crouched
  91         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
  92         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  93         {
  94                 entity wep = viewmodels[slot];
  95                 if(wep.hook && !wasfreed(wep.hook))
  96                 {
  97                         do_crouch = false;
  98                         break; // don't bother checking the others
  99                 }
 100         }
 101         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 102                 do_crouch = false;
 103         if(hud != HUD_NORMAL)
 104                 do_crouch = false;
 105         if(STAT(FROZEN, this))
 106                 do_crouch = false;
 107
 108         if (do_crouch)
 109         {
 110                 // wants to crouch, this always works
 111                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 112         }
 113         else
 114         {
 115                 // wants to stand, if currently crouching we need to check for a low ceiling first
 116                 if (IS_DUCKED(this))
 117                 {
 118                         tracebox(this.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), this.origin, MOVE_NORMAL, this);
 119                         if (!trace_startsolid) UNSET_DUCKED(this);
 120                 }
 121         }
 122
 123         if (IS_ONGROUND(this) || this.velocity.z <= 0 || PHYS_WATERJUMP_TIME(this) <= 0)
 124                 PHYS_WATERJUMP_TIME(this) = 0;
 125 #endif
 126 }
 127
 128 void CPM_PM_Aircontrol(entity this, float dt, vector wishdir, float wishspeed)
 129 {
 130         float movity = IsMoveInDirection(this.movement, 0);
 131         if(PHYS_AIRCONTROL_BACKWARDS(this))
 132                 movity += IsMoveInDirection(this.movement, 180);
 133
 134         float k = 32 * (2 * movity - 1);
 135         if (k <= 0)
 136                 return;
 137
 138         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 139
 140         float zspeed = this.velocity_z;
 141         this.velocity_z = 0;
 142         float xyspeed = vlen(this.velocity);
 143         this.velocity = normalize(this.velocity);
 144
 145         float dot = this.velocity * wishdir;
 146
 147         if (dot > 0) // we can't change direction while slowing down
 148         {
 149                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * dt;
 150                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 151                 k *= PHYS_AIRCONTROL(this);
 152                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 153         }
 154
 155         this.velocity = this.velocity * xyspeed;
 156         this.velocity_z = zspeed;
 157 }
 158
 159 float AdjustAirAccelQW(float accelqw, float factor)
 160 {
 161         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 162 }
 163
 164 // example config for alternate speed clamping:
 165 //   sv_airaccel_qw 0.8
 166 //   sv_airaccel_sideways_friction 0
 167 //   prvm_globalset server speedclamp_mode 1
 168 //     (or 2)
 169 void PM_Accelerate(entity this, float dt, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 170 {
 171         float speedclamp = stretchfactor > 0 ? stretchfactor
 172         : accelqw < 0 ? 1 // full clamping, no stretch
 173         : -1; // no clamping
 174
 175         accelqw = fabs(accelqw);
 176
 177         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 178                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 179
 180         float vel_straight = this.velocity * wishdir;
 181         float vel_z = this.velocity_z;
 182         vector vel_xy = vec2(this.velocity);
 183         vector vel_perpend = vel_xy - vel_straight * wishdir;
 184
 185         float step = accel * dt * wishspeed0;
 186
 187         float vel_xy_current  = vlen(vel_xy);
 188         if (speedlimit)
 189                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 190         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 191         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 192         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 193         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 194
 195         if (sidefric < 0 && (vel_perpend*vel_perpend))
 196                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 197         {
 198                 float f = max(0, 1 + dt * wishspeed * sidefric);
 199                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 200                 // assume: themin > 1
 201                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 202                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 203                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 204                 // obviously, this cannot be
 205                 if (themin <= 0)
 206                         vel_perpend *= f;
 207                 else
 208                 {
 209                         themin = sqrt(themin);
 210                         vel_perpend *= max(themin, f);
 211                 }
 212         }
 213         else
 214                 vel_perpend *= max(0, 1 - dt * wishspeed * sidefric);
 215
 216         vel_xy = vel_straight * wishdir + vel_perpend;
 217
 218         if (speedclamp >= 0)
 219         {
 220                 float vel_xy_preclamp;
 221                 vel_xy_preclamp = vlen(vel_xy);
 222                 if (vel_xy_preclamp > 0) // prevent division by zero
 223                 {
 224                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 225                         if (vel_xy_current < vel_xy_preclamp)
 226                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 227                 }
 228         }
 229
 230         this.velocity = vel_xy + vel_z * '0 0 1';
 231 }
 232
 233 void PM_AirAccelerate(entity this, float dt, vector wishdir, float wishspeed)
 234 {
 235         if (wishspeed == 0)
 236                 return;
 237
 238         vector curvel = this.velocity;
 239         curvel_z = 0;
 240         float curspeed = vlen(curvel);
 241
 242         if (wishspeed > curspeed * 1.01)
 243                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * dt);
 244         else
 245         {
 246                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 247                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * dt;
 248         }
 249         vector wishvel = wishdir * wishspeed;
 250         vector acceldir = wishvel - curvel;
 251         float addspeed = vlen(acceldir);
 252         acceldir = normalize(acceldir);
 253
 254         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * dt);
 255
 256         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 257         {
 258                 vector curdir = normalize(curvel);
 259                 float dot = acceldir * curdir;
 260                 if (dot < 0)
 261                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 262         }
 263
 264         this.velocity += accelspeed * acceldir;
 265 }
 266
 267
 268 /*
 269 =============
 270 PlayerJump
 271
 272 When you press the jump key
 273 returns true if handled
 274 =============
 275 */
 276 bool PlayerJump(entity this)
 277 {
 278         if (PHYS_FROZEN(this))
 279                 return true; // no jumping in freezetag when frozen
 280
 281 #ifdef SVQC
 282         if (this.player_blocked)
 283                 return true; // no jumping while blocked
 284 #endif
 285
 286         bool doublejump = false;
 287         float mjumpheight = PHYS_JUMPVELOCITY(this);
 288
 289         if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
 290                 return true;
 291
 292         mjumpheight = M_ARGV(1, float);
 293         doublejump = M_ARGV(2, bool);
 294
 295         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 296         {
 297                 if(this.viewloc)
 298                 {
 299                         doublejump = true;
 300                         mjumpheight *= 0.7;
 301                 }
 302                 else
 303                 {
 304                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 305                         return true;
 306                 }
 307         }
 308
 309         if (!doublejump)
 310                 if (!IS_ONGROUND(this))
 311                         return IS_JUMP_HELD(this);
 312
 313         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 314         if(PHYS_TRACK_CANJUMP(this))
 315                 track_jump = true;
 316
 317         if (track_jump)
 318                 if (IS_JUMP_HELD(this))
 319                         return true;
 320
 321         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 322         // velocity bounds.  Final velocity is bound between (jumpheight *
 323         // min + jumpheight) and (jumpheight * max + jumpheight);
 324
 325         if(PHYS_JUMPSPEEDCAP_MIN != "")
 326         {
 327                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 328
 329                 if (this.velocity_z < minjumpspeed)
 330                         mjumpheight += minjumpspeed - this.velocity_z;
 331         }
 332
 333         if(PHYS_JUMPSPEEDCAP_MAX != "")
 334         {
 335                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 336                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 337
 338                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 339                 {
 340                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 341
 342                         if (this.velocity_z > maxjumpspeed)
 343                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 344                 }
 345         }
 346
 347         if (!WAS_ONGROUND(this))
 348         {
 349 #ifdef SVQC
 350                 if(autocvar_speedmeter)
 351                         LOG_TRACE("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")");
 352 #endif
 353                 if(this.lastground < time - 0.3)
 354                 {
 355                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 356                         this.velocity_x *= f;
 357                         this.velocity_y *= f;
 358                 }
 359 #ifdef SVQC
 360                 if(this.jumppadcount > 1)
 361                         LOG_TRACE(ftos(this.jumppadcount), "x jumppad combo");
 362                 this.jumppadcount = 0;
 363 #endif
 364         }
 365
 366         this.velocity_z += mjumpheight;
 367
 368         UNSET_ONGROUND(this);
 369         SET_JUMP_HELD(this);
 370
 371 #ifdef SVQC
 372
 373         this.oldvelocity_z = this.velocity_z;
 374
 375         animdecide_setaction(this, ANIMACTION_JUMP, true);
 376
 377         if (autocvar_g_jump_grunt)
 378                 PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 379 #endif
 380         return true;
 381 }
 382
 383 void CheckWaterJump(entity this)
 384 {
 385 // check for a jump-out-of-water
 386         makevectors(this.v_angle);
 387         vector start = this.origin;
 388         start_z += 8;
 389         v_forward_z = 0;
 390         normalize(v_forward);
 391         vector end = start + v_forward*24;
 392         traceline (start, end, true, this);
 393         if (trace_fraction < 1)
 394         {       // solid at waist
 395                 start_z = start_z + this.maxs_z - 8;
 396                 end = start + v_forward*24;
 397                 this.movedir = trace_plane_normal * -50;
 398                 traceline(start, end, true, this);
 399                 if (trace_fraction == 1)
 400                 {       // open at eye level
 401                         this.velocity_z = 225;
 402                         this.flags |= FL_WATERJUMP;
 403                         SET_JUMP_HELD(this);
 404                 #ifdef SVQC
 405                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 406                 #elif defined(CSQC)
 407                         PHYS_WATERJUMP_TIME(this) = 2;
 408                 #endif
 409                 }
 410         }
 411 }
 412
 413
 414 #ifdef SVQC
 415         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 416 #elif defined(CSQC)
 417         float autocvar_cl_jetpack_jump;
 418         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 419 #endif
 420 .float jetpack_stopped;
 421 void CheckPlayerJump(entity this)
 422 {
 423 #ifdef SVQC
 424         bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
 425 #endif
 426         if (JETPACK_JUMP(this) < 2)
 427                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 428
 429         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 430         {
 431                 bool playerjump = PlayerJump(this); // required
 432
 433                 bool air_jump = !playerjump || M_ARGV(2, bool);
 434                 bool activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 435                 bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO);
 436
 437                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 438                 else if (this.jetpack_stopped) { }
 439                 else if (!has_fuel)
 440                 {
 441 #ifdef SVQC
 442                         if (was_flying) // TODO: ran out of fuel message
 443                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 444                         else if (activate)
 445                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 446 #endif
 447                         this.jetpack_stopped = true;
 448                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 449                 }
 450                 else if (activate && !PHYS_FROZEN(this))
 451                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 452         }
 453         else
 454         {
 455                 this.jetpack_stopped = false;
 456                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 457         }
 458         if (!PHYS_INPUT_BUTTON_JUMP(this))
 459                 UNSET_JUMP_HELD(this);
 460
 461         if (this.waterlevel == WATERLEVEL_SWIMMING)
 462                 CheckWaterJump(this);
 463 }
 464
 465 float racecar_angle(float forward, float down)
 466 {
 467         if (forward < 0)
 468         {
 469                 forward = -forward;
 470                 down = -down;
 471         }
 472
 473         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 474
 475         float angle_mult = forward / (800 + forward);
 476
 477         if (ret > 180)
 478                 return ret * angle_mult + 360 * (1 - angle_mult);
 479         else
 480                 return ret * angle_mult;
 481 }
 482
 483 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 484 .float specialcommand_pos;
 485 void SpecialCommand(entity this)
 486 {
 487 #ifdef SVQC
 488         if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 489                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 490 #endif
 491 }
 492
 493 bool PM_check_specialcommand(entity this, int buttons)
 494 {
 495 #ifdef SVQC
 496         string c;
 497         if (!buttons)
 498                 c = "x";
 499         else if (buttons == 1)
 500                 c = "1";
 501         else if (buttons == 2)
 502                 c = " ";
 503         else if (buttons == 128)
 504                 c = "s";
 505         else if (buttons == 256)
 506                 c = "w";
 507         else if (buttons == 512)
 508                 c = "a";
 509         else if (buttons == 1024)
 510                 c = "d";
 511         else
 512                 c = "?";
 513
 514         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 515         {
 516                 this.specialcommand_pos += 1;
 517                 if (this.specialcommand_pos >= strlen(specialcommand))
 518                 {
 519                         this.specialcommand_pos = 0;
 520                         SpecialCommand(this);
 521                         return true;
 522                 }
 523         }
 524         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 525                 this.specialcommand_pos = 0;
 526 #endif
 527         return false;
 528 }
 529
 530 void PM_check_nickspam(entity this)
 531 {
 532 #ifdef SVQC
 533         if (time >= this.nickspamtime)
 534                 return;
 535         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 536         {
 537                 // slight annoyance for nick change scripts
 538                 this.movement = -1 * this.movement;
 539                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 540
 541                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 542                 {
 543                         this.v_angle_x = random() * 360;
 544                         this.v_angle_y = random() * 360;
 545                         // at least I'm not forcing retardedview by also assigning to angles_z
 546                         this.fixangle = true;
 547                 }
 548         }
 549 #endif
 550 }
 551
 552 void PM_check_punch(entity this, float dt)
 553 {
 554 #ifdef SVQC
 555         if (this.punchangle != '0 0 0')
 556         {
 557                 float f = vlen(this.punchangle) - 10 * dt;
 558                 if (f > 0)
 559                         this.punchangle = normalize(this.punchangle) * f;
 560                 else
 561                         this.punchangle = '0 0 0';
 562         }
 563
 564         if (this.punchvector != '0 0 0')
 565         {
 566                 float f = vlen(this.punchvector) - 30 * dt;
 567                 if (f > 0)
 568                         this.punchvector = normalize(this.punchvector) * f;
 569                 else
 570                         this.punchvector = '0 0 0';
 571         }
 572 #endif
 573 }
 574
 575 // predict frozen movement, as frozen players CAN move in some cases
 576 void PM_check_frozen(entity this)
 577 {
 578         if (!PHYS_FROZEN(this))
 579                 return;
 580         if (PHYS_DODGING_FROZEN(this)
 581 #ifdef SVQC
 582         && IS_REAL_CLIENT(this)
 583 #endif
 584         )
 585         {
 586                 this.movement_x = bound(-5, this.movement.x, 5);
 587                 this.movement_y = bound(-5, this.movement.y, 5);
 588                 this.movement_z = bound(-5, this.movement.z, 5);
 589         }
 590         else
 591                 this.movement = '0 0 0';
 592
 593         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 594         if (pointcontents(midpoint) == CONTENT_WATER)
 595         {
 596                 this.velocity = this.velocity * 0.5;
 597
 598                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 599                         this.velocity_z = 200;
 600         }
 601 }
 602
 603 void PM_check_hitground(entity this)
 604 {
 605 #ifdef SVQC
 606         if (!this.wasFlying) return;
 607     this.wasFlying = false;
 608     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 609     if (time < this.ladder_time) return;
 610     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 611     {
 612         .entity weaponentity = weaponentities[slot];
 613         if(this.(weaponentity).hook)
 614                 return;
 615     }
 616     this.nextstep = time + 0.3 + random() * 0.1;
 617     trace_dphitq3surfaceflags = 0;
 618     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 619     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 620     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 621         ? GS_FALL_METAL
 622         : GS_FALL;
 623     float vol = ((IS_DUCKED(this)) ? VOL_MUFFLED : VOL_BASE);
 624     GlobalSound(this, gs, CH_PLAYER, vol, VOICETYPE_PLAYERSOUND);
 625 #endif
 626 }
 627
 628 void PM_Footsteps(entity this)
 629 {
 630 #ifdef SVQC
 631         if (!g_footsteps) return;
 632         if (IS_DUCKED(this)) return;
 633         if (time >= this.lastground + 0.2) return;
 634         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 635         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 636         {
 637                 this.nextstep = time + 0.3 + random() * 0.1;
 638                 trace_dphitq3surfaceflags = 0;
 639                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 640                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 641                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 642                         ? GS_STEP_METAL
 643                         : GS_STEP;
 644                 GlobalSound(this, gs, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 645         }
 646 #endif
 647 }
 648
 649 void PM_check_blocked(entity this)
 650 {
 651 #ifdef SVQC
 652         if (!this.player_blocked)
 653                 return;
 654         this.movement = '0 0 0';
 655         this.disableclientprediction = 1;
 656 #endif
 657 }
 658
 659 .vector oldmovement;
 660
 661 void PM_jetpack(entity this, float maxspd_mod, float dt)
 662 {
 663         //makevectors(this.v_angle.y * '0 1 0');
 664         makevectors(this.v_angle);
 665         vector wishvel = v_forward * this.movement_x
 666                                         + v_right * this.movement_y;
 667         // add remaining speed as Z component
 668         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 669         // fix speedhacks :P
 670         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 671         // add the unused velocity as up component
 672         wishvel_z = 0;
 673
 674         // if (PHYS_INPUT_BUTTON_JUMP(this))
 675                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 676
 677         // it is now normalized, so...
 678         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
 679         float a_up = PHYS_JETPACK_ACCEL_UP(this);
 680         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
 681
 682         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(self)) { a_up = PHYS_JETPACK_REVERSE_THRUST(this); }
 683
 684         wishvel_x *= a_side;
 685         wishvel_y *= a_side;
 686         wishvel_z *= a_up;
 687         wishvel_z += a_add;
 688
 689         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(self)) { wishvel_z *= -1; }
 690
 691         float best = 0;
 692         //////////////////////////////////////////////////////////////////////////////////////
 693         // finding the maximum over all vectors of above form
 694         // with wishvel having an absolute value of 1
 695         //////////////////////////////////////////////////////////////////////////////////////
 696         // we're finding the maximum over
 697         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 698         // for z in the range from -1 to 1
 699         //////////////////////////////////////////////////////////////////////////////////////
 700         // maximum is EITHER attained at the single extreme point:
 701         float a_diff = a_side * a_side - a_up * a_up;
 702         float f;
 703         if (a_diff != 0)
 704         {
 705                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 706                 if (f > -1 && f < 1) // can it be attained?
 707                 {
 708                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 709                         //print("middle\n");
 710                 }
 711         }
 712         // OR attained at z = 1:
 713         f = (a_up + a_add) * (a_up + a_add);
 714         if (f > best)
 715         {
 716                 best = f;
 717                 //print("top\n");
 718         }
 719         // OR attained at z = -1:
 720         f = (a_up - a_add) * (a_up - a_add);
 721         if (f > best)
 722         {
 723                 best = f;
 724                 //print("bottom\n");
 725         }
 726         best = sqrt(best);
 727         //////////////////////////////////////////////////////////////////////////////////////
 728
 729         //print("best possible acceleration: ", ftos(best), "\n");
 730
 731         float fxy, fz;
 732         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
 733         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 734                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 735         else
 736                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 737
 738         float fvel;
 739         fvel = vlen(wishvel);
 740         wishvel_x *= fxy;
 741         wishvel_y *= fxy;
 742         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
 743
 744         fvel = min(1, vlen(wishvel) / best);
 745         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 746                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * dt * fvel));
 747         else
 748                 f = 1;
 749
 750         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 751
 752         if (f > 0 && wishvel != '0 0 0')
 753         {
 754                 this.velocity = this.velocity + wishvel * f * dt;
 755                 UNSET_ONGROUND(this);
 756
 757 #ifdef SVQC
 758                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 759                         this.ammo_fuel -= PHYS_JETPACK_FUEL(this) * dt * fvel * f;
 760
 761                 ITEMS_STAT(this) |= IT_USING_JETPACK;
 762
 763                 // jetpack also inhibits health regeneration, but only for 1 second
 764                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 765 #endif
 766         }
 767 }
 768
 769 // used for calculating airshots
 770 bool IsFlying(entity this)
 771 {
 772         if(IS_ONGROUND(this))
 773                 return false;
 774         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 775                 return false;
 776         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
 777         if(trace_fraction < 1)
 778                 return false;
 779         return true;
 780 }
 781
 782
 783 void sys_phys_update(entity this, float dt);
 784 #if defined(SVQC)
 785 void SV_PlayerPhysics(entity this)
 786 #elif defined(CSQC)
 787 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
 788 #endif
 789 {
 790         sys_phys_update(this, PHYS_INPUT_TIMELENGTH);
 791
 792 #ifdef SVQC
 793         this.pm_frametime = frametime;
 794 #endif
 795 }