qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../triggers/include.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/miscfunctions.qh>
   8 #include "../triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return cvar(strcat("sv_", option));
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw"), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw"))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw"), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw") * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed") * maxspd_mod; // also slow walking
  41
  42         // old stats
  43         // fix some new settings
  44         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor");
  45         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed");
  46         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed");
  47         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate");
  48         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel");
  49         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction");
  50         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol");
  51         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power");
  52         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty");
  53         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel");
  54         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed");
  55         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel");
  56         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio");
  57         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction");
  58         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate");
  59         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed");
  60         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate");
  61         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate");
  62         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity");
  63         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump");
  64 }
  65 #endif
  66
  67 float IsMoveInDirection(vector mv, float ang) // key mix factor
  68 {
  69         if (mv_x == 0 && mv_y == 0)
  70                 return 0; // avoid division by zero
  71         ang -= RAD2DEG * atan2(mv_y, mv_x);
  72         ang = remainder(ang, 360) / 45;
  73         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  74 }
  75
  76 float GeomLerp(float a, float _lerp, float b)
  77 {
  78         return a == 0 ? (_lerp < 1 ? 0 : b)
  79                 : b == 0 ? (_lerp > 0 ? 0 : a)
  80                 : a * pow(fabs(b / a), _lerp);
  81 }
  82
  83 #define unstick_offsets(X) \
  84 /* 1 no nudge (just return the original if this test passes) */ \
  85         X(' 0.000  0.000  0.000') \
  86 /* 6 simple nudges */ \
  87         X(' 0.000  0.000  0.125') X('0.000  0.000 -0.125') \
  88         X('-0.125  0.000  0.000') X('0.125  0.000  0.000') \
  89         X(' 0.000 -0.125  0.000') X('0.000  0.125  0.000') \
  90 /* 4 diagonal flat nudges */ \
  91         X('-0.125 -0.125  0.000') X('0.125 -0.125  0.000') \
  92         X('-0.125  0.125  0.000') X('0.125  0.125  0.000') \
  93 /* 8 diagonal upward nudges */ \
  94         X('-0.125  0.000  0.125') X('0.125  0.000  0.125') \
  95         X(' 0.000 -0.125  0.125') X('0.000  0.125  0.125') \
  96         X('-0.125 -0.125  0.125') X('0.125 -0.125  0.125') \
  97         X('-0.125  0.125  0.125') X('0.125  0.125  0.125') \
  98 /* 8 diagonal downward nudges */ \
  99         X('-0.125  0.000 -0.125') X('0.125  0.000 -0.125') \
 100         X(' 0.000 -0.125 -0.125') X('0.000  0.125 -0.125') \
 101         X('-0.125 -0.125 -0.125') X('0.125 -0.125 -0.125') \
 102         X('-0.125  0.125 -0.125') X('0.125  0.125 -0.125') \
 103 /**/
 104
 105 void PM_ClientMovement_Unstick(entity this)
 106 {
 107         #define X(unstick_offset) \
 108         { \
 109                 vector neworigin = unstick_offset + this.origin; \
 110                 tracebox(neworigin, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL), neworigin, MOVE_NORMAL, this); \
 111                 if (!trace_startsolid) \
 112                 { \
 113                         setorigin(this, neworigin); \
 114                         return; \
 115                 } \
 116         }
 117         unstick_offsets(X);
 118         #undef X
 119 }
 120
 121 void PM_ClientMovement_UpdateStatus(entity this, bool ground)
 122 {
 123 #ifdef CSQC
 124         if(!IS_PLAYER(this))
 125                 return;
 126         // make sure player is not stuck
 127         if(autocvar_cl_movement == 3)
 128                 PM_ClientMovement_Unstick(this);
 129
 130         // set crouched
 131         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
 132         if(this.hook && !wasfreed(this.hook))
 133                 do_crouch = false;
 134         if(hud != HUD_NORMAL)
 135                 do_crouch = false;
 136         if(STAT(FROZEN, this))
 137                 do_crouch = false;
 138         if((activeweapon == WEP_SHOCKWAVE || activeweapon == WEP_SHOTGUN) && viewmodel.animstate_startframe == viewmodel.anim_fire2_x && time < viewmodel.weapon_nextthink)
 139                 do_crouch = false;
 140
 141         if (do_crouch)
 142         {
 143                 // wants to crouch, this always works
 144                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 145         }
 146         else
 147         {
 148                 // wants to stand, if currently crouching we need to check for a low ceiling first
 149                 if (IS_DUCKED(this))
 150                 {
 151                         tracebox(this.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), this.origin, MOVE_NORMAL, this);
 152                         if (!trace_startsolid) UNSET_DUCKED(this);
 153                 }
 154         }
 155
 156         // set onground
 157         vector origin1 = this.origin + '0 0 1';
 158         vector origin2 = this.origin - '0 0 1';
 159
 160         if (ground && autocvar_cl_movement == 3)
 161         {
 162                 tracebox(origin1, this.mins, this.maxs, origin2, MOVE_NORMAL, this);
 163                 if (trace_fraction < 1.0 && trace_plane_normal.z > 0.7)
 164                 {
 165                         SET_ONGROUND(this);
 166
 167                         // this code actually "predicts" an impact; so let's clip velocity first
 168                         this.velocity -= this.velocity * trace_plane_normal * trace_plane_normal;
 169                 }
 170                 else
 171                         UNSET_ONGROUND(this);
 172         }
 173
 174         if(autocvar_cl_movement == 3)
 175         {
 176                 // set watertype/waterlevel
 177                 origin1 = this.origin;
 178                 origin1.z += this.mins_z + 1;
 179                 this.waterlevel = WATERLEVEL_NONE;
 180
 181                 int thepoint = pointcontents(origin1);
 182
 183                 this.watertype = (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME);
 184
 185                 if (this.watertype)
 186                 {
 187                         this.waterlevel = WATERLEVEL_WETFEET;
 188                         origin1.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 189                         thepoint = pointcontents(origin1);
 190                         if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 191                         {
 192                                 this.waterlevel = WATERLEVEL_SWIMMING;
 193                                 origin1.z = this.origin.z + 22;
 194                                 thepoint = pointcontents(origin1);
 195                                 if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 196                                         this.waterlevel = WATERLEVEL_SUBMERGED;
 197                         }
 198                 }
 199         }
 200
 201         if (IS_ONGROUND(this) || this.velocity.z <= 0 || pmove_waterjumptime <= 0)
 202                 pmove_waterjumptime = 0;
 203 #endif
 204 }
 205
 206 void PM_ClientMovement_Move(entity this)
 207 {
 208 #ifdef CSQC
 209
 210         PM_ClientMovement_UpdateStatus(this, false);
 211         if(autocvar_cl_movement == 1)
 212                 return;
 213
 214         int bump;
 215         float t;
 216         float f;
 217         vector neworigin;
 218         vector currentorigin2;
 219         vector neworigin2;
 220         vector primalvelocity;
 221
 222         vector trace1_endpos = '0 0 0';
 223         vector trace2_endpos = '0 0 0';
 224         vector trace3_endpos = '0 0 0';
 225         float trace1_fraction = 0;
 226         float trace2_fraction = 0;
 227         float trace3_fraction = 0;
 228         vector trace1_plane_normal = '0 0 0';
 229         vector trace2_plane_normal = '0 0 0';
 230         vector trace3_plane_normal = '0 0 0';
 231
 232         primalvelocity = this.velocity;
 233         for(bump = 0, t = PHYS_INPUT_TIMELENGTH; bump < 8 && (this.velocity * this.velocity) > 0; bump++)
 234         {
 235                 neworigin = this.origin + t * this.velocity;
 236                 tracebox(this.origin, this.mins, this.maxs, neworigin, MOVE_NORMAL, this);
 237                 trace1_endpos = trace_endpos;
 238                 trace1_fraction = trace_fraction;
 239                 trace1_plane_normal = trace_plane_normal;
 240                 if(trace1_fraction < 1 && trace1_plane_normal_z == 0)
 241                 {
 242                         // may be a step or wall, try stepping up
 243                         // first move forward at a higher level
 244                         currentorigin2 = this.origin;
 245                         currentorigin2_z += PHYS_STEPHEIGHT(this);
 246                         neworigin2 = neworigin;
 247                         neworigin2_z += PHYS_STEPHEIGHT(this);
 248                         tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 249                         trace2_endpos = trace_endpos;
 250                         trace2_fraction = trace_fraction;
 251                         trace2_plane_normal = trace_plane_normal;
 252                         if(!trace_startsolid)
 253                         {
 254                                 // then move down from there
 255                                 currentorigin2 = trace2_endpos;
 256                                 neworigin2 = trace2_endpos;
 257                                 neworigin2_z = this.origin_z;
 258                                 tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 259                                 trace3_endpos = trace_endpos;
 260                                 trace3_fraction = trace_fraction;
 261                                 trace3_plane_normal = trace_plane_normal;
 262                                 // accept the new trace if it made some progress
 263                                 if(fabs(trace3_endpos_x - trace1_endpos_x) >= 0.03125 || fabs(trace3_endpos_y - trace1_endpos_y) >= 0.03125)
 264                                 {
 265                                         trace1_endpos = trace2_endpos;
 266                                         trace1_fraction = trace2_fraction;
 267                                         trace1_plane_normal = trace2_plane_normal;
 268                                         trace1_endpos = trace3_endpos;
 269                                 }
 270                         }
 271                 }
 272
 273                 // check if it moved at all
 274                 if(trace1_fraction >= 0.001)
 275                         setorigin(this, trace1_endpos);
 276
 277                 // check if it moved all the way
 278                 if(trace1_fraction == 1)
 279                         break;
 280
 281                 // this is only really needed for nogravityonground combined with gravityunaffectedbyticrate
 282                 // <LordHavoc> I'm pretty sure I commented it out solely because it seemed redundant
 283                 // this got commented out in a change that supposedly makes the code match QW better
 284                 // so if this is broken, maybe put it in an if(cls.protocol != PROTOCOL_QUAKEWORLD) block
 285                 if(trace1_plane_normal_z > 0.7)
 286                         SET_ONGROUND(this);
 287
 288                 t -= t * trace1_fraction;
 289
 290                 f = (this.velocity * trace1_plane_normal);
 291                 this.velocity = this.velocity + -f * trace1_plane_normal;
 292         }
 293         if(PHYS_TELEPORT_TIME(this) > 0)
 294                 this.velocity = primalvelocity;
 295 #endif
 296 }
 297
 298 void CPM_PM_Aircontrol(entity this, vector wishdir, float wishspeed)
 299 {
 300         float k = 32 * (2 * IsMoveInDirection(this.movement, 0) - 1);
 301         if (k <= 0)
 302                 return;
 303
 304         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 305
 306         float zspeed = this.velocity_z;
 307         this.velocity_z = 0;
 308         float xyspeed = vlen(this.velocity);
 309         this.velocity = normalize(this.velocity);
 310
 311         float dot = this.velocity * wishdir;
 312
 313         if (dot > 0) // we can't change direction while slowing down
 314         {
 315                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * PHYS_INPUT_TIMELENGTH;
 316                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 317                 k *= PHYS_AIRCONTROL(this);
 318                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 319         }
 320
 321         this.velocity = this.velocity * xyspeed;
 322         this.velocity_z = zspeed;
 323 }
 324
 325 float AdjustAirAccelQW(float accelqw, float factor)
 326 {
 327         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 328 }
 329
 330 // example config for alternate speed clamping:
 331 //   sv_airaccel_qw 0.8
 332 //   sv_airaccel_sideways_friction 0
 333 //   prvm_globalset server speedclamp_mode 1
 334 //     (or 2)
 335 void PM_Accelerate(entity this, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 336 {
 337         float speedclamp = stretchfactor > 0 ? stretchfactor
 338         : accelqw < 0 ? 1 // full clamping, no stretch
 339         : -1; // no clamping
 340
 341         accelqw = fabs(accelqw);
 342
 343         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 344                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 345
 346         float vel_straight = this.velocity * wishdir;
 347         float vel_z = this.velocity_z;
 348         vector vel_xy = vec2(this.velocity);
 349         vector vel_perpend = vel_xy - vel_straight * wishdir;
 350
 351         float step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
 352
 353         float vel_xy_current  = vlen(vel_xy);
 354         if (speedlimit)
 355                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 356         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 357         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 358         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 359         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 360
 361         if (sidefric < 0 && (vel_perpend*vel_perpend))
 362                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 363         {
 364                 float f = max(0, 1 + PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 365                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 366                 // assume: themin > 1
 367                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 368                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 369                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 370                 // obviously, this cannot be
 371                 if (themin <= 0)
 372                         vel_perpend *= f;
 373                 else
 374                 {
 375                         themin = sqrt(themin);
 376                         vel_perpend *= max(themin, f);
 377                 }
 378         }
 379         else
 380                 vel_perpend *= max(0, 1 - PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 381
 382         vel_xy = vel_straight * wishdir + vel_perpend;
 383
 384         if (speedclamp >= 0)
 385         {
 386                 float vel_xy_preclamp;
 387                 vel_xy_preclamp = vlen(vel_xy);
 388                 if (vel_xy_preclamp > 0) // prevent division by zero
 389                 {
 390                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 391                         if (vel_xy_current < vel_xy_preclamp)
 392                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 393                 }
 394         }
 395
 396         this.velocity = vel_xy + vel_z * '0 0 1';
 397 }
 398
 399 void PM_AirAccelerate(entity this, vector wishdir, float wishspeed)
 400 {
 401         if (wishspeed == 0)
 402                 return;
 403
 404         vector curvel = this.velocity;
 405         curvel_z = 0;
 406         float curspeed = vlen(curvel);
 407
 408         if (wishspeed > curspeed * 1.01)
 409                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 410         else
 411         {
 412                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 413                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH;
 414         }
 415         vector wishvel = wishdir * wishspeed;
 416         vector acceldir = wishvel - curvel;
 417         float addspeed = vlen(acceldir);
 418         acceldir = normalize(acceldir);
 419
 420         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 421
 422         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 423         {
 424                 vector curdir = normalize(curvel);
 425                 float dot = acceldir * curdir;
 426                 if (dot < 0)
 427                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 428         }
 429
 430         this.velocity += accelspeed * acceldir;
 431 }
 432
 433
 434 /*
 435 =============
 436 PlayerJump
 437
 438 When you press the jump key
 439 returns true if handled
 440 =============
 441 */
 442 bool PlayerJump(entity this)
 443 {
 444         if (PHYS_FROZEN(this))
 445                 return true; // no jumping in freezetag when frozen
 446
 447 #ifdef SVQC
 448         if (this.player_blocked)
 449                 return true; // no jumping while blocked
 450 #endif
 451
 452         bool doublejump = false;
 453         float mjumpheight = PHYS_JUMPVELOCITY(this);
 454
 455         if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
 456                 return true;
 457
 458         mjumpheight = M_ARGV(1, float);
 459         doublejump = M_ARGV(2, bool);
 460
 461         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 462         {
 463                 if(this.viewloc)
 464                 {
 465                         doublejump = true;
 466                         mjumpheight *= 0.7;
 467                 }
 468                 else
 469                 {
 470                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 471                         return true;
 472                 }
 473         }
 474
 475         if (!doublejump)
 476                 if (!IS_ONGROUND(this))
 477                         return IS_JUMP_HELD(this);
 478
 479         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 480         if(PHYS_TRACK_CANJUMP(this))
 481                 track_jump = true;
 482
 483         if (track_jump)
 484                 if (IS_JUMP_HELD(this))
 485                         return true;
 486
 487         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 488         // velocity bounds.  Final velocity is bound between (jumpheight *
 489         // min + jumpheight) and (jumpheight * max + jumpheight);
 490
 491         if(PHYS_JUMPSPEEDCAP_MIN != "")
 492         {
 493                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 494
 495                 if (this.velocity_z < minjumpspeed)
 496                         mjumpheight += minjumpspeed - this.velocity_z;
 497         }
 498
 499         if(PHYS_JUMPSPEEDCAP_MAX != "")
 500         {
 501                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 502                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 503
 504                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 505                 {
 506                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 507
 508                         if (this.velocity_z > maxjumpspeed)
 509                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 510                 }
 511         }
 512
 513         if (!WAS_ONGROUND(this))
 514         {
 515 #ifdef SVQC
 516                 if(autocvar_speedmeter)
 517                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
 518 #endif
 519                 if(this.lastground < time - 0.3)
 520                 {
 521                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 522                         this.velocity_x *= f;
 523                         this.velocity_y *= f;
 524                 }
 525 #ifdef SVQC
 526                 if(this.jumppadcount > 1)
 527                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
 528                 this.jumppadcount = 0;
 529 #endif
 530         }
 531
 532         this.velocity_z += mjumpheight;
 533
 534         UNSET_ONGROUND(this);
 535         SET_JUMP_HELD(this);
 536
 537 #ifdef SVQC
 538
 539         this.oldvelocity_z = this.velocity_z;
 540
 541         animdecide_setaction(this, ANIMACTION_JUMP, true);
 542
 543         if (autocvar_g_jump_grunt)
 544                 PlayerSound(this, playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 545 #endif
 546         return true;
 547 }
 548
 549 void CheckWaterJump(entity this)
 550 {
 551 // check for a jump-out-of-water
 552         makevectors(this.v_angle);
 553         vector start = this.origin;
 554         start_z += 8;
 555         v_forward_z = 0;
 556         normalize(v_forward);
 557         vector end = start + v_forward*24;
 558         traceline (start, end, true, this);
 559         if (trace_fraction < 1)
 560         {       // solid at waist
 561                 start_z = start_z + this.maxs_z - 8;
 562                 end = start + v_forward*24;
 563                 this.movedir = trace_plane_normal * -50;
 564                 traceline(start, end, true, this);
 565                 if (trace_fraction == 1)
 566                 {       // open at eye level
 567                         this.velocity_z = 225;
 568                         this.flags |= FL_WATERJUMP;
 569                         SET_JUMP_HELD(this);
 570                 #ifdef SVQC
 571                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 572                 #elif defined(CSQC)
 573                         pmove_waterjumptime = 2;
 574                 #endif
 575                 }
 576         }
 577 }
 578
 579
 580 #ifdef SVQC
 581         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 582 #elif defined(CSQC)
 583         float autocvar_cl_jetpack_jump;
 584         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 585 #endif
 586 .float jetpack_stopped;
 587 void CheckPlayerJump(entity this)
 588 {
 589 #ifdef SVQC
 590         bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
 591 #endif
 592         if (JETPACK_JUMP(this) < 2)
 593                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 594
 595         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 596         {
 597                 bool playerjump = PlayerJump(this); // required
 598
 599                 bool air_jump = !playerjump || M_ARGV(2, bool);
 600                 bool activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 601                 bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO);
 602
 603                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 604                 else if (this.jetpack_stopped) { }
 605                 else if (!has_fuel)
 606                 {
 607 #ifdef SVQC
 608                         if (was_flying) // TODO: ran out of fuel message
 609                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 610                         else if (activate)
 611                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 612 #endif
 613                         this.jetpack_stopped = true;
 614                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 615                 }
 616                 else if (activate && !PHYS_FROZEN(this))
 617                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 618         }
 619         else
 620         {
 621                 this.jetpack_stopped = false;
 622                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 623         }
 624         if (!PHYS_INPUT_BUTTON_JUMP(this))
 625                 UNSET_JUMP_HELD(this);
 626
 627         if (this.waterlevel == WATERLEVEL_SWIMMING)
 628                 CheckWaterJump(this);
 629 }
 630
 631 float racecar_angle(float forward, float down)
 632 {
 633         if (forward < 0)
 634         {
 635                 forward = -forward;
 636                 down = -down;
 637         }
 638
 639         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 640
 641         float angle_mult = forward / (800 + forward);
 642
 643         if (ret > 180)
 644                 return ret * angle_mult + 360 * (1 - angle_mult);
 645         else
 646                 return ret * angle_mult;
 647 }
 648
 649 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 650 .float specialcommand_pos;
 651 void SpecialCommand(entity this)
 652 {
 653 #ifdef SVQC
 654         if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 655                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 656 #endif
 657 }
 658
 659 bool PM_check_specialcommand(entity this, int buttons)
 660 {
 661 #ifdef SVQC
 662         string c;
 663         if (!buttons)
 664                 c = "x";
 665         else if (buttons == 1)
 666                 c = "1";
 667         else if (buttons == 2)
 668                 c = " ";
 669         else if (buttons == 128)
 670                 c = "s";
 671         else if (buttons == 256)
 672                 c = "w";
 673         else if (buttons == 512)
 674                 c = "a";
 675         else if (buttons == 1024)
 676                 c = "d";
 677         else
 678                 c = "?";
 679
 680         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 681         {
 682                 this.specialcommand_pos += 1;
 683                 if (this.specialcommand_pos >= strlen(specialcommand))
 684                 {
 685                         this.specialcommand_pos = 0;
 686                         SpecialCommand(this);
 687                         return true;
 688                 }
 689         }
 690         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 691                 this.specialcommand_pos = 0;
 692 #endif
 693         return false;
 694 }
 695
 696 void PM_check_nickspam(entity this)
 697 {
 698 #ifdef SVQC
 699         if (time >= this.nickspamtime)
 700                 return;
 701         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 702         {
 703                 // slight annoyance for nick change scripts
 704                 this.movement = -1 * this.movement;
 705                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 706
 707                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 708                 {
 709                         this.v_angle_x = random() * 360;
 710                         this.v_angle_y = random() * 360;
 711                         // at least I'm not forcing retardedview by also assigning to angles_z
 712                         this.fixangle = true;
 713                 }
 714         }
 715 #endif
 716 }
 717
 718 void PM_check_punch(entity this)
 719 {
 720 #ifdef SVQC
 721         if (this.punchangle != '0 0 0')
 722         {
 723                 float f = vlen(this.punchangle) - 10 * PHYS_INPUT_TIMELENGTH;
 724                 if (f > 0)
 725                         this.punchangle = normalize(this.punchangle) * f;
 726                 else
 727                         this.punchangle = '0 0 0';
 728         }
 729
 730         if (this.punchvector != '0 0 0')
 731         {
 732                 float f = vlen(this.punchvector) - 30 * PHYS_INPUT_TIMELENGTH;
 733                 if (f > 0)
 734                         this.punchvector = normalize(this.punchvector) * f;
 735                 else
 736                         this.punchvector = '0 0 0';
 737         }
 738 #endif
 739 }
 740
 741 // predict frozen movement, as frozen players CAN move in some cases
 742 void PM_check_frozen(entity this)
 743 {
 744         if (!PHYS_FROZEN(this))
 745                 return;
 746         if (PHYS_DODGING_FROZEN(this)
 747 #ifdef SVQC
 748         && IS_REAL_CLIENT(this)
 749 #endif
 750         )
 751         {
 752                 this.movement_x = bound(-5, this.movement.x, 5);
 753                 this.movement_y = bound(-5, this.movement.y, 5);
 754                 this.movement_z = bound(-5, this.movement.z, 5);
 755         }
 756         else
 757                 this.movement = '0 0 0';
 758
 759         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 760         if (pointcontents(midpoint) == CONTENT_WATER)
 761         {
 762                 this.velocity = this.velocity * 0.5;
 763
 764                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 765                         this.velocity_z = 200;
 766         }
 767 }
 768
 769 void PM_check_hitground(entity this)
 770 {
 771 #ifdef SVQC
 772         if (!this.wasFlying) return;
 773     this.wasFlying = false;
 774     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 775     if (time < this.ladder_time) return;
 776     if (this.hook) return;
 777     this.nextstep = time + 0.3 + random() * 0.1;
 778     trace_dphitq3surfaceflags = 0;
 779     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 780     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 781     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 782         ? GS_FALL_METAL
 783         : GS_FALL;
 784     GlobalSound(this, gs, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 785 #endif
 786 }
 787
 788 void PM_Footsteps(entity this)
 789 {
 790 #ifdef SVQC
 791         if (!g_footsteps) return;
 792         if (IS_DUCKED(this)) return;
 793         if (time >= this.lastground + 0.2) return;
 794         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 795         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 796         {
 797                 this.nextstep = time + 0.3 + random() * 0.1;
 798                 trace_dphitq3surfaceflags = 0;
 799                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 800                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 801                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 802                         ? GS_STEP_METAL
 803                         : GS_STEP;
 804                 GlobalSound(this, gs, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 805         }
 806 #endif
 807 }
 808
 809 void PM_check_blocked(entity this)
 810 {
 811 #ifdef SVQC
 812         if (!this.player_blocked)
 813                 return;
 814         this.movement = '0 0 0';
 815         this.disableclientprediction = 1;
 816 #endif
 817 }
 818
 819 void PM_fly(entity this, float maxspd_mod)
 820 {
 821         // noclipping or flying
 822         UNSET_ONGROUND(this);
 823
 824         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 825         makevectors(this.v_angle);
 826         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 827         vector wishvel = v_forward * this.movement.x
 828                                         + v_right * this.movement.y
 829                                         + '0 0 1' * this.movement.z;
 830         // acceleration
 831         vector wishdir = normalize(wishvel);
 832         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 833 #ifdef SVQC
 834         if(time >= PHYS_TELEPORT_TIME(this))
 835 #endif
 836                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 837         PM_ClientMovement_Move(this);
 838 }
 839
 840 void PM_swim(entity this, float maxspd_mod)
 841 {
 842         // swimming
 843         UNSET_ONGROUND(this);
 844
 845         float jump = PHYS_INPUT_BUTTON_JUMP(this);
 846         // water jump only in certain situations
 847         // this mimics quakeworld code
 848         if (jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180 && !this.viewloc)
 849         {
 850                 vector yawangles = '0 1 0' * this.v_angle.y;
 851                 makevectors(yawangles);
 852                 vector forward = v_forward;
 853                 vector spot = this.origin + 24 * forward;
 854                 spot_z += 8;
 855                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 856                 if (trace_startsolid)
 857                 {
 858                         spot_z += 24;
 859                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 860                         if (!trace_startsolid)
 861                         {
 862                                 this.velocity = forward * 50;
 863                                 this.velocity_z = 310;
 864                         #ifdef CSQC
 865                                 pmove_waterjumptime = 2;
 866                         #endif
 867                                 UNSET_ONGROUND(this);
 868                                 SET_JUMP_HELD(this);
 869                         }
 870                 }
 871         }
 872         makevectors(this.v_angle);
 873         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 874         vector wishvel = v_forward * this.movement.x
 875                                         + v_right * this.movement.y
 876                                         + '0 0 1' * this.movement.z;
 877         if(this.viewloc)
 878                 wishvel.z = -160; // drift anyway
 879         else if (wishvel == '0 0 0')
 880                 wishvel = '0 0 -60'; // drift towards bottom
 881
 882
 883         vector wishdir = normalize(wishvel);
 884         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod) * 0.7;
 885
 886         if (IS_DUCKED(this))
 887         wishspeed *= 0.5;
 888
 889 //      if (pmove_waterjumptime <= 0) // TODO: use
 890     {
 891                 // water friction
 892                 float f = 1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this);
 893                 f = min(max(0, f), 1);
 894                 this.velocity *= f;
 895
 896                 f = wishspeed - this.velocity * wishdir;
 897                 if (f > 0)
 898                 {
 899                         float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, f);
 900                         this.velocity += accelspeed * wishdir;
 901                 }
 902
 903                 // holding jump button swims upward slowly
 904                 if (jump && !this.viewloc)
 905                 {
 906 #if 0
 907                         if (this.watertype & CONTENT_LAVA)
 908                                 this.velocity_z =  50;
 909                         else if (this.watertype & CONTENT_SLIME)
 910                                 this.velocity_z =  80;
 911                         else
 912                         {
 913                                 if (IS_NEXUIZ_DERIVED(gamemode))
 914 #endif
 915                                         this.velocity_z = 200;
 916 #if 0
 917                                 else
 918                                         this.velocity_z = 100;
 919                         }
 920 #endif
 921                 }
 922         }
 923         if(this.viewloc)
 924         {
 925                 const float addspeed = wishspeed - this.velocity * wishdir;
 926                 if (addspeed > 0)
 927                 {
 928                         const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
 929                         this.velocity += accelspeed * wishdir;
 930                 }
 931         }
 932         else
 933         {
 934                 // water acceleration
 935                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 936                 PM_ClientMovement_Move(this);
 937         }
 938 }
 939
 940 .vector oldmovement;
 941 void PM_ladder(entity this, float maxspd_mod)
 942 {
 943         // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 944         UNSET_ONGROUND(this);
 945
 946         float g;
 947         g = PHYS_GRAVITY(this) * PHYS_INPUT_TIMELENGTH;
 948         if (PHYS_ENTGRAVITY(this))
 949                 g *= PHYS_ENTGRAVITY(this);
 950         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 951         {
 952                 g *= 0.5;
 953                 this.velocity_z += g;
 954         }
 955
 956         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 957         makevectors(this.v_angle);
 958         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 959         vector wishvel = v_forward * this.movement_x
 960                                         + v_right * this.movement_y
 961                                         + '0 0 1' * this.movement_z;
 962         if(this.viewloc)
 963                 wishvel.z = this.oldmovement.x;
 964         this.velocity_z += g;
 965         if (this.ladder_entity.classname == "func_water")
 966         {
 967                 float f = vlen(wishvel);
 968                 if (f > this.ladder_entity.speed)
 969                         wishvel *= (this.ladder_entity.speed / f);
 970
 971                 this.watertype = this.ladder_entity.skin;
 972                 f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 973                 if ((this.origin_z + this.view_ofs_z) < f)
 974                         this.waterlevel = WATERLEVEL_SUBMERGED;
 975                 else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f)
 976                         this.waterlevel = WATERLEVEL_SWIMMING;
 977                 else if ((this.origin_z + this.mins_z + 1) < f)
 978                         this.waterlevel = WATERLEVEL_WETFEET;
 979                 else
 980                 {
 981                         this.waterlevel = WATERLEVEL_NONE;
 982                         this.watertype = CONTENT_EMPTY;
 983                 }
 984         }
 985         // acceleration
 986         vector wishdir = normalize(wishvel);
 987         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 988         if(time >= PHYS_TELEPORT_TIME(this))
 989                 // water acceleration
 990                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this)*maxspd_mod, 1, 0, 0, 0);
 991         PM_ClientMovement_Move(this);
 992 }
 993
 994 void PM_jetpack(entity this, float maxspd_mod)
 995 {
 996         //makevectors(this.v_angle.y * '0 1 0');
 997         makevectors(this.v_angle);
 998         vector wishvel = v_forward * this.movement_x
 999                                         + v_right * this.movement_y;
1000         // add remaining speed as Z component
1001         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
1002         // fix speedhacks :P
1003         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
1004         // add the unused velocity as up component
1005         wishvel_z = 0;
1006
1007         // if (PHYS_INPUT_BUTTON_JUMP(this))
1008                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1009
1010         // it is now normalized, so...
1011         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
1012         float a_up = PHYS_JETPACK_ACCEL_UP(this);
1013         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
1014
1015         wishvel_x *= a_side;
1016         wishvel_y *= a_side;
1017         wishvel_z *= a_up;
1018         wishvel_z += a_add;
1019
1020         float best = 0;
1021         //////////////////////////////////////////////////////////////////////////////////////
1022         // finding the maximum over all vectors of above form
1023         // with wishvel having an absolute value of 1
1024         //////////////////////////////////////////////////////////////////////////////////////
1025         // we're finding the maximum over
1026         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1027         // for z in the range from -1 to 1
1028         //////////////////////////////////////////////////////////////////////////////////////
1029         // maximum is EITHER attained at the single extreme point:
1030         float a_diff = a_side * a_side - a_up * a_up;
1031         float f;
1032         if (a_diff != 0)
1033         {
1034                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1035                 if (f > -1 && f < 1) // can it be attained?
1036                 {
1037                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1038                         //print("middle\n");
1039                 }
1040         }
1041         // OR attained at z = 1:
1042         f = (a_up + a_add) * (a_up + a_add);
1043         if (f > best)
1044         {
1045                 best = f;
1046                 //print("top\n");
1047         }
1048         // OR attained at z = -1:
1049         f = (a_up - a_add) * (a_up - a_add);
1050         if (f > best)
1051         {
1052                 best = f;
1053                 //print("bottom\n");
1054         }
1055         best = sqrt(best);
1056         //////////////////////////////////////////////////////////////////////////////////////
1057
1058         //print("best possible acceleration: ", ftos(best), "\n");
1059
1060         float fxy, fz;
1061         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
1062         if (wishvel_z - PHYS_GRAVITY(this) > 0)
1063                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
1064         else
1065                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
1066
1067         float fvel;
1068         fvel = vlen(wishvel);
1069         wishvel_x *= fxy;
1070         wishvel_y *= fxy;
1071         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
1072
1073         fvel = min(1, vlen(wishvel) / best);
1074         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1075                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * PHYS_INPUT_TIMELENGTH * fvel));
1076         else
1077                 f = 1;
1078
1079         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1080
1081         if (f > 0 && wishvel != '0 0 0')
1082         {
1083                 this.velocity = this.velocity + wishvel * f * PHYS_INPUT_TIMELENGTH;
1084                 UNSET_ONGROUND(this);
1085
1086 #ifdef SVQC
1087                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1088                         this.ammo_fuel -= PHYS_JETPACK_FUEL(this) * PHYS_INPUT_TIMELENGTH * fvel * f;
1089
1090                 ITEMS_STAT(this) |= IT_USING_JETPACK;
1091
1092                 // jetpack also inhibits health regeneration, but only for 1 second
1093                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1094 #endif
1095         }
1096
1097 #ifdef CSQC
1098         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1099         if(autocvar_cl_movement == 3)
1100         {
1101                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1102                         this.velocity_z -= g * 0.5;
1103                 else
1104                         this.velocity_z -= g;
1105         }
1106         PM_ClientMovement_Move(this);
1107         if(autocvar_cl_movement == 3)
1108         {
1109                 if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1110                         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1111                                 this.velocity_z -= g * 0.5;
1112         }
1113 #endif
1114 }
1115
1116 void PM_walk(entity this, float maxspd_mod)
1117 {
1118         if (!WAS_ONGROUND(this))
1119         {
1120 #ifdef SVQC
1121                 if (autocvar_speedmeter)
1122                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
1123 #endif
1124                 if (this.lastground < time - 0.3)
1125                         this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
1126 #ifdef SVQC
1127                 if (this.jumppadcount > 1)
1128                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
1129                 this.jumppadcount = 0;
1130 #endif
1131         }
1132
1133         // walking
1134         makevectors(this.v_angle.y * '0 1 0');
1135         const vector wishvel = v_forward * this.movement.x
1136                                                 + v_right * this.movement.y;
1137         // acceleration
1138         const vector wishdir = normalize(wishvel);
1139         float wishspeed = vlen(wishvel);
1140         wishspeed = min(wishspeed, PHYS_MAXSPEED(this) * maxspd_mod);
1141         if (IS_DUCKED(this)) wishspeed *= 0.5;
1142
1143         // apply edge friction
1144         const float f2 = vlen2(vec2(this.velocity));
1145         if (f2 > 0)
1146         {
1147                 trace_dphitq3surfaceflags = 0;
1148                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
1149                 // TODO: apply edge friction
1150                 // apply ground friction
1151                 const int realfriction = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
1152                         ? PHYS_FRICTION_SLICK(this)
1153                         : PHYS_FRICTION(this);
1154
1155                 float f = sqrt(f2);
1156                 f = 1 - PHYS_INPUT_TIMELENGTH * realfriction * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
1157                 f = max(0, f);
1158                 this.velocity *= f;
1159                 /*
1160                    Mathematical analysis time!
1161
1162                    Our goal is to invert this mess.
1163
1164                    For the two cases we get:
1165                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
1166                           = v0 - PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1167                         v0 = v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1168                    and
1169                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1170                         v0 = v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1171
1172                    These cases would be chosen ONLY if:
1173                         v0 < PHYS_STOPSPEED(this)
1174                         v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
1175                         v < PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1176                    and, respectively:
1177                         v0 >= PHYS_STOPSPEED(this)
1178                         v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
1179                         v >= PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1180                  */
1181         }
1182         const float addspeed = wishspeed - this.velocity * wishdir;
1183         if (addspeed > 0)
1184         {
1185                 const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
1186                 this.velocity += accelspeed * wishdir;
1187         }
1188 #ifdef CSQC
1189         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1190         if(autocvar_cl_movement == 3)
1191         {
1192                 if (!(GAMEPLAYFIX_NOGRAVITYONGROUND))
1193                         this.velocity_z -= g * (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1);
1194         }
1195         if (vdist(this.velocity, >, 0))
1196                 PM_ClientMovement_Move(this);
1197         if(autocvar_cl_movement == 3)
1198         {
1199                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1200                         if (!IS_ONGROUND(this) || !GAMEPLAYFIX_NOGRAVITYONGROUND)
1201                                 this.velocity_z -= g * 0.5;
1202         }
1203 #endif
1204 }
1205
1206 void PM_air(entity this, float buttons_prev, float maxspd_mod)
1207 {
1208         makevectors(this.v_angle.y * '0 1 0');
1209         vector wishvel = v_forward * this.movement.x
1210                                         + v_right * this.movement.y;
1211         // acceleration
1212         vector wishdir = normalize(wishvel);
1213         float wishspeed = vlen(wishvel);
1214
1215 #ifdef SVQC
1216         if(time >= PHYS_TELEPORT_TIME(this))
1217 #elif defined(CSQC)
1218         if(pmove_waterjumptime <= 0)
1219 #endif
1220         {
1221                 float maxairspd = PHYS_MAXAIRSPEED(this) * min(maxspd_mod, 1);
1222
1223                 // apply air speed limit
1224                 float airaccelqw = PHYS_AIRACCEL_QW(this);
1225                 float wishspeed0 = wishspeed;
1226                 wishspeed = min(wishspeed, maxairspd);
1227                 if (IS_DUCKED(this))
1228                         wishspeed *= 0.5;
1229                 float airaccel = PHYS_AIRACCELERATE(this) * min(maxspd_mod, 1);
1230
1231                 float accelerating = (this.velocity * wishdir > 0);
1232                 float wishspeed2 = wishspeed;
1233
1234                 // CPM: air control
1235                 if (PHYS_AIRSTOPACCELERATE(this))
1236                 {
1237                         vector curdir = normalize(vec2(this.velocity));
1238                         airaccel += (PHYS_AIRSTOPACCELERATE(this)*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1239                 }
1240                 // note that for straight forward jumping:
1241                 // step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
1242                 // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1243                 // -->
1244                 // dv/dt = accel * maxspeed (when slow)
1245                 // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1246                 // log dv/dt = logaccel + logmaxspeed (when slow)
1247                 // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1248                 float strafity = IsMoveInDirection(this.movement, -90) + IsMoveInDirection(this.movement, +90); // if one is nonzero, other is always zero
1249                 if (PHYS_MAXAIRSTRAFESPEED(this))
1250                         wishspeed = min(wishspeed, GeomLerp(PHYS_MAXAIRSPEED(this)*maxspd_mod, strafity, PHYS_MAXAIRSTRAFESPEED(this)*maxspd_mod));
1251                 if (PHYS_AIRSTRAFEACCELERATE(this))
1252                         airaccel = GeomLerp(airaccel, strafity, PHYS_AIRSTRAFEACCELERATE(this)*maxspd_mod);
1253                 if (PHYS_AIRSTRAFEACCEL_QW(this))
1254                         airaccelqw =
1255                 (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
1256                 *
1257                 (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
1258                 // !CPM
1259
1260                 if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && this.movement.y == 0 && this.movement.x != 0)
1261                         PM_AirAccelerate(this, wishdir, wishspeed2);
1262                 else {
1263                     float sidefric = maxairspd ? (PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd) : 0;
1264                         PM_Accelerate(this, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, PHYS_AIRACCEL_QW_STRETCHFACTOR(this), sidefric, PHYS_AIRSPEEDLIMIT_NONQW(this));
1265         }
1266
1267                 if (PHYS_AIRCONTROL(this))
1268                         CPM_PM_Aircontrol(this, wishdir, wishspeed2);
1269         }
1270 #ifdef CSQC
1271         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1272         if(autocvar_cl_movement == 3)
1273         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1274                 this.velocity_z -= g * 0.5;
1275         else
1276                 this.velocity_z -= g;
1277 #endif
1278         PM_ClientMovement_Move(this);
1279 #ifdef CSQC
1280         if(autocvar_cl_movement == 3)
1281         if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1282                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1283                         this.velocity_z -= g * 0.5;
1284 #endif
1285 }
1286
1287 // used for calculating airshots
1288 bool IsFlying(entity this)
1289 {
1290         if(IS_ONGROUND(this))
1291                 return false;
1292         if(this.waterlevel >= WATERLEVEL_SWIMMING)
1293                 return false;
1294         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
1295         if(trace_fraction < 1)
1296                 return false;
1297         return true;
1298 }
1299
1300 void PM_Main(entity this)
1301 {
1302         int buttons = PHYS_INPUT_BUTTON_MASK(this);
1303 #ifdef CSQC
1304         this.items = STAT(ITEMS);
1305
1306         this.movement = PHYS_INPUT_MOVEVALUES(this);
1307
1308         this.spectatorspeed = STAT(SPECTATORSPEED);
1309
1310         this.team = myteam + 1; // is this correct?
1311         if (!(PHYS_INPUT_BUTTON_JUMP(this))) // !jump
1312                 UNSET_JUMP_HELD(this); // canjump = true
1313         pmove_waterjumptime -= PHYS_INPUT_TIMELENGTH;
1314
1315         PM_ClientMovement_UpdateStatus(this, true);
1316 #endif
1317
1318         this.oldmovement = this.movement;
1319
1320
1321 #ifdef SVQC
1322         WarpZone_PlayerPhysics_FixVAngle(this);
1323 #endif
1324         float maxspeed_mod = 1;
1325         maxspeed_mod *= PHYS_HIGHSPEED(this);
1326
1327 #ifdef SVQC
1328         Physics_UpdateStats(this, maxspeed_mod);
1329
1330         if (this.PlayerPhysplug)
1331                 if (this.PlayerPhysplug(this))
1332                         return;
1333 #elif defined(CSQC)
1334         if(hud != HUD_NORMAL)
1335                 return; // no vehicle prediction (yet)
1336 #endif
1337
1338 #ifdef SVQC
1339         anticheat_physics(this);
1340 #endif
1341
1342         if (PM_check_specialcommand(this, buttons))
1343                 return;
1344 #ifdef SVQC
1345         if (sv_maxidle > 0)
1346         {
1347                 if (buttons != this.buttons_old || this.movement != this.movement_old || this.v_angle != this.v_angle_old)
1348                         this.parm_idlesince = time;
1349         }
1350 #endif
1351         int buttons_prev = this.buttons_old;
1352         this.buttons_old = buttons;
1353         this.movement_old = this.movement;
1354         this.v_angle_old = this.v_angle;
1355
1356         PM_check_nickspam(this);
1357
1358         PM_check_punch(this);
1359 #ifdef SVQC
1360         if (IS_BOT_CLIENT(this))
1361         {
1362                 if (playerdemo_read(this))
1363                         return;
1364                 bot_think(this);
1365         }
1366 #endif
1367
1368 #ifdef SVQC
1369         if (IS_PLAYER(this))
1370         {
1371                 const bool allowed_to_move = (time >= game_starttime);
1372                 if (!allowed_to_move)
1373                 {
1374                         this.velocity = '0 0 0';
1375                         this.movetype = MOVETYPE_NONE;
1376                         this.disableclientprediction = 2;
1377                 }
1378                 else if (this.disableclientprediction == 2)
1379                 {
1380                         if (this.movetype == MOVETYPE_NONE)
1381                                 this.movetype = MOVETYPE_WALK;
1382                         this.disableclientprediction = 0;
1383                 }
1384         }
1385 #endif
1386
1387 #ifdef SVQC
1388         if (this.movetype == MOVETYPE_NONE)
1389                 return;
1390
1391         // when we get here, disableclientprediction cannot be 2
1392         this.disableclientprediction = 0;
1393 #endif
1394
1395         viewloc_PlayerPhysics(this);
1396
1397         PM_check_frozen(this);
1398
1399         PM_check_blocked(this);
1400
1401         maxspeed_mod = 1;
1402
1403         if (this.in_swamp)
1404                 maxspeed_mod *= this.swamp_slowdown; //cvar("g_balance_swamp_moverate");
1405
1406         // conveyors: first fix velocity
1407         if (this.conveyor.state)
1408                 this.velocity -= this.conveyor.movedir;
1409
1410         MUTATOR_CALLHOOK(PlayerPhysics, this);
1411
1412         if (!IS_PLAYER(this))
1413         {
1414 #ifdef SVQC
1415                 maxspeed_mod = autocvar_sv_spectator_speed_multiplier;
1416                 if (!this.spectatorspeed)
1417                         this.spectatorspeed = maxspeed_mod;
1418                 if (this.impulse && this.impulse <= 19 || (this.impulse >= 200 && this.impulse <= 209) || (this.impulse >= 220 && this.impulse <= 229))
1419                 {
1420                         if (this.lastclassname != STR_PLAYER)
1421                         {
1422                                 if (this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209))
1423                                         this.spectatorspeed = bound(1, this.spectatorspeed + 0.5, 5);
1424                                 else if (this.impulse == 11)
1425                                         this.spectatorspeed = maxspeed_mod;
1426                                 else if (this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229))
1427                                         this.spectatorspeed = bound(1, this.spectatorspeed - 0.5, 5);
1428                                 else if (this.impulse >= 1 && this.impulse <= 9)
1429                                         this.spectatorspeed = 1 + 0.5 * (this.impulse - 1);
1430                         } // otherwise just clear
1431                         this.impulse = 0;
1432                 }
1433 #endif
1434                 maxspeed_mod = this.spectatorspeed;
1435         }
1436 #ifdef SVQC
1437
1438         float spd = max(PHYS_MAXSPEED(this), PHYS_MAXAIRSPEED(this)) * maxspeed_mod;
1439         if(this.speed != spd)
1440         {
1441                 this.speed = spd;
1442                 string temps = ftos(spd);
1443                 stuffcmd(this, strcat("cl_forwardspeed ", temps, "\n"));
1444                 stuffcmd(this, strcat("cl_backspeed ", temps, "\n"));
1445                 stuffcmd(this, strcat("cl_sidespeed ", temps, "\n"));
1446                 stuffcmd(this, strcat("cl_upspeed ", temps, "\n"));
1447         }
1448
1449         if(this.jumpspeedcap_min != autocvar_sv_jumpspeedcap_min)
1450         {
1451                 this.jumpspeedcap_min = autocvar_sv_jumpspeedcap_min;
1452                 stuffcmd(this, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1453         }
1454         if(this.jumpspeedcap_max != autocvar_sv_jumpspeedcap_max)
1455         {
1456                 this.jumpspeedcap_max = autocvar_sv_jumpspeedcap_max;
1457                 stuffcmd(this, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1458         }
1459 #endif
1460
1461         if(IS_DEAD(this))
1462         {
1463                 // handle water here
1464                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
1465                 if(pointcontents(midpoint) == CONTENT_WATER)
1466                 {
1467                         this.velocity = this.velocity * 0.5;
1468
1469                         // do we want this?
1470                         //if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
1471                                 //{ this.velocity_z = 70; }
1472                 }
1473                 goto end;
1474         }
1475
1476 #ifdef SVQC
1477         if (!this.fixangle)
1478                 this.angles = '0 1 0' * this.v_angle.y;
1479 #endif
1480
1481         if (IS_PLAYER(this) && IS_ONGROUND(this))
1482         {
1483                 PM_check_hitground(this);
1484                 PM_Footsteps(this);
1485         }
1486
1487 #ifdef SVQC
1488         if(IsFlying(this))
1489                 this.wasFlying = 1;
1490 #endif
1491
1492         if (IS_PLAYER(this))
1493                 CheckPlayerJump(this);
1494
1495         if (this.flags & FL_WATERJUMP)
1496         {
1497                 this.velocity_x = this.movedir.x;
1498                 this.velocity_y = this.movedir.y;
1499                 if (time > PHYS_TELEPORT_TIME(this) || this.waterlevel == WATERLEVEL_NONE
1500                 #ifdef CSQC
1501                         || pmove_waterjumptime <= 0
1502                 #endif
1503                         )
1504                 {
1505                         this.flags &= ~FL_WATERJUMP;
1506                         PHYS_TELEPORT_TIME(this) = 0;
1507                 #ifdef CSQC
1508                         pmove_waterjumptime = 0;
1509                 #endif
1510                 }
1511         }
1512
1513         else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod))
1514                 { }
1515
1516 #ifdef SVQC
1517         else if (this.movetype == MOVETYPE_NOCLIP || this.movetype == MOVETYPE_FLY || this.movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1518 #elif defined(CSQC)
1519         else if (this.move_movetype == MOVETYPE_NOCLIP || this.move_movetype == MOVETYPE_FLY || this.move_movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1520 #endif
1521                 PM_fly(this, maxspeed_mod);
1522
1523         else if (this.waterlevel >= WATERLEVEL_SWIMMING)
1524                 PM_swim(this, maxspeed_mod);
1525
1526         else if (time < this.ladder_time)
1527                 PM_ladder(this, maxspeed_mod);
1528
1529         else if (ITEMS_STAT(this) & IT_USING_JETPACK)
1530                 PM_jetpack(this, maxspeed_mod);
1531
1532         else if (IS_ONGROUND(this))
1533                 PM_walk(this, maxspeed_mod);
1534
1535         else
1536                 PM_air(this, buttons_prev, maxspeed_mod);
1537
1538 LABEL(end)
1539         if (IS_ONGROUND(this))
1540                 this.lastground = time;
1541
1542         // conveyors: then break velocity again
1543         if(this.conveyor.state)
1544                 this.velocity += this.conveyor.movedir;
1545
1546         this.lastflags = this.flags;
1547
1548         this.lastclassname = this.classname;
1549 }
1550
1551 #if defined(SVQC)
1552 void SV_PlayerPhysics(entity this)
1553 #elif defined(CSQC)
1554 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
1555 #endif
1556 {
1557         PM_Main(this);
1558 }