qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if(!veh_hud)
  62         if(this.ItemStatus & ITS_STAYWEP)
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67 }
  68
  69 void ItemDraw(entity this)
  70 {
  71     if(this.gravity)
  72     {
  73         Movetype_Physics_MatchServer(this, false);
  74         if(IS_ONGROUND(this))
  75         { // For some reason avelocity gets set to '0 0 0' here ...
  76             this.oldorigin = this.origin;
  77             this.gravity = 0;
  78
  79             if(autocvar_cl_animate_items)
  80             { // ... so reset it if animations are requested.
  81                 if(this.ItemStatus & ITS_ANIMATE1)
  82                     this.avelocity = '0 180 0';
  83
  84                 if(this.ItemStatus & ITS_ANIMATE2)
  85                     this.avelocity = '0 -90 0';
  86             }
  87
  88             // delay is for blocking item's position for a while;
  89             // it's a workaround for dropped weapons that receive the position
  90             // another time right after they spawn overriding animation position
  91             this.onground_time = time + 0.5;
  92         }
  93     }
  94     else if (autocvar_cl_animate_items)
  95     {
  96         if(this.ItemStatus & ITS_ANIMATE1)
  97         {
  98             this.angles += this.avelocity * frametime;
  99             float fade_in = bound(0, time - this.onground_time, 1);
 100             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 101         }
 102
 103         if(this.ItemStatus & ITS_ANIMATE2)
 104         {
 105             this.angles += this.avelocity * frametime;
 106             float fade_in = bound(0, time - this.onground_time, 1);
 107             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 108         }
 109     }
 110
 111     Item_SetAlpha(this);
 112 }
 113
 114 void ItemDrawSimple(entity this)
 115 {
 116     if(this.gravity)
 117     {
 118         Movetype_Physics_MatchServer(this, false);
 119
 120         if(IS_ONGROUND(this))
 121             this.gravity = 0;
 122     }
 123
 124     Item_SetAlpha(this);
 125 }
 126
 127 void Item_PreDraw(entity this)
 128 {
 129         if(warpzone_warpzones_exist)
 130         {
 131                 // just incase warpzones were initialized last, reset these
 132                 //this.alpha = 1; // alpha is already set by the draw function
 133                 this.drawmask = MASK_NORMAL;
 134                 return;
 135         }
 136         float alph;
 137         vector org = getpropertyvec(VF_ORIGIN);
 138         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 139                 alph = 0;
 140         else if(this.fade_start)
 141                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 142         else
 143                 alph = 1;
 144         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 145         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 146                 this.alpha = alph;
 147         if(alph <= 0)
 148                 this.drawmask = 0;
 149         else
 150                 this.drawmask = MASK_NORMAL;
 151 }
 152
 153 void ItemRemove(entity this)
 154 {
 155         if(this.mdl)
 156                 strunzone(this.mdl);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin_x = ReadCoord();
 166         this.origin_y = ReadCoord();
 167         this.origin_z = ReadCoord();
 168         setorigin(this, this.origin);
 169         this.oldorigin = this.origin;
 170     }
 171
 172     if(sf & ISF_ANGLES)
 173     {
 174         this.angles_x = ReadAngle();
 175         this.angles_y = ReadAngle();
 176         this.angles_z = ReadAngle();
 177     }
 178
 179     if(sf & ISF_SIZE)
 180     {
 181         float use_bigsize = ReadByte();
 182         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 183     }
 184
 185     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 186     {
 187         this.ItemStatus = ReadByte();
 188
 189         Item_SetAlpha(this);
 190
 191         if(autocvar_cl_fullbright_items)
 192             if(this.ItemStatus & ITS_ALLOWFB)
 193                 this.effects |= EF_FULLBRIGHT;
 194
 195         if(this.ItemStatus & ITS_GLOW)
 196         {
 197             if(this.ItemStatus & ITS_AVAILABLE)
 198                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 199             else
 200                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 201         }
 202     }
 203
 204     if(sf & ISF_MODEL)
 205     {
 206         this.drawmask  = MASK_NORMAL;
 207                 set_movetype(this, MOVETYPE_TOSS);
 208                 if (isnew) IL_PUSH(g_drawables, this);
 209         this.draw       = ItemDraw;
 210         this.solid = SOLID_TRIGGER;
 211         //this.flags |= FL_ITEM;
 212
 213         bool use_bigsize = ReadByte();
 214
 215         this.fade_end = ReadShort();
 216         this.fade_start = ReadShort();
 217         if(this.fade_start && !autocvar_cl_items_nofade)
 218                 setpredraw(this, Item_PreDraw);
 219
 220         if(this.mdl)
 221             strunzone(this.mdl);
 222
 223         this.mdl = "";
 224         string _fn = ReadString();
 225
 226         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 227         {
 228             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 229             this.draw = ItemDrawSimple;
 230
 231             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 237             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 238                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 239             else
 240             {
 241                 this.draw = ItemDraw;
 242                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 243             }
 244         }
 245
 246         if(this.draw != ItemDrawSimple)
 247             this.mdl = strzone(_fn);
 248
 249
 250         if(this.mdl == "")
 251             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 252
 253         precache_model(this.mdl);
 254         _setmodel(this, this.mdl);
 255
 256         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 257     }
 258
 259     if(sf & ISF_COLORMAP)
 260     {
 261         this.colormap = ReadShort();
 262         this.item_glowmod_x = ReadByte() / 255.0;
 263         this.item_glowmod_y = ReadByte() / 255.0;
 264         this.item_glowmod_z = ReadByte() / 255.0;
 265     }
 266
 267     if(sf & ISF_DROP)
 268     {
 269         this.gravity = 1;
 270         this.pushable = true;
 271         //this.angles = '0 0 0';
 272         set_movetype(this, MOVETYPE_TOSS);
 273         this.velocity_x = ReadCoord();
 274         this.velocity_y = ReadCoord();
 275         this.velocity_z = ReadCoord();
 276         setorigin(this, this.oldorigin);
 277
 278         if(!this.move_time)
 279         {
 280             this.move_time = time;
 281             this.spawntime = time;
 282         }
 283         else
 284             this.move_time = max(this.move_time, time);
 285     }
 286
 287     if(autocvar_cl_animate_items)
 288     {
 289         if(this.ItemStatus & ITS_ANIMATE1)
 290             this.avelocity = '0 180 0';
 291
 292         if(this.ItemStatus & ITS_ANIMATE2)
 293             this.avelocity = '0 -90 0';
 294     }
 295
 296     this.entremove = ItemRemove;
 297
 298     return true;
 299 }
 300
 301 #endif
 302
 303 #ifdef SVQC
 304 bool ItemSend(entity this, entity to, int sf)
 305 {
 306         if(this.gravity)
 307                 sf |= ISF_DROP;
 308         else
 309                 sf &= ~ISF_DROP;
 310
 311         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 312         WriteByte(MSG_ENTITY, sf);
 313
 314         //WriteByte(MSG_ENTITY, this.cnt);
 315         if(sf & ISF_LOCATION)
 316         {
 317                 WriteCoord(MSG_ENTITY, this.origin.x);
 318                 WriteCoord(MSG_ENTITY, this.origin.y);
 319                 WriteCoord(MSG_ENTITY, this.origin.z);
 320         }
 321
 322         if(sf & ISF_ANGLES)
 323         {
 324                 WriteAngle(MSG_ENTITY, this.angles_x);
 325                 WriteAngle(MSG_ENTITY, this.angles_y);
 326                 WriteAngle(MSG_ENTITY, this.angles_z);
 327         }
 328
 329         if(sf & ISF_SIZE)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333         }
 334
 335         if(sf & ISF_STATUS)
 336                 WriteByte(MSG_ENTITY, this.ItemStatus);
 337
 338         if(sf & ISF_MODEL)
 339         {
 340                 Pickup p = this.itemdef;
 341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 342                 WriteShort(MSG_ENTITY, this.fade_end);
 343                 WriteShort(MSG_ENTITY, this.fade_start);
 344
 345                 if(this.mdl == "")
 346                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 347
 348                 WriteString(MSG_ENTITY, this.mdl);
 349         }
 350
 351
 352         if(sf & ISF_COLORMAP)
 353         {
 354                 WriteShort(MSG_ENTITY, this.colormap);
 355                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 357         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 358         }
 359
 360         if(sf & ISF_DROP)
 361         {
 362                 WriteCoord(MSG_ENTITY, this.velocity.x);
 363                 WriteCoord(MSG_ENTITY, this.velocity.y);
 364                 WriteCoord(MSG_ENTITY, this.velocity.z);
 365         }
 366
 367         return true;
 368 }
 369
 370 void ItemUpdate(entity this)
 371 {
 372         this.oldorigin = this.origin;
 373         this.SendFlags |= ISF_LOCATION;
 374 }
 375
 376 void UpdateItemAfterTeleport(entity this)
 377 {
 378         if(getSendEntity(this) == ItemSend)
 379                 ItemUpdate(this);
 380 }
 381
 382 bool have_pickup_item(entity this)
 383 {
 384         if(this.itemdef.instanceOfPowerup)
 385         {
 386                 if(autocvar_g_powerups > 0)
 387                         return true;
 388                 if(autocvar_g_powerups == 0)
 389                         return false;
 390         }
 391         else
 392         {
 393                 if(autocvar_g_pickup_items > 0)
 394                         return true;
 395                 if(autocvar_g_pickup_items == 0)
 396                         return false;
 397                 if(g_weaponarena)
 398                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 399                                 return false;
 400         }
 401         return true;
 402 }
 403
 404 /*
 405 float Item_Customize()
 406 {
 407         if(this.spawnshieldtime)
 408                 return true;
 409         if(this.weapons & ~other.weapons)
 410         {
 411                 this.colormod = '0 0 0';
 412                 this.glowmod = this.colormod;
 413                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 414                 return true;
 415         }
 416         else
 417         {
 418                 if(g_ghost_items)
 419                 {
 420                         this.colormod = stov(autocvar_g_ghost_items_color);
 421                         this.glowmod = this.colormod;
 422                         this.alpha = g_ghost_items;
 423                         return true;
 424                 }
 425                 else
 426                         return false;
 427         }
 428 }
 429 */
 430
 431 void Item_Show (entity e, float mode)
 432 {
 433         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 434         e.ItemStatus &= ~ITS_STAYWEP;
 435         entity def = e.itemdef;
 436         if (mode > 0)
 437         {
 438                 // make the item look normal, and be touchable
 439                 e.model = e.mdl;
 440                 e.solid = SOLID_TRIGGER;
 441                 e.spawnshieldtime = 1;
 442                 e.ItemStatus |= ITS_AVAILABLE;
 443         }
 444         else if (mode < 0)
 445         {
 446                 // hide the item completely
 447                 e.model = string_null;
 448                 e.solid = SOLID_NOT;
 449                 e.spawnshieldtime = 1;
 450                 e.ItemStatus &= ~ITS_AVAILABLE;
 451         }
 452         else {
 453         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 454                 || e.team // weapon stay isn't supported for teamed weapons
 455                 ;
 456         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 457         {
 458                 // make the item translucent and not touchable
 459                 e.model = e.mdl;
 460                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 461                 e.effects |= EF_STARDUST;
 462                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 463                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 464         }
 465         else
 466         {
 467                 //setmodel(e, "null");
 468                 e.solid = SOLID_NOT;
 469                 e.colormod = '0 0 0';
 470                 //e.glowmod = e.colormod;
 471                 e.spawnshieldtime = 1;
 472                 e.ItemStatus &= ~ITS_AVAILABLE;
 473         }}
 474
 475         if (def.m_glow)
 476                 e.ItemStatus |= ITS_GLOW;
 477
 478         if (autocvar_g_nodepthtestitems)
 479                 e.effects |= EF_NODEPTHTEST;
 480
 481
 482         if (autocvar_g_fullbrightitems)
 483                 e.ItemStatus |= ITS_ALLOWFB;
 484
 485         if (autocvar_sv_simple_items)
 486                 e.ItemStatus |= ITS_ALLOWSI;
 487
 488         // relink entity (because solid may have changed)
 489         setorigin(e, e.origin);
 490         e.SendFlags |= ISF_STATUS;
 491 }
 492
 493 void Item_Think(entity this)
 494 {
 495         this.nextthink = time;
 496         if(this.origin != this.oldorigin)
 497                 ItemUpdate(this);
 498 }
 499
 500 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 501 bool Item_ItemsTime_Allow(GameItem it);
 502 float Item_ItemsTime_UpdateTime(entity e, float t);
 503 void Item_ItemsTime_SetTime(entity e, float t);
 504 void Item_ItemsTime_SetTimesForAllPlayers();
 505
 506 void Item_Respawn (entity this)
 507 {
 508         Item_Show(this, 1);
 509         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 510         setorigin(this, this.origin);
 511
 512     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 513         {
 514                 float t = Item_ItemsTime_UpdateTime(this, 0);
 515                 Item_ItemsTime_SetTime(this, t);
 516                 Item_ItemsTime_SetTimesForAllPlayers();
 517         }
 518
 519         setthink(this, Item_Think);
 520         this.nextthink = time;
 521
 522         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 523         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 524 }
 525
 526 void Item_RespawnCountdown (entity this)
 527 {
 528         if(this.count >= ITEM_RESPAWN_TICKS)
 529         {
 530                 if(this.waypointsprite_attached)
 531                         WaypointSprite_Kill(this.waypointsprite_attached);
 532                 Item_Respawn(this);
 533         }
 534         else
 535         {
 536                 this.nextthink = time + 1;
 537                 this.count += 1;
 538                 if(this.count == 1)
 539                 {
 540                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 541                         do {
 542                                 {
 543                                         entity wi = Weapons_from(this.weapon);
 544                                         if (wi != WEP_Null) {
 545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 546                                                 wp.wp_extra = wi.m_id;
 547                                                 break;
 548                                         }
 549                                 }
 550                                 {
 551                                         entity ii = this.itemdef;
 552                                         if (ii != NULL) {
 553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 554                                                 wp.wp_extra = ii.m_id;
 555                                                 break;
 556                                         }
 557                                 }
 558                         } while (0);
 559             if(this.waypointsprite_attached)
 560             {
 561                 GameItem def = this.itemdef;
 562                 if (Item_ItemsTime_SpectatorOnly(def))
 563                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 564                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 565             }
 566                 }
 567
 568                 if(this.waypointsprite_attached)
 569                 {
 570                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 571                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 572                                 {
 573                                         msg_entity = it;
 574                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 575                                 }
 576                         });
 577
 578                         WaypointSprite_Ping(this.waypointsprite_attached);
 579                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 580                 }
 581         }
 582 }
 583
 584 void Item_RespawnThink(entity this)
 585 {
 586         this.nextthink = time;
 587         if(this.origin != this.oldorigin)
 588                 ItemUpdate(this);
 589
 590         if(time >= this.wait)
 591                 Item_Respawn(this);
 592 }
 593
 594 void Item_ScheduleRespawnIn(entity e, float t)
 595 {
 596         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 597         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 598         {
 599                 setthink(e, Item_RespawnCountdown);
 600                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 601                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 602                 e.count = 0;
 603                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 604                 Item_ItemsTime_SetTime(e, t);
 605                 Item_ItemsTime_SetTimesForAllPlayers();
 606         }
 607         else
 608         {
 609                 setthink(e, Item_RespawnThink);
 610                 e.nextthink = time;
 611                 e.scheduledrespawntime = time + t;
 612                 e.wait = time + t;
 613         }
 614 }
 615
 616 void Item_ScheduleRespawn(entity e)
 617 {
 618         if(e.respawntime > 0)
 619         {
 620                 Item_Show(e, 0);
 621                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 622         }
 623         else // if respawntime is -1, this item does not respawn
 624                 Item_Show(e, -1);
 625 }
 626
 627 void Item_ScheduleInitialRespawn(entity e)
 628 {
 629         Item_Show(e, 0);
 630         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 631 }
 632
 633 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 634 {
 635         if (!item.(ammotype))
 636                 return false;
 637
 638         if (item.spawnshieldtime)
 639         {
 640                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 641                 {
 642                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 643                         goto YEAH;
 644                 }
 645         }
 646         else if(g_weapon_stay == 2)
 647         {
 648                 float mi = min(item.(ammotype), ammomax);
 649                 if (player.(ammotype) < mi)
 650                 {
 651                         player.(ammotype) = mi;
 652                         goto YEAH;
 653                 }
 654         }
 655
 656         return false;
 657
 658 LABEL(YEAH)
 659         switch(mode)
 660         {
 661                 case ITEM_MODE_FUEL:
 662                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 663                         break;
 664                 case ITEM_MODE_HEALTH:
 665                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 666                         break;
 667                 case ITEM_MODE_ARMOR:
 668                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 669                         break;
 670                 default:
 671                         break;
 672         }
 673         return true;
 674 }
 675
 676 float Item_GiveTo(entity item, entity player)
 677 {
 678         float pickedup;
 679
 680         // if nothing happens to player, just return without taking the item
 681         pickedup = false;
 682         int _switchweapon = 0;
 683         // in case the player has autoswitch enabled do the following:
 684         // if the player is using their best weapon before items are given, they
 685         // probably want to switch to an even better weapon after items are given
 686
 687         if(player.autoswitch)
 688         {
 689                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 690                 {
 691                         .entity weaponentity = weaponentities[slot];
 692                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 693                         {
 694                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 695                                         _switchweapon |= BIT(slot);
 696
 697                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 698                                         _switchweapon |= BIT(slot);
 699                         }
 700                 }
 701         }
 702
 703         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 704         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 705         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 706         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 707         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 708         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 709         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 710         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 711
 712         if (item.itemdef.instanceOfWeaponPickup)
 713         {
 714                 WepSet w;
 715                 w = item.weapons;
 716                 w &= ~player.weapons;
 717
 718                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 719                 {
 720                         pickedup = true;
 721                         FOREACH(Weapons, it != WEP_Null, {
 722                                 if(w & (it.m_wepset))
 723                                 {
 724                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 725                                         {
 726                                                 .entity weaponentity = weaponentities[slot];
 727                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 728                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 729                                         }
 730                                         W_GiveWeapon(player, it.m_id);
 731                                 }
 732                         });
 733                 }
 734         }
 735
 736         if (item.itemdef.instanceOfPowerup)
 737         {
 738                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 739                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 740                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 741                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 742         }
 743
 744         int its;
 745         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 746         {
 747                 pickedup = true;
 748                 player.items |= its;
 749                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 750         }
 751
 752         if (item.strength_finished)
 753         {
 754                 pickedup = true;
 755                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 756         }
 757         if (item.invincible_finished)
 758         {
 759                 pickedup = true;
 760                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 761         }
 762         if (item.superweapons_finished)
 763         {
 764                 pickedup = true;
 765                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 766         }
 767
 768 LABEL(skip)
 769
 770         // always eat teamed entities
 771         if(item.team)
 772                 pickedup = true;
 773
 774         if (!pickedup)
 775                 return 0;
 776
 777         // crude hack to enforce switching weapons
 778         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 779         {
 780                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781                 {
 782                         .entity weaponentity = weaponentities[slot];
 783                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 784                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 785                 }
 786                 return 1;
 787         }
 788
 789         if(_switchweapon)
 790         {
 791                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792                 {
 793                         .entity weaponentity = weaponentities[slot];
 794                         if(_switchweapon & BIT(slot))
 795                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 796                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 797                 }
 798         }
 799
 800         return 1;
 801 }
 802
 803 void Item_Touch(entity this, entity toucher)
 804 {
 805
 806         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 807         if (this.classname == "droppedweapon")
 808         {
 809                 if (ITEM_TOUCH_NEEDKILL())
 810                 {
 811                         delete(this);
 812                         return;
 813                 }
 814         }
 815
 816         if(!(toucher.flags & FL_PICKUPITEMS)
 817         || STAT(FROZEN, toucher)
 818         || IS_DEAD(toucher)
 819         || (this.solid != SOLID_TRIGGER)
 820         || (this.owner == toucher)
 821         || (time < this.item_spawnshieldtime)
 822         ) { return; }
 823
 824         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 825         {
 826                 case MUT_ITEMTOUCH_RETURN: { return; }
 827                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 828         }
 829
 830         toucher = M_ARGV(1, entity);
 831
 832         if (this.classname == "droppedweapon")
 833         {
 834                 this.strength_finished = max(0, this.strength_finished - time);
 835                 this.invincible_finished = max(0, this.invincible_finished - time);
 836                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 837         }
 838         entity it = this.itemdef;
 839         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 840         if (!gave)
 841         {
 842                 if (this.classname == "droppedweapon")
 843                 {
 844                         // undo what we did above
 845                         this.strength_finished += time;
 846                         this.invincible_finished += time;
 847                         this.superweapons_finished += time;
 848                 }
 849                 return;
 850         }
 851
 852 LABEL(pickup)
 853
 854         toucher.last_pickup = time;
 855
 856         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 857         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 858
 859         if (this.classname == "droppedweapon")
 860                 delete (this);
 861         else if (this.spawnshieldtime)
 862         {
 863                 entity e;
 864                 if(this.team)
 865                 {
 866                         RandomSelection_Init();
 867                         IL_EACH(g_items, it.team == this.team,
 868                         {
 869                                 if(it.itemdef) // is a registered item
 870                                 {
 871                                         Item_Show(it, -1);
 872                                         RandomSelection_AddEnt(it, it.cnt, 0);
 873                                 }
 874                         });
 875                         e = RandomSelection_chosen_ent;
 876
 877                 }
 878                 else
 879                         e = this;
 880                 Item_ScheduleRespawn(e);
 881         }
 882 }
 883
 884 void Item_Reset(entity this)
 885 {
 886         Item_Show(this, !this.state);
 887         setorigin(this, this.origin);
 888
 889         if (this.classname != "droppedweapon")
 890         {
 891                 setthink(this, Item_Think);
 892                 this.nextthink = time;
 893
 894                 if (this.waypointsprite_attached)
 895                         WaypointSprite_Kill(this.waypointsprite_attached);
 896
 897                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 898                         Item_ScheduleInitialRespawn(this);
 899         }
 900 }
 901
 902 void Item_FindTeam(entity this)
 903 {
 904         entity e;
 905
 906         if(this.effects & EF_NODRAW)
 907         {
 908                 // marker for item team search
 909                 LOG_TRACE("Initializing item team ", ftos(this.team));
 910                 RandomSelection_Init();
 911                 IL_EACH(g_items, it.team == this.team,
 912                 {
 913                         if(it.itemdef) // is a registered item
 914                                 RandomSelection_AddEnt(it, it.cnt, 0);
 915                 });
 916
 917                 e = RandomSelection_chosen_ent;
 918                 e.state = 0;
 919                 Item_Show(e, 1);
 920
 921                 IL_EACH(g_items, it.team == this.team,
 922                 {
 923                         if(it.itemdef) // is a registered item
 924                         {
 925                                 if(it != e)
 926                                 {
 927                                         // make it non-spawned
 928                                         Item_Show(it, -1);
 929                                         it.state = 1; // state 1 = initially hidden item, apparently
 930                                 }
 931                                 it.effects &= ~EF_NODRAW;
 932                         }
 933                 });
 934
 935                 Item_Reset(this);
 936         }
 937 }
 938
 939 // Savage: used for item garbage-collection
 940 void RemoveItem(entity this)
 941 {
 942         if(wasfreed(this) || !this) { return; }
 943         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 944         delete(this);
 945 }
 946
 947 // pickup evaluation functions
 948 // these functions decide how desirable an item is to the bots
 949
 950 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 951
 952 float weapon_pickupevalfunc(entity player, entity item)
 953 {
 954         // See if I have it already
 955         if(player.weapons & item.weapons)
 956         {
 957                 // If I can pick it up
 958                 if(!item.spawnshieldtime)
 959                         return 0;
 960                 return ammo_pickupevalfunc(player, item);
 961         }
 962         return item.bot_pickupbasevalue;
 963 }
 964
 965 float ammo_pickupevalfunc(entity player, entity item)
 966 {
 967         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 968         entity wpn = NULL;
 969         float c = 0;
 970         float rating = 0;
 971
 972         // Detect needed ammo
 973         if(item.itemdef.instanceOfWeaponPickup)
 974         {
 975                 entity ammo = NULL;
 976                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
 977                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
 978                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
 979                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
 980                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
 981                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
 982
 983                 if(!ammo)
 984                         return 0;
 985                 wpn = item;
 986                 rating = ammo.m_botvalue;
 987         }
 988         else
 989         {
 990                 FOREACH(Weapons, it != WEP_Null, {
 991                         if(!(player.weapons & (it.m_wepset)))
 992                                 continue;
 993
 994                         switch(it.ammo_field)
 995                         {
 996                                 case ammo_shells:  need_shells  = true; break;
 997                                 case ammo_shells:  need_shells  = true; break;
 998                                 case ammo_nails:   need_nails   = true; break;
 999                                 case ammo_rockets: need_rockets = true; break;
1000                                 case ammo_cells:   need_cells   = true; break;
1001                                 case ammo_plasma:  need_plasma  = true; break;
1002                                 case ammo_fuel:    need_fuel    = true; break;
1003                         }
1004                 });
1005                 rating = item.bot_pickupbasevalue;
1006         }
1007
1008         if (need_shells)
1009         if (item.ammo_shells)
1010         if (player.ammo_shells < g_pickup_shells_max)
1011                 c = (player.ammo_shells + item.ammo_shells) / player.ammo_shells;
1012         if (need_nails)
1013         if (item.ammo_nails)
1014         if (player.ammo_nails < g_pickup_nails_max)
1015                 c = (player.ammo_nails + item.ammo_nails) / player.ammo_nails;
1016         if (need_rockets)
1017         if (item.ammo_rockets)
1018         if (player.ammo_rockets < g_pickup_rockets_max)
1019                 c = (player.ammo_rockets + item.ammo_rockets) / player.ammo_rockets;
1020         if (need_cells)
1021         if (item.ammo_cells)
1022         if (player.ammo_cells < g_pickup_cells_max)
1023                 c = (player.ammo_cells + item.ammo_cells) / player.ammo_cells;
1024         if (need_plasma)
1025         if (item.ammo_plasma)
1026         if (player.ammo_plasma < g_pickup_plasma_max)
1027                 c = (player.ammo_plasma + item.ammo_plasma) / player.ammo_plasma;
1028         if (need_fuel)
1029         if (item.ammo_fuel)
1030         if (player.ammo_fuel < g_pickup_fuel_max)
1031                 c = (player.ammo_fuel + item.ammo_fuel) / player.ammo_fuel;
1032
1033         rating *= min(3, c);
1034         if(wpn)
1035                 // Skilled bots will grab more
1036                 rating += wpn.bot_pickupbasevalue * (0.1 + 0.1 * bound(0, skill / 10, 1));
1037         return rating;
1038 }
1039
1040 float healtharmor_pickupevalfunc(entity player, entity item)
1041 {
1042         float c = 0;
1043         float rating = item.bot_pickupbasevalue;
1044
1045         if (item.armorvalue)
1046         if (player.armorvalue < item.max_armorvalue)
1047                 c = (player.armorvalue + player.health + item.armorvalue) / (max(1, player.armorvalue + player.health));
1048         if (item.health)
1049         if (player.health < item.max_health)
1050                 c = (player.health + item.health) / (max(1, player.health));
1051
1052         rating *= min(3, c);
1053         return rating;
1054 }
1055
1056 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1057 {
1058         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1059                 RemoveItem(this);
1060 }
1061
1062 void item_use(entity this, entity actor, entity trigger)
1063 {
1064         // use the touch function to handle collection
1065         gettouch(this)(this, actor);
1066 }
1067
1068 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1069 {
1070         string itemname = def.m_name;
1071         Model itemmodel = def.m_model;
1072     Sound pickupsound = def.m_sound;
1073         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1074         float pickupbasevalue = def.m_botvalue;
1075         int itemflags = def.m_itemflags;
1076
1077         startitem_failed = false;
1078
1079         this.item_model_ent = itemmodel;
1080     this.item_pickupsound_ent = pickupsound;
1081
1082         if(!this.respawntime) // both need to be set
1083         {
1084                 this.respawntime = defaultrespawntime;
1085                 this.respawntimejitter = defaultrespawntimejitter;
1086         }
1087
1088         if(!this.pickup_anyway && def.m_pickupanyway)
1089                 this.pickup_anyway = def.m_pickupanyway();
1090
1091         int itemid = def.m_itemid;
1092         this.items = itemid;
1093         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1094         this.weapon = weaponid;
1095
1096         if(!this.fade_end)
1097         {
1098                 this.fade_start = autocvar_g_items_mindist;
1099                 this.fade_end = autocvar_g_items_maxdist;
1100         }
1101
1102         if(weaponid)
1103                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1104
1105         this.flags = FL_ITEM | itemflags;
1106         IL_PUSH(g_items, this);
1107
1108         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1109         {
1110                 startitem_failed = true;
1111                 delete(this);
1112                 return;
1113         }
1114
1115         // is it a dropped weapon?
1116         if (this.classname == "droppedweapon")
1117         {
1118                 this.reset = SUB_Remove;
1119                 // it's a dropped weapon
1120                 set_movetype(this, MOVETYPE_TOSS);
1121
1122                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1123                 setthink(this, RemoveItem);
1124                 this.nextthink = time + 20;
1125
1126                 this.takedamage = DAMAGE_YES;
1127                 this.event_damage = Item_Damage;
1128
1129                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1130                 {
1131                         // if item is worthless after a timer, have it expire then
1132                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1133                 }
1134
1135                 // don't drop if in a NODROP zone (such as lava)
1136                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1137                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1138                 {
1139                         startitem_failed = true;
1140                         delete(this);
1141                         return;
1142                 }
1143         }
1144         else
1145         {
1146                 if(!have_pickup_item(this))
1147                 {
1148                         startitem_failed = true;
1149                         delete (this);
1150                         return;
1151                 }
1152
1153                 if(this.angles != '0 0 0')
1154                         this.SendFlags |= ISF_ANGLES;
1155
1156                 this.reset = Item_Reset;
1157                 // it's a level item
1158                 if(this.spawnflags & 1)
1159                         this.noalign = 1;
1160                 if (this.noalign > 0)
1161                         set_movetype(this, MOVETYPE_NONE);
1162                 else
1163                         set_movetype(this, MOVETYPE_TOSS);
1164                 // do item filtering according to game mode and other things
1165                 if (this.noalign <= 0)
1166                 {
1167                         // first nudge it off the floor a little bit to avoid math errors
1168                         setorigin(this, this.origin + '0 0 1');
1169                         // set item size before we spawn a spawnfunc_waypoint
1170                         setsize(this, def.m_mins, def.m_maxs);
1171                         this.SendFlags |= ISF_SIZE;
1172                         // note droptofloor returns false if stuck/or would fall too far
1173                         if (!this.noalign)
1174                                 droptofloor(this);
1175                         waypoint_spawnforitem(this);
1176                 }
1177
1178                 /*
1179                  * can't do it that way, as it would break maps
1180                  * TODO make a target_give like entity another way, that perhaps has
1181                  * the weapon name in a key
1182                 if(this.targetname)
1183                 {
1184                         // target_give not yet supported; maybe later
1185                         print("removed targeted ", this.classname, "\n");
1186                         startitem_failed = true;
1187                         remove (this);
1188                         return;
1189                 }
1190                 */
1191
1192                 if(this.targetname != "" && (this.spawnflags & 16))
1193                         this.use = item_use;
1194
1195                 if(autocvar_spawn_debug >= 2)
1196                 {
1197             // why not flags & fl_item?
1198                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1199                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1200                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1201                 error("Mapper sucks.");
1202             });
1203                         this.is_item = true;
1204                 }
1205
1206                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1207
1208                 precache_model(this.model);
1209                 precache_sound(this.item_pickupsound);
1210
1211                 if (   def.instanceOfPowerup
1212                         || def.instanceOfWeaponPickup
1213                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1214                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1215                         || (itemid & (IT_KEY1 | IT_KEY2))
1216                 ) this.target = "###item###"; // for finding the nearest item using find()
1217
1218                 Item_ItemsTime_SetTime(this, 0);
1219         }
1220
1221         this.bot_pickup = true;
1222         this.bot_pickupevalfunc = pickupevalfunc;
1223         this.bot_pickupbasevalue = pickupbasevalue;
1224         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1225         this.netname = itemname;
1226         settouch(this, Item_Touch);
1227         setmodel(this, MDL_Null); // precision set below
1228         //this.effects |= EF_LOWPRECISION;
1229
1230         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1231
1232         this.SendFlags |= ISF_SIZE;
1233
1234         if (!(this.spawnflags & 1024)) {
1235                 if(def.instanceOfPowerup)
1236                         this.ItemStatus |= ITS_ANIMATE1;
1237
1238                 if(this.armorvalue || this.health)
1239                         this.ItemStatus |= ITS_ANIMATE2;
1240         }
1241
1242         if(def.instanceOfWeaponPickup)
1243         {
1244                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1245                         this.colormap = 1024; // color shirt=0 pants=0 grey
1246                 else
1247                         this.gravity = 1;
1248                 if (!(this.spawnflags & 1024))
1249                         this.ItemStatus |= ITS_ANIMATE1;
1250                 this.SendFlags |= ISF_COLORMAP;
1251         }
1252
1253         this.state = 0;
1254         if(this.team) // broken, no idea why.
1255         {
1256                 if(!this.cnt)
1257                         this.cnt = 1; // item probability weight
1258
1259                 this.effects |= EF_NODRAW; // marker for item team search
1260                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1261         }
1262         else
1263                 Item_Reset(this);
1264
1265         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1266
1267         // call this hook after everything else has been done
1268         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1269         {
1270                 startitem_failed = true;
1271                 delete(this);
1272                 return;
1273         }
1274 }
1275
1276 void StartItem(entity this, GameItem def)
1277 {
1278     _StartItem(
1279         this,
1280         this.itemdef = def,
1281         def.m_respawntime(), // defaultrespawntime
1282         def.m_respawntimejitter() // defaultrespawntimejitter
1283         );
1284 }
1285
1286 spawnfunc(item_rockets)
1287 {
1288         if(!this.ammo_rockets)
1289                 this.ammo_rockets = g_pickup_rockets;
1290     StartItem(this, ITEM_Rockets);
1291 }
1292
1293 spawnfunc(item_bullets)
1294 {
1295         if(!weaponswapping)
1296         if(autocvar_sv_q3acompat_machineshotgunswap)
1297         if(this.classname != "droppedweapon")
1298         {
1299                 weaponswapping = true;
1300                 spawnfunc_item_shells(this);
1301                 weaponswapping = false;
1302                 return;
1303         }
1304
1305         if(!this.ammo_nails)
1306                 this.ammo_nails = g_pickup_nails;
1307     StartItem(this, ITEM_Bullets);
1308 }
1309
1310 spawnfunc(item_cells)
1311 {
1312         if(!this.ammo_cells)
1313                 this.ammo_cells = g_pickup_cells;
1314         StartItem(this, ITEM_Cells);
1315 }
1316
1317 spawnfunc(item_plasma)
1318 {
1319         if(!this.ammo_plasma)
1320                 this.ammo_plasma = g_pickup_plasma;
1321         StartItem(this, ITEM_Plasma);
1322 }
1323
1324 spawnfunc(item_shells)
1325 {
1326         if(!weaponswapping)
1327         if(autocvar_sv_q3acompat_machineshotgunswap)
1328         if(this.classname != "droppedweapon")
1329         {
1330                 weaponswapping = true;
1331                 spawnfunc_item_bullets(this);
1332                 weaponswapping = false;
1333                 return;
1334         }
1335
1336         if(!this.ammo_shells)
1337                 this.ammo_shells = g_pickup_shells;
1338         StartItem(this, ITEM_Shells);
1339 }
1340
1341 spawnfunc(item_armor_small)
1342 {
1343         if(!this.armorvalue)
1344                 this.armorvalue = g_pickup_armorsmall;
1345         if(!this.max_armorvalue)
1346                 this.max_armorvalue = g_pickup_armorsmall_max;
1347         StartItem(this, ITEM_ArmorSmall);
1348 }
1349
1350 spawnfunc(item_armor_medium)
1351 {
1352         if(!this.armorvalue)
1353                 this.armorvalue = g_pickup_armormedium;
1354         if(!this.max_armorvalue)
1355                 this.max_armorvalue = g_pickup_armormedium_max;
1356         StartItem(this, ITEM_ArmorMedium);
1357 }
1358
1359 spawnfunc(item_armor_big)
1360 {
1361         if(!this.armorvalue)
1362                 this.armorvalue = g_pickup_armorbig;
1363         if(!this.max_armorvalue)
1364                 this.max_armorvalue = g_pickup_armorbig_max;
1365         StartItem(this, ITEM_ArmorBig);
1366 }
1367
1368 spawnfunc(item_armor_mega)
1369 {
1370         if(!this.armorvalue)
1371                 this.armorvalue = g_pickup_armormega;
1372         if(!this.max_armorvalue)
1373                 this.max_armorvalue = g_pickup_armormega_max;
1374         StartItem(this, ITEM_ArmorMega);
1375 }
1376
1377 spawnfunc(item_health_small)
1378 {
1379         if(!this.max_health)
1380                 this.max_health = g_pickup_healthsmall_max;
1381         if(!this.health)
1382                 this.health = g_pickup_healthsmall;
1383         StartItem(this, ITEM_HealthSmall);
1384 }
1385
1386 spawnfunc(item_health_medium)
1387 {
1388         if(!this.max_health)
1389                 this.max_health = g_pickup_healthmedium_max;
1390         if(!this.health)
1391                 this.health = g_pickup_healthmedium;
1392     StartItem(this, ITEM_HealthMedium);
1393 }
1394
1395 spawnfunc(item_health_big)
1396 {
1397         if(!this.max_health)
1398                 this.max_health = g_pickup_healthbig_max;
1399         if(!this.health)
1400                 this.health = g_pickup_healthbig;
1401         StartItem(this, ITEM_HealthBig);
1402 }
1403
1404 spawnfunc(item_health_mega)
1405 {
1406     if(!this.max_health)
1407         this.max_health = g_pickup_healthmega_max;
1408     if(!this.health)
1409         this.health = g_pickup_healthmega;
1410     StartItem(this, ITEM_HealthMega);
1411 }
1412
1413 // support old misnamed entities
1414 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1415 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1416 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1417 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1418 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1419 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1420 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1421
1422 spawnfunc(item_strength)
1423 {
1424                 if(!this.strength_finished)
1425                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1426                 StartItem(this, ITEM_Strength);
1427 }
1428
1429 spawnfunc(item_invincible)
1430 {
1431                 if(!this.invincible_finished)
1432                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1433                 StartItem(this, ITEM_Shield);
1434 }
1435
1436 // compatibility:
1437 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1438
1439 void target_items_use(entity this, entity actor, entity trigger)
1440 {
1441         if(actor.classname == "droppedweapon")
1442         {
1443                 EXACTTRIGGER_TOUCH(this, trigger);
1444                 delete(actor);
1445                 return;
1446         }
1447
1448         if (!IS_PLAYER(actor))
1449                 return;
1450         if(IS_DEAD(actor))
1451                 return;
1452         if(trigger.solid == SOLID_TRIGGER)
1453         {
1454                 EXACTTRIGGER_TOUCH(this, trigger);
1455         }
1456
1457         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1458         {
1459                 delete(it);
1460         });
1461
1462         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1463                 centerprint(actor, this.message);
1464 }
1465
1466 spawnfunc(target_items)
1467 {
1468         int n, j;
1469         string s;
1470
1471         this.use = target_items_use;
1472         if(!this.strength_finished)
1473                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1474         if(!this.invincible_finished)
1475                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1476         if(!this.superweapons_finished)
1477                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1478
1479         n = tokenize_console(this.netname);
1480         if(argv(0) == "give")
1481         {
1482                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1483         }
1484         else
1485         {
1486                 for(j = 0; j < n; ++j)
1487                 {
1488                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1489                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1490                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1491                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1492                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1493                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1494                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1495                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1496                         else
1497                         {
1498                                 FOREACH(Buffs, it != BUFF_Null,
1499                                 {
1500                                         s = Buff_UndeprecateName(argv(j));
1501                                         if(s == it.m_name)
1502                                         {
1503                                                 this.buffs |= (it.m_itemid);
1504                                                 break;
1505                                         }
1506                                 });
1507                                 FOREACH(Weapons, it != WEP_Null, {
1508                                         s = W_UndeprecateName(argv(j));
1509                                         if(s == it.netname)
1510                                         {
1511                                                 this.weapons |= (it.m_wepset);
1512                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1513                                                         it.wr_init(it);
1514                                                 break;
1515                                         }
1516                                 });
1517                         }
1518                 }
1519
1520                 string itemprefix, valueprefix;
1521                 if(this.spawnflags == 0)
1522                 {
1523                         itemprefix = "";
1524                         valueprefix = "";
1525                 }
1526                 else if(this.spawnflags == 1)
1527                 {
1528                         itemprefix = "max ";
1529                         valueprefix = "max ";
1530                 }
1531                 else if(this.spawnflags == 2)
1532                 {
1533                         itemprefix = "min ";
1534                         valueprefix = "min ";
1535                 }
1536                 else if(this.spawnflags == 4)
1537                 {
1538                         itemprefix = "minus ";
1539                         valueprefix = "max ";
1540                 }
1541                 else
1542                 {
1543                         error("invalid spawnflags");
1544                         itemprefix = valueprefix = string_null;
1545                 }
1546
1547                 this.netname = "";
1548                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1549                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1550                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1551                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1552                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1553                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1554                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1555                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1556                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1557                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1558                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1559                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1560                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1561                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1562                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1563                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1564                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1565         }
1566         this.netname = strzone(this.netname);
1567         //print(this.netname, "\n");
1568
1569         n = tokenize_console(this.netname);
1570         for(j = 0; j < n; ++j)
1571         {
1572                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1573             it.wr_init(it);
1574             break;
1575                 });
1576         }
1577 }
1578
1579 spawnfunc(item_fuel)
1580 {
1581         if(!this.ammo_fuel)
1582                 this.ammo_fuel = g_pickup_fuel;
1583         StartItem(this, ITEM_JetpackFuel);
1584 }
1585
1586 spawnfunc(item_fuel_regen)
1587 {
1588         if(start_items & ITEM_JetpackRegen.m_itemid)
1589         {
1590                 spawnfunc_item_fuel(this);
1591                 return;
1592         }
1593         StartItem(this, ITEM_JetpackRegen);
1594 }
1595
1596 spawnfunc(item_jetpack)
1597 {
1598         if(!this.ammo_fuel)
1599                 this.ammo_fuel = g_pickup_fuel_jetpack;
1600         if(start_items & ITEM_Jetpack.m_itemid)
1601         {
1602                 spawnfunc_item_fuel(this);
1603                 return;
1604         }
1605         StartItem(this, ITEM_Jetpack);
1606 }
1607
1608 float GiveWeapon(entity e, float wpn, float op, float val)
1609 {
1610         WepSet v0, v1;
1611         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1612         v0 = (e.weapons & s);
1613         switch(op)
1614         {
1615                 case OP_SET:
1616                         if(val > 0)
1617                                 e.weapons |= s;
1618                         else
1619                                 e.weapons &= ~s;
1620                         break;
1621                 case OP_MIN:
1622                 case OP_PLUS:
1623                         if(val > 0)
1624                                 e.weapons |= s;
1625                         break;
1626                 case OP_MAX:
1627                         if(val <= 0)
1628                                 e.weapons &= ~s;
1629                         break;
1630                 case OP_MINUS:
1631                         if(val > 0)
1632                                 e.weapons &= ~s;
1633                         break;
1634         }
1635         v1 = (e.weapons & s);
1636         return (v0 != v1);
1637 }
1638
1639 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1640 {
1641         bool had_buff = (e.buffs & thebuff.m_itemid);
1642         switch(op)
1643         {
1644                 case OP_SET:
1645                         if(val > 0)
1646                                 e.buffs |= thebuff.m_itemid;
1647                         else
1648                                 e.buffs &= ~thebuff.m_itemid;
1649                         break;
1650                 case OP_MIN:
1651                 case OP_PLUS:
1652                         if(val > 0)
1653                                 e.buffs |= thebuff.m_itemid;
1654                         break;
1655                 case OP_MAX:
1656                         if(val <= 0)
1657                                 e.buffs &= ~thebuff.m_itemid;
1658                         break;
1659                 case OP_MINUS:
1660                         if(val > 0)
1661                                 e.buffs &= ~thebuff.m_itemid;
1662                         break;
1663         }
1664         bool have_buff = (e.buffs & thebuff.m_itemid);
1665         return (had_buff != have_buff);
1666 }
1667
1668 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1669 {
1670         if(v1 == v0)
1671                 return;
1672         if(v1 <= v0 - t)
1673         {
1674                 if(snd_decr != NULL)
1675                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1676         }
1677         else if(v0 >= v0 + t)
1678         {
1679                 if(snd_incr != NULL)
1680                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1681         }
1682 }
1683
1684 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1685 {
1686         if(v0 < v1)
1687                 e.(rotfield) = max(e.(rotfield), time + rottime);
1688         else if(v0 > v1)
1689                 e.(regenfield) = max(e.(regenfield), time + regentime);
1690 }
1691 float GiveItems(entity e, float beginarg, float endarg)
1692 {
1693         float got, i, val, op;
1694         string cmd;
1695
1696         val = 999;
1697         op = OP_SET;
1698
1699         got = 0;
1700
1701         int _switchweapon = 0;
1702
1703         if(e.autoswitch)
1704         {
1705                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1706                 {
1707                         .entity weaponentity = weaponentities[slot];
1708                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1709                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1710                                 _switchweapon |= BIT(slot);
1711                 }
1712         }
1713
1714         e.strength_finished = max(0, e.strength_finished - time);
1715         e.invincible_finished = max(0, e.invincible_finished - time);
1716         e.superweapons_finished = max(0, e.superweapons_finished - time);
1717
1718         PREGIVE(e, items);
1719         PREGIVE_WEAPONS(e);
1720         PREGIVE(e, strength_finished);
1721         PREGIVE(e, invincible_finished);
1722         PREGIVE(e, superweapons_finished);
1723         PREGIVE(e, ammo_nails);
1724         PREGIVE(e, ammo_cells);
1725         PREGIVE(e, ammo_plasma);
1726         PREGIVE(e, ammo_shells);
1727         PREGIVE(e, ammo_rockets);
1728         PREGIVE(e, ammo_fuel);
1729         PREGIVE(e, armorvalue);
1730         PREGIVE(e, health);
1731
1732         for(i = beginarg; i < endarg; ++i)
1733         {
1734                 cmd = argv(i);
1735
1736                 if(cmd == "0" || stof(cmd))
1737                 {
1738                         val = stof(cmd);
1739                         continue;
1740                 }
1741                 switch(cmd)
1742                 {
1743                         case "no":
1744                                 op = OP_MAX;
1745                                 val = 0;
1746                                 continue;
1747                         case "max":
1748                                 op = OP_MAX;
1749                                 continue;
1750                         case "min":
1751                                 op = OP_MIN;
1752                                 continue;
1753                         case "plus":
1754                                 op = OP_PLUS;
1755                                 continue;
1756                         case "minus":
1757                                 op = OP_MINUS;
1758                                 continue;
1759                         case "ALL":
1760                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1761                                 got += GiveValue(e, strength_finished, op, val);
1762                                 got += GiveValue(e, invincible_finished, op, val);
1763                                 got += GiveValue(e, superweapons_finished, op, val);
1764                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1765                         case "all":
1766                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1767                                 got += GiveValue(e, health, op, val);
1768                                 got += GiveValue(e, armorvalue, op, val);
1769                         case "allweapons":
1770                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1771                         //case "allbuffs": // all buffs makes a player god, do not want!
1772                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1773                         case "allammo":
1774                                 got += GiveValue(e, ammo_cells, op, val);
1775                                 got += GiveValue(e, ammo_plasma, op, val);
1776                                 got += GiveValue(e, ammo_shells, op, val);
1777                                 got += GiveValue(e, ammo_nails, op, val);
1778                                 got += GiveValue(e, ammo_rockets, op, val);
1779                                 got += GiveValue(e, ammo_fuel, op, val);
1780                                 break;
1781                         case "unlimited_ammo":
1782                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1783                                 break;
1784                         case "unlimited_weapon_ammo":
1785                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1786                                 break;
1787                         case "unlimited_superweapons":
1788                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1789                                 break;
1790                         case "jetpack":
1791                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1792                                 break;
1793                         case "fuel_regen":
1794                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1795                                 break;
1796                         case "strength":
1797                                 got += GiveValue(e, strength_finished, op, val);
1798                                 break;
1799                         case "invincible":
1800                                 got += GiveValue(e, invincible_finished, op, val);
1801                                 break;
1802                         case "superweapons":
1803                                 got += GiveValue(e, superweapons_finished, op, val);
1804                                 break;
1805                         case "cells":
1806                                 got += GiveValue(e, ammo_cells, op, val);
1807                                 break;
1808                         case "plasma":
1809                                 got += GiveValue(e, ammo_plasma, op, val);
1810                                 break;
1811                         case "shells":
1812                                 got += GiveValue(e, ammo_shells, op, val);
1813                                 break;
1814                         case "nails":
1815                         case "bullets":
1816                                 got += GiveValue(e, ammo_nails, op, val);
1817                                 break;
1818                         case "rockets":
1819                                 got += GiveValue(e, ammo_rockets, op, val);
1820                                 break;
1821                         case "health":
1822                                 got += GiveValue(e, health, op, val);
1823                                 break;
1824                         case "armor":
1825                                 got += GiveValue(e, armorvalue, op, val);
1826                                 break;
1827                         case "fuel":
1828                                 got += GiveValue(e, ammo_fuel, op, val);
1829                                 break;
1830                         default:
1831                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1832                                 {
1833                                         got += GiveBuff(e, it, op, val);
1834                                         break;
1835                                 });
1836                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1837                     got += GiveWeapon(e, it.m_id, op, val);
1838                     break;
1839                                 });
1840                                 break;
1841                 }
1842                 val = 999;
1843                 op = OP_SET;
1844         }
1845
1846         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1847         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1848         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1849         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1850         FOREACH(Weapons, it != WEP_Null, {
1851                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1852                 if(!(save_weapons & (it.m_wepset)))
1853                         if(e.weapons & (it.m_wepset))
1854                                 it.wr_init(it);
1855         });
1856         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1857         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1858         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1859         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1864         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1865         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1866         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1867
1868         if(e.superweapons_finished <= 0)
1869                 if(e.weapons & WEPSET_SUPERWEAPONS)
1870                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1871
1872         if(e.strength_finished <= 0)
1873                 e.strength_finished = 0;
1874         else
1875                 e.strength_finished += time;
1876         if(e.invincible_finished <= 0)
1877                 e.invincible_finished = 0;
1878         else
1879                 e.invincible_finished += time;
1880         if(e.superweapons_finished <= 0)
1881                 e.superweapons_finished = 0;
1882         else
1883                 e.superweapons_finished += time;
1884
1885         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1886         {
1887                 .entity weaponentity = weaponentities[slot];
1888                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1889                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1890                         _switchweapon |= BIT(slot);
1891         }
1892
1893         if(_switchweapon)
1894         {
1895                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1896                 {
1897                         .entity weaponentity = weaponentities[slot];
1898                         if(_switchweapon & BIT(slot))
1899                                 W_SwitchWeapon_Force(e, w_getbestweapon(e, weaponentity), weaponentity);
1900                 }
1901         }
1902
1903         return got;
1904 }
1905 #endif