qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if(!veh_hud)
  62         if(this.ItemStatus & ITS_STAYWEP)
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67 }
  68
  69 void ItemDraw(entity this)
  70 {
  71     if(this.gravity)
  72     {
  73         Movetype_Physics_MatchServer(this, false);
  74         if(IS_ONGROUND(this))
  75         { // For some reason avelocity gets set to '0 0 0' here ...
  76             this.oldorigin = this.origin;
  77             this.gravity = 0;
  78
  79             if(autocvar_cl_animate_items)
  80             { // ... so reset it if animations are requested.
  81                 if(this.ItemStatus & ITS_ANIMATE1)
  82                     this.avelocity = '0 180 0';
  83
  84                 if(this.ItemStatus & ITS_ANIMATE2)
  85                     this.avelocity = '0 -90 0';
  86             }
  87
  88             // delay is for blocking item's position for a while;
  89             // it's a workaround for dropped weapons that receive the position
  90             // another time right after they spawn overriding animation position
  91             this.onground_time = time + 0.5;
  92         }
  93     }
  94     else if (autocvar_cl_animate_items)
  95     {
  96         if(this.ItemStatus & ITS_ANIMATE1)
  97         {
  98             this.angles += this.avelocity * frametime;
  99             float fade_in = bound(0, time - this.onground_time, 1);
 100             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 101         }
 102
 103         if(this.ItemStatus & ITS_ANIMATE2)
 104         {
 105             this.angles += this.avelocity * frametime;
 106             float fade_in = bound(0, time - this.onground_time, 1);
 107             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 108         }
 109     }
 110
 111     Item_SetAlpha(this);
 112 }
 113
 114 void ItemDrawSimple(entity this)
 115 {
 116     if(this.gravity)
 117     {
 118         Movetype_Physics_MatchServer(this, false);
 119
 120         if(IS_ONGROUND(this))
 121             this.gravity = 0;
 122     }
 123
 124     Item_SetAlpha(this);
 125 }
 126
 127 void Item_PreDraw(entity this)
 128 {
 129         if(warpzone_warpzones_exist)
 130         {
 131                 // just incase warpzones were initialized last, reset these
 132                 //this.alpha = 1; // alpha is already set by the draw function
 133                 this.drawmask = MASK_NORMAL;
 134                 return;
 135         }
 136         float alph;
 137         vector org = getpropertyvec(VF_ORIGIN);
 138         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 139                 alph = 0;
 140         else if(this.fade_start)
 141                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 142         else
 143                 alph = 1;
 144         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 145         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 146                 this.alpha = alph;
 147         if(alph <= 0)
 148                 this.drawmask = 0;
 149         else
 150                 this.drawmask = MASK_NORMAL;
 151 }
 152
 153 void ItemRemove(entity this)
 154 {
 155         if(this.mdl)
 156                 strunzone(this.mdl);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin_x = ReadCoord();
 166         this.origin_y = ReadCoord();
 167         this.origin_z = ReadCoord();
 168         setorigin(this, this.origin);
 169         this.oldorigin = this.origin;
 170     }
 171
 172     if(sf & ISF_ANGLES)
 173     {
 174         this.angles_x = ReadAngle();
 175         this.angles_y = ReadAngle();
 176         this.angles_z = ReadAngle();
 177     }
 178
 179     if(sf & ISF_SIZE)
 180     {
 181         float use_bigsize = ReadByte();
 182         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 183     }
 184
 185     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 186     {
 187         this.ItemStatus = ReadByte();
 188
 189         Item_SetAlpha(this);
 190
 191         if(autocvar_cl_fullbright_items)
 192             if(this.ItemStatus & ITS_ALLOWFB)
 193                 this.effects |= EF_FULLBRIGHT;
 194
 195         if(this.ItemStatus & ITS_GLOW)
 196         {
 197             if(this.ItemStatus & ITS_AVAILABLE)
 198                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 199             else
 200                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 201         }
 202     }
 203
 204     if(sf & ISF_MODEL)
 205     {
 206         this.drawmask  = MASK_NORMAL;
 207                 set_movetype(this, MOVETYPE_TOSS);
 208                 if (isnew) IL_PUSH(g_drawables, this);
 209         this.draw       = ItemDraw;
 210         this.solid = SOLID_TRIGGER;
 211         //this.flags |= FL_ITEM;
 212
 213         bool use_bigsize = ReadByte();
 214
 215         this.fade_end = ReadShort();
 216         this.fade_start = ReadShort();
 217         if(this.fade_start && !autocvar_cl_items_nofade)
 218                 setpredraw(this, Item_PreDraw);
 219
 220         if(this.mdl)
 221             strunzone(this.mdl);
 222
 223         this.mdl = "";
 224         string _fn = ReadString();
 225
 226         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 227         {
 228             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 229             this.draw = ItemDrawSimple;
 230
 231             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 237             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 238                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 239             else
 240             {
 241                 this.draw = ItemDraw;
 242                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 243             }
 244         }
 245
 246         if(this.draw != ItemDrawSimple)
 247             this.mdl = strzone(_fn);
 248
 249
 250         if(this.mdl == "")
 251             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 252
 253         precache_model(this.mdl);
 254         _setmodel(this, this.mdl);
 255
 256         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 257     }
 258
 259     if(sf & ISF_COLORMAP)
 260     {
 261         this.colormap = ReadShort();
 262         this.item_glowmod_x = ReadByte() / 255.0;
 263         this.item_glowmod_y = ReadByte() / 255.0;
 264         this.item_glowmod_z = ReadByte() / 255.0;
 265     }
 266
 267     if(sf & ISF_DROP)
 268     {
 269         this.gravity = 1;
 270         this.pushable = true;
 271         //this.angles = '0 0 0';
 272         set_movetype(this, MOVETYPE_TOSS);
 273         this.velocity_x = ReadCoord();
 274         this.velocity_y = ReadCoord();
 275         this.velocity_z = ReadCoord();
 276         setorigin(this, this.oldorigin);
 277
 278         if(!this.move_time)
 279         {
 280             this.move_time = time;
 281             this.spawntime = time;
 282         }
 283         else
 284             this.move_time = max(this.move_time, time);
 285     }
 286
 287     if(autocvar_cl_animate_items)
 288     {
 289         if(this.ItemStatus & ITS_ANIMATE1)
 290             this.avelocity = '0 180 0';
 291
 292         if(this.ItemStatus & ITS_ANIMATE2)
 293             this.avelocity = '0 -90 0';
 294     }
 295
 296     this.entremove = ItemRemove;
 297
 298     return true;
 299 }
 300
 301 #endif
 302
 303 #ifdef SVQC
 304 bool ItemSend(entity this, entity to, int sf)
 305 {
 306         if(this.gravity)
 307                 sf |= ISF_DROP;
 308         else
 309                 sf &= ~ISF_DROP;
 310
 311         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 312         WriteByte(MSG_ENTITY, sf);
 313
 314         //WriteByte(MSG_ENTITY, this.cnt);
 315         if(sf & ISF_LOCATION)
 316         {
 317                 WriteCoord(MSG_ENTITY, this.origin.x);
 318                 WriteCoord(MSG_ENTITY, this.origin.y);
 319                 WriteCoord(MSG_ENTITY, this.origin.z);
 320         }
 321
 322         if(sf & ISF_ANGLES)
 323         {
 324                 WriteAngle(MSG_ENTITY, this.angles_x);
 325                 WriteAngle(MSG_ENTITY, this.angles_y);
 326                 WriteAngle(MSG_ENTITY, this.angles_z);
 327         }
 328
 329         if(sf & ISF_SIZE)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333         }
 334
 335         if(sf & ISF_STATUS)
 336                 WriteByte(MSG_ENTITY, this.ItemStatus);
 337
 338         if(sf & ISF_MODEL)
 339         {
 340                 Pickup p = this.itemdef;
 341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 342                 WriteShort(MSG_ENTITY, this.fade_end);
 343                 WriteShort(MSG_ENTITY, this.fade_start);
 344
 345                 if(this.mdl == "")
 346                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 347
 348                 WriteString(MSG_ENTITY, this.mdl);
 349         }
 350
 351
 352         if(sf & ISF_COLORMAP)
 353         {
 354                 WriteShort(MSG_ENTITY, this.colormap);
 355                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 357         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 358         }
 359
 360         if(sf & ISF_DROP)
 361         {
 362                 WriteCoord(MSG_ENTITY, this.velocity.x);
 363                 WriteCoord(MSG_ENTITY, this.velocity.y);
 364                 WriteCoord(MSG_ENTITY, this.velocity.z);
 365         }
 366
 367         return true;
 368 }
 369
 370 void ItemUpdate(entity this)
 371 {
 372         this.oldorigin = this.origin;
 373         this.SendFlags |= ISF_LOCATION;
 374 }
 375
 376 void UpdateItemAfterTeleport(entity this)
 377 {
 378         if(getSendEntity(this) == ItemSend)
 379                 ItemUpdate(this);
 380 }
 381
 382 bool have_pickup_item(entity this)
 383 {
 384         if(this.itemdef.instanceOfPowerup)
 385         {
 386                 if(autocvar_g_powerups > 0)
 387                         return true;
 388                 if(autocvar_g_powerups == 0)
 389                         return false;
 390         }
 391         else
 392         {
 393                 if(autocvar_g_pickup_items > 0)
 394                         return true;
 395                 if(autocvar_g_pickup_items == 0)
 396                         return false;
 397                 if(g_weaponarena)
 398                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 399                                 return false;
 400         }
 401         return true;
 402 }
 403
 404 /*
 405 float Item_Customize()
 406 {
 407         if(this.spawnshieldtime)
 408                 return true;
 409         if(this.weapons & ~other.weapons)
 410         {
 411                 this.colormod = '0 0 0';
 412                 this.glowmod = this.colormod;
 413                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 414                 return true;
 415         }
 416         else
 417         {
 418                 if(g_ghost_items)
 419                 {
 420                         this.colormod = stov(autocvar_g_ghost_items_color);
 421                         this.glowmod = this.colormod;
 422                         this.alpha = g_ghost_items;
 423                         return true;
 424                 }
 425                 else
 426                         return false;
 427         }
 428 }
 429 */
 430
 431 void Item_Show (entity e, float mode)
 432 {
 433         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 434         e.ItemStatus &= ~ITS_STAYWEP;
 435         entity def = e.itemdef;
 436         if (mode > 0)
 437         {
 438                 // make the item look normal, and be touchable
 439                 e.model = e.mdl;
 440                 e.solid = SOLID_TRIGGER;
 441                 e.spawnshieldtime = 1;
 442                 e.ItemStatus |= ITS_AVAILABLE;
 443         }
 444         else if (mode < 0)
 445         {
 446                 // hide the item completely
 447                 e.model = string_null;
 448                 e.solid = SOLID_NOT;
 449                 e.spawnshieldtime = 1;
 450                 e.ItemStatus &= ~ITS_AVAILABLE;
 451         }
 452         else {
 453         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 454                 || e.team // weapon stay isn't supported for teamed weapons
 455                 ;
 456         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 457         {
 458                 // make the item translucent and not touchable
 459                 e.model = e.mdl;
 460                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 461                 e.effects |= EF_STARDUST;
 462                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 463                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 464         }
 465         else
 466         {
 467                 //setmodel(e, "null");
 468                 e.solid = SOLID_NOT;
 469                 e.colormod = '0 0 0';
 470                 //e.glowmod = e.colormod;
 471                 e.spawnshieldtime = 1;
 472                 e.ItemStatus &= ~ITS_AVAILABLE;
 473         }}
 474
 475         if (def.m_glow)
 476                 e.ItemStatus |= ITS_GLOW;
 477
 478         if (autocvar_g_nodepthtestitems)
 479                 e.effects |= EF_NODEPTHTEST;
 480
 481
 482         if (autocvar_g_fullbrightitems)
 483                 e.ItemStatus |= ITS_ALLOWFB;
 484
 485         if (autocvar_sv_simple_items)
 486                 e.ItemStatus |= ITS_ALLOWSI;
 487
 488         // relink entity (because solid may have changed)
 489         setorigin(e, e.origin);
 490         e.SendFlags |= ISF_STATUS;
 491 }
 492
 493 void Item_Think(entity this)
 494 {
 495         this.nextthink = time;
 496         if(this.origin != this.oldorigin)
 497                 ItemUpdate(this);
 498 }
 499
 500 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 501 bool Item_ItemsTime_Allow(GameItem it);
 502 float Item_ItemsTime_UpdateTime(entity e, float t);
 503 void Item_ItemsTime_SetTime(entity e, float t);
 504 void Item_ItemsTime_SetTimesForAllPlayers();
 505
 506 void Item_Respawn (entity this)
 507 {
 508         Item_Show(this, 1);
 509         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 510         setorigin(this, this.origin);
 511
 512     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 513         {
 514                 float t = Item_ItemsTime_UpdateTime(this, 0);
 515                 Item_ItemsTime_SetTime(this, t);
 516                 Item_ItemsTime_SetTimesForAllPlayers();
 517         }
 518
 519         setthink(this, Item_Think);
 520         this.nextthink = time;
 521
 522         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 523         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 524 }
 525
 526 void Item_RespawnCountdown (entity this)
 527 {
 528         if(this.count >= ITEM_RESPAWN_TICKS)
 529         {
 530                 if(this.waypointsprite_attached)
 531                         WaypointSprite_Kill(this.waypointsprite_attached);
 532                 Item_Respawn(this);
 533         }
 534         else
 535         {
 536                 this.nextthink = time + 1;
 537                 this.count += 1;
 538                 if(this.count == 1)
 539                 {
 540                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 541                         do {
 542                                 {
 543                                         entity wi = Weapons_from(this.weapon);
 544                                         if (wi != WEP_Null) {
 545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 546                                                 wp.wp_extra = wi.m_id;
 547                                                 break;
 548                                         }
 549                                 }
 550                                 {
 551                                         entity ii = this.itemdef;
 552                                         if (ii != NULL) {
 553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 554                                                 wp.wp_extra = ii.m_id;
 555                                                 break;
 556                                         }
 557                                 }
 558                         } while (0);
 559             if(this.waypointsprite_attached)
 560             {
 561                 GameItem def = this.itemdef;
 562                 if (Item_ItemsTime_SpectatorOnly(def))
 563                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 564                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 565             }
 566                 }
 567
 568                 if(this.waypointsprite_attached)
 569                 {
 570                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 571                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 572                                 {
 573                                         msg_entity = it;
 574                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 575                                 }
 576                         });
 577
 578                         WaypointSprite_Ping(this.waypointsprite_attached);
 579                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 580                 }
 581         }
 582 }
 583
 584 void Item_RespawnThink(entity this)
 585 {
 586         this.nextthink = time;
 587         if(this.origin != this.oldorigin)
 588                 ItemUpdate(this);
 589
 590         if(time >= this.wait)
 591                 Item_Respawn(this);
 592 }
 593
 594 void Item_ScheduleRespawnIn(entity e, float t)
 595 {
 596         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 597         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 598         {
 599                 setthink(e, Item_RespawnCountdown);
 600                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 601                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 602                 e.count = 0;
 603                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 604                 Item_ItemsTime_SetTime(e, t);
 605                 Item_ItemsTime_SetTimesForAllPlayers();
 606         }
 607         else
 608         {
 609                 setthink(e, Item_RespawnThink);
 610                 e.nextthink = time;
 611                 e.scheduledrespawntime = time + t;
 612                 e.wait = time + t;
 613         }
 614 }
 615
 616 void Item_ScheduleRespawn(entity e)
 617 {
 618         if(e.respawntime > 0)
 619         {
 620                 Item_Show(e, 0);
 621                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 622         }
 623         else // if respawntime is -1, this item does not respawn
 624                 Item_Show(e, -1);
 625 }
 626
 627 void Item_ScheduleInitialRespawn(entity e)
 628 {
 629         Item_Show(e, 0);
 630         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 631 }
 632
 633 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 634 {
 635         if (!item.(ammotype))
 636                 return false;
 637
 638         if (item.spawnshieldtime)
 639         {
 640                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 641                 {
 642                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 643                         goto YEAH;
 644                 }
 645         }
 646         else if(g_weapon_stay == 2)
 647         {
 648                 float mi = min(item.(ammotype), ammomax);
 649                 if (player.(ammotype) < mi)
 650                 {
 651                         player.(ammotype) = mi;
 652                         goto YEAH;
 653                 }
 654         }
 655
 656         return false;
 657
 658 LABEL(YEAH)
 659         switch(mode)
 660         {
 661                 case ITEM_MODE_FUEL:
 662                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 663                         break;
 664                 case ITEM_MODE_HEALTH:
 665                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 666                         break;
 667                 case ITEM_MODE_ARMOR:
 668                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 669                         break;
 670                 default:
 671                         break;
 672         }
 673         return true;
 674 }
 675
 676 float Item_GiveTo(entity item, entity player)
 677 {
 678         float pickedup;
 679
 680         // if nothing happens to player, just return without taking the item
 681         pickedup = false;
 682         int _switchweapon = 0;
 683         // in case the player has autoswitch enabled do the following:
 684         // if the player is using their best weapon before items are given, they
 685         // probably want to switch to an even better weapon after items are given
 686
 687         if(player.autoswitch)
 688         {
 689                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 690                 {
 691                         .entity weaponentity = weaponentities[slot];
 692                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 693                         {
 694                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 695                                         _switchweapon |= BIT(slot);
 696
 697                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 698                                         _switchweapon |= BIT(slot);
 699                         }
 700                 }
 701         }
 702
 703         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 704         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 705         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 706         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 707         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 708         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 709         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 710         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 711
 712         if (item.itemdef.instanceOfWeaponPickup)
 713         {
 714                 WepSet w;
 715                 w = item.weapons;
 716                 w &= ~player.weapons;
 717
 718                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 719                 {
 720                         pickedup = true;
 721                         FOREACH(Weapons, it != WEP_Null, {
 722                                 if(w & (it.m_wepset))
 723                                 {
 724                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 725                                         {
 726                                                 .entity weaponentity = weaponentities[slot];
 727                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 728                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 729                                         }
 730                                         W_GiveWeapon(player, it.m_id);
 731                                 }
 732                         });
 733                 }
 734         }
 735
 736         if (item.itemdef.instanceOfPowerup)
 737         {
 738                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 739                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 740                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 741                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 742         }
 743
 744         int its;
 745         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 746         {
 747                 pickedup = true;
 748                 player.items |= its;
 749                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 750         }
 751
 752         if (item.strength_finished)
 753         {
 754                 pickedup = true;
 755                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 756         }
 757         if (item.invincible_finished)
 758         {
 759                 pickedup = true;
 760                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 761         }
 762         if (item.superweapons_finished)
 763         {
 764                 pickedup = true;
 765                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 766         }
 767
 768 LABEL(skip)
 769
 770         // always eat teamed entities
 771         if(item.team)
 772                 pickedup = true;
 773
 774         if (!pickedup)
 775                 return 0;
 776
 777         // crude hack to enforce switching weapons
 778         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 779         {
 780                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781                 {
 782                         .entity weaponentity = weaponentities[slot];
 783                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 784                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 785                 }
 786                 return 1;
 787         }
 788
 789         if(_switchweapon)
 790         {
 791                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792                 {
 793                         .entity weaponentity = weaponentities[slot];
 794                         if(_switchweapon & BIT(slot))
 795                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 796                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 797                 }
 798         }
 799
 800         return 1;
 801 }
 802
 803 void Item_Touch(entity this, entity toucher)
 804 {
 805
 806         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 807         if (this.classname == "droppedweapon")
 808         {
 809                 if (ITEM_TOUCH_NEEDKILL())
 810                 {
 811                         delete(this);
 812                         return;
 813                 }
 814         }
 815
 816         if(!(toucher.flags & FL_PICKUPITEMS)
 817         || STAT(FROZEN, toucher)
 818         || IS_DEAD(toucher)
 819         || (this.solid != SOLID_TRIGGER)
 820         || (this.owner == toucher)
 821         || (time < this.item_spawnshieldtime)
 822         ) { return; }
 823
 824         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 825         {
 826                 case MUT_ITEMTOUCH_RETURN: { return; }
 827                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 828         }
 829
 830         toucher = M_ARGV(1, entity);
 831
 832         if (this.classname == "droppedweapon")
 833         {
 834                 this.strength_finished = max(0, this.strength_finished - time);
 835                 this.invincible_finished = max(0, this.invincible_finished - time);
 836                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 837         }
 838         entity it = this.itemdef;
 839         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 840         if (!gave)
 841         {
 842                 if (this.classname == "droppedweapon")
 843                 {
 844                         // undo what we did above
 845                         this.strength_finished += time;
 846                         this.invincible_finished += time;
 847                         this.superweapons_finished += time;
 848                 }
 849                 return;
 850         }
 851
 852 LABEL(pickup)
 853
 854         toucher.last_pickup = time;
 855
 856         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 857         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 858
 859         if (this.classname == "droppedweapon")
 860                 delete (this);
 861         else if (this.spawnshieldtime)
 862         {
 863                 entity e;
 864                 if(this.team)
 865                 {
 866                         RandomSelection_Init();
 867                         IL_EACH(g_items, it.team == this.team,
 868                         {
 869                                 if(it.itemdef) // is a registered item
 870                                 {
 871                                         Item_Show(it, -1);
 872                                         RandomSelection_AddEnt(it, it.cnt, 0);
 873                                 }
 874                         });
 875                         e = RandomSelection_chosen_ent;
 876
 877                 }
 878                 else
 879                         e = this;
 880                 Item_ScheduleRespawn(e);
 881         }
 882 }
 883
 884 void Item_Reset(entity this)
 885 {
 886         Item_Show(this, !this.state);
 887         setorigin(this, this.origin);
 888
 889         if (this.classname != "droppedweapon")
 890         {
 891                 setthink(this, Item_Think);
 892                 this.nextthink = time;
 893
 894                 if (this.waypointsprite_attached)
 895                         WaypointSprite_Kill(this.waypointsprite_attached);
 896
 897                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 898                         Item_ScheduleInitialRespawn(this);
 899         }
 900 }
 901
 902 void Item_FindTeam(entity this)
 903 {
 904         entity e;
 905
 906         if(this.effects & EF_NODRAW)
 907         {
 908                 // marker for item team search
 909                 LOG_TRACE("Initializing item team ", ftos(this.team));
 910                 RandomSelection_Init();
 911                 IL_EACH(g_items, it.team == this.team,
 912                 {
 913                         if(it.itemdef) // is a registered item
 914                                 RandomSelection_AddEnt(it, it.cnt, 0);
 915                 });
 916
 917                 e = RandomSelection_chosen_ent;
 918                 e.state = 0;
 919                 Item_Show(e, 1);
 920
 921                 IL_EACH(g_items, it.team == this.team,
 922                 {
 923                         if(it.itemdef) // is a registered item
 924                         {
 925                                 if(it != e)
 926                                 {
 927                                         // make it non-spawned
 928                                         Item_Show(it, -1);
 929                                         it.state = 1; // state 1 = initially hidden item, apparently
 930                                 }
 931                                 it.effects &= ~EF_NODRAW;
 932                         }
 933                 });
 934
 935                 Item_Reset(this);
 936         }
 937 }
 938
 939 // Savage: used for item garbage-collection
 940 void RemoveItem(entity this)
 941 {
 942         if(wasfreed(this) || !this) { return; }
 943         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 944         delete(this);
 945 }
 946
 947 // pickup evaluation functions
 948 // these functions decide how desirable an item is to the bots
 949
 950 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 951
 952 float weapon_pickupevalfunc(entity player, entity item)
 953 {
 954         // See if I have it already
 955         if(player.weapons & item.weapons)
 956         {
 957                 // If I can pick it up
 958                 if(!item.spawnshieldtime)
 959                         return 0;
 960                 return ammo_pickupevalfunc(player, item);
 961         }
 962         return item.bot_pickupbasevalue;
 963 }
 964
 965 float ammo_pickupevalfunc(entity player, entity item)
 966 {
 967         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 968         entity wpn = NULL;
 969         float c = 0;
 970         float rating = 0;
 971
 972         // Detect needed ammo
 973         if(item.itemdef.instanceOfWeaponPickup)
 974         {
 975                 entity ammo = NULL;
 976                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
 977                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
 978                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
 979                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
 980                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
 981                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
 982
 983                 if(!ammo)
 984                         return 0;
 985                 wpn = item;
 986                 rating = ammo.m_botvalue;
 987         }
 988         else
 989         {
 990                 FOREACH(Weapons, it != WEP_Null, {
 991                         if(!(player.weapons & (it.m_wepset)))
 992                                 continue;
 993
 994                         switch(it.ammo_field)
 995                         {
 996                                 case ammo_shells:  need_shells  = true; break;
 997                                 case ammo_shells:  need_shells  = true; break;
 998                                 case ammo_nails:   need_nails   = true; break;
 999                                 case ammo_rockets: need_rockets = true; break;
1000                                 case ammo_cells:   need_cells   = true; break;
1001                                 case ammo_plasma:  need_plasma  = true; break;
1002                                 case ammo_fuel:    need_fuel    = true; break;
1003                         }
1004                 });
1005                 rating = item.bot_pickupbasevalue;
1006         }
1007
1008         if (need_shells)
1009         if (item.ammo_shells)
1010         if (player.ammo_shells < g_pickup_shells_max)
1011                 c = (player.ammo_shells + item.ammo_shells) / player.ammo_shells;
1012         if (need_nails)
1013         if (item.ammo_nails)
1014         if (player.ammo_nails < g_pickup_nails_max)
1015                 c = (player.ammo_nails + item.ammo_nails) / player.ammo_nails;
1016         if (need_rockets)
1017         if (item.ammo_rockets)
1018         if (player.ammo_rockets < g_pickup_rockets_max)
1019                 c = (player.ammo_rockets + item.ammo_rockets) / player.ammo_rockets;
1020         if (need_cells)
1021         if (item.ammo_cells)
1022         if (player.ammo_cells < g_pickup_cells_max)
1023                 c = (player.ammo_cells + item.ammo_cells) / player.ammo_cells;
1024         if (need_plasma)
1025         if (item.ammo_plasma)
1026         if (player.ammo_plasma < g_pickup_plasma_max)
1027                 c = (player.ammo_plasma + item.ammo_plasma) / player.ammo_plasma;
1028         if (need_fuel)
1029         if (item.ammo_fuel)
1030         if (player.ammo_fuel < g_pickup_fuel_max)
1031                 c = (player.ammo_fuel + item.ammo_fuel) / player.ammo_fuel;
1032
1033         rating *= min(3, c);
1034         if(wpn)
1035                 // Skilled bots will grab more
1036                 rating += wpn.bot_pickupbasevalue * (0.1 + 0.1 * bound(0, skill / 10, 1));
1037         return rating;
1038 }
1039
1040 float healtharmor_pickupevalfunc(entity player, entity item)
1041 {
1042         float c = 0;
1043         float rating = item.bot_pickupbasevalue;
1044
1045         if (item.armorvalue)
1046         if (player.armorvalue < item.max_armorvalue)
1047                 c = (player.armorvalue + player.health + item.armorvalue) / (max(1, player.armorvalue + player.health));
1048         if (item.health)
1049         if (player.health < item.max_health)
1050                 c = (player.health + item.health) / (max(1, player.health));
1051
1052         rating *= min(3, c);
1053         return rating;
1054 }
1055
1056 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1057 {
1058         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1059                 RemoveItem(this);
1060 }
1061
1062 void item_use(entity this, entity actor, entity trigger)
1063 {
1064         // use the touch function to handle collection
1065         gettouch(this)(this, actor);
1066 }
1067
1068 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1069 {
1070         string itemname = def.m_name;
1071         Model itemmodel = def.m_model;
1072     Sound pickupsound = def.m_sound;
1073         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1074         float pickupbasevalue = def.m_botvalue;
1075         int itemflags = def.m_itemflags;
1076
1077         startitem_failed = false;
1078
1079         this.item_model_ent = itemmodel;
1080     this.item_pickupsound_ent = pickupsound;
1081
1082     if(def.m_iteminit)
1083         def.m_iteminit(this);
1084
1085         if(!this.respawntime) // both need to be set
1086         {
1087                 this.respawntime = defaultrespawntime;
1088                 this.respawntimejitter = defaultrespawntimejitter;
1089         }
1090
1091         if(!this.pickup_anyway && def.m_pickupanyway)
1092                 this.pickup_anyway = def.m_pickupanyway();
1093
1094         int itemid = def.m_itemid;
1095         this.items = itemid;
1096         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1097         this.weapon = weaponid;
1098
1099         if(!this.fade_end)
1100         {
1101                 this.fade_start = autocvar_g_items_mindist;
1102                 this.fade_end = autocvar_g_items_maxdist;
1103         }
1104
1105         if(weaponid)
1106                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1107
1108         this.flags = FL_ITEM | itemflags;
1109         IL_PUSH(g_items, this);
1110
1111         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1112         {
1113                 startitem_failed = true;
1114                 delete(this);
1115                 return;
1116         }
1117
1118         // is it a dropped weapon?
1119         if (this.classname == "droppedweapon")
1120         {
1121                 this.reset = SUB_Remove;
1122                 // it's a dropped weapon
1123                 set_movetype(this, MOVETYPE_TOSS);
1124
1125                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1126                 setthink(this, RemoveItem);
1127                 this.nextthink = time + 20;
1128
1129                 this.takedamage = DAMAGE_YES;
1130                 this.event_damage = Item_Damage;
1131
1132                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1133                 {
1134                         // if item is worthless after a timer, have it expire then
1135                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1136                 }
1137
1138                 // don't drop if in a NODROP zone (such as lava)
1139                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1140                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1141                 {
1142                         startitem_failed = true;
1143                         delete(this);
1144                         return;
1145                 }
1146         }
1147         else
1148         {
1149                 if(!have_pickup_item(this))
1150                 {
1151                         startitem_failed = true;
1152                         delete (this);
1153                         return;
1154                 }
1155
1156                 if(this.angles != '0 0 0')
1157                         this.SendFlags |= ISF_ANGLES;
1158
1159                 this.reset = Item_Reset;
1160                 // it's a level item
1161                 if(this.spawnflags & 1)
1162                         this.noalign = 1;
1163                 if (this.noalign > 0)
1164                         set_movetype(this, MOVETYPE_NONE);
1165                 else
1166                         set_movetype(this, MOVETYPE_TOSS);
1167                 // do item filtering according to game mode and other things
1168                 if (this.noalign <= 0)
1169                 {
1170                         // first nudge it off the floor a little bit to avoid math errors
1171                         setorigin(this, this.origin + '0 0 1');
1172                         // set item size before we spawn a spawnfunc_waypoint
1173                         setsize(this, def.m_mins, def.m_maxs);
1174                         this.SendFlags |= ISF_SIZE;
1175                         // note droptofloor returns false if stuck/or would fall too far
1176                         if (!this.noalign)
1177                                 droptofloor(this);
1178                         waypoint_spawnforitem(this);
1179                 }
1180
1181                 /*
1182                  * can't do it that way, as it would break maps
1183                  * TODO make a target_give like entity another way, that perhaps has
1184                  * the weapon name in a key
1185                 if(this.targetname)
1186                 {
1187                         // target_give not yet supported; maybe later
1188                         print("removed targeted ", this.classname, "\n");
1189                         startitem_failed = true;
1190                         remove (this);
1191                         return;
1192                 }
1193                 */
1194
1195                 if(this.targetname != "" && (this.spawnflags & 16))
1196                         this.use = item_use;
1197
1198                 if(autocvar_spawn_debug >= 2)
1199                 {
1200             // why not flags & fl_item?
1201                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1202                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1203                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1204                 error("Mapper sucks.");
1205             });
1206                         this.is_item = true;
1207                 }
1208
1209                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1210
1211                 precache_model(this.model);
1212                 precache_sound(this.item_pickupsound);
1213
1214                 if (   def.instanceOfPowerup
1215                         || def.instanceOfWeaponPickup
1216                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1217                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1218                         || (itemid & (IT_KEY1 | IT_KEY2))
1219                 ) this.target = "###item###"; // for finding the nearest item using find()
1220
1221                 Item_ItemsTime_SetTime(this, 0);
1222         }
1223
1224         this.bot_pickup = true;
1225         this.bot_pickupevalfunc = pickupevalfunc;
1226         this.bot_pickupbasevalue = pickupbasevalue;
1227         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1228         this.netname = itemname;
1229         settouch(this, Item_Touch);
1230         setmodel(this, MDL_Null); // precision set below
1231         //this.effects |= EF_LOWPRECISION;
1232
1233         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1234
1235         this.SendFlags |= ISF_SIZE;
1236
1237         if (!(this.spawnflags & 1024)) {
1238                 if(def.instanceOfPowerup)
1239                         this.ItemStatus |= ITS_ANIMATE1;
1240
1241                 if(this.armorvalue || this.health)
1242                         this.ItemStatus |= ITS_ANIMATE2;
1243         }
1244
1245         if(def.instanceOfWeaponPickup)
1246         {
1247                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1248                         this.colormap = 1024; // color shirt=0 pants=0 grey
1249                 else
1250                         this.gravity = 1;
1251                 if (!(this.spawnflags & 1024))
1252                         this.ItemStatus |= ITS_ANIMATE1;
1253                 this.SendFlags |= ISF_COLORMAP;
1254         }
1255
1256         this.state = 0;
1257         if(this.team) // broken, no idea why.
1258         {
1259                 if(!this.cnt)
1260                         this.cnt = 1; // item probability weight
1261
1262                 this.effects |= EF_NODRAW; // marker for item team search
1263                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1264         }
1265         else
1266                 Item_Reset(this);
1267
1268         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1269
1270         // call this hook after everything else has been done
1271         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1272         {
1273                 startitem_failed = true;
1274                 delete(this);
1275                 return;
1276         }
1277 }
1278
1279 void StartItem(entity this, GameItem def)
1280 {
1281     _StartItem(
1282         this,
1283         this.itemdef = def,
1284         def.m_respawntime(), // defaultrespawntime
1285         def.m_respawntimejitter() // defaultrespawntimejitter
1286         );
1287 }
1288
1289 spawnfunc(item_rockets)
1290 {
1291     StartItem(this, ITEM_Rockets);
1292 }
1293
1294 spawnfunc(item_bullets)
1295 {
1296         if(!weaponswapping)
1297         if(autocvar_sv_q3acompat_machineshotgunswap)
1298         if(this.classname != "droppedweapon")
1299         {
1300                 weaponswapping = true;
1301                 spawnfunc_item_shells(this);
1302                 weaponswapping = false;
1303                 return;
1304         }
1305
1306     StartItem(this, ITEM_Bullets);
1307 }
1308
1309 spawnfunc(item_cells)
1310 {
1311         StartItem(this, ITEM_Cells);
1312 }
1313
1314 spawnfunc(item_plasma)
1315 {
1316         StartItem(this, ITEM_Plasma);
1317 }
1318
1319 spawnfunc(item_shells)
1320 {
1321         if(!weaponswapping)
1322         if(autocvar_sv_q3acompat_machineshotgunswap)
1323         if(this.classname != "droppedweapon")
1324         {
1325                 weaponswapping = true;
1326                 spawnfunc_item_bullets(this);
1327                 weaponswapping = false;
1328                 return;
1329         }
1330
1331         StartItem(this, ITEM_Shells);
1332 }
1333
1334 spawnfunc(item_armor_small)
1335 {
1336         StartItem(this, ITEM_ArmorSmall);
1337 }
1338
1339 spawnfunc(item_armor_medium)
1340 {
1341         StartItem(this, ITEM_ArmorMedium);
1342 }
1343
1344 spawnfunc(item_armor_big)
1345 {
1346         StartItem(this, ITEM_ArmorBig);
1347 }
1348
1349 spawnfunc(item_armor_mega)
1350 {
1351         StartItem(this, ITEM_ArmorMega);
1352 }
1353
1354 spawnfunc(item_health_small)
1355 {
1356         StartItem(this, ITEM_HealthSmall);
1357 }
1358
1359 spawnfunc(item_health_medium)
1360 {
1361     StartItem(this, ITEM_HealthMedium);
1362 }
1363
1364 spawnfunc(item_health_big)
1365 {
1366         StartItem(this, ITEM_HealthBig);
1367 }
1368
1369 spawnfunc(item_health_mega)
1370 {
1371     StartItem(this, ITEM_HealthMega);
1372 }
1373
1374 // support old misnamed entities
1375 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1376 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1377 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1378 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1379 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1380 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1381 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1382
1383 spawnfunc(item_strength)
1384 {
1385         StartItem(this, ITEM_Strength);
1386 }
1387
1388 spawnfunc(item_invincible)
1389 {
1390         StartItem(this, ITEM_Shield);
1391 }
1392
1393 // compatibility:
1394 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1395
1396 void target_items_use(entity this, entity actor, entity trigger)
1397 {
1398         if(actor.classname == "droppedweapon")
1399         {
1400                 EXACTTRIGGER_TOUCH(this, trigger);
1401                 delete(actor);
1402                 return;
1403         }
1404
1405         if (!IS_PLAYER(actor))
1406                 return;
1407         if(IS_DEAD(actor))
1408                 return;
1409         if(trigger.solid == SOLID_TRIGGER)
1410         {
1411                 EXACTTRIGGER_TOUCH(this, trigger);
1412         }
1413
1414         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1415         {
1416                 delete(it);
1417         });
1418
1419         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1420                 centerprint(actor, this.message);
1421 }
1422
1423 spawnfunc(target_items)
1424 {
1425         int n, j;
1426         string s;
1427
1428         this.use = target_items_use;
1429         if(!this.strength_finished)
1430                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1431         if(!this.invincible_finished)
1432                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1433         if(!this.superweapons_finished)
1434                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1435
1436         n = tokenize_console(this.netname);
1437         if(argv(0) == "give")
1438         {
1439                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1440         }
1441         else
1442         {
1443                 for(j = 0; j < n; ++j)
1444                 {
1445                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1446                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1447                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1448                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1449                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1450                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1451                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1452                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1453                         else
1454                         {
1455                                 FOREACH(Buffs, it != BUFF_Null,
1456                                 {
1457                                         s = Buff_UndeprecateName(argv(j));
1458                                         if(s == it.m_name)
1459                                         {
1460                                                 this.buffs |= (it.m_itemid);
1461                                                 break;
1462                                         }
1463                                 });
1464                                 FOREACH(Weapons, it != WEP_Null, {
1465                                         s = W_UndeprecateName(argv(j));
1466                                         if(s == it.netname)
1467                                         {
1468                                                 this.weapons |= (it.m_wepset);
1469                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1470                                                         it.wr_init(it);
1471                                                 break;
1472                                         }
1473                                 });
1474                         }
1475                 }
1476
1477                 string itemprefix, valueprefix;
1478                 if(this.spawnflags == 0)
1479                 {
1480                         itemprefix = "";
1481                         valueprefix = "";
1482                 }
1483                 else if(this.spawnflags == 1)
1484                 {
1485                         itemprefix = "max ";
1486                         valueprefix = "max ";
1487                 }
1488                 else if(this.spawnflags == 2)
1489                 {
1490                         itemprefix = "min ";
1491                         valueprefix = "min ";
1492                 }
1493                 else if(this.spawnflags == 4)
1494                 {
1495                         itemprefix = "minus ";
1496                         valueprefix = "max ";
1497                 }
1498                 else
1499                 {
1500                         error("invalid spawnflags");
1501                         itemprefix = valueprefix = string_null;
1502                 }
1503
1504                 this.netname = "";
1505                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1506                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1507                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1508                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1509                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1510                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1511                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1512                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1513                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1514                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1515                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1516                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1517                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1518                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1519                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1520                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1521                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1522         }
1523         this.netname = strzone(this.netname);
1524         //print(this.netname, "\n");
1525
1526         n = tokenize_console(this.netname);
1527         for(j = 0; j < n; ++j)
1528         {
1529                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1530             it.wr_init(it);
1531             break;
1532                 });
1533         }
1534 }
1535
1536 spawnfunc(item_fuel)
1537 {
1538         StartItem(this, ITEM_JetpackFuel);
1539 }
1540
1541 spawnfunc(item_fuel_regen)
1542 {
1543         if(start_items & ITEM_JetpackRegen.m_itemid)
1544         {
1545                 spawnfunc_item_fuel(this);
1546                 return;
1547         }
1548         StartItem(this, ITEM_JetpackRegen);
1549 }
1550
1551 spawnfunc(item_jetpack)
1552 {
1553         if(start_items & ITEM_Jetpack.m_itemid)
1554         {
1555                 spawnfunc_item_fuel(this);
1556                 return;
1557         }
1558         StartItem(this, ITEM_Jetpack);
1559 }
1560
1561 float GiveWeapon(entity e, float wpn, float op, float val)
1562 {
1563         WepSet v0, v1;
1564         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1565         v0 = (e.weapons & s);
1566         switch(op)
1567         {
1568                 case OP_SET:
1569                         if(val > 0)
1570                                 e.weapons |= s;
1571                         else
1572                                 e.weapons &= ~s;
1573                         break;
1574                 case OP_MIN:
1575                 case OP_PLUS:
1576                         if(val > 0)
1577                                 e.weapons |= s;
1578                         break;
1579                 case OP_MAX:
1580                         if(val <= 0)
1581                                 e.weapons &= ~s;
1582                         break;
1583                 case OP_MINUS:
1584                         if(val > 0)
1585                                 e.weapons &= ~s;
1586                         break;
1587         }
1588         v1 = (e.weapons & s);
1589         return (v0 != v1);
1590 }
1591
1592 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1593 {
1594         bool had_buff = (e.buffs & thebuff.m_itemid);
1595         switch(op)
1596         {
1597                 case OP_SET:
1598                         if(val > 0)
1599                                 e.buffs |= thebuff.m_itemid;
1600                         else
1601                                 e.buffs &= ~thebuff.m_itemid;
1602                         break;
1603                 case OP_MIN:
1604                 case OP_PLUS:
1605                         if(val > 0)
1606                                 e.buffs |= thebuff.m_itemid;
1607                         break;
1608                 case OP_MAX:
1609                         if(val <= 0)
1610                                 e.buffs &= ~thebuff.m_itemid;
1611                         break;
1612                 case OP_MINUS:
1613                         if(val > 0)
1614                                 e.buffs &= ~thebuff.m_itemid;
1615                         break;
1616         }
1617         bool have_buff = (e.buffs & thebuff.m_itemid);
1618         return (had_buff != have_buff);
1619 }
1620
1621 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1622 {
1623         if(v1 == v0)
1624                 return;
1625         if(v1 <= v0 - t)
1626         {
1627                 if(snd_decr != NULL)
1628                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1629         }
1630         else if(v0 >= v0 + t)
1631         {
1632                 if(snd_incr != NULL)
1633                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1634         }
1635 }
1636
1637 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1638 {
1639         if(v0 < v1)
1640                 e.(rotfield) = max(e.(rotfield), time + rottime);
1641         else if(v0 > v1)
1642                 e.(regenfield) = max(e.(regenfield), time + regentime);
1643 }
1644 float GiveItems(entity e, float beginarg, float endarg)
1645 {
1646         float got, i, val, op;
1647         string cmd;
1648
1649         val = 999;
1650         op = OP_SET;
1651
1652         got = 0;
1653
1654         int _switchweapon = 0;
1655
1656         if(e.autoswitch)
1657         {
1658                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1659                 {
1660                         .entity weaponentity = weaponentities[slot];
1661                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1662                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1663                                 _switchweapon |= BIT(slot);
1664                 }
1665         }
1666
1667         e.strength_finished = max(0, e.strength_finished - time);
1668         e.invincible_finished = max(0, e.invincible_finished - time);
1669         e.superweapons_finished = max(0, e.superweapons_finished - time);
1670
1671         PREGIVE(e, items);
1672         PREGIVE_WEAPONS(e);
1673         PREGIVE(e, strength_finished);
1674         PREGIVE(e, invincible_finished);
1675         PREGIVE(e, superweapons_finished);
1676         PREGIVE(e, ammo_nails);
1677         PREGIVE(e, ammo_cells);
1678         PREGIVE(e, ammo_plasma);
1679         PREGIVE(e, ammo_shells);
1680         PREGIVE(e, ammo_rockets);
1681         PREGIVE(e, ammo_fuel);
1682         PREGIVE(e, armorvalue);
1683         PREGIVE(e, health);
1684
1685         for(i = beginarg; i < endarg; ++i)
1686         {
1687                 cmd = argv(i);
1688
1689                 if(cmd == "0" || stof(cmd))
1690                 {
1691                         val = stof(cmd);
1692                         continue;
1693                 }
1694                 switch(cmd)
1695                 {
1696                         case "no":
1697                                 op = OP_MAX;
1698                                 val = 0;
1699                                 continue;
1700                         case "max":
1701                                 op = OP_MAX;
1702                                 continue;
1703                         case "min":
1704                                 op = OP_MIN;
1705                                 continue;
1706                         case "plus":
1707                                 op = OP_PLUS;
1708                                 continue;
1709                         case "minus":
1710                                 op = OP_MINUS;
1711                                 continue;
1712                         case "ALL":
1713                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1714                                 got += GiveValue(e, strength_finished, op, val);
1715                                 got += GiveValue(e, invincible_finished, op, val);
1716                                 got += GiveValue(e, superweapons_finished, op, val);
1717                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1718                         case "all":
1719                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1720                                 got += GiveValue(e, health, op, val);
1721                                 got += GiveValue(e, armorvalue, op, val);
1722                         case "allweapons":
1723                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1724                         //case "allbuffs": // all buffs makes a player god, do not want!
1725                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1726                         case "allammo":
1727                                 got += GiveValue(e, ammo_cells, op, val);
1728                                 got += GiveValue(e, ammo_plasma, op, val);
1729                                 got += GiveValue(e, ammo_shells, op, val);
1730                                 got += GiveValue(e, ammo_nails, op, val);
1731                                 got += GiveValue(e, ammo_rockets, op, val);
1732                                 got += GiveValue(e, ammo_fuel, op, val);
1733                                 break;
1734                         case "unlimited_ammo":
1735                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1736                                 break;
1737                         case "unlimited_weapon_ammo":
1738                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1739                                 break;
1740                         case "unlimited_superweapons":
1741                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1742                                 break;
1743                         case "jetpack":
1744                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1745                                 break;
1746                         case "fuel_regen":
1747                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1748                                 break;
1749                         case "strength":
1750                                 got += GiveValue(e, strength_finished, op, val);
1751                                 break;
1752                         case "invincible":
1753                                 got += GiveValue(e, invincible_finished, op, val);
1754                                 break;
1755                         case "superweapons":
1756                                 got += GiveValue(e, superweapons_finished, op, val);
1757                                 break;
1758                         case "cells":
1759                                 got += GiveValue(e, ammo_cells, op, val);
1760                                 break;
1761                         case "plasma":
1762                                 got += GiveValue(e, ammo_plasma, op, val);
1763                                 break;
1764                         case "shells":
1765                                 got += GiveValue(e, ammo_shells, op, val);
1766                                 break;
1767                         case "nails":
1768                         case "bullets":
1769                                 got += GiveValue(e, ammo_nails, op, val);
1770                                 break;
1771                         case "rockets":
1772                                 got += GiveValue(e, ammo_rockets, op, val);
1773                                 break;
1774                         case "health":
1775                                 got += GiveValue(e, health, op, val);
1776                                 break;
1777                         case "armor":
1778                                 got += GiveValue(e, armorvalue, op, val);
1779                                 break;
1780                         case "fuel":
1781                                 got += GiveValue(e, ammo_fuel, op, val);
1782                                 break;
1783                         default:
1784                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1785                                 {
1786                                         got += GiveBuff(e, it, op, val);
1787                                         break;
1788                                 });
1789                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1790                     got += GiveWeapon(e, it.m_id, op, val);
1791                     break;
1792                                 });
1793                                 break;
1794                 }
1795                 val = 999;
1796                 op = OP_SET;
1797         }
1798
1799         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1800         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1801         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1802         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1803         FOREACH(Weapons, it != WEP_Null, {
1804                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1805                 if(!(save_weapons & (it.m_wepset)))
1806                         if(e.weapons & (it.m_wepset))
1807                                 it.wr_init(it);
1808         });
1809         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1810         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1811         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1812         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1813         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1814         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1815         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1816         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1817         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1818         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1819         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1820
1821         if(e.superweapons_finished <= 0)
1822                 if(e.weapons & WEPSET_SUPERWEAPONS)
1823                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1824
1825         if(e.strength_finished <= 0)
1826                 e.strength_finished = 0;
1827         else
1828                 e.strength_finished += time;
1829         if(e.invincible_finished <= 0)
1830                 e.invincible_finished = 0;
1831         else
1832                 e.invincible_finished += time;
1833         if(e.superweapons_finished <= 0)
1834                 e.superweapons_finished = 0;
1835         else
1836                 e.superweapons_finished += time;
1837
1838         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1839         {
1840                 .entity weaponentity = weaponentities[slot];
1841                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1842                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1843                         _switchweapon |= BIT(slot);
1844         }
1845
1846         if(_switchweapon)
1847         {
1848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849                 {
1850                         .entity weaponentity = weaponentities[slot];
1851                         if(_switchweapon & BIT(slot))
1852                                 W_SwitchWeapon_Force(e, w_getbestweapon(e, weaponentity), weaponentity);
1853                 }
1854         }
1855
1856         return got;
1857 }
1858 #endif