qcsrc/common/turrets/turret/walker.qc

   1 #include "walker.qh"
   2
   3 #ifdef SVQC
   4
   5 float autocvar_g_turrets_unit_walker_melee_damage;
   6 float autocvar_g_turrets_unit_walker_melee_force;
   7 float autocvar_g_turrets_unit_walker_melee_range;
   8 float autocvar_g_turrets_unit_walker_rocket_damage;
   9 float autocvar_g_turrets_unit_walker_rocket_radius;
  10 float autocvar_g_turrets_unit_walker_rocket_force;
  11 float autocvar_g_turrets_unit_walker_rocket_speed;
  12 float autocvar_g_turrets_unit_walker_rocket_range;
  13 float autocvar_g_turrets_unit_walker_rocket_range_min;
  14 float autocvar_g_turrets_unit_walker_rocket_refire;
  15 float autocvar_g_turrets_unit_walker_rocket_turnrate;
  16 float autocvar_g_turrets_unit_walker_speed_stop;
  17 float autocvar_g_turrets_unit_walker_speed_walk;
  18 float autocvar_g_turrets_unit_walker_speed_run;
  19 float autocvar_g_turrets_unit_walker_speed_jump;
  20 float autocvar_g_turrets_unit_walker_speed_swim;
  21 float autocvar_g_turrets_unit_walker_speed_roam;
  22 float autocvar_g_turrets_unit_walker_turn;
  23 float autocvar_g_turrets_unit_walker_turn_walk;
  24 float autocvar_g_turrets_unit_walker_turn_strafe;
  25 float autocvar_g_turrets_unit_walker_turn_swim;
  26 float autocvar_g_turrets_unit_walker_turn_run;
  27
  28 const int ANIM_NO         = 0;
  29 const int ANIM_TURN       = 1;
  30 const int ANIM_WALK       = 2;
  31 const int ANIM_RUN        = 3;
  32 const int ANIM_STRAFE_L   = 4;
  33 const int ANIM_STRAFE_R   = 5;
  34 const int ANIM_JUMP       = 6;
  35 const int ANIM_LAND       = 7;
  36 const int ANIM_PAIN       = 8;
  37 const int ANIM_MELEE      = 9;
  38 const int ANIM_SWIM       = 10;
  39 const int ANIM_ROAM       = 11;
  40
  41 .float animflag;
  42 .float idletime;
  43
  44 bool walker_firecheck(entity this)
  45 {
  46     if (this.animflag == ANIM_MELEE)
  47         return false;
  48
  49     return turret_firecheck(this);
  50 }
  51
  52 void walker_melee_do_dmg(entity this)
  53 {
  54     vector where;
  55     entity e;
  56
  57     makevectors(this.angles);
  58     where = this.origin + v_forward * 128;
  59
  60     e = findradius(where,32);
  61     while (e)
  62     {
  63         if (turret_validate_target(this, e, this.target_validate_flags))
  64             if (e != this && e.owner != this)
  65                 Damage(e, this, this, (autocvar_g_turrets_unit_walker_melee_damage), DEATH_TURRET_WALK_MELEE.m_id, DMG_NOWEP, '0 0 0', v_forward * (autocvar_g_turrets_unit_walker_melee_force));
  66
  67         e = e.chain;
  68     }
  69 }
  70
  71 void walker_setnoanim(entity this)
  72 {
  73     turrets_setframe(this, ANIM_NO, false);
  74     this.animflag = this.frame;
  75 }
  76 void walker_rocket_explode(entity this)
  77 {
  78     RadiusDamage (this, this.owner, (autocvar_g_turrets_unit_walker_rocket_damage), 0, (autocvar_g_turrets_unit_walker_rocket_radius), this, NULL, (autocvar_g_turrets_unit_walker_rocket_force), DEATH_TURRET_WALK_ROCKET.m_id, DMG_NOWEP, NULL);
  79     delete(this);
  80 }
  81
  82 void walker_rocket_touch(entity this, entity toucher)
  83 {
  84     walker_rocket_explode(this);
  85 }
  86
  87 void walker_rocket_damage(entity this, entity inflictor, entity attacker, float damage, float deathtype, .entity weaponentity, vector hitloc, vector vforce)
  88 {
  89     TakeResource(this, RES_HEALTH, damage);
  90     this.velocity = this.velocity + vforce;
  91
  92     if (GetResource(this, RES_HEALTH) <= 0)
  93         W_PrepareExplosionByDamage(this, this.owner, walker_rocket_explode);
  94 }
  95
  96 #define WALKER_ROCKET_MOVE(s) movelib_move_simple((s), newdir, (autocvar_g_turrets_unit_walker_rocket_speed), (autocvar_g_turrets_unit_walker_rocket_turnrate)); UpdateCSQCProjectile(s)
  97 void walker_rocket_loop(entity this);
  98 void walker_rocket_think(entity this)
  99 {
 100     vector newdir;
 101     float edist;
 102     float itime;
 103     float m_speed;
 104
 105     this.nextthink = time;
 106
 107     edist = vlen(this.enemy.origin - this.origin);
 108
 109     // Simulate crude guidance
 110     if (this.cnt < time)
 111     {
 112         if (edist < 1000)
 113             this.tur_shotorg = randomvec() * min(edist, 64);
 114         else
 115             this.tur_shotorg = randomvec() * min(edist, 256);
 116
 117         this.cnt = time + 0.5;
 118     }
 119
 120     if (edist < 128)
 121         this.tur_shotorg = '0 0 0';
 122
 123     if (this.max_health < time)
 124     {
 125         setthink(this, walker_rocket_explode);
 126         this.nextthink  = time;
 127         return;
 128     }
 129
 130     if (this.shot_dmg != 1337 && random() < 0.01)
 131     {
 132         walker_rocket_loop(this);
 133         return;
 134     }
 135
 136     m_speed = vlen(this.velocity);
 137
 138     // Enemy dead? just keep on the current heading then.
 139     if (this.enemy == NULL || IS_DEAD(this.enemy))
 140         this.enemy = NULL;
 141
 142     if (this.enemy)
 143     {
 144         itime = max(edist / m_speed, 1);
 145         newdir = steerlib_pull(this, this.enemy.origin + this.tur_shotorg);
 146     }
 147     else
 148         newdir  = normalize(this.velocity);
 149
 150     WALKER_ROCKET_MOVE(this);
 151 }
 152
 153 void walker_rocket_loop3(entity this)
 154 {
 155     this.nextthink = time;
 156
 157     if (this.max_health < time)
 158     {
 159         setthink(this, walker_rocket_explode);
 160         return;
 161     }
 162
 163     if(vdist(this.origin - this.tur_shotorg, <, 100))
 164     {
 165         setthink(this, walker_rocket_think);
 166         return;
 167     }
 168
 169     vector newdir = steerlib_pull(this, this.tur_shotorg);
 170     WALKER_ROCKET_MOVE(this);
 171
 172     this.angles = vectoangles(this.velocity);
 173 }
 174
 175 void walker_rocket_loop2(entity this)
 176 {
 177     this.nextthink = time;
 178
 179     if (this.max_health < time)
 180     {
 181         setthink(this, walker_rocket_explode);
 182         return;
 183     }
 184
 185     if(vdist(this.origin - this.tur_shotorg, <, 100))
 186     {
 187         this.tur_shotorg = this.origin - '0 0 200';
 188         setthink(this, walker_rocket_loop3);
 189         return;
 190     }
 191
 192     vector newdir = steerlib_pull(this, this.tur_shotorg);
 193     WALKER_ROCKET_MOVE(this);
 194 }
 195
 196 void walker_rocket_loop(entity this)
 197 {
 198     this.nextthink = time;
 199     this.tur_shotorg = this.origin + '0 0 300';
 200     setthink(this, walker_rocket_loop2);
 201     this.shot_dmg = 1337;
 202 }
 203
 204 void walker_fire_rocket(entity this, vector org)
 205 {
 206     fixedmakevectors(this.angles);
 207
 208     te_explosion (org);
 209
 210     entity rocket = new(walker_rocket);
 211     setorigin(rocket, org);
 212     rocket.solid                          = SOLID_BBOX; // before setsize so it will be linked to the area grid
 213     sound (this, CH_WEAPON_A, SND_HAGAR_FIRE, VOL_BASE, ATTEN_NORM);
 214     setsize (rocket, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 215
 216     rocket.owner                          = this;
 217     rocket.bot_dodge              = true;
 218     rocket.bot_dodgerating      = 50;
 219     rocket.takedamage            = DAMAGE_YES;
 220     rocket.damageforcescale   = 2;
 221     SetResourceExplicit(rocket, RES_HEALTH, 25);
 222     rocket.tur_shotorg          = randomvec() * 512;
 223     rocket.cnt                          = time + 1;
 224     rocket.enemy                          = this.enemy;
 225
 226     if (random() < 0.01)
 227         setthink(rocket, walker_rocket_loop);
 228     else
 229         setthink(rocket, walker_rocket_think);
 230
 231     rocket.event_damage    = walker_rocket_damage;
 232
 233     rocket.nextthink              = time;
 234     set_movetype(rocket, MOVETYPE_FLY);
 235     rocket.velocity                = normalize((v_forward + v_up * 0.5) + (randomvec() * 0.2)) * (autocvar_g_turrets_unit_walker_rocket_speed);
 236     rocket.angles                        = vectoangles(rocket.velocity);
 237     settouch(rocket, walker_rocket_touch);
 238     rocket.flags = FL_PROJECTILE;
 239     IL_PUSH(g_projectiles, rocket);
 240     IL_PUSH(g_bot_dodge, rocket);
 241     rocket.max_health            = time + 9;
 242     rocket.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_GUIDED_HEAT;
 243
 244     CSQCProjectile(rocket, false, PROJECTILE_ROCKET, false); // no culling, has fly sound
 245 }
 246
 247 .vector enemy_last_loc;
 248 .float enemy_last_time;
 249 void walker_move_to(entity this, vector _target, float _dist)
 250 {
 251     switch (this.waterlevel)
 252     {
 253         case WATERLEVEL_NONE:
 254             if (_dist > 500)
 255                 this.animflag = ANIM_RUN;
 256             else
 257                 this.animflag = ANIM_WALK;
 258         case WATERLEVEL_WETFEET:
 259         case WATERLEVEL_SWIMMING:
 260             if (this.animflag != ANIM_SWIM)
 261                 this.animflag = ANIM_WALK;
 262             else
 263                 this.animflag = ANIM_SWIM;
 264             break;
 265         case WATERLEVEL_SUBMERGED:
 266             this.animflag = ANIM_SWIM;
 267     }
 268
 269     this.moveto = _target;
 270     this.steerto = steerlib_attract2(this, this.moveto, 0.5, 500, 0.95);
 271
 272     if(this.enemy)
 273     {
 274         this.enemy_last_loc = _target;
 275         this.enemy_last_time = time;
 276     }
 277 }
 278
 279 void walker_move_path(entity this)
 280 {
 281 #ifdef WALKER_FANCYPATHING
 282     // Are we close enougth to a path node to switch to the next?
 283     if(turret_closetotarget(this, this.pathcurrent.origin, 64))
 284     {
 285         if (this.pathcurrent.path_next == NULL)
 286         {
 287             // Path endpoint reached
 288             pathlib_deletepath(this.pathcurrent.owner);
 289             this.pathcurrent = NULL;
 290
 291             if (this.pathgoal)
 292             {
 293                 if (this.pathgoal.use)
 294                     this.pathgoal.use(this, NULL, NULL);
 295
 296                 if (this.pathgoal.enemy)
 297                 {
 298                     this.pathcurrent = pathlib_astar(this, this.pathgoal.origin, this.pathgoal.enemy.origin);
 299                     this.pathgoal = this.pathgoal.enemy;
 300                 }
 301             }
 302             else
 303                 this.pathgoal = NULL;
 304         }
 305         else
 306             this.pathcurrent = this.pathcurrent.path_next;
 307     }
 308
 309     this.moveto = this.pathcurrent.origin;
 310     this.steerto = steerlib_attract2(this, this.moveto,0.5,500,0.95);
 311     walker_move_to(this, this.moveto, 0);
 312
 313 #else
 314     if(turret_closetotarget(this, this.pathcurrent.origin, 64))
 315         this.pathcurrent = this.pathcurrent.enemy;
 316
 317     if(!this.pathcurrent)
 318         return;
 319
 320     this.moveto = this.pathcurrent.origin;
 321     this.steerto = steerlib_attract2(this, this.moveto, 0.5, 500, 0.95);
 322     walker_move_to(this, this.moveto, 0);
 323 #endif
 324 }
 325
 326 void walker_findtarget(entity this)
 327 {
 328     entity e = find(NULL, targetname, this.target);
 329     if (!e)
 330     {
 331         LOG_TRACE("Initital waypoint for walker does NOT exist, fix your map!");
 332         this.target = "";
 333     }
 334
 335     if (e.classname != "turret_checkpoint")
 336         LOG_TRACE("Warning: not a turrret path");
 337     else
 338     {
 339 #ifdef WALKER_FANCYPATHING
 340         this.pathcurrent = pathlib_astar(this, this.origin, e.origin);
 341         this.pathgoal = e;
 342 #else
 343         this.pathcurrent = e;
 344 #endif
 345     }
 346
 347     // TODO: this doesn't reset target, so tur_defend will be the checkpoint too!
 348 }
 349
 350 spawnfunc(turret_walker) { if(!turret_initialize(this, TUR_WALKER)) delete(this); }
 351
 352 METHOD(WalkerTurret, tr_think, void(WalkerTurret thistur, entity it))
 353 {
 354     fixedmakevectors(it.angles);
 355
 356     if ((it.spawnflags & TSF_NO_PATHBREAK) && it.pathcurrent)
 357         walker_move_path(it);
 358     else if (it.enemy == NULL)
 359     {
 360         if(it.pathcurrent)
 361             walker_move_path(it);
 362         else
 363         {
 364             if(it.enemy_last_time != 0)
 365             {
 366                 if(vdist(it.origin - it.enemy_last_loc, <, 128) || time - it.enemy_last_time > 10)
 367                     it.enemy_last_time = 0;
 368                 else
 369                     walker_move_to(it, it.enemy_last_loc, 0);
 370             }
 371             else
 372             {
 373                 if(it.animflag != ANIM_NO)
 374                 {
 375                     traceline(it.origin + '0 0 64', it.origin + '0 0 64' + v_forward * 128, MOVE_NORMAL, it);
 376
 377                     if(trace_fraction != 1.0)
 378                         it.tur_head.idletime = -1337;
 379                     else
 380                     {
 381                         traceline(trace_endpos, trace_endpos - '0 0 256', MOVE_NORMAL, it);
 382                         if(trace_fraction == 1.0)
 383                             it.tur_head.idletime = -1337;
 384                     }
 385
 386                     if(it.tur_head.idletime == -1337)
 387                     {
 388                         it.moveto = it.origin + randomvec() * 256;
 389                         it.tur_head.idletime = 0;
 390                     }
 391
 392                     it.moveto = it.moveto * 0.9 + ((it.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 393                     it.moveto_z = it.origin_z + 64;
 394                     walker_move_to(it, it.moveto, 0);
 395                 }
 396
 397                 if(it.idletime < time)
 398                 {
 399                     if(random() < 0.5 || !(it.spawnflags & TSL_ROAM))
 400                     {
 401                         it.idletime = time + 1 + random() * 5;
 402                         it.moveto = it.origin;
 403                         it.animflag = ANIM_NO;
 404                     }
 405                     else
 406                     {
 407                         it.animflag = ANIM_WALK;
 408                         it.idletime = time + 4 + random() * 2;
 409                         it.moveto = it.origin + randomvec() * 256;
 410                         it.tur_head.moveto = it.moveto;
 411                         it.tur_head.idletime = 0;
 412                     }
 413                 }
 414             }
 415         }
 416     }
 417     else
 418     {
 419         if (it.tur_dist_enemy < (autocvar_g_turrets_unit_walker_melee_range) && it.animflag != ANIM_MELEE)
 420         {
 421             vector wish_angle;
 422
 423             wish_angle = angleofs(it, it.enemy);
 424             if (it.animflag != ANIM_SWIM)
 425             if (fabs(wish_angle_y) < 15)
 426             {
 427                 it.moveto   = it.enemy.origin;
 428                 it.steerto  = steerlib_attract2(it, it.moveto, 0.5, 500, 0.95);
 429                 it.animflag = ANIM_MELEE;
 430             }
 431         }
 432         else if (it.tur_head.attack_finished_single[0] < time)
 433         {
 434             if(it.tur_head.shot_volly)
 435             {
 436                 it.animflag = ANIM_NO;
 437
 438                 it.tur_head.shot_volly = it.tur_head.shot_volly -1;
 439                 if(it.tur_head.shot_volly == 0)
 440                     it.tur_head.attack_finished_single[0] = time + (autocvar_g_turrets_unit_walker_rocket_refire);
 441                 else
 442                     it.tur_head.attack_finished_single[0] = time + 0.2;
 443
 444                 if(it.tur_head.shot_volly > 1)
 445                     walker_fire_rocket(it, gettaginfo(it, gettagindex(it, "tag_rocket01")));
 446                 else
 447                     walker_fire_rocket(it, gettaginfo(it, gettagindex(it, "tag_rocket02")));
 448             }
 449             else
 450             {
 451                 if (it.tur_dist_enemy > (autocvar_g_turrets_unit_walker_rocket_range_min))
 452                 if (it.tur_dist_enemy < (autocvar_g_turrets_unit_walker_rocket_range))
 453                     it.tur_head.shot_volly = 4;
 454             }
 455         }
 456         else
 457         {
 458             if (it.animflag != ANIM_MELEE)
 459                 walker_move_to(it, it.enemy.origin, it.tur_dist_enemy);
 460         }
 461     }
 462
 463     {
 464         vector real_angle;
 465         float turny = 0, turnx = 0;
 466         float vz;
 467
 468         real_angle = vectoangles(it.steerto) - it.angles;
 469         vz = it.velocity_z;
 470
 471         switch (it.animflag)
 472         {
 473             case ANIM_NO:
 474                 movelib_brake_simple(it, (autocvar_g_turrets_unit_walker_speed_stop));
 475                 break;
 476
 477             case ANIM_TURN:
 478                 turny = (autocvar_g_turrets_unit_walker_turn);
 479                 movelib_brake_simple(it, (autocvar_g_turrets_unit_walker_speed_stop));
 480                 break;
 481
 482             case ANIM_WALK:
 483                 turny = (autocvar_g_turrets_unit_walker_turn_walk);
 484                 movelib_move_simple(it, v_forward, (autocvar_g_turrets_unit_walker_speed_walk), 0.6);
 485                 break;
 486
 487             case ANIM_RUN:
 488                 turny = (autocvar_g_turrets_unit_walker_turn_run);
 489                 movelib_move_simple(it, v_forward, (autocvar_g_turrets_unit_walker_speed_run), 0.6);
 490                 break;
 491
 492             case ANIM_STRAFE_L:
 493                 turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 494                 movelib_move_simple(it, v_right * -1, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 495                 break;
 496
 497             case ANIM_STRAFE_R:
 498                 turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 499                 movelib_move_simple(it, v_right, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 500                 break;
 501
 502             case ANIM_JUMP:
 503                 it.velocity += '0 0 1' * (autocvar_g_turrets_unit_walker_speed_jump);
 504                 break;
 505
 506             case ANIM_LAND:
 507                 break;
 508
 509             case ANIM_PAIN:
 510                 if(it.frame != ANIM_PAIN)
 511                     defer(it, 0.25, walker_setnoanim);
 512
 513                 break;
 514
 515             case ANIM_MELEE:
 516                 if(it.frame != ANIM_MELEE)
 517                 {
 518                     defer(it, 0.41, walker_setnoanim);
 519                     defer(it, 0.21, walker_melee_do_dmg);
 520                 }
 521
 522                 movelib_brake_simple(it, (autocvar_g_turrets_unit_walker_speed_stop));
 523                 break;
 524
 525             case ANIM_SWIM:
 526                 turny = (autocvar_g_turrets_unit_walker_turn_swim);
 527                 turnx = (autocvar_g_turrets_unit_walker_turn_swim);
 528
 529                 it.angles_x += bound(-10, shortangle_f(real_angle_x, it.angles_x), 10);
 530                 movelib_move_simple(it, v_forward, (autocvar_g_turrets_unit_walker_speed_swim), 0.3);
 531                 vz = it.velocity_z + sin(time * 4) * 8;
 532                 break;
 533
 534             case ANIM_ROAM:
 535                 turny = (autocvar_g_turrets_unit_walker_turn_walk);
 536                 movelib_move_simple(it, v_forward ,(autocvar_g_turrets_unit_walker_speed_roam), 0.5);
 537                 break;
 538         }
 539
 540         if(turny)
 541         {
 542             turny = bound( turny * -1, shortangle_f(real_angle_y, it.angles_y), turny );
 543             it.angles_y += turny;
 544         }
 545
 546         if(turnx)
 547         {
 548             turnx = bound( turnx * -1, shortangle_f(real_angle_x, it.angles_x), turnx );
 549             it.angles_x += turnx;
 550         }
 551
 552         it.velocity_z = vz;
 553     }
 554
 555
 556     if(it.origin != it.oldorigin)
 557         it.SendFlags |= TNSF_MOVE;
 558
 559     it.oldorigin = it.origin;
 560     turrets_setframe(it, it.animflag, false);
 561 }
 562 METHOD(WalkerTurret, tr_death, void(WalkerTurret this, entity it))
 563 {
 564 #ifdef WALKER_FANCYPATHING
 565     if (it.pathcurrent)
 566         pathlib_deletepath(it.pathcurrent.owner);
 567 #endif
 568     it.pathcurrent = NULL;
 569 }
 570 METHOD(WalkerTurret, tr_setup, void(WalkerTurret this, entity it))
 571 {
 572     it.ticrate = 0.05;
 573
 574     // Respawn is called & first spawn to, to set team. need to make sure we do not move the initial spawn.
 575     if(it.move_movetype == MOVETYPE_WALK)
 576     {
 577         if(it.pos1)
 578             setorigin(it, it.pos1);
 579         if(it.pos2)
 580             it.angles = it.pos2;
 581     }
 582
 583     it.ammo_flags = TFL_AMMO_BULLETS | TFL_AMMO_RECHARGE | TFL_AMMO_RECIEVE;
 584     it.aim_flags = TFL_AIM_LEAD;
 585     it.turret_flags |= TUR_FLAG_HITSCAN;
 586
 587     it.target_select_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 588     it.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 589     it.iscreature = true;
 590     it.teleportable = TELEPORT_NORMAL;
 591     if(!it.damagedbycontents)
 592         IL_PUSH(g_damagedbycontents, it);
 593     it.damagedbycontents = true;
 594     it.solid = SOLID_SLIDEBOX;
 595     it.takedamage = DAMAGE_AIM;
 596     if(it.move_movetype != MOVETYPE_WALK)
 597     {
 598         setorigin(it, it.origin);
 599         tracebox(it.origin + '0 0 128', it.mins, it.maxs, it.origin - '0 0 10000', MOVE_NORMAL, it);
 600         setorigin(it, trace_endpos + '0 0 4');
 601         it.pos1 = it.origin;
 602         it.pos2 = it.angles;
 603     }
 604     set_movetype(it, MOVETYPE_WALK);
 605     it.idle_aim = '0 0 0';
 606     it.turret_firecheckfunc = walker_firecheck;
 607
 608     if (it.target != "")
 609         InitializeEntity(it, walker_findtarget, INITPRIO_FINDTARGET);
 610 }
 611
 612 #endif // SVQC
 613 #ifdef CSQC
 614
 615 #include <common/physics/movelib.qh>
 616
 617 void walker_draw(entity this)
 618 {
 619     float dt;
 620
 621     dt = time - this.move_time;
 622     this.move_time = time;
 623     if(dt <= 0)
 624         return;
 625
 626     fixedmakevectors(this.angles);
 627     movelib_groundalign4point(this, 300, 100, 0.25, 45);
 628     setorigin(this, this.origin + this.velocity * dt);
 629     this.tur_head.angles += dt * this.tur_head.avelocity;
 630
 631     if(GetResource(this, RES_HEALTH) < 127)
 632     if(random() < 0.15)
 633         te_spark(this.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 634 }
 635
 636 METHOD(WalkerTurret, tr_setup, void(WalkerTurret this, entity it))
 637 {
 638     it.gravity          = 1;
 639     set_movetype(it, MOVETYPE_BOUNCE);
 640     it.move_time                = time;
 641     it.draw                     = walker_draw;
 642 }
 643
 644 #endif // CSQC